Tue, 02 Apr 2013 14:13:06 -0400
8011278: Allow using a system-installed giflib
Reviewed-by: andrew, prr
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 AC_DEFUN([BPERF_CHECK_CORES],
27 [
28 AC_MSG_CHECKING([for number of cores])
29 NUM_CORES=1
30 FOUND_CORES=no
32 if test -f /proc/cpuinfo; then
33 # Looks like a Linux (or cygwin) system
34 NUM_CORES=`cat /proc/cpuinfo | grep -c processor`
35 FOUND_CORES=yes
36 elif test -x /usr/sbin/psrinfo; then
37 # Looks like a Solaris system
38 NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`
39 FOUND_CORES=yes
40 elif test -x /usr/sbin/system_profiler; then
41 # Looks like a MacOSX system
42 NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk '{print [$]5}'`
43 FOUND_CORES=yes
44 elif test -n "$NUMBER_OF_PROCESSORS"; then
45 # On windows, look in the env
46 NUM_CORES=$NUMBER_OF_PROCESSORS
47 FOUND_CORES=yes
48 fi
50 if test "x$FOUND_CORES" = xyes; then
51 AC_MSG_RESULT([$NUM_CORES])
52 else
53 AC_MSG_RESULT([could not detect number of cores, defaulting to 1])
54 AC_MSG_WARN([This will disable all parallelism from build!])
55 fi
57 ])
59 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],
60 [
61 AC_MSG_CHECKING([for memory size])
62 # Default to 1024 MB
63 MEMORY_SIZE=1024
64 FOUND_MEM=no
66 if test -f /proc/meminfo; then
67 # Looks like a Linux (or cygwin) system
68 MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`
69 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`
70 FOUND_MEM=yes
71 elif test -x /usr/sbin/prtconf; then
72 # Looks like a Solaris system
73 MEMORY_SIZE=`/usr/sbin/prtconf | grep "Memory size" | awk '{ print [$]3 }'`
74 FOUND_MEM=yes
75 elif test -x /usr/sbin/system_profiler; then
76 # Looks like a MacOSX system
77 MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk '{print [$]2}'`
78 MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`
79 FOUND_MEM=yes
80 elif test "x$OPENJDK_BUILD_OS" = xwindows; then
81 # Windows, but without cygwin
82 MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`
83 MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`
84 FOUND_MEM=yes
85 fi
87 if test "x$FOUND_MEM" = xyes; then
88 AC_MSG_RESULT([$MEMORY_SIZE MB])
89 else
90 AC_MSG_RESULT([could not detect memory size, defaulting to 1024 MB])
91 AC_MSG_WARN([This might seriously impact build performance!])
92 fi
93 ])
95 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],
96 [
97 # How many cores do we have on this build system?
98 AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],
99 [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])
100 if test "x$with_num_cores" = x; then
101 # The number of cores were not specified, try to probe them.
102 BPERF_CHECK_CORES
103 else
104 NUM_CORES=$with_num_cores
105 fi
106 AC_SUBST(NUM_CORES)
107 ])
109 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],
110 [
111 # How much memory do we have on this build system?
112 AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],
113 [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])
114 if test "x$with_memory_size" = x; then
115 # The memory size was not specified, try to probe it.
116 BPERF_CHECK_MEMORY_SIZE
117 else
118 MEMORY_SIZE=$with_memory_size
119 fi
120 AC_SUBST(MEMORY_SIZE)
121 ])
123 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],
124 [
125 # Provide a decent default number of parallel jobs for make depending on
126 # number of cores, amount of memory and machine architecture.
127 AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],
128 [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])
129 if test "x$with_jobs" = x; then
130 # Number of jobs was not specified, calculate.
131 AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])
132 # Approximate memory in GB, rounding up a bit.
133 memory_gb=`expr $MEMORY_SIZE / 1100`
134 # Pick the lowest of memory in gb and number of cores.
135 if test "$memory_gb" -lt "$NUM_CORES"; then
136 JOBS="$memory_gb"
137 else
138 JOBS="$NUM_CORES"
139 # On bigger machines, leave some room for other processes to run
140 if test "$JOBS" -gt "4"; then
141 JOBS=`expr $JOBS '*' 90 / 100`
142 fi
143 fi
144 # Cap number of jobs to 16
145 if test "$JOBS" -gt "16"; then
146 JOBS=16
147 fi
148 AC_MSG_RESULT([$JOBS])
149 else
150 JOBS=$with_jobs
151 fi
152 AC_SUBST(JOBS)
153 ])
155 AC_DEFUN([BPERF_SETUP_CCACHE],
156 [
157 AC_ARG_ENABLE([ccache],
158 [AS_HELP_STRING([--disable-ccache],
159 [disable using ccache to speed up recompilations @<:@enabled@:>@])],
160 [ENABLE_CCACHE=${enable_ccache}], [ENABLE_CCACHE=yes])
161 if test "x$ENABLE_CCACHE" = xyes; then
162 AC_PATH_PROG(CCACHE, ccache)
163 else
164 AC_MSG_CHECKING([for ccache])
165 AC_MSG_RESULT([explicitly disabled])
166 CCACHE=
167 fi
168 AC_SUBST(CCACHE)
170 AC_ARG_WITH([ccache-dir],
171 [AS_HELP_STRING([--with-ccache-dir],
172 [where to store ccache files @<:@~/.ccache@:>@])])
174 if test "x$with_ccache_dir" != x; then
175 # When using a non home ccache directory, assume the use is to share ccache files
176 # with other users. Thus change the umask.
177 SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"
178 fi
179 CCACHE_FOUND=""
180 if test "x$CCACHE" != x; then
181 BPERF_SETUP_CCACHE_USAGE
182 fi
183 ])
185 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],
186 [
187 if test "x$CCACHE" != x; then
188 CCACHE_FOUND="true"
189 # Only use ccache if it is 3.1.4 or later, which supports
190 # precompiled headers.
191 AC_MSG_CHECKING([if ccache supports precompiled headers])
192 HAS_GOOD_CCACHE=`($CCACHE --version | head -n 1 | grep -E 3.1.@<:@456789@:>@) 2> /dev/null`
193 if test "x$HAS_GOOD_CCACHE" = x; then
194 AC_MSG_RESULT([no, disabling ccache])
195 CCACHE=
196 else
197 AC_MSG_RESULT([yes])
198 AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])
199 PUSHED_FLAGS="$CXXFLAGS"
200 CXXFLAGS="-fpch-preprocess $CXXFLAGS"
201 AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])
202 CXXFLAGS="$PUSHED_FLAGS"
203 if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then
204 AC_MSG_RESULT([yes])
205 else
206 AC_MSG_RESULT([no, disabling ccaching of precompiled headers])
207 CCACHE=
208 fi
209 fi
210 fi
212 if test "x$CCACHE" != x; then
213 CCACHE_SLOPPINESS=time_macros
214 CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS $CCACHE"
215 CCACHE_FLAGS=-fpch-preprocess
217 if test "x$SET_CCACHE_DIR" != x; then
218 mkdir -p $CCACHE_DIR > /dev/null 2>&1
219 chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1
220 fi
221 fi
222 ])
224 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],
225 [
227 ###############################################################################
228 #
229 # Can the C/C++ compiler use precompiled headers?
230 #
231 AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],
232 [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],
233 [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])
235 USE_PRECOMPILED_HEADER=1
236 if test "x$ENABLE_PRECOMPH" = xno; then
237 USE_PRECOMPILED_HEADER=0
238 fi
240 if test "x$ENABLE_PRECOMPH" = xyes; then
241 # Check that the compiler actually supports precomp headers.
242 if test "x$GCC" = xyes; then
243 AC_MSG_CHECKING([that precompiled headers work])
244 echo "int alfa();" > conftest.h
245 $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD
246 if test ! -f conftest.hpp.gch; then
247 USE_PRECOMPILED_HEADER=0
248 AC_MSG_RESULT([no])
249 else
250 AC_MSG_RESULT([yes])
251 fi
252 rm -f conftest.h conftest.hpp.gch
253 fi
254 fi
256 AC_SUBST(USE_PRECOMPILED_HEADER)
257 ])
260 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],
261 [
262 AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],
263 [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])
265 if test "x$with_sjavac_server_java" != x; then
266 SJAVAC_SERVER_JAVA="$with_sjavac_server_java"
267 FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`
268 if test "x$FOUND_VERSION" = x; then
269 AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])
270 fi
271 else
272 SJAVAC_SERVER_JAVA=""
273 # Hotspot specific options.
274 ADD_JVM_ARG_IF_OK([-verbosegc],SJAVAC_SERVER_JAVA,[$JAVA])
275 # JRockit specific options.
276 ADD_JVM_ARG_IF_OK([-Xverbose:gc],SJAVAC_SERVER_JAVA,[$JAVA])
277 SJAVAC_SERVER_JAVA="$JAVA $SJAVAC_SERVER_JAVA"
278 fi
279 AC_SUBST(SJAVAC_SERVER_JAVA)
281 AC_ARG_WITH(sjavac-server-cores, [AS_HELP_STRING([--with-sjavac-server-cores],
282 [use at most this number of concurrent threads on the sjavac server @<:@probed@:>@])])
283 if test "x$with_sjavac_server_cores" != x; then
284 SJAVAC_SERVER_CORES="$with_sjavac_server_cores"
285 else
286 if test "$NUM_CORES" -gt 16; then
287 # We set this arbitrary limit because we want to limit the heap
288 # size of the javac server.
289 # In the future we will make the javac compilers in the server
290 # share more and more state, thus enabling us to use more and
291 # more concurrent threads in the server.
292 SJAVAC_SERVER_CORES="16"
293 else
294 SJAVAC_SERVER_CORES="$NUM_CORES"
295 fi
297 if test "$MEMORY_SIZE" -gt "17000"; then
298 MAX_HEAP_MEM=10000
299 ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
300 ADD_JVM_ARG_IF_OK([-Xms10G -Xmx10G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
301 elif test "$MEMORY_SIZE" -gt "10000"; then
302 MAX_HEAP_MEM=6000
303 ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
304 ADD_JVM_ARG_IF_OK([-Xms6G -Xmx6G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
305 elif test "$MEMORY_SIZE" -gt "5000"; then
306 MAX_HEAP_MEM=3000
307 ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
308 ADD_JVM_ARG_IF_OK([-Xms1G -Xmx3G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
309 elif test "$MEMORY_SIZE" -gt "3800"; then
310 MAX_HEAP_MEM=2500
311 ADD_JVM_ARG_IF_OK([-Xms1G -Xmx2500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
312 elif test "$MEMORY_SIZE" -gt "1900"; then
313 MAX_HEAP_MEM=1200
314 ADD_JVM_ARG_IF_OK([-Xms700M -Xmx1400M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
315 elif test "$MEMORY_SIZE" -gt "1000"; then
316 MAX_HEAP_MEM=900
317 ADD_JVM_ARG_IF_OK([-Xms400M -Xmx1100M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
318 else
319 MAX_HEAP_MEM=512
320 ADD_JVM_ARG_IF_OK([-Xms256M -Xmx512M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
321 fi
323 ADD_JVM_ARG_IF_OK([-XX:PermSize=32m],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
324 ADD_JVM_ARG_IF_OK([-XX:MaxPermSize=160m],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
325 ADD_JVM_ARG_IF_OK([-XX:ThreadStackSize=$STACK_SIZE],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])
327 MAX_COMPILERS_IN_HEAP=`expr $MAX_HEAP_MEM / 501`
328 if test "$SJAVAC_SERVER_CORES" -gt "$MAX_COMPILERS_IN_HEAP"; then
329 AC_MSG_CHECKING([if number of server cores must be reduced])
330 SJAVAC_SERVER_CORES="$MAX_COMPILERS_IN_HEAP"
331 AC_MSG_RESULT([yes, to $SJAVAC_SERVER_CORES with max heap size $MAX_HEAP_MEM MB])
332 fi
333 fi
334 AC_SUBST(SJAVAC_SERVER_CORES)
336 AC_MSG_CHECKING([whether to use sjavac])
337 AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],
338 [use sjavac to do fast incremental compiles @<:@disabled@:>@])],
339 [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC='no'])
340 AC_MSG_RESULT([$ENABLE_SJAVAC])
341 AC_SUBST(ENABLE_SJAVAC)
343 if test "x$ENABLE_SJAVAC" = xyes; then
344 SJAVAC_SERVER_DIR="$OUTPUT_ROOT/javacservers"
345 else
346 SJAVAC_SERVER_DIR=
347 fi
348 AC_SUBST(SJAVAC_SERVER_DIR)
350 ])