jdk8-mips64-public: common/autoconf/build-performance.m4@584dc2e95e04

1 #

     2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 AC_DEFUN([BPERF_CHECK_CORES],

    27 [

    28     AC_MSG_CHECKING([for number of cores])

    29     NUM_CORES=1

    30     FOUND_CORES=no

    32     if test -f /proc/cpuinfo; then

    33         # Looks like a Linux (or cygwin) system

    34         NUM_CORES=`cat /proc/cpuinfo  | grep -c processor`

    35         FOUND_CORES=yes

    36     elif test -x /usr/sbin/psrinfo; then

    37         # Looks like a Solaris system

    38         NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`

    39         FOUND_CORES=yes

    40     elif test -x /usr/sbin/system_profiler; then

    41         # Looks like a MacOSX system

    42         NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk  '{print [$]5}'`

    43         FOUND_CORES=yes

    44     elif test "x$OPENJDK_BUILD_OS" = xaix ; then

    45         NUM_CORES=`/usr/sbin/prtconf | grep "^Number Of Processors" | awk '{ print [$]4 }'`

    46         FOUND_CORES=yes

    47     elif test -n "$NUMBER_OF_PROCESSORS"; then

    48         # On windows, look in the env

    49         NUM_CORES=$NUMBER_OF_PROCESSORS

    50         FOUND_CORES=yes

    51     fi

    53     if test "x$FOUND_CORES" = xyes; then

    54         AC_MSG_RESULT([$NUM_CORES])

    55     else

    56         AC_MSG_RESULT([could not detect number of cores, defaulting to 1])

    57         AC_MSG_WARN([This will disable all parallelism from build!])

    58     fi

    60 ])

    62 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],

    63 [

    64     AC_MSG_CHECKING([for memory size])

    65     # Default to 1024 MB

    66     MEMORY_SIZE=1024

    67     FOUND_MEM=no

    69     if test -f /proc/meminfo; then

    70         # Looks like a Linux (or cygwin) system

    71         MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`

    72         MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`

    73         FOUND_MEM=yes

    74     elif test -x /usr/sbin/prtconf; then

    75         # Looks like a Solaris or AIX system

    76         MEMORY_SIZE=`/usr/sbin/prtconf | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`

    77         FOUND_MEM=yes

    78     elif test -x /usr/sbin/system_profiler; then

    79         # Looks like a MacOSX system

    80         MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk  '{print [$]2}'`

    81         MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`

    82         FOUND_MEM=yes

    83     elif test "x$OPENJDK_BUILD_OS" = xwindows; then

    84         # Windows, but without cygwin

    85         MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`

    86         MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`

    87         FOUND_MEM=yes

    88     fi

    90     if test "x$FOUND_MEM" = xyes; then

    91         AC_MSG_RESULT([$MEMORY_SIZE MB])

    92     else

    93         AC_MSG_RESULT([could not detect memory size, defaulting to 1024 MB])

    94         AC_MSG_WARN([This might seriously impact build performance!])

    95     fi

    96 ])

    98 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],

    99 [

   100   # How many cores do we have on this build system?

   101   AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],

   102     [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])

   103   if test "x$with_num_cores" = x; then

   104     # The number of cores were not specified, try to probe them.

   105     BPERF_CHECK_CORES

   106   else

   107     NUM_CORES=$with_num_cores

   108   fi

   109   AC_SUBST(NUM_CORES)

   110 ])

   112 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],

   113 [

   114   # How much memory do we have on this build system?

   115   AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],

   116     [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])

   117   if test "x$with_memory_size" = x; then

   118     # The memory size was not specified, try to probe it.

   119     BPERF_CHECK_MEMORY_SIZE

   120   else

   121     MEMORY_SIZE=$with_memory_size

   122   fi

   123   AC_SUBST(MEMORY_SIZE)

   124 ])

   126 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],

   127 [

   128   # Provide a decent default number of parallel jobs for make depending on

   129   # number of cores, amount of memory and machine architecture.

   130   AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],

   131     [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])

   132   if test "x$with_jobs" = x; then

   133     # Number of jobs was not specified, calculate.

   134     AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])

   135     # Approximate memory in GB, rounding up a bit.

   136     memory_gb=`expr $MEMORY_SIZE / 1100`

   137     # Pick the lowest of memory in gb and number of cores.

   138     if test "$memory_gb" -lt "$NUM_CORES"; then

   139       JOBS="$memory_gb"

   140     else

   141       JOBS="$NUM_CORES"

   142       # On bigger machines, leave some room for other processes to run

   143       if test "$JOBS" -gt "4"; then

   144         JOBS=`expr $JOBS '*' 90 / 100`

   145       fi

   146     fi

   147     # Cap number of jobs to 16

   148     if test "$JOBS" -gt "16"; then

   149       JOBS=16

   150     fi

   151     if test "$JOBS" -eq "0"; then

   152       JOBS=1

   153     fi

   154     AC_MSG_RESULT([$JOBS])

   155   else

   156     JOBS=$with_jobs

   157   fi

   158   AC_SUBST(JOBS)

   159 ])

   161 AC_DEFUN([BPERF_SETUP_CCACHE],

   162 [

   163     AC_ARG_ENABLE([ccache],

   164 	      [AS_HELP_STRING([--disable-ccache],

   165 	      		      [disable using ccache to speed up recompilations @<:@enabled@:>@])],

   166               [ENABLE_CCACHE=${enable_ccache}], [ENABLE_CCACHE=yes])

   167     if test "x$ENABLE_CCACHE" = xyes; then

   168         OLD_PATH="$PATH"

   169         if test "x$TOOLS_DIR" != x; then

   170           PATH=$TOOLS_DIR:$PATH

   171         fi

   172         AC_PATH_PROG(CCACHE, ccache)

   173         PATH="$OLD_PATH"

   174     else

   175         AC_MSG_CHECKING([for ccache])

   176         AC_MSG_RESULT([explicitly disabled])

   177         CCACHE=

   178     fi

   179     AC_SUBST(CCACHE)

   181     AC_ARG_WITH([ccache-dir],

   182 	      [AS_HELP_STRING([--with-ccache-dir],

   183 	      		      [where to store ccache files @<:@~/.ccache@:>@])])

   185     if test "x$with_ccache_dir" != x; then

   186         # When using a non home ccache directory, assume the use is to share ccache files

   187         # with other users. Thus change the umask.

   188         SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"

   189     fi

   190     CCACHE_FOUND=""

   191     if test "x$CCACHE" != x; then

   192         BPERF_SETUP_CCACHE_USAGE

   193     fi

   194 ])

   196 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],

   197 [

   198     if test "x$CCACHE" != x; then

   199         CCACHE_FOUND="true"

   200         # Only use ccache if it is 3.1.4 or later, which supports

   201         # precompiled headers.

   202         AC_MSG_CHECKING([if ccache supports precompiled headers])

   203         HAS_GOOD_CCACHE=`($CCACHE --version | head -n 1 | grep -E 3.1.@<:@456789@:>@) 2> /dev/null`

   204         if test "x$HAS_GOOD_CCACHE" = x; then

   205             AC_MSG_RESULT([no, disabling ccache])

   206             CCACHE=

   207         else

   208             AC_MSG_RESULT([yes])

   209             AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])

   210             PUSHED_FLAGS="$CXXFLAGS"

   211             CXXFLAGS="-fpch-preprocess $CXXFLAGS"

   212             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])

   213             CXXFLAGS="$PUSHED_FLAGS"

   214             if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then

   215                 AC_MSG_RESULT([yes])

   216             else

   217                 AC_MSG_RESULT([no, disabling ccaching of precompiled headers])

   218                 CCACHE=

   219             fi

   220         fi

   221     fi

   223     if test "x$CCACHE" != x; then

   224         CCACHE_SLOPPINESS=time_macros

   225         CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS $CCACHE"

   226         CCACHE_FLAGS=-fpch-preprocess

   228         if test "x$SET_CCACHE_DIR" != x; then

   229             mkdir -p $CCACHE_DIR > /dev/null 2>&1

   230 	    chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1

   231         fi

   232     fi

   233 ])

   235 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],

   236 [

   238 ###############################################################################

   239 #

   240 # Can the C/C++ compiler use precompiled headers?

   241 #

   242 AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],

   243 	[disable using precompiled headers when compiling C++ @<:@enabled@:>@])],

   244     [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])

   246 USE_PRECOMPILED_HEADER=1

   247 if test "x$ENABLE_PRECOMPH" = xno; then

   248     USE_PRECOMPILED_HEADER=0

   249 fi

   251 if test "x$ENABLE_PRECOMPH" = xyes; then

   252     # Check that the compiler actually supports precomp headers.

   253     if test "x$GCC" = xyes; then

   254          AC_MSG_CHECKING([that precompiled headers work])

   255          echo "int alfa();" > conftest.h

   256          $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD

   257          if test ! -f conftest.hpp.gch; then

   258              USE_PRECOMPILED_HEADER=0

   259              AC_MSG_RESULT([no])

   260          else

   261              AC_MSG_RESULT([yes])

   262          fi

   263          rm -f conftest.h conftest.hpp.gch

   264     fi

   265 fi

   267 AC_SUBST(USE_PRECOMPILED_HEADER)

   268 ])

   271 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],

   272 [

   273 AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],

   274 	[use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])

   276 if test "x$with_sjavac_server_java" != x; then

   277     SJAVAC_SERVER_JAVA="$with_sjavac_server_java"

   278     FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`

   279     if test "x$FOUND_VERSION" = x; then

   280         AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])

   281     fi

   282 else

   283     SJAVAC_SERVER_JAVA=""

   284     # Hotspot specific options.

   285     ADD_JVM_ARG_IF_OK([-verbosegc],SJAVAC_SERVER_JAVA,[$JAVA])

   286     # JRockit specific options.

   287     ADD_JVM_ARG_IF_OK([-Xverbose:gc],SJAVAC_SERVER_JAVA,[$JAVA])

   288     SJAVAC_SERVER_JAVA="$JAVA $SJAVAC_SERVER_JAVA"

   289 fi

   290 AC_SUBST(SJAVAC_SERVER_JAVA)

   292 if test "$MEMORY_SIZE" -gt "2500"; then

   293     ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   294     if test "$JVM_ARG_OK" = true; then

   295         JVM_64BIT=true

   296 	JVM_ARG_OK=false

   297     fi

   298     fi

   300 if test "$JVM_64BIT" = true; then

   301     if test "$MEMORY_SIZE" -gt "17000"; then

   302         ADD_JVM_ARG_IF_OK([-Xms10G -Xmx10G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   303     fi

   304     if test "$MEMORY_SIZE" -gt "10000" && test "$JVM_ARG_OK" = false; then

   305         ADD_JVM_ARG_IF_OK([-Xms6G -Xmx6G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   306     fi

   307     if test "$MEMORY_SIZE" -gt "5000" && test "$JVM_ARG_OK" = false; then

   308         ADD_JVM_ARG_IF_OK([-Xms1G -Xmx3G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   309     fi

   310     if test "$MEMORY_SIZE" -gt "3800" && test "$JVM_ARG_OK" = false; then

   311         ADD_JVM_ARG_IF_OK([-Xms1G -Xmx2500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   312     fi

   313 fi

   314 if test "$MEMORY_SIZE" -gt "2500" && test "$JVM_ARG_OK" = false; then

   315     ADD_JVM_ARG_IF_OK([-Xms1000M -Xmx1500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   316 fi

   317 if test "$MEMORY_SIZE" -gt "1000" && test "$JVM_ARG_OK" = false; then

   318     ADD_JVM_ARG_IF_OK([-Xms400M -Xmx1100M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   319 fi

   320 if test "$JVM_ARG_OK" = false; then

   321     ADD_JVM_ARG_IF_OK([-Xms256M -Xmx512M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   322 fi

   324 AC_MSG_CHECKING([whether to use sjavac])

   325 AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],

   326 	[use sjavac to do fast incremental compiles @<:@disabled@:>@])],

   327 	[ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC='no'])

   328 AC_MSG_RESULT([$ENABLE_SJAVAC])

   329 AC_SUBST(ENABLE_SJAVAC)

   331 if test "x$ENABLE_SJAVAC" = xyes; then

   332     SJAVAC_SERVER_DIR="$OUTPUT_ROOT/javacservers"

   333 else

   334     SJAVAC_SERVER_DIR=

   335 fi

   336 AC_SUBST(SJAVAC_SERVER_DIR)

   338 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/build-performance.m4@584dc2e95e04

common/autoconf/build-performance.m4