Wed, 02 Apr 2014 10:01:38 -0700
Merge
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64)
34 VAR_CPU=x86_64
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=64
37 VAR_CPU_ENDIAN=little
38 ;;
39 i?86)
40 VAR_CPU=x86
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=32
43 VAR_CPU_ENDIAN=little
44 ;;
45 arm*)
46 VAR_CPU=arm
47 VAR_CPU_ARCH=arm
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 powerpc)
52 VAR_CPU=ppc
53 VAR_CPU_ARCH=ppc
54 VAR_CPU_BITS=32
55 VAR_CPU_ENDIAN=big
56 ;;
57 powerpc64)
58 VAR_CPU=ppc64
59 VAR_CPU_ARCH=ppc
60 VAR_CPU_BITS=64
61 VAR_CPU_ENDIAN=big
62 ;;
63 s390)
64 VAR_CPU=s390
65 VAR_CPU_ARCH=s390
66 VAR_CPU_BITS=32
67 VAR_CPU_ENDIAN=big
68 ;;
69 s390x)
70 VAR_CPU=s390x
71 VAR_CPU_ARCH=s390
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=big
74 ;;
75 sparc)
76 VAR_CPU=sparc
77 VAR_CPU_ARCH=sparc
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 sparcv9)
82 VAR_CPU=sparcv9
83 VAR_CPU_ARCH=sparc
84 VAR_CPU_BITS=64
85 VAR_CPU_ENDIAN=big
86 ;;
87 *)
88 AC_MSG_ERROR([unsupported cpu $1])
89 ;;
90 esac
91 ])
93 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
94 # Converts autoconf style OS name to OpenJDK style, into
95 # VAR_OS and VAR_OS_API.
96 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
97 [
98 case "$1" in
99 *linux*)
100 VAR_OS=linux
101 VAR_OS_API=posix
102 VAR_OS_ENV=linux
103 ;;
104 *solaris*)
105 VAR_OS=solaris
106 VAR_OS_API=posix
107 VAR_OS_ENV=solaris
108 ;;
109 *darwin*)
110 VAR_OS=macosx
111 VAR_OS_API=posix
112 VAR_OS_ENV=macosx
113 ;;
114 *bsd*)
115 VAR_OS=bsd
116 VAR_OS_API=posix
117 VAR_OS_ENV=bsd
118 ;;
119 *cygwin*)
120 VAR_OS=windows
121 VAR_OS_API=winapi
122 VAR_OS_ENV=windows.cygwin
123 ;;
124 *mingw*)
125 VAR_OS=windows
126 VAR_OS_API=winapi
127 VAR_OS_ENV=windows.msys
128 ;;
129 *aix*)
130 VAR_OS=aix
131 VAR_OS_API=posix
132 VAR_OS_ENV=aix
133 ;;
134 *)
135 AC_MSG_ERROR([unsupported operating system $1])
136 ;;
137 esac
138 ])
140 # Expects $host_os $host_cpu $build_os and $build_cpu
141 # and $with_target_bits to have been setup!
142 #
143 # Translate the standard triplet(quadruplet) definition
144 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
145 # OPENJDK_BUILD_OS, etc.
146 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
147 [
148 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
149 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
150 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
151 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
152 OPENJDK_TARGET_AUTOCONF_NAME="$host"
153 OPENJDK_BUILD_AUTOCONF_NAME="$build"
154 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
155 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
157 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
158 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
159 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
160 # ..and setup our own variables. (Do this explicitely to facilitate searching)
161 OPENJDK_BUILD_OS="$VAR_OS"
162 OPENJDK_BUILD_OS_API="$VAR_OS_API"
163 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
164 OPENJDK_BUILD_CPU="$VAR_CPU"
165 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
166 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
167 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
168 AC_SUBST(OPENJDK_BUILD_OS)
169 AC_SUBST(OPENJDK_BUILD_OS_API)
170 AC_SUBST(OPENJDK_BUILD_CPU)
171 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
172 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
173 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
175 AC_MSG_CHECKING([openjdk-build os-cpu])
176 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
178 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
179 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
180 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
181 # ... and setup our own variables. (Do this explicitely to facilitate searching)
182 OPENJDK_TARGET_OS="$VAR_OS"
183 OPENJDK_TARGET_OS_API="$VAR_OS_API"
184 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
185 OPENJDK_TARGET_CPU="$VAR_CPU"
186 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
187 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
188 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
189 AC_SUBST(OPENJDK_TARGET_OS)
190 AC_SUBST(OPENJDK_TARGET_OS_API)
191 AC_SUBST(OPENJDK_TARGET_CPU)
192 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
193 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
194 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
196 AC_MSG_CHECKING([openjdk-target os-cpu])
197 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
198 ])
200 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
201 # accordingly. Must be done after setting up build and target system, but before
202 # doing anything else with these values.
203 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
204 [
205 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
206 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
208 # We have three types of compiles:
209 # native == normal compilation, target system == build system
210 # cross == traditional cross compilation, target system != build system; special toolchain needed
211 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
212 #
213 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
214 # We're doing a proper cross-compilation
215 COMPILE_TYPE="cross"
216 else
217 COMPILE_TYPE="native"
218 fi
220 if test "x$with_target_bits" != x; then
221 if test "x$COMPILE_TYPE" = "xcross"; then
222 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
223 fi
225 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
226 # A reduced build is requested
227 COMPILE_TYPE="reduced"
228 OPENJDK_TARGET_CPU_BITS=32
229 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
230 OPENJDK_TARGET_CPU=x86
231 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
232 OPENJDK_TARGET_CPU=sparc
233 else
234 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
235 fi
236 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
237 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
238 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
239 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
240 else
241 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
242 fi
243 fi
244 AC_SUBST(COMPILE_TYPE)
246 AC_MSG_CHECKING([compilation type])
247 AC_MSG_RESULT([$COMPILE_TYPE])
248 ])
250 # Setup the legacy variables, for controlling the old makefiles.
251 #
252 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
253 [
254 # Also store the legacy naming of the cpu.
255 # Ie i586 and amd64 instead of x86 and x86_64
256 OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"
257 if test "x$OPENJDK_TARGET_CPU" = xx86; then
258 OPENJDK_TARGET_CPU_LEGACY="i586"
259 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
260 # On all platforms except MacOSX replace x86_64 with amd64.
261 OPENJDK_TARGET_CPU_LEGACY="amd64"
262 fi
263 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)
265 # And the second legacy naming of the cpu.
266 # Ie i386 and amd64 instead of x86 and x86_64.
267 OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"
268 if test "x$OPENJDK_TARGET_CPU" = xx86; then
269 OPENJDK_TARGET_CPU_LEGACY_LIB="i386"
270 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
271 OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"
272 fi
273 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)
275 # This is the name of the cpu (but using i386 and amd64 instead of
276 # x86 and x86_64, respectively), preceeded by a /, to be used when
277 # locating libraries. On macosx, it's empty, though.
278 OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"
279 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
280 OPENJDK_TARGET_CPU_LIBDIR=""
281 fi
282 AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)
284 # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
285 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
286 # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so
287 OPENJDK_TARGET_CPU_ISADIR=""
288 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
289 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
290 OPENJDK_TARGET_CPU_ISADIR="/amd64"
291 elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then
292 OPENJDK_TARGET_CPU_ISADIR="/sparcv9"
293 fi
294 fi
295 AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)
297 # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property
298 OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"
299 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then
300 # On linux only, we replace x86 with i386.
301 OPENJDK_TARGET_CPU_OSARCH="i386"
302 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
303 # On all platforms except macosx, we replace x86_64 with amd64.
304 OPENJDK_TARGET_CPU_OSARCH="amd64"
305 fi
306 AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)
308 OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"
309 if test "x$OPENJDK_TARGET_CPU" = xx86; then
310 OPENJDK_TARGET_CPU_JLI="i386"
311 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
312 # On all platforms except macosx, we replace x86_64 with amd64.
313 OPENJDK_TARGET_CPU_JLI="amd64"
314 fi
315 # Now setup the -D flags for building libjli.
316 OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"
317 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
318 if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then
319 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"
320 elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
321 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"
322 fi
323 fi
324 AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)
326 # Setup OPENJDK_TARGET_OS_API_DIR, used in source paths.
327 if test "x$OPENJDK_TARGET_OS_API" = xposix; then
328 OPENJDK_TARGET_OS_API_DIR="solaris"
329 fi
330 if test "x$OPENJDK_TARGET_OS_API" = xwinapi; then
331 OPENJDK_TARGET_OS_API_DIR="windows"
332 fi
333 AC_SUBST(OPENJDK_TARGET_OS_API_DIR)
335 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
336 OPENJDK_TARGET_OS_EXPORT_DIR=macosx
337 else
338 OPENJDK_TARGET_OS_EXPORT_DIR=${OPENJDK_TARGET_OS_API_DIR}
339 fi
340 AC_SUBST(OPENJDK_TARGET_OS_EXPORT_DIR)
342 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
343 A_LP64="LP64:="
344 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
345 # unpack200.exe
346 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then
347 ADD_LP64="-D_LP64=1"
348 fi
349 fi
350 AC_SUBST(LP64,$A_LP64)
352 if test "x$COMPILE_TYPE" = "xcross"; then
353 # FIXME: ... or should this include reduced builds..?
354 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"
355 else
356 DEFINE_CROSS_COMPILE_ARCH=""
357 fi
358 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
360 # ZERO_ARCHDEF is used to enable architecture-specific code
361 case "${OPENJDK_TARGET_CPU}" in
362 ppc*) ZERO_ARCHDEF=PPC ;;
363 s390*) ZERO_ARCHDEF=S390 ;;
364 sparc*) ZERO_ARCHDEF=SPARC ;;
365 x86_64*) ZERO_ARCHDEF=AMD64 ;;
366 x86) ZERO_ARCHDEF=IA32 ;;
367 *) ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)
368 esac
369 AC_SUBST(ZERO_ARCHDEF)
370 ])
372 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
373 [
374 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
375 REQUIRED_OS_NAME=SunOS
376 REQUIRED_OS_VERSION=5.10
377 fi
378 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
379 REQUIRED_OS_NAME=Linux
380 REQUIRED_OS_VERSION=2.6
381 fi
382 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
383 REQUIRED_OS_NAME=Windows
384 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
385 REQUIRED_OS_VERSION=5.2
386 else
387 REQUIRED_OS_VERSION=5.1
388 fi
389 fi
390 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
391 REQUIRED_OS_NAME=Darwin
392 REQUIRED_OS_VERSION=11.2
393 fi
395 AC_SUBST(REQUIRED_OS_NAME)
396 AC_SUBST(REQUIRED_OS_VERSION)
397 ])
399 #%%% Build and target systems %%%
400 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
401 [
402 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
403 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
404 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
405 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
406 # to use the configure naming style.
407 AC_CANONICAL_BUILD
408 AC_CANONICAL_HOST
409 AC_CANONICAL_TARGET
411 PLATFORM_EXTRACT_TARGET_AND_BUILD
412 PLATFORM_SETUP_TARGET_CPU_BITS
413 PLATFORM_SET_RELEASE_FILE_OS_VALUES
414 PLATFORM_SETUP_LEGACY_VARS
415 ])
417 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
418 [
419 ###############################################################################
421 # Note that this is the build platform OS version!
423 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
424 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
425 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
426 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
427 AC_SUBST(OS_VERSION_MAJOR)
428 AC_SUBST(OS_VERSION_MINOR)
429 AC_SUBST(OS_VERSION_MICRO)
430 ])
432 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
433 # Add -mX to various FLAGS variables.
434 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
435 [
436 # When we add flags to the "official" CFLAGS etc, we need to
437 # keep track of these additions in ADDED_CFLAGS etc. These
438 # will later be checked to make sure only controlled additions
439 # have been made to CFLAGS etc.
440 ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
441 ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
442 ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
444 CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
445 CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
446 LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
448 CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
449 CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
450 LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
451 ])
453 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
454 [
455 ###############################################################################
456 #
457 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
458 # (The JVM can use 32 or 64 bit Java pointers but that decision
459 # is made at runtime.)
460 #
462 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
463 # Always specify -m flag on Solaris
464 # And -q on AIX because otherwise the compiler produces 32-bit objects by default
465 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
466 elif test "x$COMPILE_TYPE" = xreduced; then
467 if test "x$OPENJDK_TARGET_OS" != xwindows; then
468 # Specify -m if running reduced on other Posix platforms
469 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
470 fi
471 fi
473 # Make compilation sanity check
474 AC_CHECK_HEADERS([stdio.h], , [
475 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
476 if test "x$COMPILE_TYPE" = xreduced; then
477 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed.])
478 elif test "x$COMPILE_TYPE" = xcross; then
479 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
480 fi
481 AC_MSG_ERROR([Cannot continue.])
482 ])
484 AC_CHECK_SIZEOF([int *], [1111])
486 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
487 if test "x$ac_cv_sizeof_int_p" = x; then
488 # The test failed, lets stick to the assumed value.
489 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
490 else
491 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
493 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
494 # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
495 # Let's try to implicitely set the compilers target architecture and retry the test
496 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
497 AC_MSG_NOTICE([I'll retry after setting the platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
498 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
500 # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
501 unset ac_cv_sizeof_int_p
502 # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
503 cat >>confdefs.h <<_ACEOF
504 #undef SIZEOF_INT_P
505 _ACEOF
507 AC_CHECK_SIZEOF([int *], [1111])
509 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
511 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
512 AC_MSG_ERROR([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
513 fi
514 fi
515 fi
517 AC_MSG_CHECKING([for target address size])
518 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
519 ])
521 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
522 [
523 ###############################################################################
524 #
525 # Is the target little of big endian?
526 #
527 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
529 if test "x$ENDIAN" = xuniversal_endianness; then
530 AC_MSG_ERROR([Building with both big and little endianness is not supported])
531 fi
532 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
533 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
534 fi
535 ])