Tue, 18 Jun 2013 11:30:36 +0200
8015377: Support using compiler devkits on Linux
Reviewed-by: tbell, dholmes
1 #
2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2\
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
46 # This will make sure the given variable points to a full and proper
47 # path. This means:
48 # 1) There will be no spaces in the path. On posix platforms,
49 # spaces in the path will result in an error. On Windows,
50 # the path will be rewritten using short-style to be space-free.
51 # 2) The path will be absolute, and it will be in unix-style (on
52 # cygwin).
53 # $1: The name of the variable to fix
54 AC_DEFUN([BASIC_FIXUP_PATH],
55 [
56 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
57 BASIC_FIXUP_PATH_CYGWIN($1)
58 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
59 BASIC_FIXUP_PATH_MSYS($1)
60 else
61 # We're on a posix platform. Hooray! :)
62 path="[$]$1"
63 has_space=`$ECHO "$path" | $GREP " "`
64 if test "x$has_space" != x; then
65 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
66 AC_MSG_ERROR([Spaces are not allowed in this path.])
67 fi
69 # Use eval to expand a potential ~
70 eval path="$path"
71 if test ! -f "$path" && test ! -d "$path"; then
72 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
73 fi
75 $1="`cd "$path"; $THEPWDCMD -L`"
76 fi
77 ])
79 # This will make sure the given variable points to a executable
80 # with a full and proper path. This means:
81 # 1) There will be no spaces in the path. On posix platforms,
82 # spaces in the path will result in an error. On Windows,
83 # the path will be rewritten using short-style to be space-free.
84 # 2) The path will be absolute, and it will be in unix-style (on
85 # cygwin).
86 # Any arguments given to the executable is preserved.
87 # If the input variable does not have a directory specification, then
88 # it need to be in the PATH.
89 # $1: The name of the variable to fix
90 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
91 [
92 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
93 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
94 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
95 BASIC_FIXUP_EXECUTABLE_MSYS($1)
96 else
97 # We're on a posix platform. Hooray! :)
98 # First separate the path from the arguments. This will split at the first
99 # space.
100 complete="[$]$1"
101 path="${complete%% *}"
102 tmp="$complete EOL"
103 arguments="${tmp#* }"
105 # Cannot rely on the command "which" here since it doesn't always work.
106 is_absolute_path=`$ECHO "$path" | $GREP ^/`
107 if test -z "$is_absolute_path"; then
108 # Path to executable is not absolute. Find it.
109 IFS_save="$IFS"
110 IFS=:
111 for p in $PATH; do
112 if test -f "$p/$path" && test -x "$p/$path"; then
113 new_path="$p/$path"
114 break
115 fi
116 done
117 IFS="$IFS_save"
118 else
119 AC_MSG_NOTICE([Resolving $1 (as $path) failed, using $path directly.])
120 new_path="$path"
121 fi
123 if test "x$new_path" = x; then
124 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
125 has_space=`$ECHO "$complete" | $GREP " "`
126 if test "x$has_space" != x; then
127 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
128 fi
129 AC_MSG_ERROR([Cannot locate the the path of $1])
130 fi
131 fi
133 # Now join together the path and the arguments once again
134 if test "x$arguments" != xEOL; then
135 new_complete="$new_path ${arguments% *}"
136 else
137 new_complete="$new_path"
138 fi
140 if test "x$complete" != "x$new_complete"; then
141 $1="$new_complete"
142 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
143 fi
144 ])
146 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
147 [
148 if test "x$OPENJDK_BUILD_OS" != xwindows; then
149 # Follow a chain of symbolic links. Use readlink
150 # where it exists, else fall back to horribly
151 # complicated shell code.
152 if test "x$READLINK_TESTED" != yes; then
153 # On MacOSX there is a readlink tool with a different
154 # purpose than the GNU readlink tool. Check the found readlink.
155 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
156 if test "x$ISGNU" = x; then
157 # A readlink that we do not know how to use.
158 # Are there other non-GNU readlinks out there?
159 READLINK_TESTED=yes
160 READLINK=
161 fi
162 fi
164 if test "x$READLINK" != x; then
165 $1=`$READLINK -f [$]$1`
166 else
167 # Save the current directory for restoring afterwards
168 STARTDIR=$PWD
169 COUNTER=0
170 sym_link_dir=`$DIRNAME [$]$1`
171 sym_link_file=`$BASENAME [$]$1`
172 cd $sym_link_dir
173 # Use -P flag to resolve symlinks in directories.
174 cd `$THEPWDCMD -P`
175 sym_link_dir=`$THEPWDCMD -P`
176 # Resolve file symlinks
177 while test $COUNTER -lt 20; do
178 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
179 if test "x$ISLINK" == x; then
180 # This is not a symbolic link! We are done!
181 break
182 fi
183 # Again resolve directory symlinks since the target of the just found
184 # link could be in a different directory
185 cd `$DIRNAME $ISLINK`
186 sym_link_dir=`$THEPWDCMD -P`
187 sym_link_file=`$BASENAME $ISLINK`
188 let COUNTER=COUNTER+1
189 done
190 cd $STARTDIR
191 $1=$sym_link_dir/$sym_link_file
192 fi
193 fi
194 ])
196 AC_DEFUN_ONCE([BASIC_INIT],
197 [
198 # Save the original command line. This is passed to us by the wrapper configure script.
199 AC_SUBST(CONFIGURE_COMMAND_LINE)
200 DATE_WHEN_CONFIGURED=`LANG=C date`
201 AC_SUBST(DATE_WHEN_CONFIGURED)
202 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
203 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
204 ])
206 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
207 # $1: variable to check
208 # $2: executable name to print in warning (optional)
209 AC_DEFUN([BASIC_CHECK_NONEMPTY],
210 [
211 if test "x[$]$1" = x; then
212 if test "x$2" = x; then
213 PROG_NAME=translit($1,A-Z,a-z)
214 else
215 PROG_NAME=$2
216 fi
217 AC_MSG_NOTICE([Could not find $PROG_NAME!])
218 AC_MSG_ERROR([Cannot continue])
219 fi
220 ])
222 # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.
223 # Arguments as AC_PATH_PROG:
224 # $1: variable to set
225 # $2: executable name to look for
226 AC_DEFUN([BASIC_REQUIRE_PROG],
227 [
228 AC_PATH_PROGS($1, $2)
229 BASIC_CHECK_NONEMPTY($1, $2)
230 ])
232 # Setup the most fundamental tools that relies on not much else to set up,
233 # but is used by much of the early bootstrap code.
234 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
235 [
237 # Start with tools that do not need have cross compilation support
238 # and can be expected to be found in the default PATH. These tools are
239 # used by configure. Nor are these tools expected to be found in the
240 # devkit from the builddeps server either, since they are
241 # needed to download the devkit.
243 # First are all the simple required tools.
244 BASIC_REQUIRE_PROG(BASENAME, basename)
245 BASIC_REQUIRE_PROG(BASH, bash)
246 BASIC_REQUIRE_PROG(CAT, cat)
247 BASIC_REQUIRE_PROG(CHMOD, chmod)
248 BASIC_REQUIRE_PROG(CMP, cmp)
249 BASIC_REQUIRE_PROG(COMM, comm)
250 BASIC_REQUIRE_PROG(CP, cp)
251 BASIC_REQUIRE_PROG(CPIO, cpio)
252 BASIC_REQUIRE_PROG(CUT, cut)
253 BASIC_REQUIRE_PROG(DATE, date)
254 BASIC_REQUIRE_PROG(DIFF, [gdiff diff])
255 BASIC_REQUIRE_PROG(DIRNAME, dirname)
256 BASIC_REQUIRE_PROG(ECHO, echo)
257 BASIC_REQUIRE_PROG(EXPR, expr)
258 BASIC_REQUIRE_PROG(FILE, file)
259 BASIC_REQUIRE_PROG(FIND, find)
260 BASIC_REQUIRE_PROG(HEAD, head)
261 BASIC_REQUIRE_PROG(LN, ln)
262 BASIC_REQUIRE_PROG(LS, ls)
263 BASIC_REQUIRE_PROG(MKDIR, mkdir)
264 BASIC_REQUIRE_PROG(MKTEMP, mktemp)
265 BASIC_REQUIRE_PROG(MV, mv)
266 BASIC_REQUIRE_PROG(PRINTF, printf)
267 BASIC_REQUIRE_PROG(RM, rm)
268 BASIC_REQUIRE_PROG(SH, sh)
269 BASIC_REQUIRE_PROG(SORT, sort)
270 BASIC_REQUIRE_PROG(TAIL, tail)
271 BASIC_REQUIRE_PROG(TAR, tar)
272 BASIC_REQUIRE_PROG(TEE, tee)
273 BASIC_REQUIRE_PROG(TOUCH, touch)
274 BASIC_REQUIRE_PROG(TR, tr)
275 BASIC_REQUIRE_PROG(UNAME, uname)
276 BASIC_REQUIRE_PROG(UNIQ, uniq)
277 BASIC_REQUIRE_PROG(WC, wc)
278 BASIC_REQUIRE_PROG(WHICH, which)
279 BASIC_REQUIRE_PROG(XARGS, xargs)
281 # Then required tools that require some special treatment.
282 AC_PROG_AWK
283 BASIC_CHECK_NONEMPTY(AWK)
284 AC_PROG_GREP
285 BASIC_CHECK_NONEMPTY(GREP)
286 AC_PROG_EGREP
287 BASIC_CHECK_NONEMPTY(EGREP)
288 AC_PROG_FGREP
289 BASIC_CHECK_NONEMPTY(FGREP)
290 AC_PROG_SED
291 BASIC_CHECK_NONEMPTY(SED)
293 AC_PATH_PROGS(NAWK, [nawk gawk awk])
294 BASIC_CHECK_NONEMPTY(NAWK)
296 # Always force rm.
297 RM="$RM -f"
299 # pwd behaves differently on various platforms and some don't support the -L flag.
300 # Always use the bash builtin pwd to get uniform behavior.
301 THEPWDCMD=pwd
303 # These are not required on all platforms
304 AC_PATH_PROG(CYGPATH, cygpath)
305 AC_PATH_PROG(READLINK, readlink)
306 AC_PATH_PROG(DF, df)
307 AC_PATH_PROG(SETFILE, SetFile)
308 ])
310 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
311 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
312 [
313 # Locate the directory of this script.
314 SCRIPT="[$]0"
315 AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD -L`
317 # Where is the source? It is located two levels above the configure script.
318 CURDIR="$PWD"
319 cd "$AUTOCONF_DIR/../.."
320 SRC_ROOT="`$THEPWDCMD -L`"
322 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
323 PATH_SEP=";"
324 BASIC_CHECK_PATHS_WINDOWS
325 else
326 PATH_SEP=":"
327 fi
329 AC_SUBST(SRC_ROOT)
330 AC_SUBST(PATH_SEP)
331 cd "$CURDIR"
333 BASIC_FIXUP_PATH(SRC_ROOT)
334 BASIC_FIXUP_PATH(CURDIR)
336 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
337 # Add extra search paths on solaris for utilities like ar and as etc...
338 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
339 fi
341 # You can force the sys-root if the sys-root encoded into the cross compiler tools
342 # is not correct.
343 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
344 [pass this sys-root to the compilers and tools (for cross-compiling)])])
346 if test "x$with_sys_root" != x; then
347 SYS_ROOT=$with_sys_root
348 else
349 SYS_ROOT=/
350 fi
351 AC_SUBST(SYS_ROOT)
353 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
354 [search this directory for compilers and tools (for cross-compiling)])], [TOOLS_DIR=$with_tools_dir])
356 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
357 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
358 [
359 if test "x$with_sys_root" != x; then
360 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
361 fi
362 if test "x$with_tools_dir" != x; then
363 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-tools-dir at the same time])
364 fi
365 TOOLS_DIR=$with_devkit/bin
366 if test -d "$with_devkit/$host_alias/libc"; then
367 SYS_ROOT=$with_devkit/$host_alias/libc
368 elif test -d "$with_devkit/$host/sys-root"; then
369 SYS_ROOT=$with_devkit/$host/sys-root
370 fi
371 ])
373 ])
375 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
376 [
378 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
379 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
380 [ CONF_NAME=${with_conf_name} ])
382 # Test from where we are running configure, in or outside of src root.
383 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
384 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
385 || test "x$CURDIR" = "x$SRC_ROOT/common/makefiles" ; then
386 # We are running configure from the src root.
387 # Create a default ./build/target-variant-debuglevel output root.
388 if test "x${CONF_NAME}" = x; then
389 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
390 fi
391 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
392 $MKDIR -p "$OUTPUT_ROOT"
393 if test ! -d "$OUTPUT_ROOT"; then
394 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
395 fi
396 else
397 # We are running configure from outside of the src dir.
398 # Then use the current directory as output dir!
399 # If configuration is situated in normal build directory, just use the build
400 # directory name as configuration name, otherwise use the complete path.
401 if test "x${CONF_NAME}" = x; then
402 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
403 fi
404 OUTPUT_ROOT="$CURDIR"
406 # WARNING: This might be a bad thing to do. You need to be sure you want to
407 # have a configuration in this directory. Do some sanity checks!
409 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
410 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
411 # other files
412 files_present=`$LS $OUTPUT_ROOT`
413 # Configure has already touched config.log and confdefs.h in the current dir when this check
414 # is performed.
415 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
416 | $TR -d '\n'`
417 if test "x$filtered_files" != x; then
418 AC_MSG_NOTICE([Current directory is $CURDIR.])
419 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
420 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
421 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
422 AC_MSG_NOTICE([seriously mess up just about everything.])
423 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
424 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
425 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
426 fi
427 fi
428 fi
429 AC_MSG_CHECKING([what configuration name to use])
430 AC_MSG_RESULT([$CONF_NAME])
432 BASIC_FIXUP_PATH(OUTPUT_ROOT)
434 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
435 AC_SUBST(CONF_NAME, $CONF_NAME)
436 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
438 # Most of the probed defines are put into config.h
439 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
440 # The spec.gmk file contains all variables for the make system.
441 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
442 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
443 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
444 # The bootcycle-spec.gmk file contains support for boot cycle builds.
445 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
446 # The compare.sh is used to compare the build output to other builds.
447 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
448 # Spec.sh is currently used by compare-objects.sh
449 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
450 # The generated Makefile knows where the spec.gmk is and where the source is.
451 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
452 # which will look for generated configurations
453 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
455 # Save the arguments given to us
456 echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
457 ])
459 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
460 [
461 # Setup default logging of stdout and stderr to build.log in the output root.
462 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
463 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
464 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
465 AC_SUBST(BUILD_LOG)
466 AC_SUBST(BUILD_LOG_PREVIOUS)
467 AC_SUBST(BUILD_LOG_WRAPPER)
468 ])
471 #%%% Simple tools %%%
473 # Check if we have found a usable version of make
474 # $1: the path to a potential make binary (or empty)
475 # $2: the description on how we found this
476 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
477 [
478 MAKE_CANDIDATE="$1"
479 DESCRIPTION="$2"
480 if test "x$MAKE_CANDIDATE" != x; then
481 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
482 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
483 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
484 if test "x$IS_GNU_MAKE" = x; then
485 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
486 else
487 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP '3.8[[12346789]]'`
488 if test "x$IS_MODERN_MAKE" = x; then
489 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
490 else
491 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
492 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
493 MAKE_EXPECTED_ENV='cygwin'
494 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
495 MAKE_EXPECTED_ENV='msys'
496 else
497 AC_MSG_ERROR([Unknown Windows environment])
498 fi
499 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
500 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
501 else
502 # Not relevant for non-Windows
503 IS_MAKE_CORRECT_ENV=true
504 fi
505 if test "x$IS_MAKE_CORRECT_ENV" = x; then
506 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
507 else
508 FOUND_MAKE=$MAKE_CANDIDATE
509 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
510 fi
511 fi
512 fi
513 fi
514 ])
516 # Goes looking for a usable version of GNU make.
517 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
518 [
519 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
520 if test "x$MAKE" != x; then
521 # User has supplied a make, test it.
522 if test ! -f "$MAKE"; then
523 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
524 fi
525 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
526 if test "x$FOUND_MAKE" = x; then
527 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
528 fi
529 else
530 # Try our hardest to locate a correct version of GNU make
531 AC_PATH_PROGS(CHECK_GMAKE, gmake)
532 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
534 if test "x$FOUND_MAKE" = x; then
535 AC_PATH_PROGS(CHECK_MAKE, make)
536 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
537 fi
539 if test "x$FOUND_MAKE" = x; then
540 if test "x$TOOLS_DIR" != x; then
541 # We have a tools-dir, check that as well before giving up.
542 OLD_PATH=$PATH
543 PATH=$TOOLS_DIR:$PATH
544 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
545 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
546 if test "x$FOUND_MAKE" = x; then
547 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
548 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
549 fi
550 PATH=$OLD_PATH
551 fi
552 fi
554 if test "x$FOUND_MAKE" = x; then
555 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
556 fi
557 fi
559 MAKE=$FOUND_MAKE
560 AC_SUBST(MAKE)
561 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
562 ])
564 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
565 [
566 # Test if find supports -delete
567 AC_MSG_CHECKING([if find supports -delete])
568 FIND_DELETE="-delete"
570 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
572 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
574 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
575 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
576 # No, it does not.
577 rm $DELETEDIR/TestIfFindSupportsDelete
578 FIND_DELETE="-exec rm \{\} \+"
579 AC_MSG_RESULT([no])
580 else
581 AC_MSG_RESULT([yes])
582 fi
583 rmdir $DELETEDIR
584 AC_SUBST(FIND_DELETE)
585 ])
587 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
588 [
589 BASIC_CHECK_GNU_MAKE
591 BASIC_CHECK_FIND_DELETE
593 # These tools might not be installed by default,
594 # need hint on how to install them.
595 BASIC_REQUIRE_PROG(UNZIP, unzip)
596 BASIC_REQUIRE_PROG(ZIP, zip)
598 # Non-required basic tools
600 AC_PATH_PROG(LDD, ldd)
601 if test "x$LDD" = "x"; then
602 # List shared lib dependencies is used for
603 # debug output and checking for forbidden dependencies.
604 # We can build without it.
605 LDD="true"
606 fi
607 AC_PATH_PROG(OTOOL, otool)
608 if test "x$OTOOL" = "x"; then
609 OTOOL="true"
610 fi
611 AC_PATH_PROGS(READELF, [readelf greadelf])
612 AC_PATH_PROG(HG, hg)
613 AC_PATH_PROG(STAT, stat)
614 AC_PATH_PROG(TIME, time)
616 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
617 BASIC_REQUIRE_PROG(COMM, comm)
618 fi
620 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
621 BASIC_REQUIRE_PROG(XATTR, xattr)
622 AC_PATH_PROG(CODESIGN, codesign)
623 if test "x$CODESIGN" != "x"; then
624 # Verify that the openjdk_codesign certificate is present
625 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
626 rm -f codesign-testfile
627 touch codesign-testfile
628 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
629 rm -f codesign-testfile
630 if test "x$CODESIGN" = x; then
631 AC_MSG_RESULT([no])
632 else
633 AC_MSG_RESULT([yes])
634 fi
635 fi
636 fi
637 ])
639 # Check if build directory is on local disk. If not possible to determine,
640 # we prefer to claim it's local.
641 # Argument 1: directory to test
642 # Argument 2: what to do if it is on local disk
643 # Argument 3: what to do otherwise (remote disk or failure)
644 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
645 [
646 # df -l lists only local disks; if the given directory is not found then
647 # a non-zero exit code is given
648 if test "x$DF" = x; then
649 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
650 # msys does not have df; use Windows "net use" instead.
651 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
652 if test "x$IS_NETWORK_DISK" = x; then
653 $2
654 else
655 $3
656 fi
657 else
658 # No df here, say it's local
659 $2
660 fi
661 else
662 if $DF -l $1 > /dev/null 2>&1; then
663 $2
664 else
665 $3
666 fi
667 fi
668 ])
670 # Check that source files have basic read permissions set. This might
671 # not be the case in cygwin in certain conditions.
672 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
673 [
674 if test x"$OPENJDK_BUILD_OS" = xwindows; then
675 file_to_test="$SRC_ROOT/LICENSE"
676 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
677 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
678 fi
679 fi
680 ])
682 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
683 [
685 AC_MSG_CHECKING([if build directory is on local disk])
686 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
687 [OUTPUT_DIR_IS_LOCAL="yes"],
688 [OUTPUT_DIR_IS_LOCAL="no"])
689 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
691 BASIC_CHECK_SRC_PERMS
693 # Check if the user has any old-style ALT_ variables set.
694 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
696 # Before generating output files, test if they exist. If they do, this is a reconfigure.
697 # Since we can't properly handle the dependencies for this, warn the user about the situation
698 if test -e $OUTPUT_ROOT/spec.gmk; then
699 IS_RECONFIGURE=yes
700 else
701 IS_RECONFIGURE=no
702 fi
704 if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then
705 HIDE_PERFORMANCE_HINTS=yes
706 else
707 HIDE_PERFORMANCE_HINTS=no
708 # Hide it the next time around...
709 $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1
710 fi
712 ])