aoqi@0: #
aoqi@0: # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
aoqi@0: # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
aoqi@0: #
aoqi@0: # This code is free software; you can redistribute it and/or modify it
aoqi@0: # under the terms of the GNU General Public License version 2 only, as
aoqi@0: # published by the Free Software Foundation.  Oracle designates this
aoqi@0: # particular file as subject to the "Classpath" exception as provided
aoqi@0: # by Oracle in the LICENSE file that accompanied this code.
aoqi@0: #
aoqi@0: # This code is distributed in the hope that it will be useful, but WITHOUT
aoqi@0: # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
aoqi@0: # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License
aoqi@0: # version 2 for more details (a copy is included in the LICENSE file that
aoqi@0: # accompanied this code).
aoqi@0: #
aoqi@0: # You should have received a copy of the GNU General Public License version
aoqi@0: # 2 along with this work; if not, write to the Free Software Foundation,
aoqi@0: # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
aoqi@0: #
aoqi@0: # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
aoqi@0: # or visit www.oracle.com if you need additional information or have any
aoqi@0: # questions.
aoqi@0: #
aoqi@0: 
aoqi@0: # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
aoqi@0: # If so, then append $1 to $2 \
aoqi@0: # Also set JVM_ARG_OK to true/false depending on outcome.
aoqi@0: AC_DEFUN([ADD_JVM_ARG_IF_OK],
aoqi@0: [
aoqi@0:   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
aoqi@0:   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
aoqi@0:   OUTPUT=`$3 $1 -version 2>&1`
aoqi@0:   FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
aoqi@0:   FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
aoqi@0:   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
aoqi@0:     $2="[$]$2 $1"
aoqi@0:     JVM_ARG_OK=true
aoqi@0:   else
aoqi@0:     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
aoqi@0:     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
aoqi@0:     JVM_ARG_OK=false
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: # Appends a string to a path variable, only adding the : when needed.
aoqi@0: AC_DEFUN([BASIC_APPEND_TO_PATH],
aoqi@0: [
aoqi@0:   if test "x[$]$1" = x; then
aoqi@0:     $1="$2"
aoqi@0:   else
aoqi@0:     $1="[$]$1:$2"
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: # This will make sure the given variable points to a full and proper
aoqi@0: # path. This means:
aoqi@0: # 1) There will be no spaces in the path. On posix platforms,
aoqi@0: #    spaces in the path will result in an error. On Windows,
aoqi@0: #    the path will be rewritten using short-style to be space-free.
aoqi@0: # 2) The path will be absolute, and it will be in unix-style (on
aoqi@0: #     cygwin).
aoqi@0: # $1: The name of the variable to fix
aoqi@0: AC_DEFUN([BASIC_FIXUP_PATH],
aoqi@0: [
aoqi@0:   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
aoqi@0:     BASIC_FIXUP_PATH_CYGWIN($1)
aoqi@0:   elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
aoqi@0:     BASIC_FIXUP_PATH_MSYS($1)
aoqi@0:   else
aoqi@0:     # We're on a posix platform. Hooray! :)
aoqi@0:     path="[$]$1"
aoqi@0:     has_space=`$ECHO "$path" | $GREP " "`
aoqi@0:     if test "x$has_space" != x; then
aoqi@0:       AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
aoqi@0:       AC_MSG_ERROR([Spaces are not allowed in this path.])
aoqi@0:     fi
aoqi@0: 
aoqi@0:     # Use eval to expand a potential ~
aoqi@0:     eval path="$path"
aoqi@0:     if test ! -f "$path" && test ! -d "$path"; then
aoqi@0:       AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
aoqi@0:     fi
aoqi@0: 
aoqi@0:     $1="`cd "$path"; $THEPWDCMD -L`"
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: # This will make sure the given variable points to a executable
aoqi@0: # with a full and proper path. This means:
aoqi@0: # 1) There will be no spaces in the path. On posix platforms,
aoqi@0: #    spaces in the path will result in an error. On Windows,
aoqi@0: #    the path will be rewritten using short-style to be space-free.
aoqi@0: # 2) The path will be absolute, and it will be in unix-style (on
aoqi@0: #     cygwin).
aoqi@0: # Any arguments given to the executable is preserved.
aoqi@0: # If the input variable does not have a directory specification, then
aoqi@0: # it need to be in the PATH.
aoqi@0: # $1: The name of the variable to fix
aoqi@0: AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
aoqi@0: [
aoqi@0:   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
aoqi@0:     BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
aoqi@0:   elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
aoqi@0:     BASIC_FIXUP_EXECUTABLE_MSYS($1)
aoqi@0:   else
aoqi@0:     # We're on a posix platform. Hooray! :)
aoqi@0:     # First separate the path from the arguments. This will split at the first
aoqi@0:     # space.
aoqi@0:     complete="[$]$1"
aoqi@0:     path="${complete%% *}"
aoqi@0:     tmp="$complete EOL"
aoqi@0:     arguments="${tmp#* }"
aoqi@0: 
aoqi@0:     # Cannot rely on the command "which" here since it doesn't always work.
aoqi@0:     is_absolute_path=`$ECHO "$path" | $GREP ^/`
aoqi@0:     if test -z "$is_absolute_path"; then
aoqi@0:       # Path to executable is not absolute. Find it.
aoqi@0:       IFS_save="$IFS"
aoqi@0:       IFS=:
aoqi@0:       for p in $PATH; do
aoqi@0:         if test -f "$p/$path" && test -x "$p/$path"; then
aoqi@0:           new_path="$p/$path"
aoqi@0:           break
aoqi@0:         fi
aoqi@0:       done
aoqi@0:       IFS="$IFS_save"
aoqi@0:     else
aoqi@0:       AC_MSG_NOTICE([Resolving $1 (as $path) failed, using $path directly.])
aoqi@0:       new_path="$path"
aoqi@0:     fi
aoqi@0: 
aoqi@0:     if test "x$new_path" = x; then
aoqi@0:       AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
aoqi@0:       has_space=`$ECHO "$complete" | $GREP " "`
aoqi@0:       if test "x$has_space" != x; then
aoqi@0:         AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
aoqi@0:       fi
aoqi@0:       AC_MSG_ERROR([Cannot locate the the path of $1])
aoqi@0:     fi
aoqi@0:   fi
aoqi@0: 
aoqi@0:   # Now join together the path and the arguments once again
aoqi@0:   if test "x$arguments" != xEOL; then
aoqi@0:     new_complete="$new_path ${arguments% *}"
aoqi@0:   else
aoqi@0:     new_complete="$new_path"
aoqi@0:   fi
aoqi@0: 
aoqi@0:   if test "x$complete" != "x$new_complete"; then
aoqi@0:     $1="$new_complete"
aoqi@0:     AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
aoqi@0: [
aoqi@0:   if test "x$OPENJDK_BUILD_OS" != xwindows; then
aoqi@0:     # Follow a chain of symbolic links. Use readlink
aoqi@0:     # where it exists, else fall back to horribly
aoqi@0:     # complicated shell code.
aoqi@0:     if test "x$READLINK_TESTED" != yes; then
aoqi@0:       # On MacOSX there is a readlink tool with a different
aoqi@0:       # purpose than the GNU readlink tool. Check the found readlink.
aoqi@0:       ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
aoqi@0:       if test "x$ISGNU" = x; then
aoqi@0:         # A readlink that we do not know how to use.
aoqi@0:         # Are there other non-GNU readlinks out there?
aoqi@0:         READLINK_TESTED=yes
aoqi@0:         READLINK=
aoqi@0:       fi
aoqi@0:     fi
aoqi@0: 
aoqi@0:     if test "x$READLINK" != x; then
aoqi@0:       $1=`$READLINK -f [$]$1`
aoqi@0:     else
aoqi@0:       # Save the current directory for restoring afterwards
aoqi@0:       STARTDIR=$PWD
aoqi@0:       COUNTER=0
aoqi@0:       sym_link_dir=`$DIRNAME [$]$1`
aoqi@0:       sym_link_file=`$BASENAME [$]$1`
aoqi@0:       cd $sym_link_dir
aoqi@0:       # Use -P flag to resolve symlinks in directories.
aoqi@0:       cd `$THEPWDCMD -P`
aoqi@0:       sym_link_dir=`$THEPWDCMD -P`
aoqi@0:       # Resolve file symlinks
aoqi@0:       while test $COUNTER -lt 20; do
aoqi@0:         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
aoqi@0:         if test "x$ISLINK" == x; then
aoqi@0:           # This is not a symbolic link! We are done!
aoqi@0:           break
aoqi@0:         fi
aoqi@0:         # Again resolve directory symlinks since the target of the just found
aoqi@0:         # link could be in a different directory
aoqi@0:         cd `$DIRNAME $ISLINK`
aoqi@0:         sym_link_dir=`$THEPWDCMD -P`
aoqi@0:         sym_link_file=`$BASENAME $ISLINK`
aoqi@0:         let COUNTER=COUNTER+1
aoqi@0:       done
aoqi@0:       cd $STARTDIR
aoqi@0:       $1=$sym_link_dir/$sym_link_file
aoqi@0:     fi
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: # Register a --with argument but mark it as deprecated
aoqi@0: # $1: The name of the with argument to deprecate, not including --with-
aoqi@0: AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
aoqi@0: [
aoqi@0:   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
aoqi@0:       [Deprecated. Option is kept for backwards compatibility and is ignored])],
aoqi@0:       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
aoqi@0: ])
aoqi@0: 
aoqi@0: # Register a --enable argument but mark it as deprecated
aoqi@0: # $1: The name of the with argument to deprecate, not including --enable-
aoqi@0: # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
aoqi@0: AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
aoqi@0: [
aoqi@0:   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
aoqi@0:       [Deprecated. Option is kept for backwards compatibility and is ignored])])
aoqi@0:   if test "x$enable_$2" != x; then
aoqi@0:     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: AC_DEFUN_ONCE([BASIC_INIT],
aoqi@0: [
aoqi@0:   # Save the original command line. This is passed to us by the wrapper configure script.
aoqi@0:   AC_SUBST(CONFIGURE_COMMAND_LINE)
aoqi@0:   DATE_WHEN_CONFIGURED=`LANG=C date`
aoqi@0:   AC_SUBST(DATE_WHEN_CONFIGURED)
aoqi@0:   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
aoqi@0:   AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
aoqi@0: ])
aoqi@0: 
aoqi@0: # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
aoqi@0: # $1: variable to check
aoqi@0: # $2: executable name to print in warning (optional)
aoqi@0: AC_DEFUN([BASIC_CHECK_NONEMPTY],
aoqi@0: [
aoqi@0:   if test "x[$]$1" = x; then
aoqi@0:     if test "x$2" = x; then
aoqi@0:       PROG_NAME=translit($1,A-Z,a-z)
aoqi@0:     else
aoqi@0:       PROG_NAME=$2
aoqi@0:     fi
aoqi@0:     AC_MSG_NOTICE([Could not find $PROG_NAME!])
aoqi@0:     AC_MSG_ERROR([Cannot continue])
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.
aoqi@0: # Arguments as AC_PATH_PROG:
aoqi@0: # $1: variable to set
aoqi@0: # $2: executable name to look for
aoqi@0: AC_DEFUN([BASIC_REQUIRE_PROG],
aoqi@0: [
aoqi@0:   AC_PATH_PROGS($1, $2)
aoqi@0:   BASIC_CHECK_NONEMPTY($1, $2)
aoqi@0: ])
aoqi@0: 
aoqi@0: # Setup the most fundamental tools that relies on not much else to set up,
aoqi@0: # but is used by much of the early bootstrap code.
aoqi@0: AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
aoqi@0: [
aoqi@0: 
aoqi@0:   # Start with tools that do not need have cross compilation support
aoqi@0:   # and can be expected to be found in the default PATH. These tools are
aoqi@0:   # used by configure. Nor are these tools expected to be found in the
aoqi@0:   # devkit from the builddeps server either, since they are
aoqi@0:   # needed to download the devkit.
aoqi@0: 
aoqi@0:   # First are all the simple required tools.
aoqi@0:   BASIC_REQUIRE_PROG(BASENAME, basename)
aoqi@0:   BASIC_REQUIRE_PROG(BASH, bash)
aoqi@0:   BASIC_REQUIRE_PROG(CAT, cat)
aoqi@0:   BASIC_REQUIRE_PROG(CHMOD, chmod)
aoqi@0:   BASIC_REQUIRE_PROG(CMP, cmp)
aoqi@0:   BASIC_REQUIRE_PROG(COMM, comm)
aoqi@0:   BASIC_REQUIRE_PROG(CP, cp)
aoqi@0:   BASIC_REQUIRE_PROG(CPIO, cpio)
aoqi@0:   BASIC_REQUIRE_PROG(CUT, cut)
aoqi@0:   BASIC_REQUIRE_PROG(DATE, date)
aoqi@0:   BASIC_REQUIRE_PROG(DIFF, [gdiff diff])
aoqi@0:   BASIC_REQUIRE_PROG(DIRNAME, dirname)
aoqi@0:   BASIC_REQUIRE_PROG(ECHO, echo)
aoqi@0:   BASIC_REQUIRE_PROG(EXPR, expr)
aoqi@0:   BASIC_REQUIRE_PROG(FILE, file)
aoqi@0:   BASIC_REQUIRE_PROG(FIND, find)
aoqi@0:   BASIC_REQUIRE_PROG(HEAD, head)
aoqi@0:   BASIC_REQUIRE_PROG(LN, ln)
aoqi@0:   BASIC_REQUIRE_PROG(LS, ls)
aoqi@0:   BASIC_REQUIRE_PROG(MKDIR, mkdir)
aoqi@0:   BASIC_REQUIRE_PROG(MKTEMP, mktemp)
aoqi@0:   BASIC_REQUIRE_PROG(MV, mv)
aoqi@0:   BASIC_REQUIRE_PROG(PRINTF, printf)
aoqi@0:   BASIC_REQUIRE_PROG(RM, rm)
aoqi@0:   BASIC_REQUIRE_PROG(SH, sh)
aoqi@0:   BASIC_REQUIRE_PROG(SORT, sort)
aoqi@0:   BASIC_REQUIRE_PROG(TAIL, tail)
aoqi@0:   BASIC_REQUIRE_PROG(TAR, tar)
aoqi@0:   BASIC_REQUIRE_PROG(TEE, tee)
aoqi@0:   BASIC_REQUIRE_PROG(TOUCH, touch)
aoqi@0:   BASIC_REQUIRE_PROG(TR, tr)
aoqi@0:   BASIC_REQUIRE_PROG(UNAME, uname)
aoqi@0:   BASIC_REQUIRE_PROG(UNIQ, uniq)
aoqi@0:   BASIC_REQUIRE_PROG(WC, wc)
aoqi@0:   BASIC_REQUIRE_PROG(WHICH, which)
aoqi@0:   BASIC_REQUIRE_PROG(XARGS, xargs)
aoqi@0: 
aoqi@0:   # Then required tools that require some special treatment.
aoqi@0:   AC_PROG_AWK
aoqi@0:   BASIC_CHECK_NONEMPTY(AWK)
aoqi@0:   AC_PROG_GREP
aoqi@0:   BASIC_CHECK_NONEMPTY(GREP)
aoqi@0:   AC_PROG_EGREP
aoqi@0:   BASIC_CHECK_NONEMPTY(EGREP)
aoqi@0:   AC_PROG_FGREP
aoqi@0:   BASIC_CHECK_NONEMPTY(FGREP)
aoqi@0:   AC_PROG_SED
aoqi@0:   BASIC_CHECK_NONEMPTY(SED)
aoqi@0: 
aoqi@0:   AC_PATH_PROGS(NAWK, [nawk gawk awk])
aoqi@0:   BASIC_CHECK_NONEMPTY(NAWK)
aoqi@0: 
aoqi@0:   # Always force rm.
aoqi@0:   RM="$RM -f"
aoqi@0: 
aoqi@0:   # pwd behaves differently on various platforms and some don't support the -L flag.
aoqi@0:   # Always use the bash builtin pwd to get uniform behavior.
aoqi@0:   THEPWDCMD=pwd
aoqi@0: 
aoqi@0:   # These are not required on all platforms
aoqi@0:   AC_PATH_PROG(CYGPATH, cygpath)
aoqi@0:   AC_PATH_PROG(READLINK, readlink)
aoqi@0:   AC_PATH_PROG(DF, df)
aoqi@0:   AC_PATH_PROG(SETFILE, SetFile)
aoqi@0: ])
aoqi@0: 
aoqi@0: # Setup basic configuration paths, and platform-specific stuff related to PATHs.
aoqi@0: AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
aoqi@0: [
aoqi@0:   # Locate the directory of this script.
aoqi@0:   SCRIPT="[$]0"
aoqi@0:   AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD -L`
aoqi@0: 
aoqi@0:   # Where is the source? It is located two levels above the configure script.
aoqi@0:   CURDIR="$PWD"
aoqi@0:   cd "$AUTOCONF_DIR/../.."
aoqi@0:   SRC_ROOT="`$THEPWDCMD -L`"
aoqi@0: 
aoqi@0:   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
aoqi@0:     PATH_SEP=";"
aoqi@0:     BASIC_CHECK_PATHS_WINDOWS
aoqi@0:   else
aoqi@0:     PATH_SEP=":"
aoqi@0:   fi
aoqi@0: 
aoqi@0:   AC_SUBST(SRC_ROOT)
aoqi@0:   AC_SUBST(PATH_SEP)
aoqi@0:   cd "$CURDIR"
aoqi@0: 
aoqi@0:   BASIC_FIXUP_PATH(SRC_ROOT)
aoqi@0:   BASIC_FIXUP_PATH(CURDIR)
aoqi@0: 
aoqi@0:   if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
aoqi@0:     # Add extra search paths on solaris for utilities like ar and as etc...
aoqi@0:     PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
aoqi@0:   fi
aoqi@0: 
aoqi@0:   # You can force the sys-root if the sys-root encoded into the cross compiler tools
aoqi@0:   # is not correct.
aoqi@0:   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
aoqi@0:       [pass this sys-root to the compilers and tools (for cross-compiling)])])
aoqi@0: 
aoqi@0:   if test "x$with_sys_root" != x; then
aoqi@0:     SYS_ROOT=$with_sys_root
aoqi@0:   else
aoqi@0:     SYS_ROOT=/
aoqi@0:   fi
aoqi@0:   AC_SUBST(SYS_ROOT)
aoqi@0: 
aoqi@0:   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
aoqi@0:       [search this directory for compilers and tools (for cross-compiling)])],
aoqi@0:       [TOOLS_DIR=$with_tools_dir]
aoqi@0:   )
aoqi@0: 
aoqi@0:   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
aoqi@0:       [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
aoqi@0:       [
aoqi@0:         if test "x$with_sys_root" != x; then
aoqi@0:           AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
aoqi@0:         fi
aoqi@0:         BASIC_FIXUP_PATH([with_devkit])
aoqi@0:         BASIC_APPEND_TO_PATH([TOOLS_DIR],$with_devkit/bin)
aoqi@0:         if test -d "$with_devkit/$host_alias/libc"; then
aoqi@0:           SYS_ROOT=$with_devkit/$host_alias/libc
aoqi@0:         elif test -d "$with_devkit/$host/sys-root"; then
aoqi@0:           SYS_ROOT=$with_devkit/$host/sys-root
aoqi@0:         fi
aoqi@0:       ])
aoqi@0: ])
aoqi@0: 
aoqi@0: AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
aoqi@0: [
aoqi@0: 
aoqi@0:   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
aoqi@0:       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
aoqi@0:       [ CONF_NAME=${with_conf_name} ])
aoqi@0: 
aoqi@0:   # Test from where we are running configure, in or outside of src root.
aoqi@0:   if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
aoqi@0:       || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
aoqi@0:       || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
aoqi@0:     # We are running configure from the src root.
aoqi@0:     # Create a default ./build/target-variant-debuglevel output root.
aoqi@0:     if test "x${CONF_NAME}" = x; then
aoqi@0:       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
aoqi@0:     fi
aoqi@0:     OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
aoqi@0:     $MKDIR -p "$OUTPUT_ROOT"
aoqi@0:     if test ! -d "$OUTPUT_ROOT"; then
aoqi@0:       AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
aoqi@0:     fi
aoqi@0:   else
aoqi@0:     # We are running configure from outside of the src dir.
aoqi@0:     # Then use the current directory as output dir!
aoqi@0:     # If configuration is situated in normal build directory, just use the build
aoqi@0:     # directory name as configuration name, otherwise use the complete path.
aoqi@0:     if test "x${CONF_NAME}" = x; then
aoqi@0:       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
aoqi@0:     fi
aoqi@0:     OUTPUT_ROOT="$CURDIR"
aoqi@0: 
aoqi@0:     # WARNING: This might be a bad thing to do. You need to be sure you want to
aoqi@0:     # have a configuration in this directory. Do some sanity checks!
aoqi@0: 
aoqi@0:     if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
aoqi@0:       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
aoqi@0:       # other files
aoqi@0:       files_present=`$LS $OUTPUT_ROOT`
aoqi@0:       # Configure has already touched config.log and confdefs.h in the current dir when this check
aoqi@0:       # is performed.
aoqi@0:       filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
aoqi@0:       | $TR -d '\n'`
aoqi@0:       if test "x$filtered_files" != x; then
aoqi@0:         AC_MSG_NOTICE([Current directory is $CURDIR.])
aoqi@0:         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
aoqi@0:         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
aoqi@0:         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
aoqi@0:         AC_MSG_NOTICE([seriously mess up just about everything.])
aoqi@0:         AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
aoqi@0:         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
aoqi@0:         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
aoqi@0:       fi
aoqi@0:     fi
aoqi@0:   fi
aoqi@0:   AC_MSG_CHECKING([what configuration name to use])
aoqi@0:   AC_MSG_RESULT([$CONF_NAME])
aoqi@0: 
aoqi@0:   BASIC_FIXUP_PATH(OUTPUT_ROOT)
aoqi@0: 
aoqi@0:   AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
aoqi@0:   AC_SUBST(CONF_NAME, $CONF_NAME)
aoqi@0:   AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
aoqi@0: 
aoqi@0:   # Most of the probed defines are put into config.h
aoqi@0:   AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
aoqi@0:   # The spec.gmk file contains all variables for the make system.
aoqi@0:   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
aoqi@0:   # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
aoqi@0:   AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
aoqi@0:   # The bootcycle-spec.gmk file contains support for boot cycle builds.
aoqi@0:   AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
aoqi@0:   # The compare.sh is used to compare the build output to other builds.
aoqi@0:   AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
aoqi@0:   # Spec.sh is currently used by compare-objects.sh
aoqi@0:   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
aoqi@0:   # The generated Makefile knows where the spec.gmk is and where the source is.
aoqi@0:   # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
aoqi@0:   # which will look for generated configurations
aoqi@0:   AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
aoqi@0: 
aoqi@0:   # Save the arguments given to us
aoqi@0:   echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
aoqi@0: ])
aoqi@0: 
aoqi@0: AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
aoqi@0: [
aoqi@0:   # Setup default logging of stdout and stderr to build.log in the output root.
aoqi@0:   BUILD_LOG='$(OUTPUT_ROOT)/build.log'
aoqi@0:   BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
aoqi@0:   BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
aoqi@0:   AC_SUBST(BUILD_LOG)
aoqi@0:   AC_SUBST(BUILD_LOG_PREVIOUS)
aoqi@0:   AC_SUBST(BUILD_LOG_WRAPPER)
aoqi@0: ])
aoqi@0: 
aoqi@0: 
aoqi@0: #%%% Simple tools %%%
aoqi@0: 
aoqi@0: # Check if we have found a usable version of make
aoqi@0: # $1: the path to a potential make binary (or empty)
aoqi@0: # $2: the description on how we found this
aoqi@0: AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
aoqi@0: [
aoqi@0:   MAKE_CANDIDATE="$1"
aoqi@0:   DESCRIPTION="$2"
aoqi@0:   if test "x$MAKE_CANDIDATE" != x; then
aoqi@0:     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
aoqi@0:     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
aoqi@0:     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
aoqi@0:     if test "x$IS_GNU_MAKE" = x; then
aoqi@0:       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
aoqi@0:     else
aoqi@0:       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP -e '3\.8[[12]]' -e '4\.'`
aoqi@0:       if test "x$IS_MODERN_MAKE" = x; then
aoqi@0:         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
aoqi@0:       else
aoqi@0:         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
aoqi@0:           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
aoqi@0:             MAKE_EXPECTED_ENV='cygwin'
aoqi@0:           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
aoqi@0:             MAKE_EXPECTED_ENV='msys'
aoqi@0:           else
aoqi@0:             AC_MSG_ERROR([Unknown Windows environment])
aoqi@0:           fi
aoqi@0:           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
aoqi@0:           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
aoqi@0:         else
aoqi@0:           # Not relevant for non-Windows
aoqi@0:           IS_MAKE_CORRECT_ENV=true
aoqi@0:         fi
aoqi@0:         if test "x$IS_MAKE_CORRECT_ENV" = x; then
aoqi@0:           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
aoqi@0:         else
aoqi@0:           FOUND_MAKE=$MAKE_CANDIDATE
aoqi@0:           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
aoqi@0:         fi
aoqi@0:       fi
aoqi@0:     fi
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: # Goes looking for a usable version of GNU make.
aoqi@0: AC_DEFUN([BASIC_CHECK_GNU_MAKE],
aoqi@0: [
aoqi@0:   # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
aoqi@0:   if test "x$MAKE" != x; then
aoqi@0:     # User has supplied a make, test it.
aoqi@0:     if test ! -f "$MAKE"; then
aoqi@0:       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
aoqi@0:     fi
aoqi@0:     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
aoqi@0:     if test "x$FOUND_MAKE" = x; then
aoqi@0:       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
aoqi@0:     fi
aoqi@0:   else
aoqi@0:     # Try our hardest to locate a correct version of GNU make
aoqi@0:     AC_PATH_PROGS(CHECK_GMAKE, gmake)
aoqi@0:     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
aoqi@0: 
aoqi@0:     if test "x$FOUND_MAKE" = x; then
aoqi@0:       AC_PATH_PROGS(CHECK_MAKE, make)
aoqi@0:       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
aoqi@0:     fi
aoqi@0: 
aoqi@0:     if test "x$FOUND_MAKE" = x; then
aoqi@0:       if test "x$TOOLS_DIR" != x; then
aoqi@0:         # We have a tools-dir, check that as well before giving up.
aoqi@0:         OLD_PATH=$PATH
aoqi@0:         PATH=$TOOLS_DIR:$PATH
aoqi@0:         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
aoqi@0:         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
aoqi@0:         if test "x$FOUND_MAKE" = x; then
aoqi@0:           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
aoqi@0:           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
aoqi@0:         fi
aoqi@0:         PATH=$OLD_PATH
aoqi@0:       fi
aoqi@0:     fi
aoqi@0: 
aoqi@0:     if test "x$FOUND_MAKE" = x; then
aoqi@0:       AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
aoqi@0:     fi
aoqi@0:   fi
aoqi@0: 
aoqi@0:   MAKE=$FOUND_MAKE
aoqi@0:   AC_SUBST(MAKE)
aoqi@0:   AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
aoqi@0: ])
aoqi@0: 
aoqi@0: AC_DEFUN([BASIC_CHECK_FIND_DELETE],
aoqi@0: [
aoqi@0:   # Test if find supports -delete
aoqi@0:   AC_MSG_CHECKING([if find supports -delete])
aoqi@0:   FIND_DELETE="-delete"
aoqi@0: 
aoqi@0:   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
aoqi@0: 
aoqi@0:   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
aoqi@0: 
aoqi@0:   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
aoqi@0:   if test -f $DELETEDIR/TestIfFindSupportsDelete; then
aoqi@0:     # No, it does not.
aoqi@0:     rm $DELETEDIR/TestIfFindSupportsDelete
aoqi@0:     FIND_DELETE="-exec rm \{\} \+"
aoqi@0:     AC_MSG_RESULT([no])
aoqi@0:   else
aoqi@0:     AC_MSG_RESULT([yes])
aoqi@0:   fi
aoqi@0:   rmdir $DELETEDIR
aoqi@0:   AC_SUBST(FIND_DELETE)
aoqi@0: ])
aoqi@0: 
aoqi@0: AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
aoqi@0: [
aoqi@0:   BASIC_CHECK_GNU_MAKE
aoqi@0: 
aoqi@0:   BASIC_CHECK_FIND_DELETE
aoqi@0: 
aoqi@0:   # These tools might not be installed by default,
aoqi@0:   # need hint on how to install them.
aoqi@0:   BASIC_REQUIRE_PROG(UNZIP, unzip)
aoqi@0:   BASIC_REQUIRE_PROG(ZIP, zip)
aoqi@0: 
aoqi@0:   # Non-required basic tools
aoqi@0: 
aoqi@0:   AC_PATH_PROG(LDD, ldd)
aoqi@0:   if test "x$LDD" = "x"; then
aoqi@0:     # List shared lib dependencies is used for
aoqi@0:     # debug output and checking for forbidden dependencies.
aoqi@0:     # We can build without it.
aoqi@0:     LDD="true"
aoqi@0:   fi
aoqi@0:   AC_PATH_PROG(OTOOL, otool)
aoqi@0:   if test "x$OTOOL" = "x"; then
aoqi@0:     OTOOL="true"
aoqi@0:   fi
aoqi@0:   AC_PATH_PROGS(READELF, [readelf greadelf])
aoqi@0:   AC_PATH_PROG(HG, hg)
aoqi@0:   AC_PATH_PROG(STAT, stat)
aoqi@0:   AC_PATH_PROG(TIME, time)
aoqi@0:   # Check if it's GNU time
aoqi@0:   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
aoqi@0:   if test "x$IS_GNU_TIME" != x; then
aoqi@0:     IS_GNU_TIME=yes
aoqi@0:   else
aoqi@0:     IS_GNU_TIME=no
aoqi@0:   fi
aoqi@0:   AC_SUBST(IS_GNU_TIME)
aoqi@0: 
aoqi@0:   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
aoqi@0:     BASIC_REQUIRE_PROG(COMM, comm)
aoqi@0:   fi
aoqi@0: 
aoqi@0:   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
aoqi@0:     BASIC_REQUIRE_PROG(DSYMUTIL, dsymutil)
aoqi@0:     BASIC_REQUIRE_PROG(XATTR, xattr)
aoqi@0:     AC_PATH_PROG(CODESIGN, codesign)
aoqi@0:     if test "x$CODESIGN" != "x"; then
aoqi@0:       # Verify that the openjdk_codesign certificate is present
aoqi@0:       AC_MSG_CHECKING([if openjdk_codesign certificate is present])
aoqi@0:       rm -f codesign-testfile
aoqi@0:       touch codesign-testfile
aoqi@0:       codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
aoqi@0:       rm -f codesign-testfile
aoqi@0:       if test "x$CODESIGN" = x; then
aoqi@0:         AC_MSG_RESULT([no])
aoqi@0:       else
aoqi@0:         AC_MSG_RESULT([yes])
aoqi@0:       fi
aoqi@0:     fi
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: # Check if build directory is on local disk. If not possible to determine,
aoqi@0: # we prefer to claim it's local.
aoqi@0: # Argument 1: directory to test
aoqi@0: # Argument 2: what to do if it is on local disk
aoqi@0: # Argument 3: what to do otherwise (remote disk or failure)
aoqi@0: AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
aoqi@0: [
aoqi@0:   # df -l lists only local disks; if the given directory is not found then
aoqi@0:   # a non-zero exit code is given
aoqi@0:   if test "x$DF" = x; then
aoqi@0:     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
aoqi@0:       # msys does not have df; use Windows "net use" instead.
aoqi@0:       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
aoqi@0:       if test "x$IS_NETWORK_DISK" = x; then
aoqi@0:         $2
aoqi@0:       else
aoqi@0:         $3
aoqi@0:       fi
aoqi@0:     else
aoqi@0:       # No df here, say it's local
aoqi@0:       $2
aoqi@0:     fi
aoqi@0:   else
aoqi@0:     if $DF -l $1 > /dev/null 2>&1; then
aoqi@0:       $2
aoqi@0:     else
aoqi@0:       $3
aoqi@0:     fi
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: # Check that source files have basic read permissions set. This might
aoqi@0: # not be the case in cygwin in certain conditions.
aoqi@0: AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
aoqi@0: [
aoqi@0:   if test x"$OPENJDK_BUILD_OS" = xwindows; then
aoqi@0:     file_to_test="$SRC_ROOT/LICENSE"
aoqi@0:     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
aoqi@0:       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
aoqi@0:     fi
aoqi@0:   fi
aoqi@0: ])
aoqi@0: 
aoqi@0: AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
aoqi@0: [
aoqi@0:   AC_MSG_CHECKING([if build directory is on local disk])
aoqi@0:   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
aoqi@0:       [OUTPUT_DIR_IS_LOCAL="yes"],
aoqi@0:       [OUTPUT_DIR_IS_LOCAL="no"])
aoqi@0:   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
aoqi@0: 
aoqi@0:   BASIC_CHECK_SRC_PERMS
aoqi@0: 
aoqi@0:   # Check if the user has any old-style ALT_ variables set.
aoqi@0:   FOUND_ALT_VARIABLES=`env | grep ^ALT_`
aoqi@0: 
aoqi@0:   # Before generating output files, test if they exist. If they do, this is a reconfigure.
aoqi@0:   # Since we can't properly handle the dependencies for this, warn the user about the situation
aoqi@0:   if test -e $OUTPUT_ROOT/spec.gmk; then
aoqi@0:     IS_RECONFIGURE=yes
aoqi@0:   else
aoqi@0:     IS_RECONFIGURE=no
aoqi@0:   fi
aoqi@0: 
aoqi@0:   if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then
aoqi@0:     HIDE_PERFORMANCE_HINTS=yes
aoqi@0:   else
aoqi@0:     HIDE_PERFORMANCE_HINTS=no
aoqi@0:     # Hide it the next time around...
aoqi@0:     $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1
aoqi@0:   fi
aoqi@0: ])