Thu, 05 Apr 2018 08:14:51 -0700
8035725: Must keep microsoft VS_PATH on PATH after toolchain detection
Reviewed-by: ihse, erikj
1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 ########################################################################
27 # This file is responsible for detecting, verifying and setting up the
28 # toolchain, i.e. the compiler, linker and related utilities. It will setup
29 # proper paths to the binaries, but it will not setup any flags.
30 #
31 # The binaries used is determined by the toolchain type, which is the family of
32 # compilers and related tools that are used.
33 ########################################################################
36 # All valid toolchains, regardless of platform (used by help.m4)
37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
39 # These toolchains are valid on different platforms
40 VALID_TOOLCHAINS_linux="gcc clang"
41 VALID_TOOLCHAINS_solaris="solstudio"
42 VALID_TOOLCHAINS_macosx="gcc clang"
43 VALID_TOOLCHAINS_aix="xlc"
44 VALID_TOOLCHAINS_windows="microsoft"
46 # Toolchain descriptions
47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
53 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
54 # Must have CC_VERSION_NUMBER and CXX_VERSION_NUMBER.
55 # $1 - optional variable prefix for compiler and version variables (BUILD_)
56 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
57 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS],
58 [
59 if test "x$CC_VERSION" != "x$CXX_VERSION"; then
60 AC_MSG_WARN([C and C++ compiler has different version numbers, $CC_VERSION vs $CXX_VERSION.])
61 AC_MSG_WARN([This typically indicates a broken setup, and is not supported])
62 fi
64 # We only check CC_VERSION since we assume CXX_VERSION is equal.
65 if [ [[ "$CC_VERSION" =~ (.*\.){3} ]] ]; then
66 AC_MSG_WARN([C compiler version number has more than three parts (X.Y.Z): $CC_VERSION. Comparisons might be wrong.])
67 fi
69 if [ [[ "$CC_VERSION" =~ [0-9]{6} ]] ]; then
70 AC_MSG_WARN([C compiler version number has a part larger than 99999: $CC_VERSION. Comparisons might be wrong.])
71 fi
73 $2COMPARABLE_ACTUAL_VERSION=`$AWK -F. '{ printf("%05d%05d%05d\n", [$]1, [$]2, [$]3) }' <<< "$CC_VERSION"`
74 ])
76 # Check if the configured compiler (C and C++) is of a specific version or
77 # newer. TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS must have been called before.
78 #
79 # Arguments:
80 # $1: The version string to check against the found version
81 # $2: block to run if the compiler is at least this version (>=)
82 # $3: block to run if the compiler is older than this version (<)
83 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
84 [
85 REFERENCE_VERSION=$1
87 if [ [[ "$REFERENCE_VERSION" =~ (.*\.){3} ]] ]; then
88 AC_MSG_ERROR([Internal error: Cannot compare to $REFERENCE_VERSION, only three parts (X.Y.Z) is supported])
89 fi
91 if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
92 AC_MSG_ERROR([Internal error: Cannot compare to $REFERENCE_VERSION, only parts < 99999 is supported])
93 fi
95 # Version comparison method inspired by http://stackoverflow.com/a/24067243
96 COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d\n", [$]1, [$]2, [$]3) }' <<< "$REFERENCE_VERSION"`
98 if test $COMPARABLE_ACTUAL_VERSION -ge $COMPARABLE_REFERENCE_VERSION ; then
99 m4_ifval([$2], [$2], [:])
100 else
101 m4_ifval([$3], [$3], [:])
102 fi
103 ])
106 # Setup a number of variables describing how native output files are
107 # named on this platform/toolchain.
108 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
109 [
110 # Define filename patterns
111 if test "x$OPENJDK_TARGET_OS" = xwindows; then
112 LIBRARY_PREFIX=
113 SHARED_LIBRARY_SUFFIX='.dll'
114 STATIC_LIBRARY_SUFFIX='.lib'
115 SHARED_LIBRARY='[$]1.dll'
116 STATIC_LIBRARY='[$]1.lib'
117 OBJ_SUFFIX='.obj'
118 EXE_SUFFIX='.exe'
119 else
120 LIBRARY_PREFIX=lib
121 SHARED_LIBRARY_SUFFIX='.so'
122 STATIC_LIBRARY_SUFFIX='.a'
123 SHARED_LIBRARY='lib[$]1.so'
124 STATIC_LIBRARY='lib[$]1.a'
125 OBJ_SUFFIX='.o'
126 EXE_SUFFIX=''
127 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
128 SHARED_LIBRARY='lib[$]1.dylib'
129 SHARED_LIBRARY_SUFFIX='.dylib'
130 fi
131 fi
133 AC_SUBST(LIBRARY_PREFIX)
134 AC_SUBST(SHARED_LIBRARY_SUFFIX)
135 AC_SUBST(STATIC_LIBRARY_SUFFIX)
136 AC_SUBST(SHARED_LIBRARY)
137 AC_SUBST(STATIC_LIBRARY)
138 AC_SUBST(OBJ_SUFFIX)
139 AC_SUBST(EXE_SUFFIX)
140 ])
142 # Determine which toolchain type to use, and make sure it is valid for this
143 # platform. Setup various information about the selected toolchain.
144 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
145 [
146 AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
147 [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
149 # Use indirect variable referencing
150 toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
151 VALID_TOOLCHAINS=${!toolchain_var_name}
152 # First toolchain type in the list is the default
153 DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
155 if test "x$with_toolchain_type" = xlist; then
156 # List all toolchains
157 AC_MSG_NOTICE([The following toolchains are valid on this platform:])
158 for toolchain in $VALID_TOOLCHAINS; do
159 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
160 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
161 $PRINTF " %-10s %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
162 done
164 exit 0
165 elif test "x$with_toolchain_type" != x; then
166 # User override; check that it is valid
167 if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
168 AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
169 AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
170 AC_MSG_ERROR([Cannot continue.])
171 fi
172 TOOLCHAIN_TYPE=$with_toolchain_type
173 else
174 # No flag given, use default
175 TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
176 fi
177 AC_SUBST(TOOLCHAIN_TYPE)
179 TOOLCHAIN_CC_BINARY_clang="clang"
180 TOOLCHAIN_CC_BINARY_gcc="gcc"
181 TOOLCHAIN_CC_BINARY_microsoft="cl"
182 TOOLCHAIN_CC_BINARY_solstudio="cc"
183 TOOLCHAIN_CC_BINARY_xlc="xlc_r"
185 TOOLCHAIN_CXX_BINARY_clang="clang++"
186 TOOLCHAIN_CXX_BINARY_gcc="g++"
187 TOOLCHAIN_CXX_BINARY_microsoft="cl"
188 TOOLCHAIN_CXX_BINARY_solstudio="CC"
189 TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
191 # Use indirect variable referencing
192 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
193 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
194 toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
195 TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
196 toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
197 TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
199 TOOLCHAIN_SETUP_FILENAME_PATTERNS
201 if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
202 AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
203 else
204 AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
205 fi
206 ])
208 # Before we start detecting the toolchain executables, we might need some
209 # special setup, e.g. additional paths etc.
210 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
211 [
212 # FIXME: Is this needed?
213 AC_LANG(C++)
215 # Store the CFLAGS etal passed to the configure script.
216 ORG_CFLAGS="$CFLAGS"
217 ORG_CXXFLAGS="$CXXFLAGS"
218 ORG_OBJCFLAGS="$OBJCFLAGS"
220 # On Windows, we need to detect the visual studio installation first.
221 # This will change the PATH, but we need to keep that new PATH even
222 # after toolchain detection is done, since the compiler (on x86) uses
223 # it for DLL resolution in runtime.
224 if test "x$OPENJDK_BUILD_OS" = "xwindows" && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
225 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
226 fi
228 # autoconf magic only relies on PATH, so update it if tools dir is specified
229 OLD_PATH="$PATH"
231 # Before we locate the compilers, we need to sanitize the Xcode build environment
232 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
233 # determine path to Xcode developer directory
234 # can be empty in which case all the tools will rely on a sane Xcode 4 installation
235 SET_DEVELOPER_DIR=
237 if test -n "$XCODE_PATH"; then
238 DEVELOPER_DIR="$XCODE_PATH"/Contents/Developer
239 fi
241 # DEVELOPER_DIR could also be provided directly
242 AC_MSG_CHECKING([Determining if we need to set DEVELOPER_DIR])
243 if test -n "$DEVELOPER_DIR"; then
244 if test ! -d "$DEVELOPER_DIR"; then
245 AC_MSG_ERROR([Xcode Developer path does not exist: $DEVELOPER_DIR, please provide a path to the Xcode 4 application bundle using --with-xcode-path])
246 fi
247 if test ! -f "$DEVELOPER_DIR"/usr/bin/xcodebuild; then
248 AC_MSG_ERROR([Xcode Developer path is not valid: $DEVELOPER_DIR, it must point to Contents/Developer inside an Xcode application bundle])
249 fi
250 # make it visible to all the tools immediately
251 export DEVELOPER_DIR
252 SET_DEVELOPER_DIR="export DEVELOPER_DIR := $DEVELOPER_DIR"
253 AC_MSG_RESULT([yes ($DEVELOPER_DIR)])
254 else
255 AC_MSG_RESULT([no])
256 fi
257 AC_SUBST(SET_DEVELOPER_DIR)
259 AC_PATH_PROG(XCODEBUILD, xcodebuild)
260 if test -z "$XCODEBUILD"; then
261 AC_MSG_ERROR([The xcodebuild tool was not found, the Xcode command line tools are required to build on Mac OS X])
262 fi
264 # Fail-fast: verify we're building on Xcode 4, we cannot build with Xcode 5 or later
265 XCODE_VERSION=`$XCODEBUILD -version | grep '^Xcode ' | sed 's/Xcode //'`
266 XC_VERSION_PARTS=( ${XCODE_VERSION//./ } )
267 if test ! "${XC_VERSION_PARTS[[0]]}" = "4"; then
268 AC_MSG_ERROR([Xcode 4 is required to build JDK 8, the version found was $XCODE_VERSION. Use --with-xcode-path to specify the location of Xcode 4 or make Xcode 4 active by using xcode-select.])
269 fi
271 # Some versions of Xcode 5 command line tools install gcc and g++ as symlinks to
272 # clang and clang++, which will break the build. So handle that here if we need to.
273 if test -L "/usr/bin/gcc" -o -L "/usr/bin/g++"; then
274 # use xcrun to find the real gcc and add it's directory to PATH
275 # then autoconf magic will find it
276 AC_MSG_NOTICE([Found gcc symlinks to clang in /usr/bin, adding path to real gcc to PATH])
277 XCODE_BIN_PATH=$(dirname `xcrun -find gcc`)
278 PATH="$XCODE_BIN_PATH":$PATH
279 fi
281 # Determine appropriate SDKPATH, don't use SDKROOT as it interferes with the stub tools
282 AC_MSG_CHECKING([Determining Xcode SDK path])
283 # allow SDKNAME to be set to override the default SDK selection
284 SDKPATH=`"$XCODEBUILD" -sdk ${SDKNAME:-macosx} -version | grep '^Path: ' | sed 's/Path: //'`
285 if test -n "$SDKPATH"; then
286 AC_MSG_RESULT([$SDKPATH])
287 else
288 AC_MSG_RESULT([(none, will use system headers and frameworks)])
289 fi
290 AC_SUBST(SDKPATH)
292 # Perform a basic sanity test
293 if test ! -f "$SDKPATH/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
294 AC_MSG_ERROR([Unable to find required framework headers, provide a valid path to Xcode 4 using --with-xcode-path])
295 fi
297 # if SDKPATH is non-empty then we need to add -isysroot and -iframework for gcc and g++
298 if test -n "$SDKPATH"; then
299 # We need -isysroot <path> and -iframework<path>/System/Library/Frameworks
300 CFLAGS_JDK="${CFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
301 CXXFLAGS_JDK="${CXXFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
302 LDFLAGS_JDK="${LDFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
303 fi
305 # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
306 # setting this here means it doesn't have to be peppered throughout the forest
307 CFLAGS_JDK="$CFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
308 CXXFLAGS_JDK="$CXXFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
309 LDFLAGS_JDK="$LDFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
310 fi
312 # For solaris we really need solaris tools, and not the GNU equivalent.
313 # The build tools on Solaris reside in /usr/ccs (C Compilation System),
314 # so add that to path before starting to probe.
315 # FIXME: This was originally only done for AS,NM,GNM,STRIP,MCS,OBJCOPY,OBJDUMP.
316 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
317 PATH="/usr/ccs/bin:$PATH"
318 fi
320 # Finally add TOOLS_DIR at the beginning, to allow --with-tools-dir to
321 # override all other locations.
322 if test "x$TOOLS_DIR" != x; then
323 PATH=$TOOLS_DIR:$PATH
324 fi
326 # If a devkit is found on the builddeps server, then prepend its path to the
327 # PATH variable. If there are cross compilers available in the devkit, these
328 # will be found by AC_PROG_CC et al.
329 DEVKIT=
330 BDEPS_CHECK_MODULE(DEVKIT, devkit, xxx,
331 [
332 # Found devkit
333 PATH="$DEVKIT/bin:$PATH"
334 SYS_ROOT="$DEVKIT/${rewritten_target}/sys-root"
335 if test "x$x_includes" = "xNONE"; then
336 x_includes="$SYS_ROOT/usr/include/X11"
337 fi
338 if test "x$x_libraries" = "xNONE"; then
339 x_libraries="$SYS_ROOT/usr/lib"
340 fi
341 ],
342 [])
343 ])
345 # Restore path, etc
346 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
347 [
348 # Restore old path.
349 PATH="$OLD_PATH"
351 # Restore the flags to the user specified values.
352 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
353 CFLAGS="$ORG_CFLAGS"
354 CXXFLAGS="$ORG_CXXFLAGS"
355 OBJCFLAGS="$ORG_OBJCFLAGS"
356 ])
358 # Check if a compiler is of the toolchain type we expect, and save the version
359 # information from it. If the compiler does not match the expected type,
360 # this function will abort using AC_MSG_ERROR. If it matches, the version will
361 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
362 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
363 #
364 # $1 = compiler to test (CC or CXX)
365 # $2 = human readable name of compiler (C or C++)
366 AC_DEFUN([TOOLCHAIN_EXTRACT_COMPILER_VERSION],
367 [
368 COMPILER=[$]$1
369 COMPILER_NAME=$2
371 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
372 # cc -V output typically looks like
373 # cc: Sun C 5.12 Linux_i386 2011/11/16
374 COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
375 # Check that this is likely to be the Solaris Studio cc.
376 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
377 if test $? -ne 0; then
378 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
379 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
380 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
381 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
382 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
383 fi
384 # Remove usage instructions (if present), and
385 # collapse compiler output into a single line
386 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
387 $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
388 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
389 $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
390 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
391 # xlc -qversion output typically looks like
392 # IBM XL C/C++ for AIX, V11.1 (5724-X13)
393 # Version: 11.01.0000.0015
394 COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
395 # Check that this is likely to be the IBM XL C compiler.
396 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
397 if test $? -ne 0; then
398 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
399 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
400 AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
401 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
402 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
403 fi
404 # Collapse compiler output into a single line
405 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
406 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
407 $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
408 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
409 # There is no specific version flag, but all output starts with a version string.
410 # First line typically looks something like:
411 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
412 COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
413 # Check that this is likely to be Microsoft CL.EXE.
414 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null
415 if test $? -ne 0; then
416 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
417 AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
418 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
419 fi
420 # Collapse compiler output into a single line
421 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
422 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
423 $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
424 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
425 # gcc --version output typically looks like
426 # gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
427 # Copyright (C) 2013 Free Software Foundation, Inc.
428 # This is free software; see the source for copying conditions. There is NO
429 # warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
430 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
431 # Check that this is likely to be GCC.
432 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
433 if test $? -ne 0; then
434 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
435 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
436 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
437 fi
438 # Remove Copyright and legalese from version string, and
439 # collapse into a single line
440 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
441 $SED -e 's/ *Copyright .*//'`
442 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
443 $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\) .*$/\1/'`
444 elif test "x$TOOLCHAIN_TYPE" = xclang; then
445 # clang --version output typically looks like
446 # Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
447 # clang version 3.3 (tags/RELEASE_33/final)
448 # or
449 # Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
450 # Target: x86_64-pc-linux-gnu
451 # Thread model: posix
452 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
453 # Check that this is likely to be clang
454 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
455 if test $? -ne 0; then
456 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
457 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
458 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
459 fi
460 # Collapse compiler output into a single line
461 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
462 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
463 $SED -e 's/^.*clang version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
465 else
466 AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
467 fi
468 # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
469 $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
470 # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
471 $1_VERSION_STRING="$COMPILER_VERSION_STRING"
473 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
474 ])
477 # Try to locate the given C or C++ compiler in the path, or otherwise.
478 #
479 # $1 = compiler to test (CC or CXX)
480 # $2 = human readable name of compiler (C or C++)
481 # $3 = list of compiler names to search for
482 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
483 [
484 COMPILER_NAME=$2
485 SEARCH_LIST="$3"
487 if test "x[$]$1" != x; then
488 # User has supplied compiler name already, always let that override.
489 AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
490 if test "x`basename [$]$1`" = "x[$]$1"; then
491 # A command without a complete path is provided, search $PATH.
493 AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
494 if test "x$POTENTIAL_$1" != x; then
495 $1=$POTENTIAL_$1
496 else
497 AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
498 fi
499 else
500 # Otherwise it might already be a complete path
501 if test ! -x "[$]$1"; then
502 AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
503 fi
504 fi
505 else
506 # No user supplied value. Locate compiler ourselves.
508 # If we are cross compiling, assume cross compilation tools follows the
509 # cross compilation standard where they are prefixed with the autoconf
510 # standard name for the target. For example the binary
511 # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
512 # If we are not cross compiling, then the default compiler name will be
513 # used.
515 $1=
516 # If TOOLS_DIR is set, check for all compiler names in there first
517 # before checking the rest of the PATH.
518 # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION
519 # step, this should not be necessary.
520 if test -n "$TOOLS_DIR"; then
521 PATH_save="$PATH"
522 PATH="$TOOLS_DIR"
523 AC_PATH_PROGS(TOOLS_DIR_$1, $3)
524 $1=$TOOLS_DIR_$1
525 PATH="$PATH_save"
526 fi
528 # AC_PATH_PROGS can't be run multiple times with the same variable,
529 # so create a new name for this run.
530 if test "x[$]$1" = x; then
531 AC_PATH_PROGS(POTENTIAL_$1, $3)
532 $1=$POTENTIAL_$1
533 fi
535 if test "x[$]$1" = x; then
536 HELP_MSG_MISSING_DEPENDENCY([devkit])
537 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
538 fi
539 fi
541 # Now we have a compiler binary in $1. Make sure it's okay.
542 BASIC_FIXUP_EXECUTABLE($1)
543 TEST_COMPILER="[$]$1"
544 # Don't remove symbolic links on AIX because 'xlc_r' and 'xlC_r' may all be links
545 # to 'xlc' but it is crucial that we invoke the compiler with the right name!
546 if test "x$OPENJDK_BUILD_OS" != xaix; then
547 # FIXME: This test should not be needed anymore; we don't do that for any platform.
548 AC_MSG_CHECKING([resolved symbolic links for $1])
549 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
550 AC_MSG_RESULT([$TEST_COMPILER])
551 fi
552 AC_MSG_CHECKING([if $1 is disguised ccache])
554 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
555 if test "x$COMPILER_BASENAME" = "xccache"; then
556 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
557 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
558 # We want to control ccache invocation ourselves, so ignore this cc and try
559 # searching again.
561 # Remove the path to the fake ccache cc from the PATH
562 RETRY_COMPILER_SAVED_PATH="$PATH"
563 COMPILER_DIRNAME=`$DIRNAME [$]$1`
564 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
566 # Try again looking for our compiler
567 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
568 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
569 PATH="$RETRY_COMPILER_SAVED_PATH"
571 AC_MSG_CHECKING([for resolved symbolic links for $1])
572 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
573 AC_MSG_RESULT([$PROPER_COMPILER_$1])
574 $1="$PROPER_COMPILER_$1"
575 else
576 AC_MSG_RESULT([no, keeping $1])
577 $1="$TEST_COMPILER"
578 fi
580 TOOLCHAIN_EXTRACT_COMPILER_VERSION([$1], [$COMPILER_NAME])
581 ])
583 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
584 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
585 # archiver (AR). Verify that the compilers are correct according to the
586 # toolchain type.
587 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
588 [
589 #
590 # Setup the compilers (CC and CXX)
591 #
592 TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
593 # Now that we have resolved CC ourself, let autoconf have its go at it
594 AC_PROG_CC([$CC])
596 TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
597 # Now that we have resolved CXX ourself, let autoconf have its go at it
598 AC_PROG_CXX([$CXX])
600 # This is the compiler version number on the form X.Y[.Z]
601 AC_SUBST(CC_VERSION_NUMBER)
602 AC_SUBST(CXX_VERSION_NUMBER)
604 TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS
606 #
607 # Setup the preprocessor (CPP and CXXCPP)
608 #
609 AC_PROG_CPP
610 BASIC_FIXUP_EXECUTABLE(CPP)
611 AC_PROG_CXXCPP
612 BASIC_FIXUP_EXECUTABLE(CXXCPP)
614 #
615 # Setup the linker (LD)
616 #
617 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
618 # In the Microsoft toolchain we have a separate LD command "link".
619 # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
620 # a cygwin program for something completely different.
621 AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])
622 BASIC_FIXUP_EXECUTABLE(LD)
623 # Verify that we indeed succeeded with this trick.
624 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
625 "$LD" --version > /dev/null
626 if test $? -eq 0 ; then
627 AC_MSG_RESULT([no])
628 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
629 else
630 AC_MSG_RESULT([yes])
631 fi
632 LDCXX="$LD"
633 else
634 # All other toolchains use the compiler to link.
635 LD="$CC"
636 LDCXX="$CXX"
637 fi
638 AC_SUBST(LD)
639 # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
640 AC_SUBST(LDCXX)
642 #
643 # Setup the assembler (AS)
644 #
645 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
646 # FIXME: should this really be solaris, or solstudio?
647 BASIC_PATH_PROGS(AS, as)
648 BASIC_FIXUP_EXECUTABLE(AS)
649 else
650 # FIXME: is this correct for microsoft?
651 AS="$CC -c"
652 fi
653 AC_SUBST(AS)
655 #
656 # Setup the archiver (AR)
657 #
658 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
659 # The corresponding ar tool is lib.exe (used to create static libraries)
660 AC_CHECK_PROG([AR], [lib],[lib],,,)
661 else
662 BASIC_CHECK_TOOLS(AR, ar)
663 fi
664 BASIC_FIXUP_EXECUTABLE(AR)
665 ])
667 # Setup additional tools that is considered a part of the toolchain, but not the
668 # core part. Many of these are highly platform-specific and do not exist,
669 # and/or are not needed on all platforms.
670 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
671 [
672 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
673 AC_PROG_OBJC
674 BASIC_FIXUP_EXECUTABLE(OBJC)
675 BASIC_PATH_PROGS(LIPO, lipo)
676 BASIC_FIXUP_EXECUTABLE(LIPO)
677 else
678 OBJC=
679 fi
681 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
682 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
683 BASIC_FIXUP_EXECUTABLE(MT)
684 # Setup the resource compiler (RC)
685 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
686 BASIC_FIXUP_EXECUTABLE(RC)
687 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
688 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
689 fi
691 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
692 BASIC_PATH_PROGS(STRIP, strip)
693 BASIC_FIXUP_EXECUTABLE(STRIP)
694 BASIC_PATH_PROGS(NM, nm)
695 BASIC_FIXUP_EXECUTABLE(NM)
696 BASIC_PATH_PROGS(GNM, gnm)
697 BASIC_FIXUP_EXECUTABLE(GNM)
699 BASIC_PATH_PROGS(MCS, mcs)
700 BASIC_FIXUP_EXECUTABLE(MCS)
701 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
702 # FIXME: we should unify this with the solaris case above.
703 BASIC_CHECK_TOOLS(STRIP, strip)
704 BASIC_FIXUP_EXECUTABLE(STRIP)
705 AC_PATH_PROG(OTOOL, otool)
706 if test "x$OTOOL" = "x"; then
707 OTOOL="true"
708 fi
709 BASIC_CHECK_TOOLS(NM, nm)
710 BASIC_FIXUP_EXECUTABLE(NM)
711 GNM="$NM"
712 AC_SUBST(GNM)
713 fi
715 # objcopy is used for moving debug symbols to separate files when
716 # full debug symbols are enabled.
717 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
718 BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
719 # Only call fixup if objcopy was found.
720 if test -n "$OBJCOPY"; then
721 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
722 fi
723 fi
725 BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
726 if test "x$OBJDUMP" != x; then
727 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
728 # bails if argument is missing.
729 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
730 fi
731 ])
733 # Setup the build tools (i.e, the compiler and linker used to build programs
734 # that should be run on the build platform, not the target platform, as a build
735 # helper). Since the non-cross-compile case uses the normal, target compilers
736 # for this, we can only do this after these have been setup.
737 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
738 [
739 if test "x$COMPILE_TYPE" = "xcross"; then
740 # Now we need to find a C/C++ compiler that can build executables for the
741 # build platform. We can't use the AC_PROG_CC macro, since it can only be
742 # used once. Also, we need to do this without adding a tools dir to the
743 # path, otherwise we might pick up cross-compilers which don't use standard
744 # naming.
746 # FIXME: we should list the discovered compilers as an exclude pattern!
747 # If we do that, we can do this detection before POST_DETECTION, and still
748 # find the build compilers in the tools dir, if needed.
749 BASIC_PATH_PROGS(BUILD_CC, [cl cc gcc])
750 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
751 BASIC_PATH_PROGS(BUILD_CXX, [cl CC g++])
752 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
753 BASIC_PATH_PROGS(BUILD_LD, ld)
754 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
755 else
756 # If we are not cross compiling, use the normal target compilers for
757 # building the build platform executables.
758 BUILD_CC="$CC"
759 BUILD_CXX="$CXX"
760 BUILD_LD="$LD"
761 fi
762 ])
764 # Setup legacy variables that are still needed as alternative ways to refer to
765 # parts of the toolchain.
766 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_LEGACY],
767 [
768 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
769 # For hotspot, we need these in Windows mixed path,
770 # so rewrite them all. Need added .exe suffix.
771 HOTSPOT_CXX="$CXX.exe"
772 HOTSPOT_LD="$LD.exe"
773 HOTSPOT_MT="$MT.exe"
774 HOTSPOT_RC="$RC.exe"
775 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
776 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
777 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
778 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
779 AC_SUBST(HOTSPOT_MT)
780 AC_SUBST(HOTSPOT_RC)
781 else
782 HOTSPOT_CXX="$CXX"
783 HOTSPOT_LD="$LD"
784 fi
785 AC_SUBST(HOTSPOT_CXX)
786 AC_SUBST(HOTSPOT_LD)
788 if test "x$TOOLCHAIN_TYPE" = xclang; then
789 USE_CLANG=true
790 fi
791 AC_SUBST(USE_CLANG)
793 # LDEXE is the linker to use, when creating executables. Not really used.
794 # FIXME: These should just be removed!
795 LDEXE="$LD"
796 LDEXECXX="$LDCXX"
797 AC_SUBST(LDEXE)
798 AC_SUBST(LDEXECXX)
799 ])
801 # Do some additional checks on the detected tools.
802 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
803 [
804 # The package path is used only on macosx?
805 # FIXME: clean this up, and/or move it elsewhere.
806 PACKAGE_PATH=/opt/local
807 AC_SUBST(PACKAGE_PATH)
809 # Check for extra potential brokenness.
810 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
811 # On Windows, double-check that we got the right compiler.
812 CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`
813 COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
814 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
815 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
816 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
817 fi
818 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
819 if test "x$COMPILER_CPU_TEST" != "xx64"; then
820 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
821 fi
822 fi
823 fi
825 if test "x$TOOLCHAIN_TYPE" = xgcc; then
826 # If this is a --hash-style=gnu system, use --hash-style=both, why?
827 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
828 # This is later checked when setting flags.
829 fi
831 # Check for broken SuSE 'ld' for which 'Only anonymous version tag is allowed
832 # in executable.'
833 USING_BROKEN_SUSE_LD=no
834 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$TOOLCHAIN_TYPE" = xgcc; then
835 AC_MSG_CHECKING([for broken SuSE 'ld' which only understands anonymous version tags in executables])
836 echo "SUNWprivate_1.1 { local: *; };" > version-script.map
837 echo "int main() { }" > main.c
838 if $CXX -Xlinker -version-script=version-script.map main.c 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
839 AC_MSG_RESULT(no)
840 USING_BROKEN_SUSE_LD=no
841 else
842 AC_MSG_RESULT(yes)
843 USING_BROKEN_SUSE_LD=yes
844 fi
845 rm -rf version-script.map main.c
846 fi
847 AC_SUBST(USING_BROKEN_SUSE_LD)
848 ])
850 # Setup the JTReg Regression Test Harness.
851 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
852 [
853 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
854 [Regression Test Harness @<:@probed@:>@])],
855 [],
856 [with_jtreg=no])
858 if test "x$with_jtreg" = xno; then
859 # jtreg disabled
860 AC_MSG_CHECKING([for jtreg])
861 AC_MSG_RESULT(no)
862 else
863 if test "x$with_jtreg" != xyes; then
864 # with path specified.
865 JT_HOME="$with_jtreg"
866 fi
868 if test "x$JT_HOME" != x; then
869 AC_MSG_CHECKING([for jtreg])
871 # use JT_HOME enviroment var.
872 BASIC_FIXUP_PATH([JT_HOME])
874 # jtreg win32 script works for everybody
875 JTREGEXE="$JT_HOME/bin/jtreg"
877 if test ! -f "$JTREGEXE"; then
878 AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
879 fi
881 AC_MSG_RESULT($JTREGEXE)
882 else
883 # try to find jtreg on path
884 BASIC_REQUIRE_PROGS(JTREGEXE, jtreg)
885 JT_HOME="`$DIRNAME $JTREGEXE`"
886 fi
887 fi
889 AC_SUBST(JT_HOME)
890 AC_SUBST(JTREGEXE)
891 ])