Wed, 22 Jan 2014 12:53:21 -0800
Added tag jdk8-b125 for changeset 790bbd46b201
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 AC_DEFUN([BPERF_CHECK_CORES],
27 [
28 AC_MSG_CHECKING([for number of cores])
29 NUM_CORES=1
30 FOUND_CORES=no
32 if test -f /proc/cpuinfo; then
33 # Looks like a Linux (or cygwin) system
34 NUM_CORES=`cat /proc/cpuinfo | grep -c processor`
35 FOUND_CORES=yes
36 elif test -x /usr/sbin/psrinfo; then
37 # Looks like a Solaris system
38 NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`
39 FOUND_CORES=yes
40 elif test -x /usr/sbin/system_profiler; then
41 # Looks like a MacOSX system
42 NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk '{print [$]5}'`
43 FOUND_CORES=yes
44 elif test -n "$NUMBER_OF_PROCESSORS"; then
45 # On windows, look in the env
46 NUM_CORES=$NUMBER_OF_PROCESSORS
47 FOUND_CORES=yes
48 fi
50 if test "x$FOUND_CORES" = xyes; then
51 AC_MSG_RESULT([$NUM_CORES])
52 else
53 AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
54 AC_MSG_WARN([This will disable all parallelism from build!])
55 fi
56 ])
58 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
59 [
60 AC_MSG_CHECKING([for memory size])
61 # Default to 1024 MB
62 MEMORY_SIZE=1024
63 FOUND_MEM=no
65 if test -f /proc/meminfo; then
66 # Looks like a Linux (or cygwin) system
67 MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
68 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
69 FOUND_MEM=yes
70 elif test -x /usr/sbin/prtconf; then
71 # Looks like a Solaris system
72 MEMORY_SIZE=`/usr/sbin/prtconf | grep "Memory size" | awk '{ print [$]3 }'`
73 FOUND_MEM=yes
74 elif test -x /usr/sbin/system_profiler; then
75 # Looks like a MacOSX system
76 MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk '{print [$]2}'`
77 MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`
78 FOUND_MEM=yes
79 elif test "x$OPENJDK_BUILD_OS" = xwindows; then
80 # Windows, but without cygwin
81 MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
82 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
83 FOUND_MEM=yes
84 fi
86 if test "x$FOUND_MEM" = xyes; then
87 AC_MSG_RESULT([$MEMORY_SIZE MB])
88 else
89 AC_MSG_RESULT([could not detect memory size, defaulting to 1024 MB])
90 AC_MSG_WARN([This might seriously impact build performance!])
91 fi
92 ])
94 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
95 [
96 # How many cores do we have on this build system?
97 AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
98 [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
99 if test "x$with_num_cores" = x; then
100 # The number of cores were not specified, try to probe them.
101 BPERF_CHECK_CORES
102 else
103 NUM_CORES=$with_num_cores
104 fi
105 AC_SUBST(NUM_CORES)
106 ])
108 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
109 [
110 # How much memory do we have on this build system?
111 AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
112 [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
113 if test "x$with_memory_size" = x; then
114 # The memory size was not specified, try to probe it.
115 BPERF_CHECK_MEMORY_SIZE
116 else
117 MEMORY_SIZE=$with_memory_size
118 fi
119 AC_SUBST(MEMORY_SIZE)
120 ])
122 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
123 [
124 # Provide a decent default number of parallel jobs for make depending on
125 # number of cores, amount of memory and machine architecture.
126 AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
127 [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
128 if test "x$with_jobs" = x; then
129 # Number of jobs was not specified, calculate.
130 AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
131 # Approximate memory in GB, rounding up a bit.
132 memory_gb=`expr $MEMORY_SIZE / 1100`
133 # Pick the lowest of memory in gb and number of cores.
134 if test "$memory_gb" -lt "$NUM_CORES"; then
135 JOBS="$memory_gb"
136 else
137 JOBS="$NUM_CORES"
138 # On bigger machines, leave some room for other processes to run
139 if test "$JOBS" -gt "4"; then
140 JOBS=`expr $JOBS '*' 90 / 100`
141 fi
142 fi
143 # Cap number of jobs to 16
144 if test "$JOBS" -gt "16"; then
145 JOBS=16
146 fi
147 if test "$JOBS" -eq "0"; then
148 JOBS=1
149 fi
150 AC_MSG_RESULT([$JOBS])
151 else
152 JOBS=$with_jobs
153 fi
154 AC_SUBST(JOBS)
155 ])
157 AC_DEFUN([BPERF_SETUP_CCACHE],
158 [
159 AC_ARG_ENABLE([ccache],
160 [AS_HELP_STRING([--disable-ccache],
161 [disable using ccache to speed up recompilations @<:@enabled@:>@])],
162 [ENABLE_CCACHE=${enable_ccache}], [ENABLE_CCACHE=yes])
163 if test "x$ENABLE_CCACHE" = xyes; then
164 OLD_PATH="$PATH"
165 if test "x$TOOLS_DIR" != x; then
166 PATH=$TOOLS_DIR:$PATH
167 fi
168 AC_PATH_PROG(CCACHE, ccache)
169 PATH="$OLD_PATH"
170 else
171 AC_MSG_CHECKING([for ccache])
172 AC_MSG_RESULT([explicitly disabled])
173 CCACHE=
174 fi
175 AC_SUBST(CCACHE)
177 AC_ARG_WITH([ccache-dir],
178 [AS_HELP_STRING([--with-ccache-dir],
179 [where to store ccache files @<:@~/.ccache@:>@])])
181 if test "x$with_ccache_dir" != x; then
182 # When using a non home ccache directory, assume the use is to share ccache files
183 # with other users. Thus change the umask.
184 SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
185 fi
186 CCACHE_FOUND=""
187 if test "x$CCACHE" != x; then
188 BPERF_SETUP_CCACHE_USAGE
189 fi
190 ])
192 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
193 [
194 if test "x$CCACHE" != x; then
195 CCACHE_FOUND="true"
196 # Only use ccache if it is 3.1.4 or later, which supports
197 # precompiled headers.
198 AC_MSG_CHECKING([if ccache supports precompiled headers])
199 HAS_GOOD_CCACHE=`($CCACHE --version | head -n 1 | grep -E 3.1.@<:@456789@:>@) 2> /dev/null`
200 if test "x$HAS_GOOD_CCACHE" = x; then
201 AC_MSG_RESULT([no, disabling ccache])
202 CCACHE=
203 else
204 AC_MSG_RESULT([yes])
205 AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
206 PUSHED_FLAGS="$CXXFLAGS"
207 CXXFLAGS="-fpch-preprocess $CXXFLAGS"
208 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
209 CXXFLAGS="$PUSHED_FLAGS"
210 if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
211 AC_MSG_RESULT([yes])
212 else
213 AC_MSG_RESULT([no, disabling ccaching of precompiled headers])
214 CCACHE=
215 fi
216 fi
217 fi
219 if test "x$CCACHE" != x; then
220 CCACHE_SLOPPINESS=time_macros
221 CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS $CCACHE"
222 CCACHE_FLAGS=-fpch-preprocess
224 if test "x$SET_CCACHE_DIR" != x; then
225 mkdir -p $CCACHE_DIR > /dev/null 2>&1
226 chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
227 fi
228 fi
229 ])
231 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
232 [
234 ###############################################################################
235 #
236 # Can the C/C++ compiler use precompiled headers?
237 #
238 AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],
239 [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],
240 [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])
242 USE_PRECOMPILED_HEADER=1
243 if test "x$ENABLE_PRECOMPH" = xno; then
244 USE_PRECOMPILED_HEADER=0
245 fi
247 if test "x$ENABLE_PRECOMPH" = xyes; then
248 # Check that the compiler actually supports precomp headers.
249 if test "x$GCC" = xyes; then
250 AC_MSG_CHECKING([that precompiled headers work])
251 echo "int alfa();" > conftest.h
252 $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
253 if test ! -f conftest.hpp.gch; then
254 USE_PRECOMPILED_HEADER=0
255 AC_MSG_RESULT([no])
256 else
257 AC_MSG_RESULT([yes])
258 fi
259 rm -f conftest.h conftest.hpp.gch
260 fi
261 fi
263 AC_SUBST(USE_PRECOMPILED_HEADER)
264 ])
267 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],
268 [
269 AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],
270 [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])
272 if test "x$with_sjavac_server_java" != x; then
273 SJAVAC_SERVER_JAVA="$with_sjavac_server_java"
274 FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`
275 if test "x$FOUND_VERSION" = x; then
276 AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])
277 fi
278 else
279 SJAVAC_SERVER_JAVA=""
280 # Hotspot specific options.
281 ADD_JVM_ARG_IF_OK([-verbosegc],SJAVAC_SERVER_JAVA,[$JAVA])
282 # JRockit specific options.
283 ADD_JVM_ARG_IF_OK([-Xverbose:gc],SJAVAC_SERVER_JAVA,[$JAVA])
284 SJAVAC_SERVER_JAVA="$JAVA $SJAVAC_SERVER_JAVA"
285 fi
286 AC_SUBST(SJAVAC_SERVER_JAVA)
288 if test "$MEMORY_SIZE" -gt "2500"; then
289 ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
290 if test "$JVM_ARG_OK" = true; then
291 JVM_64BIT=true
292 JVM_ARG_OK=false
293 fi
294 fi
296 if test "$JVM_64BIT" = true; then
297 if test "$MEMORY_SIZE" -gt "17000"; then
298 ADD_JVM_ARG_IF_OK([-Xms10G -Xmx10G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
299 fi
300 if test "$MEMORY_SIZE" -gt "10000" && test "$JVM_ARG_OK" = false; then
301 ADD_JVM_ARG_IF_OK([-Xms6G -Xmx6G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
302 fi
303 if test "$MEMORY_SIZE" -gt "5000" && test "$JVM_ARG_OK" = false; then
304 ADD_JVM_ARG_IF_OK([-Xms1G -Xmx3G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
305 fi
306 if test "$MEMORY_SIZE" -gt "3800" && test "$JVM_ARG_OK" = false; then
307 ADD_JVM_ARG_IF_OK([-Xms1G -Xmx2500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
308 fi
309 fi
310 if test "$MEMORY_SIZE" -gt "2500" && test "$JVM_ARG_OK" = false; then
311 ADD_JVM_ARG_IF_OK([-Xms1000M -Xmx1500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
312 fi
313 if test "$MEMORY_SIZE" -gt "1000" && test "$JVM_ARG_OK" = false; then
314 ADD_JVM_ARG_IF_OK([-Xms400M -Xmx1100M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
315 fi
316 if test "$JVM_ARG_OK" = false; then
317 ADD_JVM_ARG_IF_OK([-Xms256M -Xmx512M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
318 fi
320 AC_MSG_CHECKING([whether to use sjavac])
321 AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],
322 [use sjavac to do fast incremental compiles @<:@disabled@:>@])],
323 [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC='no'])
324 AC_MSG_RESULT([$ENABLE_SJAVAC])
325 AC_SUBST(ENABLE_SJAVAC)
327 if test "x$ENABLE_SJAVAC" = xyes; then
328 SJAVAC_SERVER_DIR="$OUTPUT_ROOT/javacservers"
329 else
330 SJAVAC_SERVER_DIR=
331 fi
332 AC_SUBST(SJAVAC_SERVER_DIR)
333 ])