Wed, 09 Oct 2013 18:51:32 -0700
8023611: Win32 and win64: Remove all the WARNINGS in JDK 8 builds for Windows 2008 and MSVS 2010 SP1
Reviewed-by: erikj
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # $1 = compiler to test (CC or CXX)
27 # $2 = human readable name of compiler (C or C++)
28 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
29 [
30 COMPILER=[$]$1
31 COMPILER_NAME=$2
33 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
34 # Make sure we use the Sun Studio compiler and not gcc on Solaris, which won't work
35 COMPILER_VERSION_TEST=`$COMPILER -V 2>&1 | $HEAD -n 1`
36 $ECHO $COMPILER_VERSION_TEST | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
37 if test $? -ne 0; then
38 GCC_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
40 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required Sun Studio compiler.])
41 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_TEST" and with --version: "$GCC_VERSION_TEST"])
42 AC_MSG_ERROR([Sun Studio compiler is required. Try setting --with-tools-dir.])
43 else
44 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/p"`
45 COMPILER_VENDOR="Sun Studio"
46 fi
47 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
48 # First line typically looks something like:
49 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
50 COMPILER_VERSION_TEST=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
51 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*Version \(@<:@1-9@:>@@<:@0-9.@:>@*\) .*/\1/p"`
52 COMPILER_VENDOR="Microsoft CL.EXE"
53 COMPILER_CPU_TEST=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* for \(.*\)$/\1/p"`
54 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
55 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
56 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
57 fi
58 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
59 if test "x$COMPILER_CPU_TEST" != "xx64"; then
60 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
61 fi
62 fi
63 else
64 COMPILER_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
65 # Check that this is likely to be GCC.
66 $COMPILER --version 2>&1 | $GREP "Free Software Foundation" > /dev/null
67 if test $? -ne 0; then
68 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required GCC compiler.])
69 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_TEST"])
70 AC_MSG_ERROR([GCC compiler is required. Try setting --with-tools-dir.])
71 fi
73 # First line typically looks something like:
74 # gcc (Ubuntu/Linaro 4.5.2-8ubuntu4) 4.5.2
75 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/p"`
76 COMPILER_VENDOR=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^\(.*\) @<:@1-9@:>@@<:@0-9.@:>@*/\1/p"`
77 fi
78 # This sets CC_VERSION or CXX_VERSION. (This comment is a grep marker)
79 $1_VERSION="$COMPILER_VERSION"
80 # This sets CC_VENDOR or CXX_VENDOR. (This comment is a grep marker)
81 $1_VENDOR="$COMPILER_VENDOR"
83 AC_MSG_NOTICE([Using $COMPILER_VENDOR $COMPILER_NAME compiler version $COMPILER_VERSION (located at $COMPILER)])
84 ])
87 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_SYSROOT_AND_OUT_OPTIONS],
88 [
89 ###############################################################################
90 #
91 # Configure the development tool paths and potential sysroot.
92 #
93 AC_LANG(C++)
95 # The option used to specify the target .o,.a or .so file.
96 # When compiling, how to specify the to be created object file.
97 CC_OUT_OPTION='-o$(SPACE)'
98 # When linking, how to specify the to be created executable.
99 EXE_OUT_OPTION='-o$(SPACE)'
100 # When linking, how to specify the to be created dynamically linkable library.
101 LD_OUT_OPTION='-o$(SPACE)'
102 # When archiving, how to specify the to be create static archive for object files.
103 AR_OUT_OPTION='rcs$(SPACE)'
104 AC_SUBST(CC_OUT_OPTION)
105 AC_SUBST(EXE_OUT_OPTION)
106 AC_SUBST(LD_OUT_OPTION)
107 AC_SUBST(AR_OUT_OPTION)
108 ])
110 # $1 = compiler to test (CC or CXX)
111 # $2 = human readable name of compiler (C or C++)
112 # $3 = list of compiler names to search for
113 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
114 [
115 COMPILER_NAME=$2
117 $1=
118 # If TOOLS_DIR is set, check for all compiler names in there first
119 # before checking the rest of the PATH.
120 if test -n "$TOOLS_DIR"; then
121 PATH_save="$PATH"
122 PATH="$TOOLS_DIR"
123 AC_PATH_PROGS(TOOLS_DIR_$1, $3)
124 $1=$TOOLS_DIR_$1
125 PATH="$PATH_save"
126 fi
128 # AC_PATH_PROGS can't be run multiple times with the same variable,
129 # so create a new name for this run.
130 if test "x[$]$1" = x; then
131 AC_PATH_PROGS(POTENTIAL_$1, $3)
132 $1=$POTENTIAL_$1
133 fi
135 if test "x[$]$1" = x; then
136 HELP_MSG_MISSING_DEPENDENCY([devkit])
137 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
138 fi
139 BASIC_FIXUP_EXECUTABLE($1)
140 AC_MSG_CHECKING([resolved symbolic links for $1])
141 TEST_COMPILER="[$]$1"
142 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
143 AC_MSG_RESULT([$TEST_COMPILER])
144 AC_MSG_CHECKING([if $1 is disguised ccache])
146 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
147 if test "x$COMPILER_BASENAME" = "xccache"; then
148 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
149 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
150 # We want to control ccache invocation ourselves, so ignore this cc and try
151 # searching again.
153 # Remove the path to the fake ccache cc from the PATH
154 RETRY_COMPILER_SAVED_PATH="$PATH"
155 COMPILER_DIRNAME=`$DIRNAME [$]$1`
156 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
158 # Try again looking for our compiler
159 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
160 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
161 PATH="$RETRY_COMPILER_SAVED_PATH"
163 AC_MSG_CHECKING([for resolved symbolic links for $1])
164 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
165 AC_MSG_RESULT([$PROPER_COMPILER_$1])
166 $1="$PROPER_COMPILER_$1"
167 else
168 AC_MSG_RESULT([no, keeping $1])
169 $1="$TEST_COMPILER"
170 fi
171 TOOLCHAIN_CHECK_COMPILER_VERSION([$1], [$COMPILER_NAME])
172 ])
175 AC_DEFUN([TOOLCHAIN_SETUP_PATHS],
176 [
177 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
178 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
179 BASIC_DEPRECATED_ARG_WITH([dxsdk])
180 BASIC_DEPRECATED_ARG_WITH([dxsdk-lib])
181 BASIC_DEPRECATED_ARG_WITH([dxsdk-include])
182 fi
184 AC_SUBST(MSVCR_DLL)
186 # If --build AND --host is set, then the configure script will find any
187 # cross compilation tools in the PATH. Cross compilation tools
188 # follows the cross compilation standard where they are prefixed with ${host}.
189 # For example the binary i686-sun-solaris2.10-gcc
190 # will cross compile for i686-sun-solaris2.10
191 # If neither of build and host is not set, then build=host and the
192 # default compiler found in the path will be used.
193 # Setting only --host, does not seem to be really supported.
194 # Please set both --build and --host if you want to cross compile.
196 if test "x$COMPILE_TYPE" = "xcross"; then
197 # Now we to find a C/C++ compiler that can build executables for the build
198 # platform. We can't use the AC_PROG_CC macro, since it can only be used
199 # once. Also, we need to do this before adding a tools dir to the path,
200 # otherwise we might pick up cross-compilers which don't use standard naming.
201 # Otherwise, we'll set the BUILD_tools to the native tools, but that'll have
202 # to wait until they are properly discovered.
203 AC_PATH_PROGS(BUILD_CC, [cl cc gcc])
204 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
205 AC_PATH_PROGS(BUILD_CXX, [cl CC g++])
206 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
207 AC_PATH_PROG(BUILD_LD, ld)
208 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
209 fi
210 AC_SUBST(BUILD_CC)
211 AC_SUBST(BUILD_CXX)
212 AC_SUBST(BUILD_LD)
214 # If a devkit is found on the builddeps server, then prepend its path to the
215 # PATH variable. If there are cross compilers available in the devkit, these
216 # will be found by AC_PROG_CC et al.
217 DEVKIT=
218 BDEPS_CHECK_MODULE(DEVKIT, devkit, xxx,
219 [# Found devkit
220 PATH="$DEVKIT/bin:$PATH"
221 SYS_ROOT="$DEVKIT/${rewritten_target}/sys-root"
222 if test "x$x_includes" = "xNONE"; then
223 x_includes="$SYS_ROOT/usr/include/X11"
224 fi
225 if test "x$x_libraries" = "xNONE"; then
226 x_libraries="$SYS_ROOT/usr/lib"
227 fi
228 ],
229 [])
231 # Store the CFLAGS etal passed to the configure script.
232 ORG_CFLAGS="$CFLAGS"
233 ORG_CXXFLAGS="$CXXFLAGS"
234 ORG_OBJCFLAGS="$OBJCFLAGS"
236 # autoconf magic only relies on PATH, so update it if tools dir is specified
237 OLD_PATH="$PATH"
238 if test "x$TOOLS_DIR" != x; then
239 PATH=$TOOLS_DIR:$PATH
240 fi
243 ### Locate C compiler (CC)
245 # On windows, only cl.exe is supported.
246 # On Solaris, cc is preferred to gcc.
247 # Elsewhere, gcc is preferred to cc.
249 if test "x$CC" != x; then
250 COMPILER_CHECK_LIST="$CC"
251 elif test "x$OPENJDK_TARGET_OS" = "xwindows"; then
252 COMPILER_CHECK_LIST="cl"
253 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
254 COMPILER_CHECK_LIST="cc gcc"
255 else
256 COMPILER_CHECK_LIST="gcc cc"
257 fi
259 TOOLCHAIN_FIND_COMPILER([CC],[C],[$COMPILER_CHECK_LIST])
260 # Now that we have resolved CC ourself, let autoconf have its go at it
261 AC_PROG_CC([$CC])
263 ### Locate C++ compiler (CXX)
265 if test "x$CXX" != x; then
266 COMPILER_CHECK_LIST="$CXX"
267 elif test "x$OPENJDK_TARGET_OS" = "xwindows"; then
268 COMPILER_CHECK_LIST="cl"
269 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
270 COMPILER_CHECK_LIST="CC g++"
271 else
272 COMPILER_CHECK_LIST="g++ CC"
273 fi
275 TOOLCHAIN_FIND_COMPILER([CXX],[C++],[$COMPILER_CHECK_LIST])
276 # Now that we have resolved CXX ourself, let autoconf have its go at it
277 AC_PROG_CXX([$CXX])
279 ### Locate other tools
281 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
282 AC_PROG_OBJC
283 BASIC_FIXUP_EXECUTABLE(OBJC)
284 else
285 OBJC=
286 fi
288 # Restore the flags to the user specified values.
289 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
290 CFLAGS="$ORG_CFLAGS"
291 CXXFLAGS="$ORG_CXXFLAGS"
292 OBJCFLAGS="$ORG_OBJCFLAGS"
294 LD="$CC"
295 LDEXE="$CC"
296 LDCXX="$CXX"
297 LDEXECXX="$CXX"
298 AC_SUBST(LD)
299 # LDEXE is the linker to use, when creating executables.
300 AC_SUBST(LDEXE)
301 # Linking C++ libraries.
302 AC_SUBST(LDCXX)
303 # Linking C++ executables.
304 AC_SUBST(LDEXECXX)
306 if test "x$OPENJDK_TARGET_OS" != xwindows; then
307 AC_CHECK_TOOL(AR, ar)
308 BASIC_FIXUP_EXECUTABLE(AR)
309 fi
310 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
311 ARFLAGS="-r"
312 else
313 ARFLAGS=""
314 fi
315 AC_SUBST(ARFLAGS)
317 # For hotspot, we need these in Windows mixed path; other platforms keep them the same
318 HOTSPOT_CXX="$CXX"
319 HOTSPOT_LD="$LD"
320 AC_SUBST(HOTSPOT_CXX)
321 AC_SUBST(HOTSPOT_LD)
323 COMPILER_NAME=gcc
324 COMPILER_TYPE=CC
325 AS_IF([test "x$OPENJDK_TARGET_OS" = xwindows], [
326 # For now, assume that we are always compiling using cl.exe.
327 CC_OUT_OPTION=-Fo
328 EXE_OUT_OPTION=-out:
329 LD_OUT_OPTION=-out:
330 AR_OUT_OPTION=-out:
331 # On Windows, reject /usr/bin/link (as determined in CYGWIN_LINK), which is a cygwin
332 # program for something completely different.
333 AC_CHECK_PROG([WINLD], [link],[link],,, [$CYGWIN_LINK])
334 # Since we must ignore the first found link, WINLD will contain
335 # the full path to the link.exe program.
336 BASIC_FIXUP_EXECUTABLE(WINLD)
337 printf "Windows linker was found at $WINLD\n"
338 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
339 "$WINLD" --version > /dev/null
340 if test $? -eq 0 ; then
341 AC_MSG_RESULT([no])
342 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
343 else
344 AC_MSG_RESULT([yes])
345 fi
346 LD="$WINLD"
347 LDEXE="$WINLD"
348 LDCXX="$WINLD"
349 LDEXECXX="$WINLD"
351 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
352 BASIC_FIXUP_EXECUTABLE(MT)
353 # The resource compiler
354 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
355 BASIC_FIXUP_EXECUTABLE(RC)
357 # For hotspot, we need these in Windows mixed path,
358 # so rewrite them all. Need added .exe suffix.
359 HOTSPOT_CXX="$CXX.exe"
360 HOTSPOT_LD="$LD.exe"
361 HOTSPOT_MT="$MT.exe"
362 HOTSPOT_RC="$RC.exe"
363 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
364 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
365 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
366 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
367 AC_SUBST(HOTSPOT_MT)
368 AC_SUBST(HOTSPOT_RC)
370 RC_FLAGS="-nologo -l 0x409 -r"
371 AS_IF([test "x$VARIANT" = xOPT], [
372 RC_FLAGS="$RC_FLAGS -d NDEBUG"
373 ])
375 # The version variables used to create RC_FLAGS may be overridden
376 # in a custom configure script, or possibly the command line.
377 # Let those variables be expanded at make time in spec.gmk.
378 # The \$ are escaped to the shell, and the $(...) variables
379 # are evaluated by make.
380 RC_FLAGS="$RC_FLAGS \
381 -d \"JDK_BUILD_ID=\$(FULL_VERSION)\" \
382 -d \"JDK_COMPANY=\$(COMPANY_NAME)\" \
383 -d \"JDK_COMPONENT=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) binary\" \
384 -d \"JDK_VER=\$(JDK_MINOR_VERSION).\$(JDK_MICRO_VERSION).\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0).\$(COOKED_BUILD_NUMBER)\" \
385 -d \"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\" \
386 -d \"JDK_NAME=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) \$(JDK_MINOR_VERSION) \$(JDK_UPDATE_META_TAG)\" \
387 -d \"JDK_FVER=\$(JDK_MINOR_VERSION),\$(JDK_MICRO_VERSION),\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0),\$(COOKED_BUILD_NUMBER)\""
389 # lib.exe is used to create static libraries.
390 AC_CHECK_PROG([WINAR], [lib],[lib],,,)
391 BASIC_FIXUP_EXECUTABLE(WINAR)
392 AR="$WINAR"
393 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
395 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
396 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
398 COMPILER_TYPE=CL
399 CCXXFLAGS="$CCXXFLAGS -nologo"
400 ])
401 AC_SUBST(RC_FLAGS)
402 AC_SUBST(COMPILER_TYPE)
404 AC_PROG_CPP
405 BASIC_FIXUP_EXECUTABLE(CPP)
407 AC_PROG_CXXCPP
408 BASIC_FIXUP_EXECUTABLE(CXXCPP)
410 if test "x$COMPILE_TYPE" != "xcross"; then
411 # If we are not cross compiling, use the same compilers for
412 # building the build platform executables. The cross-compilation
413 # case needed to be done earlier, but this can only be done after
414 # the native tools have been localized.
415 BUILD_CC="$CC"
416 BUILD_CXX="$CXX"
417 BUILD_LD="$LD"
418 fi
420 # for solaris we really need solaris tools, and not gnu equivalent
421 # these seems to normally reside in /usr/ccs/bin so add that to path before
422 # starting to probe
423 #
424 # NOTE: I add this /usr/ccs/bin after TOOLS but before OLD_PATH
425 # so that it can be overriden --with-tools-dir
426 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
427 PATH="${TOOLS_DIR}:/usr/ccs/bin:${OLD_PATH}"
428 fi
430 # Find the right assembler.
431 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
432 AC_PATH_PROG(AS, as)
433 BASIC_FIXUP_EXECUTABLE(AS)
434 else
435 AS="$CC -c"
436 fi
437 AC_SUBST(AS)
439 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
440 AC_PATH_PROG(NM, nm)
441 BASIC_FIXUP_EXECUTABLE(NM)
442 AC_PATH_PROG(GNM, gnm)
443 BASIC_FIXUP_EXECUTABLE(GNM)
444 AC_PATH_PROG(STRIP, strip)
445 BASIC_FIXUP_EXECUTABLE(STRIP)
446 AC_PATH_PROG(MCS, mcs)
447 BASIC_FIXUP_EXECUTABLE(MCS)
448 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
449 AC_CHECK_TOOL(NM, nm)
450 BASIC_FIXUP_EXECUTABLE(NM)
451 GNM="$NM"
452 AC_SUBST(GNM)
453 AC_CHECK_TOOL(STRIP, strip)
454 BASIC_FIXUP_EXECUTABLE(STRIP)
455 fi
457 # objcopy is used for moving debug symbols to separate files when
458 # full debug symbols are enabled.
459 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
460 AC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
461 # Only call fixup if objcopy was found.
462 if test -n "$OBJCOPY"; then
463 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
464 fi
465 fi
467 AC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
468 if test "x$OBJDUMP" != x; then
469 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE bails if argument is missing.
470 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
471 fi
473 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
474 AC_PATH_PROG(LIPO, lipo)
475 BASIC_FIXUP_EXECUTABLE(LIPO)
476 fi
478 TOOLCHAIN_SETUP_JTREG
480 # Restore old path without tools dir
481 PATH="$OLD_PATH"
482 ])
485 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_LIBS],
486 [
488 ###############################################################################
489 #
490 # How to compile shared libraries.
491 #
493 if test "x$GCC" = xyes; then
494 COMPILER_NAME=gcc
495 PICFLAG="-fPIC"
496 LIBRARY_PREFIX=lib
497 SHARED_LIBRARY='lib[$]1.so'
498 STATIC_LIBRARY='lib[$]1.a'
499 SHARED_LIBRARY_FLAGS="-shared"
500 SHARED_LIBRARY_SUFFIX='.so'
501 STATIC_LIBRARY_SUFFIX='.a'
502 OBJ_SUFFIX='.o'
503 EXE_SUFFIX=''
504 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
505 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
506 C_FLAG_REORDER=''
507 CXX_FLAG_REORDER=''
508 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -z -Xlinker origin -Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
509 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
510 LD="$CC"
511 LDEXE="$CC"
512 LDCXX="$CXX"
513 LDEXECXX="$CXX"
514 POST_STRIP_CMD="$STRIP -g"
516 # Linking is different on MacOSX
517 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
518 # Might change in the future to clang.
519 COMPILER_NAME=gcc
520 SHARED_LIBRARY='lib[$]1.dylib'
521 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
522 SHARED_LIBRARY_SUFFIX='.dylib'
523 EXE_SUFFIX=''
524 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
525 SET_SHARED_LIBRARY_MAPFILE=''
526 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
527 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
528 POST_STRIP_CMD="$STRIP -S"
529 fi
530 else
531 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
532 # If it is not gcc, then assume it is the Oracle Solaris Studio Compiler
533 COMPILER_NAME=ossc
534 PICFLAG="-KPIC"
535 LIBRARY_PREFIX=lib
536 SHARED_LIBRARY='lib[$]1.so'
537 STATIC_LIBRARY='lib[$]1.a'
538 SHARED_LIBRARY_FLAGS="-G"
539 SHARED_LIBRARY_SUFFIX='.so'
540 STATIC_LIBRARY_SUFFIX='.a'
541 OBJ_SUFFIX='.o'
542 EXE_SUFFIX=''
543 SET_SHARED_LIBRARY_NAME=''
544 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
545 C_FLAG_REORDER='-xF'
546 CXX_FLAG_REORDER='-xF'
547 SET_SHARED_LIBRARY_ORIGIN='-R\$$$$ORIGIN[$]1'
548 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
549 CFLAGS_JDK="${CFLAGS_JDK} -D__solaris__"
550 CXXFLAGS_JDK="${CXXFLAGS_JDK} -D__solaris__"
551 CFLAGS_JDKLIB_EXTRA='-xstrconst'
552 POST_STRIP_CMD="$STRIP -x"
553 POST_MCS_CMD="$MCS -d -a \"JDK $FULL_VERSION\""
554 fi
555 if test "x$OPENJDK_TARGET_OS" = xwindows; then
556 # If it is not gcc, then assume it is the MS Visual Studio compiler
557 COMPILER_NAME=cl
558 PICFLAG=""
559 LIBRARY_PREFIX=
560 SHARED_LIBRARY='[$]1.dll'
561 STATIC_LIBRARY='[$]1.lib'
562 SHARED_LIBRARY_FLAGS="-LD"
563 SHARED_LIBRARY_SUFFIX='.dll'
564 STATIC_LIBRARY_SUFFIX='.lib'
565 OBJ_SUFFIX='.obj'
566 EXE_SUFFIX='.exe'
567 SET_SHARED_LIBRARY_NAME=''
568 SET_SHARED_LIBRARY_MAPFILE=''
569 SET_SHARED_LIBRARY_ORIGIN=''
570 SET_EXECUTABLE_ORIGIN=''
571 fi
572 fi
574 AC_SUBST(COMPILER_NAME)
575 AC_SUBST(OBJ_SUFFIX)
576 AC_SUBST(SHARED_LIBRARY)
577 AC_SUBST(STATIC_LIBRARY)
578 AC_SUBST(LIBRARY_PREFIX)
579 AC_SUBST(SHARED_LIBRARY_SUFFIX)
580 AC_SUBST(STATIC_LIBRARY_SUFFIX)
581 AC_SUBST(EXE_SUFFIX)
582 AC_SUBST(SHARED_LIBRARY_FLAGS)
583 AC_SUBST(SET_SHARED_LIBRARY_NAME)
584 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
585 AC_SUBST(C_FLAG_REORDER)
586 AC_SUBST(CXX_FLAG_REORDER)
587 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
588 AC_SUBST(SET_EXECUTABLE_ORIGIN)
589 AC_SUBST(POST_STRIP_CMD)
590 AC_SUBST(POST_MCS_CMD)
592 # The (cross) compiler is now configured, we can now test capabilities
593 # of the target platform.
594 ])
596 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
597 [
599 ###############################################################################
600 #
601 # Setup the opt flags for different compilers
602 # and different operating systems.
603 #
605 #
606 # NOTE: check for -mstackrealign needs to be below potential addition of -m32
607 #
608 if test "x$OPENJDK_TARGET_CPU_BITS" = x32 && test "x$OPENJDK_TARGET_OS" = xmacosx; then
609 # On 32-bit MacOSX the OS requires C-entry points to be 16 byte aligned.
610 # While waiting for a better solution, the current workaround is to use -mstackrealign.
611 CFLAGS="$CFLAGS -mstackrealign"
612 AC_MSG_CHECKING([if 32-bit compiler supports -mstackrealign])
613 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])],
614 [
615 AC_MSG_RESULT([yes])
616 ],
617 [
618 AC_MSG_RESULT([no])
619 AC_MSG_ERROR([The selected compiler $CXX does not support -mstackrealign! Try to put another compiler in the path.])
620 ])
621 fi
623 C_FLAG_DEPS="-MMD -MF"
624 CXX_FLAG_DEPS="-MMD -MF"
626 case $COMPILER_TYPE in
627 CC )
628 case $COMPILER_NAME in
629 gcc )
630 case $OPENJDK_TARGET_OS in
631 macosx )
632 # On MacOSX we optimize for size, something
633 # we should do for all platforms?
634 C_O_FLAG_HI="-Os"
635 C_O_FLAG_NORM="-Os"
636 C_O_FLAG_NONE=""
637 ;;
638 *)
639 C_O_FLAG_HI="-O3"
640 C_O_FLAG_NORM="-O2"
641 C_O_FLAG_NONE="-O0"
642 ;;
643 esac
644 CXX_O_FLAG_HI="$C_O_FLAG_HI"
645 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
646 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
647 CFLAGS_DEBUG_SYMBOLS="-g"
648 CXXFLAGS_DEBUG_SYMBOLS="-g"
649 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
650 CFLAGS_DEBUG_SYMBOLS="-g1"
651 CXXFLAGS_DEBUG_SYMBOLS="-g1"
652 fi
653 ;;
654 ossc )
655 #
656 # Forte has different names for this with their C++ compiler...
657 #
658 C_FLAG_DEPS="-xMMD -xMF"
659 CXX_FLAG_DEPS="-xMMD -xMF"
661 # Extra options used with HIGHEST
662 #
663 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
664 # done with care, there are some assumptions below that need to
665 # be understood about the use of pointers, and IEEE behavior.
666 #
667 # Use non-standard floating point mode (not IEEE 754)
668 CC_HIGHEST="$CC_HIGHEST -fns"
669 # Do some simplification of floating point arithmetic (not IEEE 754)
670 CC_HIGHEST="$CC_HIGHEST -fsimple"
671 # Use single precision floating point with 'float'
672 CC_HIGHEST="$CC_HIGHEST -fsingle"
673 # Assume memory references via basic pointer types do not alias
674 # (Source with excessing pointer casting and data access with mixed
675 # pointer types are not recommended)
676 CC_HIGHEST="$CC_HIGHEST -xalias_level=basic"
677 # Use intrinsic or inline versions for math/std functions
678 # (If you expect perfect errno behavior, do not use this)
679 CC_HIGHEST="$CC_HIGHEST -xbuiltin=%all"
680 # Loop data dependency optimizations (need -xO3 or higher)
681 CC_HIGHEST="$CC_HIGHEST -xdepend"
682 # Pointer parameters to functions do not overlap
683 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
684 # If you pass in multiple pointers to the same data, do not use this)
685 CC_HIGHEST="$CC_HIGHEST -xrestrict"
686 # Inline some library routines
687 # (If you expect perfect errno behavior, do not use this)
688 CC_HIGHEST="$CC_HIGHEST -xlibmil"
689 # Use optimized math routines
690 # (If you expect perfect errno behavior, do not use this)
691 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
692 #CC_HIGHEST="$CC_HIGHEST -xlibmopt"
694 if test "x$OPENJDK_TARGET_CPU" = xsparc; then
695 CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
696 CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
697 fi
699 case $OPENJDK_TARGET_CPU_ARCH in
700 x86)
701 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xregs=no%frameptr"
702 C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
703 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
704 C_O_FLAG_NONE="-xregs=no%frameptr"
705 CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
706 CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
707 CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
708 CXX_O_FLAG_NONE="-xregs=no%frameptr"
709 if test "x$OPENJDK_TARGET_CPU" = xx86; then
710 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
711 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
712 fi
713 ;;
714 sparc)
715 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
716 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
717 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
718 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
719 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
720 C_O_FLAG_NONE=""
721 CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
722 CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
723 CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
724 CXX_O_FLAG_NONE=""
725 ;;
726 esac
728 CFLAGS_DEBUG_SYMBOLS="-g -xs"
729 CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
730 esac
731 ;;
732 CL )
733 C_O_FLAG_HIGHEST="-O2"
734 C_O_FLAG_HI="-O1"
735 C_O_FLAG_NORM="-O1"
736 C_O_FLAG_NONE="-Od"
737 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
738 CXX_O_FLAG_HI="$C_O_FLAG_HI"
739 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
740 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
741 ;;
742 esac
744 if test -z "$C_O_FLAG_HIGHEST"; then
745 C_O_FLAG_HIGHEST="$C_O_FLAG_HI"
746 fi
748 if test -z "$CXX_O_FLAG_HIGHEST"; then
749 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HI"
750 fi
752 AC_SUBST(C_O_FLAG_HIGHEST)
753 AC_SUBST(C_O_FLAG_HI)
754 AC_SUBST(C_O_FLAG_NORM)
755 AC_SUBST(C_O_FLAG_NONE)
756 AC_SUBST(CXX_O_FLAG_HIGHEST)
757 AC_SUBST(CXX_O_FLAG_HI)
758 AC_SUBST(CXX_O_FLAG_NORM)
759 AC_SUBST(CXX_O_FLAG_NONE)
760 AC_SUBST(C_FLAG_DEPS)
761 AC_SUBST(CXX_FLAG_DEPS)
762 ])
764 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_JDK],
765 [
767 if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
768 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
769 fi
771 if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
772 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
773 fi
775 if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
776 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
777 fi
779 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
780 [extra flags to be used when compiling jdk c-files])])
782 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
783 [extra flags to be used when compiling jdk c++-files])])
785 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
786 [extra flags to be used when linking jdk])])
788 CFLAGS_JDK="${CFLAGS_JDK} $with_extra_cflags"
789 CXXFLAGS_JDK="${CXXFLAGS_JDK} $with_extra_cxxflags"
790 LDFLAGS_JDK="${LDFLAGS_JDK} $with_extra_ldflags"
792 # Hotspot needs these set in their legacy form
793 LEGACY_EXTRA_CFLAGS=$with_extra_cflags
794 LEGACY_EXTRA_CXXFLAGS=$with_extra_cxxflags
795 LEGACY_EXTRA_LDFLAGS=$with_extra_ldflags
797 AC_SUBST(LEGACY_EXTRA_CFLAGS)
798 AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
799 AC_SUBST(LEGACY_EXTRA_LDFLAGS)
801 ###############################################################################
802 #
803 # Now setup the CFLAGS and LDFLAGS for the JDK build.
804 # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
805 #
806 case $COMPILER_NAME in
807 gcc )
808 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -W -Wall -Wno-unused -Wno-parentheses \
809 -pipe \
810 -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
811 case $OPENJDK_TARGET_CPU_ARCH in
812 arm )
813 # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
814 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
815 ;;
816 ppc )
817 # on ppc we don't prevent gcc to omit frame pointer nor strict-aliasing
818 ;;
819 * )
820 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -fno-omit-frame-pointer"
821 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
822 ;;
823 esac
824 ;;
825 ossc )
826 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
827 case $OPENJDK_TARGET_CPU_ARCH in
828 x86 )
829 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_TARGET_CPU_LEGACY_LIB"
830 CFLAGS_JDK="$CFLAGS_JDK -erroff=E_BAD_PRAGMA_PACK_VALUE"
831 ;;
832 esac
834 CFLAGS_JDK="$CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
835 CXXFLAGS_JDK="$CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
837 LDFLAGS_JDK="$LDFLAGS_JDK -z defs -xildoff -ztext"
838 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK -norunpath -xnolib"
839 ;;
840 cl )
841 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -Zi -MD -Zc:wchar_t- -W3 -wd4800 \
842 -D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB -DWIN32_LEAN_AND_MEAN \
843 -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
844 -DWIN32 -DIAL"
845 case $OPENJDK_TARGET_CPU in
846 x86 )
847 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_X86_ -Dx86"
848 ;;
849 x86_64 )
850 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_AMD64_ -Damd64"
851 ;;
852 esac
853 ;;
854 esac
856 ###############################################################################
858 # Adjust flags according to debug level.
859 case $DEBUG_LEVEL in
860 fastdebug )
861 CFLAGS_JDK="$CFLAGS_JDK $CFLAGS_DEBUG_SYMBOLS"
862 CXXFLAGS_JDK="$CXXFLAGS_JDK $CXXFLAGS_DEBUG_SYMBOLS"
863 C_O_FLAG_HI="$C_O_FLAG_NORM"
864 C_O_FLAG_NORM="$C_O_FLAG_NORM"
865 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
866 CXX_O_FLAG_NORM="$CXX_O_FLAG_NORM"
867 JAVAC_FLAGS="$JAVAC_FLAGS -g"
868 ;;
869 slowdebug )
870 CFLAGS_JDK="$CFLAGS_JDK $CFLAGS_DEBUG_SYMBOLS"
871 CXXFLAGS_JDK="$CXXFLAGS_JDK $CXXFLAGS_DEBUG_SYMBOLS"
872 C_O_FLAG_HI="$C_O_FLAG_NONE"
873 C_O_FLAG_NORM="$C_O_FLAG_NONE"
874 CXX_O_FLAG_HI="$CXX_O_FLAG_NONE"
875 CXX_O_FLAG_NORM="$CXX_O_FLAG_NONE"
876 JAVAC_FLAGS="$JAVAC_FLAGS -g"
877 ;;
878 esac
880 CCXXFLAGS_JDK="$CCXXFLAGS_JDK $ADD_LP64"
882 # The package path is used only on macosx?
883 PACKAGE_PATH=/opt/local
884 AC_SUBST(PACKAGE_PATH)
886 if test "x$OPENJDK_TARGET_CPU_ENDIAN" = xlittle; then
887 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
888 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
889 # (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
890 # Note: -Dmacro is the same as #define macro 1
891 # -Dmacro= is the same as #define macro
892 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
893 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
894 else
895 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
896 fi
897 else
898 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_BIG_ENDIAN"
899 fi
900 if test "x$OPENJDK_TARGET_OS" = xlinux; then
901 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DLINUX"
902 fi
903 if test "x$OPENJDK_TARGET_OS" = xwindows; then
904 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DWINDOWS"
905 fi
906 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
907 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DSOLARIS"
908 fi
909 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
910 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMACOSX -D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
911 # Setting these parameters makes it an error to link to macosx APIs that are
912 # newer than the given OS version and makes the linked binaries compatible even
913 # if built on a newer version of the OS.
914 # The expected format is X.Y.Z
915 MACOSX_VERSION_MIN=10.7.0
916 AC_SUBST(MACOSX_VERSION_MIN)
917 # The macro takes the version with no dots, ex: 1070
918 # Let the flags variables get resolved in make for easier override on make
919 # command line.
920 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
921 LDFLAGS_JDK="$LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
922 fi
923 if test "x$OPENJDK_TARGET_OS" = xbsd; then
924 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DBSD -D_ALLBSD_SOURCE"
925 fi
926 if test "x$DEBUG_LEVEL" = xrelease; then
927 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DNDEBUG"
928 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
929 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DTRIMMED"
930 fi
931 else
932 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DDEBUG"
933 fi
935 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DARCH='\"$OPENJDK_TARGET_CPU_LEGACY\"' -D$OPENJDK_TARGET_CPU_LEGACY"
936 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DRELEASE='\"$RELEASE\"'"
938 CCXXFLAGS_JDK="$CCXXFLAGS_JDK \
939 -I${JDK_OUTPUTDIR}/include \
940 -I${JDK_OUTPUTDIR}/include/$OPENJDK_TARGET_OS \
941 -I${JDK_TOPDIR}/src/share/javavm/export \
942 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/javavm/export \
943 -I${JDK_TOPDIR}/src/share/native/common \
944 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/native/common"
946 # The shared libraries are compiled using the picflag.
947 CFLAGS_JDKLIB="$CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
948 CXXFLAGS_JDKLIB="$CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA "
950 # Executable flags
951 CFLAGS_JDKEXE="$CCXXFLAGS_JDK $CFLAGS_JDK"
952 CXXFLAGS_JDKEXE="$CCXXFLAGS_JDK $CXXFLAGS_JDK"
954 # Now this is odd. The JDK native libraries have to link against libjvm.so
955 # On 32-bit machines there is normally two distinct libjvm.so:s, client and server.
956 # Which should we link to? Are we lucky enough that the binary api to the libjvm.so library
957 # is identical for client and server? Yes. Which is picked at runtime (client or server)?
958 # Neither, since the chosen libjvm.so has already been loaded by the launcher, all the following
959 # libraries will link to whatever is in memory. Yuck.
960 #
961 # Thus we offer the compiler to find libjvm.so first in server then in client. It works. Ugh.
962 if test "x$COMPILER_NAME" = xcl; then
963 LDFLAGS_JDK="$LDFLAGS_JDK -nologo -opt:ref -incremental:no"
964 if test "x$OPENJDK_TARGET_CPU" = xx86; then
965 LDFLAGS_JDK="$LDFLAGS_JDK -safeseh"
966 fi
967 # TODO: make -debug optional "--disable-full-debug-symbols"
968 LDFLAGS_JDK="$LDFLAGS_JDK -debug"
969 LDFLAGS_JDKLIB="${LDFLAGS_JDK} -dll -libpath:${JDK_OUTPUTDIR}/lib"
970 LDFLAGS_JDKLIB_SUFFIX=""
971 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
972 LDFLAGS_STACK_SIZE=1048576
973 else
974 LDFLAGS_STACK_SIZE=327680
975 fi
976 LDFLAGS_JDKEXE="${LDFLAGS_JDK} /STACK:$LDFLAGS_STACK_SIZE"
977 else
978 if test "x$COMPILER_NAME" = xgcc; then
979 # If this is a --hash-style=gnu system, use --hash-style=both, why?
980 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
981 if test -n "$HAS_GNU_HASH"; then
982 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker --hash-style=both "
983 fi
984 if test "x$OPENJDK_TARGET_OS" = xlinux; then
985 # And since we now know that the linker is gnu, then add -z defs, to forbid
986 # undefined symbols in object files.
987 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -z -Xlinker defs"
988 if test "x$DEBUG_LEVEL" = "xrelease"; then
989 # When building release libraries, tell the linker optimize them.
990 # Should this be supplied to the OSS linker as well?
991 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -O1"
992 fi
993 fi
994 fi
995 LDFLAGS_JDKLIB="${LDFLAGS_JDK} $SHARED_LIBRARY_FLAGS \
996 -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}"
998 # On some platforms (mac) the linker warns about non existing -L dirs.
999 # Add server first if available. Linking aginst client does not always produce the same results.
1000 # Only add client dir if client is being built. Add minimal (note not minimal1) if only building minimal1.
1001 # Default to server for other variants.
1002 if test "x$JVM_VARIANT_SERVER" = xtrue; then
1003 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
1004 elif test "x$JVM_VARIANT_CLIENT" = xtrue; then
1005 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/client"
1006 elif test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
1007 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/minimal"
1008 else
1009 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
1010 fi
1012 LDFLAGS_JDKLIB_SUFFIX="-ljava -ljvm"
1013 if test "x$COMPILER_NAME" = xossc; then
1014 LDFLAGS_JDKLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX -lc"
1015 fi
1017 LDFLAGS_JDKEXE="${LDFLAGS_JDK}"
1018 if test "x$OPENJDK_TARGET_OS" = xlinux; then
1019 LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE -Xlinker --allow-shlib-undefined"
1020 fi
1021 fi
1023 AC_SUBST(CFLAGS_JDKLIB)
1024 AC_SUBST(CFLAGS_JDKEXE)
1026 AC_SUBST(CXXFLAGS_JDKLIB)
1027 AC_SUBST(CXXFLAGS_JDKEXE)
1029 AC_SUBST(LDFLAGS_JDKLIB)
1030 AC_SUBST(LDFLAGS_JDKEXE)
1031 AC_SUBST(LDFLAGS_JDKLIB_SUFFIX)
1032 AC_SUBST(LDFLAGS_JDKEXE_SUFFIX)
1033 AC_SUBST(LDFLAGS_CXX_JDK)
1034 ])
1037 # TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
1038 # [RUN-IF-FALSE])
1039 # ------------------------------------------------------------
1040 # Check that the c and c++ compilers support an argument
1041 AC_DEFUN([TOOLCHAIN_COMPILER_CHECK_ARGUMENTS],
1042 [
1043 AC_MSG_CHECKING([if compiler supports "$1"])
1044 supports=yes
1046 saved_cflags="$CFLAGS"
1047 CFLAGS="$CFLAGS $1"
1048 AC_LANG_PUSH([C])
1049 AC_COMPILE_IFELSE([
1050 AC_LANG_SOURCE([[int i;]])
1051 ], [], [supports=no])
1052 AC_LANG_POP([C])
1053 CFLAGS="$saved_cflags"
1055 saved_cxxflags="$CXXFLAGS"
1056 CXXFLAGS="$CXXFLAG $1"
1057 AC_LANG_PUSH([C++])
1058 AC_COMPILE_IFELSE([
1059 AC_LANG_SOURCE([[int i;]])
1060 ], [], [supports=no])
1061 AC_LANG_POP([C++])
1062 CXXFLAGS="$saved_cxxflags"
1064 AC_MSG_RESULT([$supports])
1065 if test "x$supports" = "xyes" ; then
1066 m4_ifval([$2], [$2], [:])
1067 else
1068 m4_ifval([$3], [$3], [:])
1069 fi
1070 ])
1072 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_MISC],
1073 [
1074 # Some Zero and Shark settings.
1075 # ZERO_ARCHFLAG tells the compiler which mode to build for
1076 case "${OPENJDK_TARGET_CPU}" in
1077 s390)
1078 ZERO_ARCHFLAG="-m31"
1079 ;;
1080 *)
1081 ZERO_ARCHFLAG="-m${OPENJDK_TARGET_CPU_BITS}"
1082 esac
1083 TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([$ZERO_ARCHFLAG], [], [ZERO_ARCHFLAG=""])
1084 AC_SUBST(ZERO_ARCHFLAG)
1086 # Check that the compiler supports -mX flags
1087 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
1088 TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([-m${OPENJDK_TARGET_CPU_BITS}],
1089 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
1090 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
1091 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
1092 ])
1094 # Setup the JTREG paths
1095 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
1096 [
1097 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
1098 [Regression Test Harness @<:@probed@:>@])],
1099 [],
1100 [with_jtreg=no])
1102 if test "x$with_jtreg" = xno; then
1103 # jtreg disabled
1104 AC_MSG_CHECKING([for jtreg])
1105 AC_MSG_RESULT(no)
1106 else
1107 if test "x$with_jtreg" != xyes; then
1108 # with path specified.
1109 JT_HOME="$with_jtreg"
1110 fi
1112 if test "x$JT_HOME" != x; then
1113 AC_MSG_CHECKING([for jtreg])
1115 # use JT_HOME enviroment var.
1116 BASIC_FIXUP_PATH([JT_HOME])
1118 # jtreg win32 script works for everybody
1119 JTREGEXE="$JT_HOME/win32/bin/jtreg"
1121 if test ! -f "$JTREGEXE"; then
1122 AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
1123 fi
1125 AC_MSG_RESULT($JTREGEXE)
1126 else
1127 # try to find jtreg on path
1128 BASIC_REQUIRE_PROG(JTREGEXE, jtreg)
1129 JT_HOME="`$DIRNAME $JTREGEXE`"
1130 fi
1131 fi
1133 AC_SUBST(JT_HOME)
1134 AC_SUBST(JTREGEXE)
1135 ])