jdk8-mips64-public: common/autoconf/jdk-options.m4@e2057191f6da

8010030: Allow configure to detect if EC implementation is present
Reviewed-by: andrew, dholmes

1 #

     2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],

    27 [

    28 ###############################################################################

    29 #

    30 # Check which variant of the JDK that we want to build.

    31 # Currently we have:

    32 #    normal:   standard edition

    33 # but the custom make system may add other variants

    34 #

    35 # Effectively the JDK variant gives a name to a specific set of

    36 # modules to compile into the JDK. In the future, these modules

    37 # might even be Jigsaw modules.

    38 #

    39 AC_MSG_CHECKING([which variant of the JDK to build])

    40 AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],

    41 	[JDK variant to build (normal) @<:@normal@:>@])])

    43 if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then

    44     JDK_VARIANT="normal"

    45 else

    46     AC_MSG_ERROR([The available JDK variants are: normal])

    47 fi

    49 AC_SUBST(JDK_VARIANT)

    51 AC_MSG_RESULT([$JDK_VARIANT])

    52 ])

    54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],

    55 [

    57 ###############################################################################

    58 #

    59 # Check which variants of the JVM that we want to build.

    60 # Currently we have:

    61 #    server: normal interpreter and a tiered C1/C2 compiler

    62 #    client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)

    63 #    minimal1: reduced form of client with optional VM services and features stripped out

    64 #    kernel: kernel footprint JVM that passes the TCK without major performance problems,

    65 #             ie normal interpreter and C1, only the serial GC, kernel jvmti etc

    66 #    zero: no machine code interpreter, no compiler

    67 #    zeroshark: zero interpreter and shark/llvm compiler backend

    68 AC_MSG_CHECKING([which variants of the JVM to build])

    69 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],

    70 	[JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark) @<:@server@:>@])])

    72 if test "x$with_jvm_variants" = x; then

    73      with_jvm_variants="server"

    74 fi

    76 JVM_VARIANTS=",$with_jvm_variants,"

    77 TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//'  -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//'`

    79 if test "x$TEST_VARIANTS" != "x,"; then

    80    AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark])

    81 fi

    82 AC_MSG_RESULT([$with_jvm_variants])

    84 JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`

    85 JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`

    86 JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`

    87 JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`

    88 JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`

    89 JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`

    91 if test "x$JVM_VARIANT_CLIENT" = xtrue; then

    92     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

    93         AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])

    94     fi

    95 fi

    96 if test "x$JVM_VARIANT_KERNEL" = xtrue; then

    97     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

    98         AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])

    99     fi

   100 fi

   101 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then

   102     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   103         AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])

   104     fi

   105 fi

   107 # Replace the commas with AND for use in the build directory name.

   108 ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/'`

   109 COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/'`

   110 if test "x$COUNT_VARIANTS" != "x,1"; then

   111     BUILDING_MULTIPLE_JVM_VARIANTS=yes

   112 else

   113     BUILDING_MULTIPLE_JVM_VARIANTS=no

   114 fi

   116 AC_SUBST(JVM_VARIANTS)

   117 AC_SUBST(JVM_VARIANT_SERVER)

   118 AC_SUBST(JVM_VARIANT_CLIENT)

   119 AC_SUBST(JVM_VARIANT_MINIMAL1)

   120 AC_SUBST(JVM_VARIANT_KERNEL)

   121 AC_SUBST(JVM_VARIANT_ZERO)

   122 AC_SUBST(JVM_VARIANT_ZEROSHARK)

   124 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   125    MACOSX_UNIVERSAL="true"

   126 fi

   128 AC_SUBST(MACOSX_UNIVERSAL)

   130 ])

   132 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],

   133 [

   134 ###############################################################################

   135 #

   136 # Set the debug level

   137 #    release: no debug information, all optimizations, no asserts.

   138 #    fastdebug: debug information (-g), all optimizations, all asserts

   139 #    slowdebug: debug information (-g), no optimizations, all asserts

   140 #

   141 DEBUG_LEVEL="release"

   142 AC_MSG_CHECKING([which debug level to use])

   143 AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],

   144 	[set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],

   145 	[

   146         ENABLE_DEBUG="${enableval}"

   147         DEBUG_LEVEL="fastdebug"

   148     ], [ENABLE_DEBUG="no"])

   150 AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],

   151 	[set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],

   152 	[

   153         DEBUG_LEVEL="${withval}"

   154         if test "x$ENABLE_DEBUG" = xyes; then

   155 			AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])

   156         fi

   157     ])

   158 AC_MSG_RESULT([$DEBUG_LEVEL])

   160 if test "x$DEBUG_LEVEL" != xrelease && \

   161    test "x$DEBUG_LEVEL" != xfastdebug && \

   162    test "x$DEBUG_LEVEL" != xslowdebug; then

   163    AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])

   164 fi

   167 ###############################################################################

   168 #

   169 # Setup legacy vars/targets and new vars to deal with different debug levels.

   170 #

   172 case $DEBUG_LEVEL in

   173       release )

   174           VARIANT="OPT"

   175           FASTDEBUG="false"

   176           DEBUG_CLASSFILES="false"

   177           BUILD_VARIANT_RELEASE=""

   178           HOTSPOT_DEBUG_LEVEL="product"

   179           HOTSPOT_EXPORT="product"

   180            ;;

   181       fastdebug )

   182           VARIANT="DBG"

   183           FASTDEBUG="true"

   184           DEBUG_CLASSFILES="true"

   185           BUILD_VARIANT_RELEASE="-fastdebug"

   186           HOTSPOT_DEBUG_LEVEL="fastdebug"

   187           HOTSPOT_EXPORT="fastdebug"

   188            ;;

   189       slowdebug )

   190           VARIANT="DBG"

   191           FASTDEBUG="false"

   192           DEBUG_CLASSFILES="true"

   193           BUILD_VARIANT_RELEASE="-debug"

   194           HOTSPOT_DEBUG_LEVEL="jvmg"

   195           HOTSPOT_EXPORT="debug"

   196            ;;

   197 esac

   199 #####

   200 # Generate the legacy makefile targets for hotspot.

   201 # The hotspot api for selecting the build artifacts, really, needs to be improved.

   202 # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to

   203 # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc

   204 # But until then ...

   205 HOTSPOT_TARGET=""

   207 if test "x$JVM_VARIANT_SERVER" = xtrue; then

   208     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "

   209 fi

   211 if test "x$JVM_VARIANT_CLIENT" = xtrue; then

   212     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "

   213 fi

   215 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then

   216     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "

   217 fi

   219 if test "x$JVM_VARIANT_KERNEL" = xtrue; then

   220     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "

   221 fi

   223 if test "x$JVM_VARIANT_ZERO" = xtrue; then

   224     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "

   225 fi

   227 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then

   228     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "

   229 fi

   231 HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"

   233 # On Macosx universal binaries are produced, but they only contain

   234 # 64 bit intel. This invalidates control of which jvms are built

   235 # from configure, but only server is valid anyway. Fix this

   236 # when hotspot makefiles are rewritten.

   237 if test "x$MACOSX_UNIVERSAL" = xtrue; then

   238     HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}

   239 fi

   241 #####

   243 AC_SUBST(DEBUG_LEVEL)

   244 AC_SUBST(VARIANT)

   245 AC_SUBST(FASTDEBUG)

   246 AC_SUBST(DEBUG_CLASSFILES)

   247 AC_SUBST(BUILD_VARIANT_RELEASE)

   248 ])

   251 ###############################################################################

   252 #

   253 # Should we build only OpenJDK even if closed sources are present?

   254 #

   255 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],

   256 [

   257   AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],

   258     [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])

   260   AC_MSG_CHECKING([for presence of closed sources])

   261   if test -d "$SRC_ROOT/jdk/src/closed"; then

   262     CLOSED_SOURCE_PRESENT=yes

   263   else

   264     CLOSED_SOURCE_PRESENT=no

   265   fi

   266   AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])

   268   AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])

   269   SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"

   270   AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])

   272   if test "x$CLOSED_SOURCE_PRESENT" = xno; then

   273     OPENJDK=true

   274     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then

   275       AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])

   276     fi

   277   else

   278     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then

   279       OPENJDK=true

   280     else

   281       OPENJDK=false

   282     fi

   283   fi

   285   if test "x$OPENJDK" = "xtrue"; then

   286     SET_OPENJDK="OPENJDK=true"

   287   fi

   289   AC_SUBST(SET_OPENJDK)

   290 ])

   292 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],

   293 [

   295 ###############################################################################

   296 #

   297 # Should we build a JDK/JVM with headful support (ie a graphical ui)?

   298 # We always build headless support.

   299 #

   300 AC_MSG_CHECKING([headful support])

   301 AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],

   302 	[disable building headful support (graphical UI support) @<:@enabled@:>@])],

   303     [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])

   305 SUPPORT_HEADLESS=yes

   306 BUILD_HEADLESS="BUILD_HEADLESS:=true"

   308 if test "x$SUPPORT_HEADFUL" = xyes; then

   309     # We are building both headful and headless.

   310     headful_msg="inlude support for both headful and headless"

   311 fi

   313 if test "x$SUPPORT_HEADFUL" = xno; then

   314     # Thus we are building headless only.

   315     BUILD_HEADLESS="BUILD_HEADLESS:=true"

   316     headful_msg="headless only"

   317 fi

   319 AC_MSG_RESULT([$headful_msg])

   321 AC_SUBST(SUPPORT_HEADLESS)

   322 AC_SUBST(SUPPORT_HEADFUL)

   323 AC_SUBST(BUILD_HEADLESS)

   325 # Control wether Hotspot runs Queens test after build.

   326 AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],

   327 	[run the Queens test after Hotspot build @<:@disabled@:>@])],,

   328     [enable_hotspot_test_in_build=no])

   329 if test "x$enable_hotspot_test_in_build" = "xyes"; then

   330     TEST_IN_BUILD=true

   331 else

   332     TEST_IN_BUILD=false

   333 fi

   334 AC_SUBST(TEST_IN_BUILD)

   336 ###############################################################################

   337 #

   338 # Choose cacerts source file

   339 #

   340 AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],

   341     [specify alternative cacerts file])])

   342 if test "x$with_cacerts_file" != x; then

   343     CACERTS_FILE=$with_cacerts_file

   344 else

   345     if test "x$OPENJDK" = "xtrue"; then

   346         CACERTS_FILE=${SRC_ROOT}/jdk/src/share/lib/security/cacerts

   347     else

   348         CACERTS_FILE=${SRC_ROOT}/jdk/src/closed/share/lib/security/cacerts.internal

   349     fi

   350 fi

   351 AC_SUBST(CACERTS_FILE)

   353 ###############################################################################

   354 #

   355 # Enable or disable unlimited crypto

   356 #

   357 AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],

   358         [Enable unlimited crypto policy @<:@disabled@:>@])],,

   359     [enable_unlimited_crypto=no])

   360 if test "x$enable_unlimited_crypto" = "xyes"; then

   361     UNLIMITED_CRYPTO=true

   362 else

   363     UNLIMITED_CRYPTO=false

   364 fi

   365 AC_SUBST(UNLIMITED_CRYPTO)

   367 ###############################################################################

   368 #

   369 # Enable or disable the elliptic curve crypto implementation

   370 #

   371 AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],

   372 [

   373 AC_MSG_CHECKING([if elliptic curve crypto implementation is present])

   375 if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then

   376     ENABLE_INTREE_EC=yes

   377     AC_MSG_RESULT([yes])

   378 else

   379     ENABLE_INTREE_EC=no

   380     AC_MSG_RESULT([no])

   381 fi

   383 AC_SUBST(ENABLE_INTREE_EC)

   384 ])

   386 ###############################################################################

   387 #

   388 # Compress jars

   389 #

   390 COMPRESS_JARS=false

   392 AC_SUBST(COMPRESS_JARS)

   393 ])

   395 ###############################################################################

   396 #

   397 # Setup version numbers

   398 #

   399 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],

   400 [

   401 # Source the version numbers

   402 . $AUTOCONF_DIR/version-numbers

   404 # Get the settings from parameters

   405 AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],

   406                        [Set milestone value for build @<:@internal@:>@])])

   407 if test "x$with_milestone" = xyes; then

   408   AC_MSG_ERROR([Milestone must have a value])

   409 elif test "x$with_milestone" != x; then

   410     MILESTONE="$with_milestone"

   411 fi

   412 if test "x$MILESTONE" = x; then

   413   MILESTONE=internal

   414 fi

   416 AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],

   417                           [Set build number value for build @<:@b00@:>@])])

   418 if test "x$with_build_number" = xyes; then

   419   AC_MSG_ERROR([Build number must have a value])

   420 elif test "x$with_build_number" != x; then

   421   JDK_BUILD_NUMBER="$with_build_number"

   422 fi

   423 if test "x$JDK_BUILD_NUMBER" = x; then

   424   JDK_BUILD_NUMBER=b00

   425 fi

   427 AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],

   428         [Add a custom string to the version string if build number isn't set.@<:@username_builddateb00@:>@])])

   429 if test "x$with_user_release_suffix" = xyes; then

   430   AC_MSG_ERROR([Release suffix must have a value])

   431 elif test "x$with_user_release_suffix" != x; then

   432   USER_RELEASE_SUFFIX="$with_user_release_suffix"

   433 else

   434   BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`

   435   # Avoid [:alnum:] since it depends on the locale.

   436   CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyz0123456789'`

   437   USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`

   438 fi

   439 AC_SUBST(USER_RELEASE_SUFFIX)

   441 # Now set the JDK version, milestone, build number etc.

   442 AC_SUBST(JDK_MAJOR_VERSION)

   443 AC_SUBST(JDK_MINOR_VERSION)

   444 AC_SUBST(JDK_MICRO_VERSION)

   445 AC_SUBST(JDK_UPDATE_VERSION)

   446 AC_SUBST(JDK_BUILD_NUMBER)

   447 AC_SUBST(MILESTONE)

   448 AC_SUBST(LAUNCHER_NAME)

   449 AC_SUBST(PRODUCT_NAME)

   450 AC_SUBST(PRODUCT_SUFFIX)

   451 AC_SUBST(JDK_RC_PLATFORM_NAME)

   452 AC_SUBST(COMPANY_NAME)

   453 AC_SUBST(MACOSX_BUNDLE_NAME_BASE)

   454 AC_SUBST(MACOSX_BUNDLE_ID_BASE)

   456 COPYRIGHT_YEAR=`date +'%Y'`

   457 AC_SUBST(COPYRIGHT_YEAR)

   459 if test "x$JDK_UPDATE_VERSION" != x; then

   460   JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"

   461 else

   462   JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"

   463 fi

   464 AC_SUBST(JDK_VERSION)

   466 COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`

   467 AC_SUBST(COOKED_BUILD_NUMBER)

   468 ])

   470 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],

   471 [

   472 HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"

   473 AC_SUBST(HOTSPOT_MAKE_ARGS)

   475 # The name of the Service Agent jar.

   476 SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"

   477 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   478   SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"

   479 fi

   480 AC_SUBST(SALIB_NAME)

   482 ])

   484 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],

   485 [

   486 #

   487 # ENABLE_DEBUG_SYMBOLS

   488 # This must be done after the toolchain is setup, since we're looking at objcopy.

   489 #

   490 AC_ARG_ENABLE([debug-symbols],

   491               [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])

   493 AC_MSG_CHECKING([if we should generate debug symbols])

   495 if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then

   496    # explicit enabling of enable-debug-symbols and can't find objcopy

   497    #   this is an error

   498    AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])

   499 fi

   501 if test "x$enable_debug_symbols" = "xyes"; then

   502   ENABLE_DEBUG_SYMBOLS=true

   503 elif test "x$enable_debug_symbols" = "xno"; then

   504   ENABLE_DEBUG_SYMBOLS=false

   505 else

   506   # default on macosx is false

   507   if test "x$OPENJDK_TARGET_OS" = xmacosx; then

   508     ENABLE_DEBUG_SYMBOLS=false

   509   # Default is on if objcopy is found, otherwise off

   510   elif test "x$OBJCOPY" != x || test "x$OPENJDK_TARGET_OS" = xwindows; then

   511     ENABLE_DEBUG_SYMBOLS=true

   512   else

   513     ENABLE_DEBUG_SYMBOLS=false

   514   fi

   515 fi

   517 AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])

   519 #

   520 # ZIP_DEBUGINFO_FILES

   521 #

   522 AC_ARG_ENABLE([zip-debug-info],

   523               [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])])

   525 AC_MSG_CHECKING([if we should zip debug-info files])

   526 AC_MSG_RESULT([${enable_zip_debug_info}])

   528 if test "x${enable_zip_debug_info}" = "xno"; then

   529    ZIP_DEBUGINFO_FILES=false

   530 else

   531    ZIP_DEBUGINFO_FILES=true

   532 fi

   534 AC_SUBST(ENABLE_DEBUG_SYMBOLS)

   535 AC_SUBST(ZIP_DEBUGINFO_FILES)

   536 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)

   537 AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)

   538 ])

   540 # Support for customization of the build process. Some build files

   541 # will include counterparts from this location, if they exist. This allows

   542 # for a degree of customization of the build targets and the rules/recipes

   543 # to create them

   544 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],

   545     [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])

   546 AC_SUBST(CUSTOM_MAKE_DIR)

Mercurial > jdk8-mips64-public / file revision

common/autoconf/jdk-options.m4@e2057191f6da

common/autoconf/jdk-options.m4