Thu, 27 Jun 2013 09:27:06 +0200
8017047: Can't use --with-java-devtools and --with-devkit at the same time
Reviewed-by: tbell
1 #
2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2\
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
46 # Appends a string to a path variable, only adding the : when needed.
47 AC_DEFUN([BASIC_APPEND_TO_PATH],
48 [
49 if test "x[$]$1" = x; then
50 $1="$2"
51 else
52 $1="[$]$1:$2"
53 fi
54 ])
56 # This will make sure the given variable points to a full and proper
57 # path. This means:
58 # 1) There will be no spaces in the path. On posix platforms,
59 # spaces in the path will result in an error. On Windows,
60 # the path will be rewritten using short-style to be space-free.
61 # 2) The path will be absolute, and it will be in unix-style (on
62 # cygwin).
63 # $1: The name of the variable to fix
64 AC_DEFUN([BASIC_FIXUP_PATH],
65 [
66 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
67 BASIC_FIXUP_PATH_CYGWIN($1)
68 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
69 BASIC_FIXUP_PATH_MSYS($1)
70 else
71 # We're on a posix platform. Hooray! :)
72 path="[$]$1"
73 has_space=`$ECHO "$path" | $GREP " "`
74 if test "x$has_space" != x; then
75 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
76 AC_MSG_ERROR([Spaces are not allowed in this path.])
77 fi
79 # Use eval to expand a potential ~
80 eval path="$path"
81 if test ! -f "$path" && test ! -d "$path"; then
82 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
83 fi
85 $1="`cd "$path"; $THEPWDCMD -L`"
86 fi
87 ])
89 # This will make sure the given variable points to a executable
90 # with a full and proper path. This means:
91 # 1) There will be no spaces in the path. On posix platforms,
92 # spaces in the path will result in an error. On Windows,
93 # the path will be rewritten using short-style to be space-free.
94 # 2) The path will be absolute, and it will be in unix-style (on
95 # cygwin).
96 # Any arguments given to the executable is preserved.
97 # If the input variable does not have a directory specification, then
98 # it need to be in the PATH.
99 # $1: The name of the variable to fix
100 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
101 [
102 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
103 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
104 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
105 BASIC_FIXUP_EXECUTABLE_MSYS($1)
106 else
107 # We're on a posix platform. Hooray! :)
108 # First separate the path from the arguments. This will split at the first
109 # space.
110 complete="[$]$1"
111 path="${complete%% *}"
112 tmp="$complete EOL"
113 arguments="${tmp#* }"
115 # Cannot rely on the command "which" here since it doesn't always work.
116 is_absolute_path=`$ECHO "$path" | $GREP ^/`
117 if test -z "$is_absolute_path"; then
118 # Path to executable is not absolute. Find it.
119 IFS_save="$IFS"
120 IFS=:
121 for p in $PATH; do
122 if test -f "$p/$path" && test -x "$p/$path"; then
123 new_path="$p/$path"
124 break
125 fi
126 done
127 IFS="$IFS_save"
128 else
129 AC_MSG_NOTICE([Resolving $1 (as $path) failed, using $path directly.])
130 new_path="$path"
131 fi
133 if test "x$new_path" = x; then
134 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
135 has_space=`$ECHO "$complete" | $GREP " "`
136 if test "x$has_space" != x; then
137 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
138 fi
139 AC_MSG_ERROR([Cannot locate the the path of $1])
140 fi
141 fi
143 # Now join together the path and the arguments once again
144 if test "x$arguments" != xEOL; then
145 new_complete="$new_path ${arguments% *}"
146 else
147 new_complete="$new_path"
148 fi
150 if test "x$complete" != "x$new_complete"; then
151 $1="$new_complete"
152 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
153 fi
154 ])
156 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
157 [
158 if test "x$OPENJDK_BUILD_OS" != xwindows; then
159 # Follow a chain of symbolic links. Use readlink
160 # where it exists, else fall back to horribly
161 # complicated shell code.
162 if test "x$READLINK_TESTED" != yes; then
163 # On MacOSX there is a readlink tool with a different
164 # purpose than the GNU readlink tool. Check the found readlink.
165 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
166 if test "x$ISGNU" = x; then
167 # A readlink that we do not know how to use.
168 # Are there other non-GNU readlinks out there?
169 READLINK_TESTED=yes
170 READLINK=
171 fi
172 fi
174 if test "x$READLINK" != x; then
175 $1=`$READLINK -f [$]$1`
176 else
177 # Save the current directory for restoring afterwards
178 STARTDIR=$PWD
179 COUNTER=0
180 sym_link_dir=`$DIRNAME [$]$1`
181 sym_link_file=`$BASENAME [$]$1`
182 cd $sym_link_dir
183 # Use -P flag to resolve symlinks in directories.
184 cd `$THEPWDCMD -P`
185 sym_link_dir=`$THEPWDCMD -P`
186 # Resolve file symlinks
187 while test $COUNTER -lt 20; do
188 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
189 if test "x$ISLINK" == x; then
190 # This is not a symbolic link! We are done!
191 break
192 fi
193 # Again resolve directory symlinks since the target of the just found
194 # link could be in a different directory
195 cd `$DIRNAME $ISLINK`
196 sym_link_dir=`$THEPWDCMD -P`
197 sym_link_file=`$BASENAME $ISLINK`
198 let COUNTER=COUNTER+1
199 done
200 cd $STARTDIR
201 $1=$sym_link_dir/$sym_link_file
202 fi
203 fi
204 ])
206 AC_DEFUN_ONCE([BASIC_INIT],
207 [
208 # Save the original command line. This is passed to us by the wrapper configure script.
209 AC_SUBST(CONFIGURE_COMMAND_LINE)
210 DATE_WHEN_CONFIGURED=`LANG=C date`
211 AC_SUBST(DATE_WHEN_CONFIGURED)
212 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
213 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
214 ])
216 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
217 # $1: variable to check
218 # $2: executable name to print in warning (optional)
219 AC_DEFUN([BASIC_CHECK_NONEMPTY],
220 [
221 if test "x[$]$1" = x; then
222 if test "x$2" = x; then
223 PROG_NAME=translit($1,A-Z,a-z)
224 else
225 PROG_NAME=$2
226 fi
227 AC_MSG_NOTICE([Could not find $PROG_NAME!])
228 AC_MSG_ERROR([Cannot continue])
229 fi
230 ])
232 # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.
233 # Arguments as AC_PATH_PROG:
234 # $1: variable to set
235 # $2: executable name to look for
236 AC_DEFUN([BASIC_REQUIRE_PROG],
237 [
238 AC_PATH_PROGS($1, $2)
239 BASIC_CHECK_NONEMPTY($1, $2)
240 ])
242 # Setup the most fundamental tools that relies on not much else to set up,
243 # but is used by much of the early bootstrap code.
244 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
245 [
247 # Start with tools that do not need have cross compilation support
248 # and can be expected to be found in the default PATH. These tools are
249 # used by configure. Nor are these tools expected to be found in the
250 # devkit from the builddeps server either, since they are
251 # needed to download the devkit.
253 # First are all the simple required tools.
254 BASIC_REQUIRE_PROG(BASENAME, basename)
255 BASIC_REQUIRE_PROG(BASH, bash)
256 BASIC_REQUIRE_PROG(CAT, cat)
257 BASIC_REQUIRE_PROG(CHMOD, chmod)
258 BASIC_REQUIRE_PROG(CMP, cmp)
259 BASIC_REQUIRE_PROG(COMM, comm)
260 BASIC_REQUIRE_PROG(CP, cp)
261 BASIC_REQUIRE_PROG(CPIO, cpio)
262 BASIC_REQUIRE_PROG(CUT, cut)
263 BASIC_REQUIRE_PROG(DATE, date)
264 BASIC_REQUIRE_PROG(DIFF, [gdiff diff])
265 BASIC_REQUIRE_PROG(DIRNAME, dirname)
266 BASIC_REQUIRE_PROG(ECHO, echo)
267 BASIC_REQUIRE_PROG(EXPR, expr)
268 BASIC_REQUIRE_PROG(FILE, file)
269 BASIC_REQUIRE_PROG(FIND, find)
270 BASIC_REQUIRE_PROG(HEAD, head)
271 BASIC_REQUIRE_PROG(LN, ln)
272 BASIC_REQUIRE_PROG(LS, ls)
273 BASIC_REQUIRE_PROG(MKDIR, mkdir)
274 BASIC_REQUIRE_PROG(MKTEMP, mktemp)
275 BASIC_REQUIRE_PROG(MV, mv)
276 BASIC_REQUIRE_PROG(PRINTF, printf)
277 BASIC_REQUIRE_PROG(RM, rm)
278 BASIC_REQUIRE_PROG(SH, sh)
279 BASIC_REQUIRE_PROG(SORT, sort)
280 BASIC_REQUIRE_PROG(TAIL, tail)
281 BASIC_REQUIRE_PROG(TAR, tar)
282 BASIC_REQUIRE_PROG(TEE, tee)
283 BASIC_REQUIRE_PROG(TOUCH, touch)
284 BASIC_REQUIRE_PROG(TR, tr)
285 BASIC_REQUIRE_PROG(UNAME, uname)
286 BASIC_REQUIRE_PROG(UNIQ, uniq)
287 BASIC_REQUIRE_PROG(WC, wc)
288 BASIC_REQUIRE_PROG(WHICH, which)
289 BASIC_REQUIRE_PROG(XARGS, xargs)
291 # Then required tools that require some special treatment.
292 AC_PROG_AWK
293 BASIC_CHECK_NONEMPTY(AWK)
294 AC_PROG_GREP
295 BASIC_CHECK_NONEMPTY(GREP)
296 AC_PROG_EGREP
297 BASIC_CHECK_NONEMPTY(EGREP)
298 AC_PROG_FGREP
299 BASIC_CHECK_NONEMPTY(FGREP)
300 AC_PROG_SED
301 BASIC_CHECK_NONEMPTY(SED)
303 AC_PATH_PROGS(NAWK, [nawk gawk awk])
304 BASIC_CHECK_NONEMPTY(NAWK)
306 # Always force rm.
307 RM="$RM -f"
309 # pwd behaves differently on various platforms and some don't support the -L flag.
310 # Always use the bash builtin pwd to get uniform behavior.
311 THEPWDCMD=pwd
313 # These are not required on all platforms
314 AC_PATH_PROG(CYGPATH, cygpath)
315 AC_PATH_PROG(READLINK, readlink)
316 AC_PATH_PROG(DF, df)
317 AC_PATH_PROG(SETFILE, SetFile)
318 ])
320 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
321 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
322 [
323 # Locate the directory of this script.
324 SCRIPT="[$]0"
325 AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD -L`
327 # Where is the source? It is located two levels above the configure script.
328 CURDIR="$PWD"
329 cd "$AUTOCONF_DIR/../.."
330 SRC_ROOT="`$THEPWDCMD -L`"
332 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
333 PATH_SEP=";"
334 BASIC_CHECK_PATHS_WINDOWS
335 else
336 PATH_SEP=":"
337 fi
339 AC_SUBST(SRC_ROOT)
340 AC_SUBST(PATH_SEP)
341 cd "$CURDIR"
343 BASIC_FIXUP_PATH(SRC_ROOT)
344 BASIC_FIXUP_PATH(CURDIR)
346 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
347 # Add extra search paths on solaris for utilities like ar and as etc...
348 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
349 fi
351 # You can force the sys-root if the sys-root encoded into the cross compiler tools
352 # is not correct.
353 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
354 [pass this sys-root to the compilers and tools (for cross-compiling)])])
356 if test "x$with_sys_root" != x; then
357 SYS_ROOT=$with_sys_root
358 else
359 SYS_ROOT=/
360 fi
361 AC_SUBST(SYS_ROOT)
363 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
364 [search this directory for compilers and tools (for cross-compiling)])],
365 [TOOLS_DIR=$with_tools_dir
366 BASIC_FIXUP_PATH([TOOLS_DIR])
367 ])
369 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
370 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
371 [
372 if test "x$with_sys_root" != x; then
373 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
374 fi
375 BASIC_FIXUP_PATH([with_devkit])
376 BASIC_APPEND_TO_PATH([TOOLS_DIR],$with_devkit/bin)
377 if test -d "$with_devkit/$host_alias/libc"; then
378 SYS_ROOT=$with_devkit/$host_alias/libc
379 elif test -d "$with_devkit/$host/sys-root"; then
380 SYS_ROOT=$with_devkit/$host/sys-root
381 fi
382 ])
383 ])
385 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
386 [
388 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
389 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
390 [ CONF_NAME=${with_conf_name} ])
392 # Test from where we are running configure, in or outside of src root.
393 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
394 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
395 || test "x$CURDIR" = "x$SRC_ROOT/common/makefiles" ; then
396 # We are running configure from the src root.
397 # Create a default ./build/target-variant-debuglevel output root.
398 if test "x${CONF_NAME}" = x; then
399 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
400 fi
401 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
402 $MKDIR -p "$OUTPUT_ROOT"
403 if test ! -d "$OUTPUT_ROOT"; then
404 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
405 fi
406 else
407 # We are running configure from outside of the src dir.
408 # Then use the current directory as output dir!
409 # If configuration is situated in normal build directory, just use the build
410 # directory name as configuration name, otherwise use the complete path.
411 if test "x${CONF_NAME}" = x; then
412 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
413 fi
414 OUTPUT_ROOT="$CURDIR"
416 # WARNING: This might be a bad thing to do. You need to be sure you want to
417 # have a configuration in this directory. Do some sanity checks!
419 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
420 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
421 # other files
422 files_present=`$LS $OUTPUT_ROOT`
423 # Configure has already touched config.log and confdefs.h in the current dir when this check
424 # is performed.
425 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
426 | $TR -d '\n'`
427 if test "x$filtered_files" != x; then
428 AC_MSG_NOTICE([Current directory is $CURDIR.])
429 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
430 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
431 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
432 AC_MSG_NOTICE([seriously mess up just about everything.])
433 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
434 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
435 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
436 fi
437 fi
438 fi
439 AC_MSG_CHECKING([what configuration name to use])
440 AC_MSG_RESULT([$CONF_NAME])
442 BASIC_FIXUP_PATH(OUTPUT_ROOT)
444 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
445 AC_SUBST(CONF_NAME, $CONF_NAME)
446 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
448 # Most of the probed defines are put into config.h
449 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
450 # The spec.gmk file contains all variables for the make system.
451 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
452 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
453 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
454 # The bootcycle-spec.gmk file contains support for boot cycle builds.
455 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
456 # The compare.sh is used to compare the build output to other builds.
457 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
458 # Spec.sh is currently used by compare-objects.sh
459 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
460 # The generated Makefile knows where the spec.gmk is and where the source is.
461 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
462 # which will look for generated configurations
463 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
465 # Save the arguments given to us
466 echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
467 ])
469 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
470 [
471 # Setup default logging of stdout and stderr to build.log in the output root.
472 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
473 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
474 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
475 AC_SUBST(BUILD_LOG)
476 AC_SUBST(BUILD_LOG_PREVIOUS)
477 AC_SUBST(BUILD_LOG_WRAPPER)
478 ])
481 #%%% Simple tools %%%
483 # Check if we have found a usable version of make
484 # $1: the path to a potential make binary (or empty)
485 # $2: the description on how we found this
486 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
487 [
488 MAKE_CANDIDATE="$1"
489 DESCRIPTION="$2"
490 if test "x$MAKE_CANDIDATE" != x; then
491 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
492 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
493 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
494 if test "x$IS_GNU_MAKE" = x; then
495 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
496 else
497 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP '3.8[[12346789]]'`
498 if test "x$IS_MODERN_MAKE" = x; then
499 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
500 else
501 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
502 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
503 MAKE_EXPECTED_ENV='cygwin'
504 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
505 MAKE_EXPECTED_ENV='msys'
506 else
507 AC_MSG_ERROR([Unknown Windows environment])
508 fi
509 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
510 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
511 else
512 # Not relevant for non-Windows
513 IS_MAKE_CORRECT_ENV=true
514 fi
515 if test "x$IS_MAKE_CORRECT_ENV" = x; then
516 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
517 else
518 FOUND_MAKE=$MAKE_CANDIDATE
519 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
520 fi
521 fi
522 fi
523 fi
524 ])
526 # Goes looking for a usable version of GNU make.
527 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
528 [
529 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
530 if test "x$MAKE" != x; then
531 # User has supplied a make, test it.
532 if test ! -f "$MAKE"; then
533 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
534 fi
535 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
536 if test "x$FOUND_MAKE" = x; then
537 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
538 fi
539 else
540 # Try our hardest to locate a correct version of GNU make
541 AC_PATH_PROGS(CHECK_GMAKE, gmake)
542 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
544 if test "x$FOUND_MAKE" = x; then
545 AC_PATH_PROGS(CHECK_MAKE, make)
546 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
547 fi
549 if test "x$FOUND_MAKE" = x; then
550 if test "x$TOOLS_DIR" != x; then
551 # We have a tools-dir, check that as well before giving up.
552 OLD_PATH=$PATH
553 PATH=$TOOLS_DIR:$PATH
554 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
555 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
556 if test "x$FOUND_MAKE" = x; then
557 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
558 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
559 fi
560 PATH=$OLD_PATH
561 fi
562 fi
564 if test "x$FOUND_MAKE" = x; then
565 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
566 fi
567 fi
569 MAKE=$FOUND_MAKE
570 AC_SUBST(MAKE)
571 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
572 ])
574 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
575 [
576 # Test if find supports -delete
577 AC_MSG_CHECKING([if find supports -delete])
578 FIND_DELETE="-delete"
580 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
582 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
584 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
585 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
586 # No, it does not.
587 rm $DELETEDIR/TestIfFindSupportsDelete
588 FIND_DELETE="-exec rm \{\} \+"
589 AC_MSG_RESULT([no])
590 else
591 AC_MSG_RESULT([yes])
592 fi
593 rmdir $DELETEDIR
594 AC_SUBST(FIND_DELETE)
595 ])
597 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
598 [
599 BASIC_CHECK_GNU_MAKE
601 BASIC_CHECK_FIND_DELETE
603 # These tools might not be installed by default,
604 # need hint on how to install them.
605 BASIC_REQUIRE_PROG(UNZIP, unzip)
606 BASIC_REQUIRE_PROG(ZIP, zip)
608 # Non-required basic tools
610 AC_PATH_PROG(LDD, ldd)
611 if test "x$LDD" = "x"; then
612 # List shared lib dependencies is used for
613 # debug output and checking for forbidden dependencies.
614 # We can build without it.
615 LDD="true"
616 fi
617 AC_PATH_PROG(OTOOL, otool)
618 if test "x$OTOOL" = "x"; then
619 OTOOL="true"
620 fi
621 AC_PATH_PROGS(READELF, [readelf greadelf])
622 AC_PATH_PROG(HG, hg)
623 AC_PATH_PROG(STAT, stat)
624 AC_PATH_PROG(TIME, time)
626 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
627 BASIC_REQUIRE_PROG(COMM, comm)
628 fi
630 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
631 BASIC_REQUIRE_PROG(XATTR, xattr)
632 AC_PATH_PROG(CODESIGN, codesign)
633 if test "x$CODESIGN" != "x"; then
634 # Verify that the openjdk_codesign certificate is present
635 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
636 rm -f codesign-testfile
637 touch codesign-testfile
638 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
639 rm -f codesign-testfile
640 if test "x$CODESIGN" = x; then
641 AC_MSG_RESULT([no])
642 else
643 AC_MSG_RESULT([yes])
644 fi
645 fi
646 fi
647 ])
649 # Check if build directory is on local disk. If not possible to determine,
650 # we prefer to claim it's local.
651 # Argument 1: directory to test
652 # Argument 2: what to do if it is on local disk
653 # Argument 3: what to do otherwise (remote disk or failure)
654 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
655 [
656 # df -l lists only local disks; if the given directory is not found then
657 # a non-zero exit code is given
658 if test "x$DF" = x; then
659 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
660 # msys does not have df; use Windows "net use" instead.
661 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
662 if test "x$IS_NETWORK_DISK" = x; then
663 $2
664 else
665 $3
666 fi
667 else
668 # No df here, say it's local
669 $2
670 fi
671 else
672 if $DF -l $1 > /dev/null 2>&1; then
673 $2
674 else
675 $3
676 fi
677 fi
678 ])
680 # Check that source files have basic read permissions set. This might
681 # not be the case in cygwin in certain conditions.
682 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
683 [
684 if test x"$OPENJDK_BUILD_OS" = xwindows; then
685 file_to_test="$SRC_ROOT/LICENSE"
686 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
687 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
688 fi
689 fi
690 ])
692 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
693 [
695 AC_MSG_CHECKING([if build directory is on local disk])
696 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
697 [OUTPUT_DIR_IS_LOCAL="yes"],
698 [OUTPUT_DIR_IS_LOCAL="no"])
699 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
701 BASIC_CHECK_SRC_PERMS
703 # Check if the user has any old-style ALT_ variables set.
704 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
706 # Before generating output files, test if they exist. If they do, this is a reconfigure.
707 # Since we can't properly handle the dependencies for this, warn the user about the situation
708 if test -e $OUTPUT_ROOT/spec.gmk; then
709 IS_RECONFIGURE=yes
710 else
711 IS_RECONFIGURE=no
712 fi
714 if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then
715 HIDE_PERFORMANCE_HINTS=yes
716 else
717 HIDE_PERFORMANCE_HINTS=no
718 # Hide it the next time around...
719 $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1
720 fi
722 ])