Sat, 03 Nov 2012 16:28:14 -0700
8002220: build-infra: update for mac, solaris 11 issues
8002184: Fixed exclude and includes for jarsigner in new build
Reviewed-by: ohair
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 AC_DEFUN([ADD_JVM_ARG_IF_OK],
27 [
28 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
29 # If so, then append $1 to $2
30 FOUND_WARN=`$3 $1 -version 2>&1 | grep -i warn`
31 FOUND_VERSION=`$3 $1 -version 2>&1 | grep " version \""`
32 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
33 $2="[$]$2 $1"
34 fi
35 ])
37 # This will make sure the given variable points to a full and proper
38 # path. This means:
39 # 1) There will be no spaces in the path. On posix platforms,
40 # spaces in the path will result in an error. On Windows,
41 # the path will be rewritten using short-style to be space-free.
42 # 2) The path will be absolute, and it will be in unix-style (on
43 # cygwin).
44 # $1: The name of the variable to fix
45 AC_DEFUN([BASIC_FIXUP_PATH],
46 [
47 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
48 BASIC_FIXUP_PATH_CYGWIN($1)
49 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
50 BASIC_FIXUP_PATH_MSYS($1)
51 else
52 # We're on a posix platform. Hooray! :)
53 path="[$]$1"
55 if test ! -f "$path" && test ! -d "$path"; then
56 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
57 fi
59 has_space=`$ECHO "$path" | $GREP " "`
60 if test "x$has_space" != x; then
61 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
62 AC_MSG_ERROR([Spaces are not allowed in this path.])
63 fi
64 fi
65 ])
67 # This will make sure the given variable points to a executable
68 # with a full and proper path. This means:
69 # 1) There will be no spaces in the path. On posix platforms,
70 # spaces in the path will result in an error. On Windows,
71 # the path will be rewritten using short-style to be space-free.
72 # 2) The path will be absolute, and it will be in unix-style (on
73 # cygwin).
74 # Any arguments given to the executable is preserved.
75 # If the input variable does not have a directory specification, then
76 # it need to be in the PATH.
77 # $1: The name of the variable to fix
78 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
79 [
80 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
81 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
82 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
83 BASIC_FIXUP_EXECUTABLE_MSYS($1)
84 else
85 # We're on a posix platform. Hooray! :)
86 # First separate the path from the arguments. This will split at the first
87 # space.
88 complete="[$]$1"
89 path="${complete%% *}"
90 tmp="$complete EOL"
91 arguments="${tmp#* }"
93 new_path=`$WHICH $path 2> /dev/null`
94 if test "x$new_path" = x; then
95 is_absolute_path=`$ECHO "$path" | $GREP ^/`
96 if test "x$is_absolute_path" != x; then
97 AC_MSG_NOTICE([Resolving $1 (as $path) with 'which' failed, using $path directly.])
98 new_path="$path"
99 else
100 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
101 has_space=`$ECHO "$complete" | $GREP " "`
102 if test "x$has_space" != x; then
103 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
104 fi
105 AC_MSG_ERROR([Cannot locate the the path of $1])
106 fi
107 fi
108 fi
110 # Now join together the path and the arguments once again
111 if test "x$arguments" != xEOL; then
112 new_complete="$new_path ${arguments% *}"
113 else
114 new_complete="$new_path"
115 fi
117 if test "x$complete" != "x$new_complete"; then
118 $1="$new_complete"
119 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
120 fi
121 ])
123 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
124 [
125 if test "x$OPENJDK_BUILD_OS" != xwindows; then
126 # Follow a chain of symbolic links. Use readlink
127 # where it exists, else fall back to horribly
128 # complicated shell code.
129 if test "x$READLINK_TESTED" != yes; then
130 # On MacOSX there is a readlink tool with a different
131 # purpose than the GNU readlink tool. Check the found readlink.
132 ISGNU=`$READLINK --help 2>&1 | $GREP GNU`
133 if test "x$ISGNU" = x; then
134 # A readlink that we do not know how to use.
135 # Are there other non-GNU readlinks out there?
136 READLINK_TESTED=yes
137 READLINK=
138 fi
139 fi
141 if test "x$READLINK" != x; then
142 $1=`$READLINK -f [$]$1`
143 else
144 STARTDIR=$PWD
145 COUNTER=0
146 sym_link_dir=`$DIRNAME [$]$1`
147 sym_link_file=`$BASENAME [$]$1`
148 while test $COUNTER -lt 20; do
149 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
150 if test "x$ISLINK" == x; then
151 # This is not a symbolic link! We are done!
152 break
153 fi
154 # The link might be relative! We have to use cd to travel safely.
155 cd $sym_link_dir
156 # ... and we must get the to the absolute path, not one using symbolic links.
157 cd `pwd -P`
158 cd `$DIRNAME $ISLINK`
159 sym_link_dir=`$THEPWDCMD`
160 sym_link_file=`$BASENAME $ISLINK`
161 let COUNTER=COUNTER+1
162 done
163 cd $STARTDIR
164 $1=$sym_link_dir/$sym_link_file
165 fi
166 fi
167 ])
169 AC_DEFUN_ONCE([BASIC_INIT],
170 [
171 # Save the original command line. This is passed to us by the wrapper configure script.
172 AC_SUBST(CONFIGURE_COMMAND_LINE)
173 DATE_WHEN_CONFIGURED=`LANG=C date`
174 AC_SUBST(DATE_WHEN_CONFIGURED)
175 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
176 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
177 ])
179 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
180 # $1: variable to check
181 # $2: executable name to print in warning (optional)
182 AC_DEFUN([BASIC_CHECK_NONEMPTY],
183 [
184 if test "x[$]$1" = x; then
185 if test "x$2" = x; then
186 PROG_NAME=translit($1,A-Z,a-z)
187 else
188 PROG_NAME=$2
189 fi
190 AC_MSG_NOTICE([Could not find $PROG_NAME!])
191 AC_MSG_ERROR([Cannot continue])
192 fi
193 ])
195 # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.
196 # Arguments as AC_PATH_PROG:
197 # $1: variable to set
198 # $2: executable name to look for
199 AC_DEFUN([BASIC_REQUIRE_PROG],
200 [
201 AC_PATH_PROGS($1, $2)
202 BASIC_CHECK_NONEMPTY($1, $2)
203 ])
205 # Setup the most fundamental tools that relies on not much else to set up,
206 # but is used by much of the early bootstrap code.
207 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
208 [
210 # Start with tools that do not need have cross compilation support
211 # and can be expected to be found in the default PATH. These tools are
212 # used by configure. Nor are these tools expected to be found in the
213 # devkit from the builddeps server either, since they are
214 # needed to download the devkit.
216 # First are all the simple required tools.
217 BASIC_REQUIRE_PROG(BASENAME, basename)
218 BASIC_REQUIRE_PROG(BASH, bash)
219 BASIC_REQUIRE_PROG(CAT, cat)
220 BASIC_REQUIRE_PROG(CHMOD, chmod)
221 BASIC_REQUIRE_PROG(CMP, cmp)
222 BASIC_REQUIRE_PROG(CP, cp)
223 BASIC_REQUIRE_PROG(CUT, cut)
224 BASIC_REQUIRE_PROG(DATE, date)
225 BASIC_REQUIRE_PROG(DIFF, [gdiff diff])
226 BASIC_REQUIRE_PROG(DIRNAME, dirname)
227 BASIC_REQUIRE_PROG(ECHO, echo)
228 BASIC_REQUIRE_PROG(EXPR, expr)
229 BASIC_REQUIRE_PROG(FILE, file)
230 BASIC_REQUIRE_PROG(FIND, find)
231 BASIC_REQUIRE_PROG(HEAD, head)
232 BASIC_REQUIRE_PROG(LN, ln)
233 BASIC_REQUIRE_PROG(LS, ls)
234 BASIC_REQUIRE_PROG(MKDIR, mkdir)
235 BASIC_REQUIRE_PROG(MKTEMP, mktemp)
236 BASIC_REQUIRE_PROG(MV, mv)
237 BASIC_REQUIRE_PROG(PRINTF, printf)
238 BASIC_REQUIRE_PROG(THEPWDCMD, pwd)
239 BASIC_REQUIRE_PROG(RM, rm)
240 BASIC_REQUIRE_PROG(SH, sh)
241 BASIC_REQUIRE_PROG(SORT, sort)
242 BASIC_REQUIRE_PROG(TAIL, tail)
243 BASIC_REQUIRE_PROG(TAR, tar)
244 BASIC_REQUIRE_PROG(TEE, tee)
245 BASIC_REQUIRE_PROG(TOUCH, touch)
246 BASIC_REQUIRE_PROG(TR, tr)
247 BASIC_REQUIRE_PROG(UNAME, uname)
248 BASIC_REQUIRE_PROG(UNIQ, uniq)
249 BASIC_REQUIRE_PROG(WC, wc)
250 BASIC_REQUIRE_PROG(WHICH, which)
251 BASIC_REQUIRE_PROG(XARGS, xargs)
253 # Then required tools that require some special treatment.
254 AC_PROG_AWK
255 BASIC_CHECK_NONEMPTY(AWK)
256 AC_PROG_GREP
257 BASIC_CHECK_NONEMPTY(GREP)
258 AC_PROG_EGREP
259 BASIC_CHECK_NONEMPTY(EGREP)
260 AC_PROG_FGREP
261 BASIC_CHECK_NONEMPTY(FGREP)
262 AC_PROG_SED
263 BASIC_CHECK_NONEMPTY(SED)
265 AC_PATH_PROGS(NAWK, [nawk gawk awk])
266 BASIC_CHECK_NONEMPTY(NAWK)
268 # Always force rm.
269 RM="$RM -f"
271 # These are not required on all platforms
272 AC_PATH_PROG(CYGPATH, cygpath)
273 AC_PATH_PROG(READLINK, readlink)
274 AC_PATH_PROG(DF, df)
275 AC_PATH_PROG(SETFILE, SetFile)
276 ])
278 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
279 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
280 [
281 # Locate the directory of this script.
282 SCRIPT="[$]0"
283 BASIC_REMOVE_SYMBOLIC_LINKS(SCRIPT)
284 AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD`
286 # Where is the source? It is located two levels above the configure script.
287 CURDIR="$PWD"
288 cd "$AUTOCONF_DIR/../.."
289 SRC_ROOT="`pwd`"
291 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
292 PATH_SEP=";"
293 BASIC_CHECK_PATHS_WINDOWS
294 else
295 PATH_SEP=":"
296 fi
298 AC_SUBST(SRC_ROOT)
299 AC_SUBST(PATH_SEP)
300 cd "$CURDIR"
302 BASIC_FIXUP_PATH(SRC_ROOT)
303 BASIC_FIXUP_PATH(CURDIR)
305 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
306 # Add extra search paths on solaris for utilities like ar and as etc...
307 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
308 fi
310 # You can force the sys-root if the sys-root encoded into the cross compiler tools
311 # is not correct.
312 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
313 [pass this sys-root to the compilers and tools (for cross-compiling)])])
315 if test "x$with_sys_root" != x; then
316 SYS_ROOT=$with_sys_root
317 else
318 SYS_ROOT=/
319 fi
320 AC_SUBST(SYS_ROOT)
322 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
323 [search this directory for compilers and tools (for cross-compiling)])], [TOOLS_DIR=$with_tools_dir])
325 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
326 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
327 [
328 if test "x$with_sys_root" != x; then
329 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
330 fi
331 if test "x$with_tools_dir" != x; then
332 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-tools-dir at the same time])
333 fi
334 TOOLS_DIR=$with_devkit/bin
335 SYS_ROOT=$with_devkit/$host_alias/libc
336 ])
338 ])
340 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
341 [
343 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
344 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
345 [ CONF_NAME=${with_conf_name} ])
347 # Test from where we are running configure, in or outside of src root.
348 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" || test "x$CURDIR" = "x$SRC_ROOT/common/makefiles" ; then
349 # We are running configure from the src root.
350 # Create a default ./build/target-variant-debuglevel output root.
351 if test "x${CONF_NAME}" = x; then
352 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
353 fi
354 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
355 $MKDIR -p "$OUTPUT_ROOT"
356 if test ! -d "$OUTPUT_ROOT"; then
357 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
358 fi
359 else
360 # We are running configure from outside of the src dir.
361 # Then use the current directory as output dir!
362 # If configuration is situated in normal build directory, just use the build
363 # directory name as configuration name, otherwise use the complete path.
364 if test "x${CONF_NAME}" = x; then
365 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
366 fi
367 OUTPUT_ROOT="$CURDIR"
369 # WARNING: This might be a bad thing to do. You need to be sure you want to
370 # have a configuration in this directory. Do some sanity checks!
372 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
373 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
374 # other files
375 files_present=`$LS $OUTPUT_ROOT`
376 # Configure has already touched config.log and confdefs.h in the current dir when this check
377 # is performed.
378 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
379 | $TR -d '\n'`
380 if test "x$filtered_files" != x; then
381 AC_MSG_NOTICE([Current directory is $CURDIR.])
382 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
383 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
384 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
385 AC_MSG_NOTICE([seriously mess up just about everything.])
386 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
387 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
388 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
389 fi
390 fi
391 fi
392 AC_MSG_CHECKING([what configuration name to use])
393 AC_MSG_RESULT([$CONF_NAME])
395 BASIC_FIXUP_PATH(OUTPUT_ROOT)
397 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
398 AC_SUBST(CONF_NAME, $CONF_NAME)
399 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
401 # Most of the probed defines are put into config.h
402 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
403 # The spec.gmk file contains all variables for the make system.
404 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
405 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
406 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
407 # The bootcycle-spec.gmk file contains support for boot cycle builds.
408 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
409 # The compare.sh is used to compare the build output to other builds.
410 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
411 # Spec.sh is currently used by compare-objects.sh
412 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
413 # The generated Makefile knows where the spec.gmk is and where the source is.
414 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
415 # which will look for generated configurations
416 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
418 # Save the arguments given to us
419 echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
420 ])
422 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
423 [
424 # Setup default logging of stdout and stderr to build.log in the output root.
425 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
426 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
427 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
428 AC_SUBST(BUILD_LOG)
429 AC_SUBST(BUILD_LOG_PREVIOUS)
430 AC_SUBST(BUILD_LOG_WRAPPER)
431 ])
434 #%%% Simple tools %%%
436 # Check if we have found a usable version of make
437 # $1: the path to a potential make binary (or empty)
438 # $2: the description on how we found this
439 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
440 [
441 MAKE_CANDIDATE="$1"
442 DESCRIPTION="$2"
443 if test "x$MAKE_CANDIDATE" != x; then
444 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
445 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
446 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
447 if test "x$IS_GNU_MAKE" = x; then
448 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
449 else
450 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP '3.8[[12346789]]'`
451 if test "x$IS_MODERN_MAKE" = x; then
452 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
453 else
454 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
455 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
456 MAKE_EXPECTED_ENV='cygwin'
457 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
458 MAKE_EXPECTED_ENV='msys'
459 else
460 AC_MSG_ERROR([Unknown Windows environment])
461 fi
462 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
463 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
464 else
465 # Not relevant for non-Windows
466 IS_MAKE_CORRECT_ENV=true
467 fi
468 if test "x$IS_MAKE_CORRECT_ENV" = x; then
469 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
470 else
471 FOUND_MAKE=$MAKE_CANDIDATE
472 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
473 fi
474 fi
475 fi
476 fi
477 ])
479 # Goes looking for a usable version of GNU make.
480 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
481 [
482 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
483 if test "x$MAKE" != x; then
484 # User has supplied a make, test it.
485 if test ! -f "$MAKE"; then
486 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
487 fi
488 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
489 if test "x$FOUND_MAKE" = x; then
490 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
491 fi
492 else
493 # Try our hardest to locate a correct version of GNU make
494 AC_PATH_PROGS(CHECK_GMAKE, gmake)
495 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
497 if test "x$FOUND_MAKE" = x; then
498 AC_PATH_PROGS(CHECK_MAKE, make)
499 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
500 fi
502 if test "x$FOUND_MAKE" = x; then
503 if test "x$TOOLS_DIR" != x; then
504 # We have a tools-dir, check that as well before giving up.
505 OLD_PATH=$PATH
506 PATH=$TOOLS_DIR:$PATH
507 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
508 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
509 if test "x$FOUND_MAKE" = x; then
510 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
511 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
512 fi
513 PATH=$OLD_PATH
514 fi
515 fi
517 if test "x$FOUND_MAKE" = x; then
518 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
519 fi
520 fi
522 MAKE=$FOUND_MAKE
523 AC_SUBST(MAKE)
524 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
525 ])
527 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
528 [
529 # Test if find supports -delete
530 AC_MSG_CHECKING([if find supports -delete])
531 FIND_DELETE="-delete"
533 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
535 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
537 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
538 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
539 # No, it does not.
540 rm $DELETEDIR/TestIfFindSupportsDelete
541 FIND_DELETE="-exec rm \{\} \+"
542 AC_MSG_RESULT([no])
543 else
544 AC_MSG_RESULT([yes])
545 fi
546 rmdir $DELETEDIR
547 AC_SUBST(FIND_DELETE)
548 ])
550 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
551 [
552 BASIC_CHECK_GNU_MAKE
554 BASIC_CHECK_FIND_DELETE
556 # These tools might not be installed by default,
557 # need hint on how to install them.
558 BASIC_REQUIRE_PROG(UNZIP, unzip)
559 BASIC_REQUIRE_PROG(ZIP, zip)
561 # Non-required basic tools
563 AC_PATH_PROG(LDD, ldd)
564 if test "x$LDD" = "x"; then
565 # List shared lib dependencies is used for
566 # debug output and checking for forbidden dependencies.
567 # We can build without it.
568 LDD="true"
569 fi
570 AC_PATH_PROG(OTOOL, otool)
571 if test "x$OTOOL" = "x"; then
572 OTOOL="true"
573 fi
574 AC_PATH_PROGS(READELF, [readelf greadelf])
575 AC_PATH_PROG(HG, hg)
576 AC_PATH_PROG(STAT, stat)
577 AC_PATH_PROG(TIME, time)
579 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
580 BASIC_REQUIRE_PROG(COMM, comm)
581 fi
582 ])
584 # Check if build directory is on local disk. If not possible to determine,
585 # we prefer to claim it's local.
586 # Argument 1: directory to test
587 # Argument 2: what to do if it is on local disk
588 # Argument 3: what to do otherwise (remote disk or failure)
589 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
590 [
591 # df -l lists only local disks; if the given directory is not found then
592 # a non-zero exit code is given
593 if test "x$DF" = x; then
594 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
595 # msys does not have df; use Windows "net use" instead.
596 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
597 if test "x$IS_NETWORK_DISK" = x; then
598 $2
599 else
600 $3
601 fi
602 else
603 # No df here, say it's local
604 $2
605 fi
606 else
607 if $DF -l $1 > /dev/null 2>&1; then
608 $2
609 else
610 $3
611 fi
612 fi
613 ])
615 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
616 [
618 AC_MSG_CHECKING([if build directory is on local disk])
619 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
620 [OUTPUT_DIR_IS_LOCAL="yes"],
621 [OUTPUT_DIR_IS_LOCAL="no"])
622 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
624 # Check if the user has any old-style ALT_ variables set.
625 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
627 # Before generating output files, test if they exist. If they do, this is a reconfigure.
628 # Since we can't properly handle the dependencies for this, warn the user about the situation
629 if test -e $OUTPUT_ROOT/spec.gmk; then
630 IS_RECONFIGURE=yes
631 else
632 IS_RECONFIGURE=no
633 fi
635 if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then
636 HIDE_PERFORMANCE_HINTS=yes
637 else
638 HIDE_PERFORMANCE_HINTS=no
639 # Hide it the next time around...
640 $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1
641 fi
643 ])