jdk8-mips64-public: common/autoconf/build-performance.m4@f3697e0783e2

1 #

     2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 AC_DEFUN([BPERF_CHECK_CORES],

    27 [

    28   AC_MSG_CHECKING([for number of cores])

    29   NUM_CORES=1

    30   FOUND_CORES=no

    32   if test -f /proc/cpuinfo; then

    33     # Looks like a Linux (or cygwin) system

    34     NUM_CORES=`cat /proc/cpuinfo  | grep -c processor`

    35     FOUND_CORES=yes

    36   elif test -x /usr/sbin/psrinfo; then

    37     # Looks like a Solaris system

    38     NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`

    39     FOUND_CORES=yes

    40   elif test -x /usr/sbin/system_profiler; then

    41     # Looks like a MacOSX system

    42     NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk  '{print [$]5}'`

    43     FOUND_CORES=yes

    44   elif test "x$OPENJDK_BUILD_OS" = xaix ; then

    45     NUM_CORES=`/usr/sbin/prtconf | grep "^Number Of Processors" | awk '{ print [$]4 }'`

    46     FOUND_CORES=yes

    47   elif test -n "$NUMBER_OF_PROCESSORS"; then

    48     # On windows, look in the env

    49     NUM_CORES=$NUMBER_OF_PROCESSORS

    50     FOUND_CORES=yes

    51   fi

    53   if test "x$FOUND_CORES" = xyes; then

    54     AC_MSG_RESULT([$NUM_CORES])

    55   else

    56     AC_MSG_RESULT([could not detect number of cores, defaulting to 1])

    57     AC_MSG_WARN([This will disable all parallelism from build!])

    58   fi

    59 ])

    61 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],

    62 [

    63   AC_MSG_CHECKING([for memory size])

    64   # Default to 1024 MB

    65   MEMORY_SIZE=1024

    66   FOUND_MEM=no

    68   if test -f /proc/meminfo; then

    69     # Looks like a Linux (or cygwin) system

    70     MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`

    71     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`

    72     FOUND_MEM=yes

    73   elif test -x /usr/sbin/prtconf; then

    74     # Looks like a Solaris or AIX system

    75     MEMORY_SIZE=`/usr/sbin/prtconf | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`

    76     FOUND_MEM=yes

    77   elif test -x /usr/sbin/system_profiler; then

    78     # Looks like a MacOSX system

    79     MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk  '{print [$]2}'`

    80     MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`

    81     FOUND_MEM=yes

    82   elif test "x$OPENJDK_BUILD_OS" = xwindows; then

    83     # Windows, but without cygwin

    84     MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`

    85     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`

    86     FOUND_MEM=yes

    87   fi

    89   if test "x$FOUND_MEM" = xyes; then

    90     AC_MSG_RESULT([$MEMORY_SIZE MB])

    91   else

    92     AC_MSG_RESULT([could not detect memory size, defaulting to 1024 MB])

    93     AC_MSG_WARN([This might seriously impact build performance!])

    94   fi

    95 ])

    97 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],

    98 [

    99   # How many cores do we have on this build system?

   100   AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],

   101       [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])

   102   if test "x$with_num_cores" = x; then

   103     # The number of cores were not specified, try to probe them.

   104     BPERF_CHECK_CORES

   105   else

   106     NUM_CORES=$with_num_cores

   107   fi

   108   AC_SUBST(NUM_CORES)

   109 ])

   111 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],

   112 [

   113   # How much memory do we have on this build system?

   114   AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],

   115       [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])

   116   if test "x$with_memory_size" = x; then

   117     # The memory size was not specified, try to probe it.

   118     BPERF_CHECK_MEMORY_SIZE

   119   else

   120     MEMORY_SIZE=$with_memory_size

   121   fi

   122   AC_SUBST(MEMORY_SIZE)

   123 ])

   125 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],

   126 [

   127   # Provide a decent default number of parallel jobs for make depending on

   128   # number of cores, amount of memory and machine architecture.

   129   AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],

   130       [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])

   131   if test "x$with_jobs" = x; then

   132     # Number of jobs was not specified, calculate.

   133     AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])

   134     # Approximate memory in GB, rounding up a bit.

   135     memory_gb=`expr $MEMORY_SIZE / 1100`

   136     # Pick the lowest of memory in gb and number of cores.

   137     if test "$memory_gb" -lt "$NUM_CORES"; then

   138       JOBS="$memory_gb"

   139     else

   140       JOBS="$NUM_CORES"

   141       # On bigger machines, leave some room for other processes to run

   142       if test "$JOBS" -gt "4"; then

   143         JOBS=`expr $JOBS '*' 90 / 100`

   144       fi

   145     fi

   146     # Cap number of jobs to 16

   147     if test "$JOBS" -gt "16"; then

   148       JOBS=16

   149     fi

   150     if test "$JOBS" -eq "0"; then

   151       JOBS=1

   152     fi

   153     AC_MSG_RESULT([$JOBS])

   154   else

   155     JOBS=$with_jobs

   156   fi

   157   AC_SUBST(JOBS)

   158 ])

   160 AC_DEFUN([BPERF_SETUP_CCACHE],

   161 [

   162   AC_ARG_ENABLE([ccache],

   163       [AS_HELP_STRING([--disable-ccache],

   164       [disable using ccache to speed up recompilations @<:@enabled@:>@])],

   165       [ENABLE_CCACHE=${enable_ccache}], [ENABLE_CCACHE=yes])

   166   if test "x$ENABLE_CCACHE" = xyes; then

   167     OLD_PATH="$PATH"

   168     if test "x$TOOLS_DIR" != x; then

   169       PATH=$TOOLS_DIR:$PATH

   170     fi

   171     AC_PATH_PROG(CCACHE, ccache)

   172     PATH="$OLD_PATH"

   173   else

   174     AC_MSG_CHECKING([for ccache])

   175     AC_MSG_RESULT([explicitly disabled])

   176     CCACHE=

   177   fi

   178   AC_SUBST(CCACHE)

   180   AC_ARG_WITH([ccache-dir],

   181       [AS_HELP_STRING([--with-ccache-dir],

   182       [where to store ccache files @<:@~/.ccache@:>@])])

   184   if test "x$with_ccache_dir" != x; then

   185     # When using a non home ccache directory, assume the use is to share ccache files

   186     # with other users. Thus change the umask.

   187     SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"

   188   fi

   189   CCACHE_FOUND=""

   190   if test "x$CCACHE" != x; then

   191     BPERF_SETUP_CCACHE_USAGE

   192   fi

   193 ])

   195 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],

   196 [

   197   if test "x$CCACHE" != x; then

   198     CCACHE_FOUND="true"

   199     # Only use ccache if it is 3.1.4 or later, which supports

   200     # precompiled headers.

   201     AC_MSG_CHECKING([if ccache supports precompiled headers])

   202     HAS_GOOD_CCACHE=`($CCACHE --version | head -n 1 | grep -E 3.1.@<:@456789@:>@) 2> /dev/null`

   203     if test "x$HAS_GOOD_CCACHE" = x; then

   204       AC_MSG_RESULT([no, disabling ccache])

   205       CCACHE=

   206     else

   207       AC_MSG_RESULT([yes])

   208       AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])

   209       PUSHED_FLAGS="$CXXFLAGS"

   210       CXXFLAGS="-fpch-preprocess $CXXFLAGS"

   211       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])

   212       CXXFLAGS="$PUSHED_FLAGS"

   213       if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then

   214         AC_MSG_RESULT([yes])

   215       else

   216         AC_MSG_RESULT([no, disabling ccaching of precompiled headers])

   217         CCACHE=

   218       fi

   219     fi

   220   fi

   222   if test "x$CCACHE" != x; then

   223     CCACHE_SLOPPINESS=time_macros

   224     CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS $CCACHE"

   225     CCACHE_FLAGS=-fpch-preprocess

   227     if test "x$SET_CCACHE_DIR" != x; then

   228       mkdir -p $CCACHE_DIR > /dev/null 2>&1

   229       chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1

   230     fi

   231   fi

   232 ])

   234 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],

   235 [

   237   ###############################################################################

   238   #

   239   # Can the C/C++ compiler use precompiled headers?

   240   #

   241   AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],

   242       [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],

   243       [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])

   245   USE_PRECOMPILED_HEADER=1

   246   if test "x$ENABLE_PRECOMPH" = xno; then

   247     USE_PRECOMPILED_HEADER=0

   248   fi

   250   if test "x$ENABLE_PRECOMPH" = xyes; then

   251     # Check that the compiler actually supports precomp headers.

   252     if test "x$GCC" = xyes; then

   253       AC_MSG_CHECKING([that precompiled headers work])

   254       echo "int alfa();" > conftest.h

   255       $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD

   256       if test ! -f conftest.hpp.gch; then

   257         USE_PRECOMPILED_HEADER=0

   258         AC_MSG_RESULT([no])

   259       else

   260         AC_MSG_RESULT([yes])

   261       fi

   262       rm -f conftest.h conftest.hpp.gch

   263     fi

   264   fi

   266   AC_SUBST(USE_PRECOMPILED_HEADER)

   267 ])

   270 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],

   271 [

   272   AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],

   273       [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])

   275   if test "x$with_sjavac_server_java" != x; then

   276     SJAVAC_SERVER_JAVA="$with_sjavac_server_java"

   277     FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`

   278     if test "x$FOUND_VERSION" = x; then

   279       AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])

   280     fi

   281   else

   282     SJAVAC_SERVER_JAVA=""

   283     # Hotspot specific options.

   284     ADD_JVM_ARG_IF_OK([-verbosegc],SJAVAC_SERVER_JAVA,[$JAVA])

   285     # JRockit specific options.

   286     ADD_JVM_ARG_IF_OK([-Xverbose:gc],SJAVAC_SERVER_JAVA,[$JAVA])

   287     SJAVAC_SERVER_JAVA="$JAVA $SJAVAC_SERVER_JAVA"

   288   fi

   289   AC_SUBST(SJAVAC_SERVER_JAVA)

   291   if test "$MEMORY_SIZE" -gt "2500"; then

   292     ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   293     if test "$JVM_ARG_OK" = true; then

   294       JVM_64BIT=true

   295       JVM_ARG_OK=false

   296     fi

   297   fi

   299   if test "$JVM_64BIT" = true; then

   300     if test "$MEMORY_SIZE" -gt "17000"; then

   301       ADD_JVM_ARG_IF_OK([-Xms10G -Xmx10G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   302     fi

   303     if test "$MEMORY_SIZE" -gt "10000" && test "$JVM_ARG_OK" = false; then

   304       ADD_JVM_ARG_IF_OK([-Xms6G -Xmx6G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   305     fi

   306     if test "$MEMORY_SIZE" -gt "5000" && test "$JVM_ARG_OK" = false; then

   307       ADD_JVM_ARG_IF_OK([-Xms1G -Xmx3G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   308     fi

   309     if test "$MEMORY_SIZE" -gt "3800" && test "$JVM_ARG_OK" = false; then

   310       ADD_JVM_ARG_IF_OK([-Xms1G -Xmx2500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   311     fi

   312   fi

   313   if test "$MEMORY_SIZE" -gt "2500" && test "$JVM_ARG_OK" = false; then

   314     ADD_JVM_ARG_IF_OK([-Xms1000M -Xmx1500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   315   fi

   316   if test "$MEMORY_SIZE" -gt "1000" && test "$JVM_ARG_OK" = false; then

   317     ADD_JVM_ARG_IF_OK([-Xms400M -Xmx1100M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   318   fi

   319   if test "$JVM_ARG_OK" = false; then

   320     ADD_JVM_ARG_IF_OK([-Xms256M -Xmx512M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   321   fi

   323   AC_MSG_CHECKING([whether to use sjavac])

   324   AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],

   325       [use sjavac to do fast incremental compiles @<:@disabled@:>@])],

   326       [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC='no'])

   327   AC_MSG_RESULT([$ENABLE_SJAVAC])

   328   AC_SUBST(ENABLE_SJAVAC)

   330   if test "x$ENABLE_SJAVAC" = xyes; then

   331     SJAVAC_SERVER_DIR="$OUTPUT_ROOT/javacservers"

   332   else

   333     SJAVAC_SERVER_DIR=

   334   fi

   335   AC_SUBST(SJAVAC_SERVER_DIR)

   336 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/build-performance.m4@f3697e0783e2

common/autoconf/build-performance.m4