jdk8-mips64-public: common/autoconf/toolchain.m4@7ba4e17574e0

8034788: Rewrite toolchain.m4 to support multiple toolchains per platform.
Reviewed-by: ihse, henryjen, erikj

1 #

     2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 ########################################################################

    27 # This file is responsible for detecting, verifying and setting up the

    28 # toolchain, i.e. the compiler, linker and related utilities. It will setup

    29 # proper paths to the binaries, but it will not setup any flags.

    30 #

    31 # The binaries used is determined by the toolchain type, which is the family of

    32 # compilers and related tools that are used.

    33 ########################################################################

    36 # All valid toolchains, regardless of platform (used by help.m4)

    37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"

    39 # These toolchains are valid on different platforms

    40 VALID_TOOLCHAINS_linux="gcc clang"

    41 VALID_TOOLCHAINS_solaris="solstudio"

    42 VALID_TOOLCHAINS_macosx="gcc clang"

    43 VALID_TOOLCHAINS_aix="xlc"

    44 VALID_TOOLCHAINS_windows="microsoft"

    46 # Toolchain descriptions

    47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"

    48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"

    49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"

    50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"

    51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"

    53 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.

    54 # Must have CC_VERSION_NUMBER and CXX_VERSION_NUMBER.

    55 # $1 - optional variable prefix for compiler and version variables (BUILD_)

    56 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)

    57 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS],

    58 [

    59   if test "x$CC_VERSION" != "x$CXX_VERSION"; then

    60     AC_MSG_WARN([C and C++ compiler has different version numbers, $CC_VERSION vs $CXX_VERSION.])

    61     AC_MSG_WARN([This typically indicates a broken setup, and is not supported])

    62   fi

    64   # We only check CC_VERSION since we assume CXX_VERSION is equal.

    65   if [ [[ "$CC_VERSION" =~ (.*\.){3} ]] ]; then

    66     AC_MSG_WARN([C compiler version number has more than three parts (X.Y.Z): $CC_VERSION. Comparisons might be wrong.])

    67   fi

    69   if [ [[  "$CC_VERSION" =~ [0-9]{6} ]] ]; then

    70     AC_MSG_WARN([C compiler version number has a part larger than 99999: $CC_VERSION. Comparisons might be wrong.])

    71   fi

    73   $2COMPARABLE_ACTUAL_VERSION=`$AWK -F. '{ printf("%05d%05d%05d\n", [$]1, [$]2, [$]3) }' <<< "$CC_VERSION"`

    74 ])

    76 # Check if the configured compiler (C and C++) is of a specific version or

    77 # newer. TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS must have been called before.

    78 #

    79 # Arguments:

    80 #   $1:   The version string to check against the found version

    81 #   $2:   block to run if the compiler is at least this version (>=)

    82 #   $3:   block to run if the compiler is older than this version (<)

    83 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],

    84 [

    85   REFERENCE_VERSION=$1

    87   if [ [[ "$REFERENCE_VERSION" =~ (.*\.){3} ]] ]; then

    88     AC_MSG_ERROR([Internal error: Cannot compare to $REFERENCE_VERSION, only three parts (X.Y.Z) is supported])

    89   fi

    91   if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then

    92     AC_MSG_ERROR([Internal error: Cannot compare to $REFERENCE_VERSION, only parts < 99999 is supported])

    93   fi

    95   # Version comparison method inspired by http://stackoverflow.com/a/24067243

    96   COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d\n", [$]1, [$]2, [$]3) }' <<< "$REFERENCE_VERSION"`

    98   if test $COMPARABLE_ACTUAL_VERSION -ge $COMPARABLE_REFERENCE_VERSION ; then

    99     m4_ifval([$2], [$2], [:])

   100   else

   101     m4_ifval([$3], [$3], [:])

   102   fi

   103 ])

   106 # Setup a number of variables describing how native output files are

   107 # named on this platform/toolchain.

   108 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],

   109 [

   110   # Define filename patterns

   111   if test "x$OPENJDK_TARGET_OS" = xwindows; then

   112     LIBRARY_PREFIX=

   113     SHARED_LIBRARY_SUFFIX='.dll'

   114     STATIC_LIBRARY_SUFFIX='.lib'

   115     SHARED_LIBRARY='[$]1.dll'

   116     STATIC_LIBRARY='[$]1.lib'

   117     OBJ_SUFFIX='.obj'

   118     EXE_SUFFIX='.exe'

   119   else

   120     LIBRARY_PREFIX=lib

   121     SHARED_LIBRARY_SUFFIX='.so'

   122     STATIC_LIBRARY_SUFFIX='.a'

   123     SHARED_LIBRARY='lib[$]1.so'

   124     STATIC_LIBRARY='lib[$]1.a'

   125     OBJ_SUFFIX='.o'

   126     EXE_SUFFIX=''

   127     if test "x$OPENJDK_TARGET_OS" = xmacosx; then

   128       SHARED_LIBRARY='lib[$]1.dylib'

   129       SHARED_LIBRARY_SUFFIX='.dylib'

   130     fi

   131   fi

   133   AC_SUBST(LIBRARY_PREFIX)

   134   AC_SUBST(SHARED_LIBRARY_SUFFIX)

   135   AC_SUBST(STATIC_LIBRARY_SUFFIX)

   136   AC_SUBST(SHARED_LIBRARY)

   137   AC_SUBST(STATIC_LIBRARY)

   138   AC_SUBST(OBJ_SUFFIX)

   139   AC_SUBST(EXE_SUFFIX)

   140 ])

   142 # Determine which toolchain type to use, and make sure it is valid for this

   143 # platform. Setup various information about the selected toolchain.

   144 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],

   145 [

   146   AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],

   147       [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])

   149   # Use indirect variable referencing

   150   toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS

   151   VALID_TOOLCHAINS=${!toolchain_var_name}

   152   # First toolchain type in the list is the default

   153   DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}

   155   if test "x$with_toolchain_type" = xlist; then

   156     # List all toolchains

   157     AC_MSG_NOTICE([The following toolchains are valid on this platform:])

   158     for toolchain in $VALID_TOOLCHAINS; do

   159       toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain

   160       TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}

   161       $PRINTF "  %-10s  %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"

   162     done

   164     exit 0

   165   elif test "x$with_toolchain_type" != x; then

   166     # User override; check that it is valid

   167     if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then

   168       AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])

   169       AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])

   170       AC_MSG_ERROR([Cannot continue.])

   171     fi

   172     TOOLCHAIN_TYPE=$with_toolchain_type

   173   else

   174     # No flag given, use default

   175     TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN

   176   fi

   177   AC_SUBST(TOOLCHAIN_TYPE)

   179   TOOLCHAIN_CC_BINARY_clang="clang"

   180   TOOLCHAIN_CC_BINARY_gcc="gcc"

   181   TOOLCHAIN_CC_BINARY_microsoft="cl"

   182   TOOLCHAIN_CC_BINARY_solstudio="cc"

   183   TOOLCHAIN_CC_BINARY_xlc="xlc_r"

   185   TOOLCHAIN_CXX_BINARY_clang="clang++"

   186   TOOLCHAIN_CXX_BINARY_gcc="g++"

   187   TOOLCHAIN_CXX_BINARY_microsoft="cl"

   188   TOOLCHAIN_CXX_BINARY_solstudio="CC"

   189   TOOLCHAIN_CXX_BINARY_xlc="xlC_r"

   191   # Use indirect variable referencing

   192   toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE

   193   TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}

   194   toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE

   195   TOOLCHAIN_CC_BINARY=${!toolchain_var_name}

   196   toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE

   197   TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}

   199   TOOLCHAIN_SETUP_FILENAME_PATTERNS

   201   if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then

   202     AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])

   203   else

   204     AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])

   205   fi

   206 ])

   208 # Before we start detecting the toolchain executables, we might need some

   209 # special setup, e.g. additional paths etc.

   210 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],

   211 [

   212   # FIXME: Is this needed?

   213   AC_LANG(C++)

   215   # Store the CFLAGS etal passed to the configure script.

   216   ORG_CFLAGS="$CFLAGS"

   217   ORG_CXXFLAGS="$CXXFLAGS"

   218   ORG_OBJCFLAGS="$OBJCFLAGS"

   220   # autoconf magic only relies on PATH, so update it if tools dir is specified

   221   OLD_PATH="$PATH"

   223   # Before we locate the compilers, we need to sanitize the Xcode build environment

   224   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   225     # determine path to Xcode developer directory

   226     # can be empty in which case all the tools will rely on a sane Xcode 4 installation

   227     SET_DEVELOPER_DIR=

   229     if test -n "$XCODE_PATH"; then

   230       DEVELOPER_DIR="$XCODE_PATH"/Contents/Developer

   231     fi

   233     # DEVELOPER_DIR could also be provided directly

   234     AC_MSG_CHECKING([Determining if we need to set DEVELOPER_DIR])

   235     if test -n "$DEVELOPER_DIR"; then

   236       if test ! -d "$DEVELOPER_DIR"; then

   237         AC_MSG_ERROR([Xcode Developer path does not exist: $DEVELOPER_DIR, please provide a path to the Xcode 4 application bundle using --with-xcode-path])

   238       fi

   239       if test ! -f "$DEVELOPER_DIR"/usr/bin/xcodebuild; then

   240         AC_MSG_ERROR([Xcode Developer path is not valid: $DEVELOPER_DIR, it must point to Contents/Developer inside an Xcode application bundle])

   241       fi

   242       # make it visible to all the tools immediately

   243       export DEVELOPER_DIR

   244       SET_DEVELOPER_DIR="export DEVELOPER_DIR := $DEVELOPER_DIR"

   245       AC_MSG_RESULT([yes ($DEVELOPER_DIR)])

   246     else

   247       AC_MSG_RESULT([no])

   248     fi

   249     AC_SUBST(SET_DEVELOPER_DIR)

   251     AC_PATH_PROG(XCODEBUILD, xcodebuild)

   252     if test -z "$XCODEBUILD"; then

   253       AC_MSG_ERROR([The xcodebuild tool was not found, the Xcode command line tools are required to build on Mac OS X])

   254     fi

   256     # Fail-fast: verify we're building on Xcode 4, we cannot build with Xcode 5 or later

   257     XCODE_VERSION=`$XCODEBUILD -version | grep '^Xcode ' | sed 's/Xcode //'`

   258     XC_VERSION_PARTS=( ${XCODE_VERSION//./ } )

   259     if test ! "${XC_VERSION_PARTS[[0]]}" = "4"; then

   260       AC_MSG_ERROR([Xcode 4 is required to build JDK 8, the version found was $XCODE_VERSION. Use --with-xcode-path to specify the location of Xcode 4 or make Xcode 4 active by using xcode-select.])

   261     fi

   263     # Some versions of Xcode 5 command line tools install gcc and g++ as symlinks to

   264     # clang and clang++, which will break the build. So handle that here if we need to.

   265     if test -L "/usr/bin/gcc" -o -L "/usr/bin/g++"; then

   266       # use xcrun to find the real gcc and add it's directory to PATH

   267       # then autoconf magic will find it

   268       AC_MSG_NOTICE([Found gcc symlinks to clang in /usr/bin, adding path to real gcc to PATH])

   269       XCODE_BIN_PATH=$(dirname `xcrun -find gcc`)

   270       PATH="$XCODE_BIN_PATH":$PATH

   271     fi

   273     # Determine appropriate SDKPATH, don't use SDKROOT as it interferes with the stub tools

   274     AC_MSG_CHECKING([Determining Xcode SDK path])

   275     # allow SDKNAME to be set to override the default SDK selection

   276     SDKPATH=`"$XCODEBUILD" -sdk ${SDKNAME:-macosx} -version | grep '^Path: ' | sed 's/Path: //'`

   277     if test -n "$SDKPATH"; then

   278       AC_MSG_RESULT([$SDKPATH])

   279     else

   280       AC_MSG_RESULT([(none, will use system headers and frameworks)])

   281     fi

   282     AC_SUBST(SDKPATH)

   284     # Perform a basic sanity test

   285     if test ! -f "$SDKPATH/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then

   286       AC_MSG_ERROR([Unable to find required framework headers, provide a valid path to Xcode 4 using --with-xcode-path])

   287     fi

   289     # if SDKPATH is non-empty then we need to add -isysroot and -iframework for gcc and g++

   290     if test -n "$SDKPATH"; then

   291       # We need -isysroot <path> and -iframework<path>/System/Library/Frameworks

   292       CFLAGS_JDK="${CFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""

   293       CXXFLAGS_JDK="${CXXFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""

   294       LDFLAGS_JDK="${LDFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""

   295     fi

   297     # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework

   298     # setting this here means it doesn't have to be peppered throughout the forest

   299     CFLAGS_JDK="$CFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""

   300     CXXFLAGS_JDK="$CXXFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""

   301     LDFLAGS_JDK="$LDFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""

   302   fi

   304   # For solaris we really need solaris tools, and not the GNU equivalent.

   305   # The build tools on Solaris reside in /usr/ccs (C Compilation System),

   306   # so add that to path before starting to probe.

   307   # FIXME: This was originally only done for AS,NM,GNM,STRIP,MCS,OBJCOPY,OBJDUMP.

   308   if test "x$OPENJDK_BUILD_OS" = xsolaris; then

   309     PATH="/usr/ccs/bin:$PATH"

   310   fi

   312   # On Windows, we need to detect the visual studio installation first.

   313   if test "x$OPENJDK_BUILD_OS" = "xwindows" && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then

   314     TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV

   315   fi

   317   # Finally add TOOLS_DIR at the beginning, to allow --with-tools-dir to

   318   # override all other locations.

   319   if test "x$TOOLS_DIR" != x; then

   320     PATH=$TOOLS_DIR:$PATH

   321   fi

   323   # If a devkit is found on the builddeps server, then prepend its path to the

   324   # PATH variable. If there are cross compilers available in the devkit, these

   325   # will be found by AC_PROG_CC et al.

   326   DEVKIT=

   327   BDEPS_CHECK_MODULE(DEVKIT, devkit, xxx,

   328       [

   329         # Found devkit

   330         PATH="$DEVKIT/bin:$PATH"

   331         SYS_ROOT="$DEVKIT/${rewritten_target}/sys-root"

   332         if test "x$x_includes" = "xNONE"; then

   333           x_includes="$SYS_ROOT/usr/include/X11"

   334         fi

   335         if test "x$x_libraries" = "xNONE"; then

   336           x_libraries="$SYS_ROOT/usr/lib"

   337         fi

   338       ],

   339       [])

   340 ])

   342 # Restore path, etc

   343 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],

   344 [

   345   # Restore old path.

   346   PATH="$OLD_PATH"

   348   # Restore the flags to the user specified values.

   349   # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"

   350   CFLAGS="$ORG_CFLAGS"

   351   CXXFLAGS="$ORG_CXXFLAGS"

   352   OBJCFLAGS="$ORG_OBJCFLAGS"

   353 ])

   355 # Check if a compiler is of the toolchain type we expect, and save the version

   356 # information from it. If the compiler does not match the expected type,

   357 # this function will abort using AC_MSG_ERROR. If it matches, the version will

   358 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and

   359 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.

   360 #

   361 # $1 = compiler to test (CC or CXX)

   362 # $2 = human readable name of compiler (C or C++)

   363 AC_DEFUN([TOOLCHAIN_EXTRACT_COMPILER_VERSION],

   364 [

   365   COMPILER=[$]$1

   366   COMPILER_NAME=$2

   368   if test "x$TOOLCHAIN_TYPE" = xsolstudio; then

   369     # cc -V output typically looks like

   370     #     cc: Sun C 5.12 Linux_i386 2011/11/16

   371     COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`

   372     # Check that this is likely to be the Solaris Studio cc.

   373     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null

   374     if test $? -ne 0; then

   375       ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`

   376       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])

   377       AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])

   378       AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])

   379       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])

   380     fi

   381     # Remove usage instructions (if present), and

   382     # collapse compiler output into a single line

   383     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \

   384         $SED -e 's/ *@<:@Uu@:>@sage:.*//'`

   385     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \

   386         $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`

   387   elif test  "x$TOOLCHAIN_TYPE" = xxlc; then

   388     # xlc -qversion output typically looks like

   389     #     IBM XL C/C++ for AIX, V11.1 (5724-X13)

   390     #     Version: 11.01.0000.0015

   391     COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`

   392     # Check that this is likely to be the IBM XL C compiler.

   393     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null

   394     if test $? -ne 0; then

   395       ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`

   396       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])

   397       AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])

   398       AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])

   399       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])

   400     fi

   401     # Collapse compiler output into a single line

   402     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`

   403     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \

   404         $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`

   405   elif test  "x$TOOLCHAIN_TYPE" = xmicrosoft; then

   406     # There is no specific version flag, but all output starts with a version string.

   407     # First line typically looks something like:

   408     # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86

   409     COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`

   410     # Check that this is likely to be Microsoft CL.EXE.

   411     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null

   412     if test $? -ne 0; then

   413       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])

   414       AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])

   415       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])

   416     fi

   417     # Collapse compiler output into a single line

   418     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`

   419     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \

   420         $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`

   421   elif test  "x$TOOLCHAIN_TYPE" = xgcc; then

   422     # gcc --version output typically looks like

   423     #     gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1

   424     #     Copyright (C) 2013 Free Software Foundation, Inc.

   425     #     This is free software; see the source for copying conditions.  There is NO

   426     #     warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

   427     COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`

   428     # Check that this is likely to be GCC.

   429     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null

   430     if test $? -ne 0; then

   431       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])

   432       AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])

   433       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])

   434     fi

   435     # Remove Copyright and legalese from version string, and

   436     # collapse into a single line

   437     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \

   438         $SED -e 's/ *Copyright .*//'`

   439     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \

   440         $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\) .*$/\1/'`

   441   elif test  "x$TOOLCHAIN_TYPE" = xclang; then

   442     # clang --version output typically looks like

   443     #    Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)

   444     #    clang version 3.3 (tags/RELEASE_33/final)

   445     # or

   446     #    Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)

   447     #    Target: x86_64-pc-linux-gnu

   448     #    Thread model: posix

   449     COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`

   450     # Check that this is likely to be clang

   451     $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null

   452     if test $? -ne 0; then

   453       AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])

   454       AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])

   455       AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])

   456     fi

   457     # Collapse compiler output into a single line

   458     COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`

   459     COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \

   460         $SED -e 's/^.*clang version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`

   462   else

   463       AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])

   464   fi

   465   # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)

   466   $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"

   467   # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)

   468   $1_VERSION_STRING="$COMPILER_VERSION_STRING"

   470   AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])

   471 ])

   474 # Try to locate the given C or C++ compiler in the path, or otherwise.

   475 #

   476 # $1 = compiler to test (CC or CXX)

   477 # $2 = human readable name of compiler (C or C++)

   478 # $3 = list of compiler names to search for

   479 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],

   480 [

   481   COMPILER_NAME=$2

   482   SEARCH_LIST="$3"

   484   if test "x[$]$1" != x; then

   485     # User has supplied compiler name already, always let that override.

   486     AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])

   487     if test "x`basename [$]$1`" = "x[$]$1"; then

   488       # A command without a complete path is provided, search $PATH.

   490       AC_PATH_PROGS(POTENTIAL_$1, [$]$1)

   491       if test "x$POTENTIAL_$1" != x; then

   492         $1=$POTENTIAL_$1

   493       else

   494         AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])

   495       fi

   496     else

   497       # Otherwise it might already be a complete path

   498       if test ! -x "[$]$1"; then

   499         AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])

   500       fi

   501     fi

   502   else

   503     # No user supplied value. Locate compiler ourselves.

   505     # If we are cross compiling, assume cross compilation tools follows the

   506     # cross compilation standard where they are prefixed with the autoconf

   507     # standard name for the target. For example the binary

   508     # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.

   509     # If we are not cross compiling, then the default compiler name will be

   510     # used.

   512     $1=

   513     # If TOOLS_DIR is set, check for all compiler names in there first

   514     # before checking the rest of the PATH.

   515     # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION

   516     # step, this should not be necessary.

   517     if test -n "$TOOLS_DIR"; then

   518       PATH_save="$PATH"

   519       PATH="$TOOLS_DIR"

   520       AC_PATH_PROGS(TOOLS_DIR_$1, $3)

   521       $1=$TOOLS_DIR_$1

   522       PATH="$PATH_save"

   523     fi

   525     # AC_PATH_PROGS can't be run multiple times with the same variable,

   526     # so create a new name for this run.

   527     if test "x[$]$1" = x; then

   528       AC_PATH_PROGS(POTENTIAL_$1, $3)

   529       $1=$POTENTIAL_$1

   530     fi

   532     if test "x[$]$1" = x; then

   533       HELP_MSG_MISSING_DEPENDENCY([devkit])

   534       AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])

   535     fi

   536   fi

   538   # Now we have a compiler binary in $1. Make sure it's okay.

   539   BASIC_FIXUP_EXECUTABLE($1)

   540   TEST_COMPILER="[$]$1"

   541   # Don't remove symbolic links on AIX because 'xlc_r' and 'xlC_r' may all be links

   542   # to 'xlc' but it is crucial that we invoke the compiler with the right name!

   543   if test "x$OPENJDK_BUILD_OS" != xaix; then

   544     # FIXME: This test should not be needed anymore; we don't do that for any platform.

   545     AC_MSG_CHECKING([resolved symbolic links for $1])

   546     BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)

   547     AC_MSG_RESULT([$TEST_COMPILER])

   548   fi

   549   AC_MSG_CHECKING([if $1 is disguised ccache])

   551   COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`

   552   if test "x$COMPILER_BASENAME" = "xccache"; then

   553     AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])

   554     # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.

   555     # We want to control ccache invocation ourselves, so ignore this cc and try

   556     # searching again.

   558     # Remove the path to the fake ccache cc from the PATH

   559     RETRY_COMPILER_SAVED_PATH="$PATH"

   560     COMPILER_DIRNAME=`$DIRNAME [$]$1`

   561     PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"

   563     # Try again looking for our compiler

   564     AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)

   565     BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)

   566     PATH="$RETRY_COMPILER_SAVED_PATH"

   568     AC_MSG_CHECKING([for resolved symbolic links for $1])

   569     BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)

   570     AC_MSG_RESULT([$PROPER_COMPILER_$1])

   571     $1="$PROPER_COMPILER_$1"

   572   else

   573     AC_MSG_RESULT([no, keeping $1])

   574     $1="$TEST_COMPILER"

   575   fi

   577   TOOLCHAIN_EXTRACT_COMPILER_VERSION([$1], [$COMPILER_NAME])

   578 ])

   580 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),

   581 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the

   582 # archiver (AR). Verify that the compilers are correct according to the

   583 # toolchain type.

   584 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],

   585 [

   586   #

   587   # Setup the compilers (CC and CXX)

   588   #

   589   TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)

   590   # Now that we have resolved CC ourself, let autoconf have its go at it

   591   AC_PROG_CC([$CC])

   593   TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)

   594   # Now that we have resolved CXX ourself, let autoconf have its go at it

   595   AC_PROG_CXX([$CXX])

   597   # This is the compiler version number on the form X.Y[.Z]

   598   AC_SUBST(CC_VERSION_NUMBER)

   599   AC_SUBST(CXX_VERSION_NUMBER)

   601   TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS

   603   #

   604   # Setup the preprocessor (CPP and CXXCPP)

   605   #

   606   AC_PROG_CPP

   607   BASIC_FIXUP_EXECUTABLE(CPP)

   608   AC_PROG_CXXCPP

   609   BASIC_FIXUP_EXECUTABLE(CXXCPP)

   611   #

   612   # Setup the linker (LD)

   613   #

   614   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then

   615     # In the Microsoft toolchain we have a separate LD command "link".

   616     # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is

   617     # a cygwin program for something completely different.

   618     AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])

   619     BASIC_FIXUP_EXECUTABLE(LD)

   620     # Verify that we indeed succeeded with this trick.

   621     AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])

   622     "$LD" --version > /dev/null

   623     if test $? -eq 0 ; then

   624       AC_MSG_RESULT([no])

   625       AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])

   626     else

   627       AC_MSG_RESULT([yes])

   628     fi

   629     LDCXX="$LD"

   630   else

   631     # All other toolchains use the compiler to link.

   632     LD="$CC"

   633     LDCXX="$CXX"

   634   fi

   635   AC_SUBST(LD)

   636   # FIXME: it should be CXXLD, according to standard (cf CXXCPP)

   637   AC_SUBST(LDCXX)

   639   #

   640   # Setup the assembler (AS)

   641   #

   642   if test "x$OPENJDK_TARGET_OS" = xsolaris; then

   643     # FIXME: should this really be solaris, or solstudio?

   644     BASIC_PATH_PROGS(AS, as)

   645     BASIC_FIXUP_EXECUTABLE(AS)

   646   else

   647     # FIXME: is this correct for microsoft?

   648     AS="$CC -c"

   649   fi

   650   AC_SUBST(AS)

   652   #

   653   # Setup the archiver (AR)

   654   #

   655   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then

   656     # The corresponding ar tool is lib.exe (used to create static libraries)

   657     AC_CHECK_PROG([AR], [lib],[lib],,,)

   658   else

   659     BASIC_CHECK_TOOLS(AR, ar)

   660   fi

   661   BASIC_FIXUP_EXECUTABLE(AR)

   662 ])

   664 # Setup additional tools that is considered a part of the toolchain, but not the

   665 # core part. Many of these are highly platform-specific and do not exist,

   666 # and/or are not needed on all platforms.

   667 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],

   668 [

   669   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   670     AC_PROG_OBJC

   671     BASIC_FIXUP_EXECUTABLE(OBJC)

   672     BASIC_PATH_PROGS(LIPO, lipo)

   673     BASIC_FIXUP_EXECUTABLE(LIPO)

   674   else

   675     OBJC=

   676   fi

   678   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then

   679     AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])

   680     BASIC_FIXUP_EXECUTABLE(MT)

   681     # Setup the resource compiler (RC)

   682     AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])

   683     BASIC_FIXUP_EXECUTABLE(RC)

   684     AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)

   685     BASIC_FIXUP_EXECUTABLE(DUMPBIN)

   686   fi

   688   if test "x$OPENJDK_TARGET_OS" = xsolaris; then

   689     BASIC_PATH_PROGS(STRIP, strip)

   690     BASIC_FIXUP_EXECUTABLE(STRIP)

   691     BASIC_PATH_PROGS(NM, nm)

   692     BASIC_FIXUP_EXECUTABLE(NM)

   693     BASIC_PATH_PROGS(GNM, gnm)

   694     BASIC_FIXUP_EXECUTABLE(GNM)

   696     BASIC_PATH_PROGS(MCS, mcs)

   697     BASIC_FIXUP_EXECUTABLE(MCS)

   698   elif test "x$OPENJDK_TARGET_OS" != xwindows; then

   699     # FIXME: we should unify this with the solaris case above.

   700     BASIC_CHECK_TOOLS(STRIP, strip)

   701     BASIC_FIXUP_EXECUTABLE(STRIP)

   702     AC_PATH_PROG(OTOOL, otool)

   703     if test "x$OTOOL" = "x"; then

   704       OTOOL="true"

   705     fi

   706     BASIC_CHECK_TOOLS(NM, nm)

   707     BASIC_FIXUP_EXECUTABLE(NM)

   708     GNM="$NM"

   709     AC_SUBST(GNM)

   710   fi

   712   # objcopy is used for moving debug symbols to separate files when

   713   # full debug symbols are enabled.

   714   if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then

   715     BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])

   716     # Only call fixup if objcopy was found.

   717     if test -n "$OBJCOPY"; then

   718       BASIC_FIXUP_EXECUTABLE(OBJCOPY)

   719     fi

   720   fi

   722   BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])

   723   if test "x$OBJDUMP" != x; then

   724     # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE

   725     # bails if argument is missing.

   726     BASIC_FIXUP_EXECUTABLE(OBJDUMP)

   727   fi

   728 ])

   730 # Setup the build tools (i.e, the compiler and linker used to build programs

   731 # that should be run on the build platform, not the target platform, as a build

   732 # helper). Since the non-cross-compile case uses the normal, target compilers

   733 # for this, we can only do this after these have been setup.

   734 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],

   735 [

   736   if test "x$COMPILE_TYPE" = "xcross"; then

   737     # Now we need to find a C/C++ compiler that can build executables for the

   738     # build platform. We can't use the AC_PROG_CC macro, since it can only be

   739     # used once. Also, we need to do this without adding a tools dir to the

   740     # path, otherwise we might pick up cross-compilers which don't use standard

   741     # naming.

   743     # FIXME: we should list the discovered compilers as an exclude pattern!

   744     # If we do that, we can do this detection before POST_DETECTION, and still

   745     # find the build compilers in the tools dir, if needed.

   746     BASIC_PATH_PROGS(BUILD_CC, [cl cc gcc])

   747     BASIC_FIXUP_EXECUTABLE(BUILD_CC)

   748     BASIC_PATH_PROGS(BUILD_CXX, [cl CC g++])

   749     BASIC_FIXUP_EXECUTABLE(BUILD_CXX)

   750     BASIC_PATH_PROGS(BUILD_LD, ld)

   751     BASIC_FIXUP_EXECUTABLE(BUILD_LD)

   752   else

   753     # If we are not cross compiling, use the normal target compilers for

   754     # building the build platform executables.

   755     BUILD_CC="$CC"

   756     BUILD_CXX="$CXX"

   757     BUILD_LD="$LD"

   758   fi

   759 ])

   761 # Setup legacy variables that are still needed as alternative ways to refer to

   762 # parts of the toolchain.

   763 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_LEGACY],

   764 [

   765   if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then

   766     # For hotspot, we need these in Windows mixed path,

   767     # so rewrite them all. Need added .exe suffix.

   768     HOTSPOT_CXX="$CXX.exe"

   769     HOTSPOT_LD="$LD.exe"

   770     HOTSPOT_MT="$MT.exe"

   771     HOTSPOT_RC="$RC.exe"

   772     BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)

   773     BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)

   774     BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)

   775     BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)

   776     AC_SUBST(HOTSPOT_MT)

   777     AC_SUBST(HOTSPOT_RC)

   778   else

   779     HOTSPOT_CXX="$CXX"

   780     HOTSPOT_LD="$LD"

   781   fi

   782   AC_SUBST(HOTSPOT_CXX)

   783   AC_SUBST(HOTSPOT_LD)

   785   if test  "x$TOOLCHAIN_TYPE" = xclang; then

   786     USE_CLANG=true

   787   fi

   788   AC_SUBST(USE_CLANG)

   790   # LDEXE is the linker to use, when creating executables. Not really used.

   791   # FIXME: These should just be removed!

   792   LDEXE="$LD"

   793   LDEXECXX="$LDCXX"

   794   AC_SUBST(LDEXE)

   795   AC_SUBST(LDEXECXX)

   796 ])

   798 # Do some additional checks on the detected tools.

   799 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],

   800  [

   801   # The package path is used only on macosx?

   802   # FIXME: clean this up, and/or move it elsewhere.

   803   PACKAGE_PATH=/opt/local

   804   AC_SUBST(PACKAGE_PATH)

   806   # Check for extra potential brokenness.

   807   if test  "x$TOOLCHAIN_TYPE" = xmicrosoft; then

   808     # On Windows, double-check that we got the right compiler.

   809     CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`

   810     COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`

   811     if test "x$OPENJDK_TARGET_CPU" = "xx86"; then

   812       if test "x$COMPILER_CPU_TEST" != "x80x86"; then

   813         AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])

   814       fi

   815     elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then

   816       if test "x$COMPILER_CPU_TEST" != "xx64"; then

   817         AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])

   818       fi

   819     fi

   820   fi

   822   if test "x$TOOLCHAIN_TYPE" = xgcc; then

   823     # If this is a --hash-style=gnu system, use --hash-style=both, why?

   824     HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`

   825     # This is later checked when setting flags.

   826   fi

   828   # Check for broken SuSE 'ld' for which 'Only anonymous version tag is allowed

   829   # in executable.'

   830   USING_BROKEN_SUSE_LD=no

   831   if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$TOOLCHAIN_TYPE" = xgcc; then

   832     AC_MSG_CHECKING([for broken SuSE 'ld' which only understands anonymous version tags in executables])

   833     echo "SUNWprivate_1.1 { local: *; };" > version-script.map

   834     echo "int main() { }" > main.c

   835     if $CXX -Xlinker -version-script=version-script.map main.c 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then

   836       AC_MSG_RESULT(no)

   837       USING_BROKEN_SUSE_LD=no

   838     else

   839       AC_MSG_RESULT(yes)

   840       USING_BROKEN_SUSE_LD=yes

   841     fi

   842     rm -rf version-script.map main.c

   843   fi

   844   AC_SUBST(USING_BROKEN_SUSE_LD)

   845 ])

   847 # Setup the JTReg Regression Test Harness.

   848 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],

   849 [

   850   AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],

   851       [Regression Test Harness @<:@probed@:>@])],

   852       [],

   853       [with_jtreg=no])

   855   if test "x$with_jtreg" = xno; then

   856     # jtreg disabled

   857     AC_MSG_CHECKING([for jtreg])

   858     AC_MSG_RESULT(no)

   859   else

   860     if test "x$with_jtreg" != xyes; then

   861       # with path specified.

   862       JT_HOME="$with_jtreg"

   863     fi

   865     if test "x$JT_HOME" != x; then

   866       AC_MSG_CHECKING([for jtreg])

   868       # use JT_HOME enviroment var.

   869       BASIC_FIXUP_PATH([JT_HOME])

   871       # jtreg win32 script works for everybody

   872       JTREGEXE="$JT_HOME/bin/jtreg"

   874       if test ! -f "$JTREGEXE"; then

   875         AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])

   876       fi

   878       AC_MSG_RESULT($JTREGEXE)

   879     else

   880       # try to find jtreg on path

   881       BASIC_REQUIRE_PROGS(JTREGEXE, jtreg)

   882       JT_HOME="`$DIRNAME $JTREGEXE`"

   883     fi

   884   fi

   886   AC_SUBST(JT_HOME)

   887   AC_SUBST(JTREGEXE)

   888 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/toolchain.m4@7ba4e17574e0

common/autoconf/toolchain.m4