Mercurial > jdk8-mips64-public / file revision
common/autoconf/toolchain.m4@db3144e1f89b
common/autoconf/toolchain.m4
Tue, 04 Jun 2013 10:36:00 +0200
- author
- mduigou
- date
- Tue, 04 Jun 2013 10:36:00 +0200
- changeset 728
- db3144e1f89b
- parent 718
- e7c09a983c3c
- child 739
- 0d1e8518c722
- permissions
- -rw-r--r--
8015510: (s) Improve JTReg location detection and provide location to test/Makefile
Reviewed-by: erikj
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # $1 = compiler to test (CC or CXX)
27 # $2 = human readable name of compiler (C or C++)
28 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
29 [
30 COMPILER=[$]$1
31 COMPILER_NAME=$2
33 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
34 # Make sure we use the Sun Studio compiler and not gcc on Solaris, which won't work
35 COMPILER_VERSION_TEST=`$COMPILER -V 2>&1 | $HEAD -n 1`
36 $ECHO $COMPILER_VERSION_TEST | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
37 if test $? -ne 0; then
38 GCC_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
40 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required Sun Studio compiler.])
41 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_TEST" and with --version: "$GCC_VERSION_TEST"])
42 AC_MSG_ERROR([Sun Studio compiler is required. Try setting --with-tools-dir.])
43 else
44 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/p"`
45 COMPILER_VENDOR="Sun Studio"
46 fi
47 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
48 # First line typically looks something like:
49 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.30319.01 for 80x86
50 COMPILER_VERSION_TEST=`$COMPILER 2>&1 | $HEAD -n 1`
51 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*Version \(@<:@1-9@:>@@<:@0-9.@:>@*\) .*/\1/p"`
52 COMPILER_VENDOR="Microsoft CL.EXE"
53 COMPILER_CPU_TEST=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* for \(.*\)$/\1/p"`
54 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
55 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
56 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
57 fi
58 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
59 if test "x$COMPILER_CPU_TEST" != "xx64"; then
60 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
61 fi
62 fi
63 else
64 COMPILER_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
65 # Check that this is likely to be GCC.
66 $COMPILER --version 2>&1 | $GREP "Free Software Foundation" > /dev/null
67 if test $? -ne 0; then
68 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required GCC compiler.])
69 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_TEST"])
70 AC_MSG_ERROR([GCC compiler is required. Try setting --with-tools-dir.])
71 fi
73 # First line typically looks something like:
74 # gcc (Ubuntu/Linaro 4.5.2-8ubuntu4) 4.5.2
75 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/p"`
76 COMPILER_VENDOR=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^\(.*\) @<:@1-9@:>@@<:@0-9.@:>@*/\1/p"`
77 fi
78 # This sets CC_VERSION or CXX_VERSION. (This comment is a grep marker)
79 $1_VERSION="$COMPILER_VERSION"
80 # This sets CC_VENDOR or CXX_VENDOR. (This comment is a grep marker)
81 $1_VENDOR="$COMPILER_VENDOR"
83 AC_MSG_NOTICE([Using $COMPILER_VENDOR $COMPILER_NAME compiler version $COMPILER_VERSION (located at $COMPILER)])
84 ])
87 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_SYSROOT_AND_OUT_OPTIONS],
88 [
89 ###############################################################################
90 #
91 # Configure the development tool paths and potential sysroot.
92 #
93 AC_LANG(C++)
95 # The option used to specify the target .o,.a or .so file.
96 # When compiling, how to specify the to be created object file.
97 CC_OUT_OPTION='-o$(SPACE)'
98 # When linking, how to specify the to be created executable.
99 EXE_OUT_OPTION='-o$(SPACE)'
100 # When linking, how to specify the to be created dynamically linkable library.
101 LD_OUT_OPTION='-o$(SPACE)'
102 # When archiving, how to specify the to be create static archive for object files.
103 AR_OUT_OPTION='rcs$(SPACE)'
104 AC_SUBST(CC_OUT_OPTION)
105 AC_SUBST(EXE_OUT_OPTION)
106 AC_SUBST(LD_OUT_OPTION)
107 AC_SUBST(AR_OUT_OPTION)
108 ])
110 # $1 = compiler to test (CC or CXX)
111 # $2 = human readable name of compiler (C or C++)
112 # $3 = list of compiler names to search for
113 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
114 [
115 COMPILER_NAME=$2
117 $1=
118 # If TOOLS_DIR is set, check for all compiler names in there first
119 # before checking the rest of the PATH.
120 if test -n "$TOOLS_DIR"; then
121 PATH_save="$PATH"
122 PATH="$TOOLS_DIR"
123 AC_PATH_PROGS(TOOLS_DIR_$1, $3)
124 $1=$TOOLS_DIR_$1
125 PATH="$PATH_save"
126 fi
128 # AC_PATH_PROGS can't be run multiple times with the same variable,
129 # so create a new name for this run.
130 if test "x[$]$1" = x; then
131 AC_PATH_PROGS(POTENTIAL_$1, $3)
132 $1=$POTENTIAL_$1
133 fi
135 if test "x[$]$1" = x; then
136 HELP_MSG_MISSING_DEPENDENCY([devkit])
137 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
138 fi
139 BASIC_FIXUP_EXECUTABLE($1)
140 AC_MSG_CHECKING([resolved symbolic links for $1])
141 TEST_COMPILER="[$]$1"
142 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
143 AC_MSG_RESULT([$TEST_COMPILER])
144 AC_MSG_CHECKING([if $1 is disguised ccache])
146 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
147 if test "x$COMPILER_BASENAME" = "xccache"; then
148 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
149 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
150 # We want to control ccache invocation ourselves, so ignore this cc and try
151 # searching again.
153 # Remove the path to the fake ccache cc from the PATH
154 RETRY_COMPILER_SAVED_PATH="$PATH"
155 COMPILER_DIRNAME=`$DIRNAME [$]$1`
156 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
158 # Try again looking for our compiler
159 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
160 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
161 PATH="$RETRY_COMPILER_SAVED_PATH"
163 AC_MSG_CHECKING([for resolved symbolic links for $1])
164 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
165 AC_MSG_RESULT([$PROPER_COMPILER_$1])
166 $1="$PROPER_COMPILER_$1"
167 else
168 AC_MSG_RESULT([no, keeping $1])
169 $1="$TEST_COMPILER"
170 fi
171 TOOLCHAIN_CHECK_COMPILER_VERSION([$1], [$COMPILER_NAME])
172 ])
175 AC_DEFUN([TOOLCHAIN_SETUP_PATHS],
176 [
177 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
178 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
179 TOOLCHAIN_SETUP_DXSDK
180 fi
182 AC_SUBST(MSVCR_DLL)
184 # If --build AND --host is set, then the configure script will find any
185 # cross compilation tools in the PATH. Cross compilation tools
186 # follows the cross compilation standard where they are prefixed with ${host}.
187 # For example the binary i686-sun-solaris2.10-gcc
188 # will cross compile for i686-sun-solaris2.10
189 # If neither of build and host is not set, then build=host and the
190 # default compiler found in the path will be used.
191 # Setting only --host, does not seem to be really supported.
192 # Please set both --build and --host if you want to cross compile.
194 if test "x$COMPILE_TYPE" = "xcross"; then
195 # Now we to find a C/C++ compiler that can build executables for the build
196 # platform. We can't use the AC_PROG_CC macro, since it can only be used
197 # once. Also, we need to do this before adding a tools dir to the path,
198 # otherwise we might pick up cross-compilers which don't use standard naming.
199 # Otherwise, we'll set the BUILD_tools to the native tools, but that'll have
200 # to wait until they are properly discovered.
201 AC_PATH_PROGS(BUILD_CC, [cl cc gcc])
202 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
203 AC_PATH_PROGS(BUILD_CXX, [cl CC g++])
204 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
205 AC_PATH_PROG(BUILD_LD, ld)
206 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
207 fi
208 AC_SUBST(BUILD_CC)
209 AC_SUBST(BUILD_CXX)
210 AC_SUBST(BUILD_LD)
212 # If a devkit is found on the builddeps server, then prepend its path to the
213 # PATH variable. If there are cross compilers available in the devkit, these
214 # will be found by AC_PROG_CC et al.
215 DEVKIT=
216 BDEPS_CHECK_MODULE(DEVKIT, devkit, xxx,
217 [# Found devkit
218 PATH="$DEVKIT/bin:$PATH"
219 SYS_ROOT="$DEVKIT/${rewritten_target}/sys-root"
220 if test "x$x_includes" = "xNONE"; then
221 x_includes="$SYS_ROOT/usr/include/X11"
222 fi
223 if test "x$x_libraries" = "xNONE"; then
224 x_libraries="$SYS_ROOT/usr/lib"
225 fi
226 ],
227 [])
229 if test "x$SYS_ROOT" != "x/" ; then
230 CFLAGS="--sysroot=$SYS_ROOT $CFLAGS"
231 CXXFLAGS="--sysroot=$SYS_ROOT $CXXFLAGS"
232 OBJCFLAGS="--sysroot=$SYS_ROOT $OBJCFLAGS"
233 OBJCXXFLAGS="--sysroot=$SYS_ROOT $OBJCFLAGS"
234 CPPFLAGS="--sysroot=$SYS_ROOT $CPPFLAGS"
235 LDFLAGS="--sysroot=$SYS_ROOT $LDFLAGS"
236 fi
238 # Store the CFLAGS etal passed to the configure script.
239 ORG_CFLAGS="$CFLAGS"
240 ORG_CXXFLAGS="$CXXFLAGS"
241 ORG_OBJCFLAGS="$OBJCFLAGS"
243 # autoconf magic only relies on PATH, so update it if tools dir is specified
244 OLD_PATH="$PATH"
245 if test "x$TOOLS_DIR" != x; then
246 PATH=$TOOLS_DIR:$PATH
247 fi
250 ### Locate C compiler (CC)
252 # On windows, only cl.exe is supported.
253 # On Solaris, cc is preferred to gcc.
254 # Elsewhere, gcc is preferred to cc.
256 if test "x$CC" != x; then
257 COMPILER_CHECK_LIST="$CC"
258 elif test "x$OPENJDK_TARGET_OS" = "xwindows"; then
259 COMPILER_CHECK_LIST="cl"
260 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
261 COMPILER_CHECK_LIST="cc gcc"
262 else
263 COMPILER_CHECK_LIST="gcc cc"
264 fi
266 TOOLCHAIN_FIND_COMPILER([CC],[C],[$COMPILER_CHECK_LIST])
267 # Now that we have resolved CC ourself, let autoconf have its go at it
268 AC_PROG_CC([$CC])
270 ### Locate C++ compiler (CXX)
272 if test "x$CXX" != x; then
273 COMPILER_CHECK_LIST="$CXX"
274 elif test "x$OPENJDK_TARGET_OS" = "xwindows"; then
275 COMPILER_CHECK_LIST="cl"
276 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
277 COMPILER_CHECK_LIST="CC g++"
278 else
279 COMPILER_CHECK_LIST="g++ CC"
280 fi
282 TOOLCHAIN_FIND_COMPILER([CXX],[C++],[$COMPILER_CHECK_LIST])
283 # Now that we have resolved CXX ourself, let autoconf have its go at it
284 AC_PROG_CXX([$CXX])
286 ### Locate other tools
288 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
289 AC_PROG_OBJC
290 BASIC_FIXUP_EXECUTABLE(OBJC)
291 else
292 OBJC=
293 fi
295 # Restore the flags to the user specified values.
296 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
297 CFLAGS="$ORG_CFLAGS"
298 CXXFLAGS="$ORG_CXXFLAGS"
299 OBJCFLAGS="$ORG_OBJCFLAGS"
301 LD="$CC"
302 LDEXE="$CC"
303 LDCXX="$CXX"
304 LDEXECXX="$CXX"
305 AC_SUBST(LD)
306 # LDEXE is the linker to use, when creating executables.
307 AC_SUBST(LDEXE)
308 # Linking C++ libraries.
309 AC_SUBST(LDCXX)
310 # Linking C++ executables.
311 AC_SUBST(LDEXECXX)
313 if test "x$OPENJDK_TARGET_OS" != xwindows; then
314 AC_CHECK_TOOL(AR, ar)
315 BASIC_FIXUP_EXECUTABLE(AR)
316 fi
317 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
318 ARFLAGS="-r"
319 else
320 ARFLAGS=""
321 fi
322 AC_SUBST(ARFLAGS)
324 # For hotspot, we need these in Windows mixed path; other platforms keep them the same
325 HOTSPOT_CXX="$CXX"
326 HOTSPOT_LD="$LD"
327 AC_SUBST(HOTSPOT_CXX)
328 AC_SUBST(HOTSPOT_LD)
330 COMPILER_NAME=gcc
331 COMPILER_TYPE=CC
332 AS_IF([test "x$OPENJDK_TARGET_OS" = xwindows], [
333 # For now, assume that we are always compiling using cl.exe.
334 CC_OUT_OPTION=-Fo
335 EXE_OUT_OPTION=-out:
336 LD_OUT_OPTION=-out:
337 AR_OUT_OPTION=-out:
338 # On Windows, reject /usr/bin/link (as determined in CYGWIN_LINK), which is a cygwin
339 # program for something completely different.
340 AC_CHECK_PROG([WINLD], [link],[link],,, [$CYGWIN_LINK])
341 # Since we must ignore the first found link, WINLD will contain
342 # the full path to the link.exe program.
343 BASIC_FIXUP_EXECUTABLE(WINLD)
344 printf "Windows linker was found at $WINLD\n"
345 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
346 "$WINLD" --version > /dev/null
347 if test $? -eq 0 ; then
348 AC_MSG_RESULT([no])
349 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
350 else
351 AC_MSG_RESULT([yes])
352 fi
353 LD="$WINLD"
354 LDEXE="$WINLD"
355 LDCXX="$WINLD"
356 LDEXECXX="$WINLD"
358 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
359 BASIC_FIXUP_EXECUTABLE(MT)
360 # The resource compiler
361 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
362 BASIC_FIXUP_EXECUTABLE(RC)
364 # For hotspot, we need these in Windows mixed path,
365 # so rewrite them all. Need added .exe suffix.
366 HOTSPOT_CXX="$CXX.exe"
367 HOTSPOT_LD="$LD.exe"
368 HOTSPOT_MT="$MT.exe"
369 HOTSPOT_RC="$RC.exe"
370 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
371 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
372 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
373 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
374 AC_SUBST(HOTSPOT_MT)
375 AC_SUBST(HOTSPOT_RC)
377 RC_FLAGS="-nologo -l 0x409 -r"
378 AS_IF([test "x$VARIANT" = xOPT], [
379 RC_FLAGS="$RC_FLAGS -d NDEBUG"
380 ])
381 JDK_UPDATE_VERSION_NOTNULL=$JDK_UPDATE_VERSION
382 AS_IF([test "x$JDK_UPDATE_VERSION" = x], [
383 JDK_UPDATE_VERSION_NOTNULL=0
384 ])
385 RC_FLAGS="$RC_FLAGS -d \"JDK_BUILD_ID=$FULL_VERSION\""
386 RC_FLAGS="$RC_FLAGS -d \"JDK_COMPANY=$COMPANY_NAME\""
387 RC_FLAGS="$RC_FLAGS -d \"JDK_COMPONENT=$PRODUCT_NAME $JDK_RC_PLATFORM_NAME binary\""
388 RC_FLAGS="$RC_FLAGS -d \"JDK_VER=$JDK_MINOR_VERSION.$JDK_MICRO_VERSION.$JDK_UPDATE_VERSION_NOTNULL.$COOKED_BUILD_NUMBER\""
389 RC_FLAGS="$RC_FLAGS -d \"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\""
390 RC_FLAGS="$RC_FLAGS -d \"JDK_NAME=$PRODUCT_NAME $JDK_RC_PLATFORM_NAME $JDK_MINOR_VERSION $JDK_UPDATE_META_TAG\""
391 RC_FLAGS="$RC_FLAGS -d \"JDK_FVER=$JDK_MINOR_VERSION,$JDK_MICRO_VERSION,$JDK_UPDATE_VERSION_NOTNULL,$COOKED_BUILD_NUMBER\""
393 # lib.exe is used to create static libraries.
394 AC_CHECK_PROG([WINAR], [lib],[lib],,,)
395 BASIC_FIXUP_EXECUTABLE(WINAR)
396 AR="$WINAR"
397 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
399 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
400 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
402 COMPILER_TYPE=CL
403 CCXXFLAGS="$CCXXFLAGS -nologo"
404 ])
405 AC_SUBST(RC_FLAGS)
406 AC_SUBST(COMPILER_TYPE)
408 AC_PROG_CPP
409 BASIC_FIXUP_EXECUTABLE(CPP)
411 AC_PROG_CXXCPP
412 BASIC_FIXUP_EXECUTABLE(CXXCPP)
414 if test "x$COMPILE_TYPE" != "xcross"; then
415 # If we are not cross compiling, use the same compilers for
416 # building the build platform executables. The cross-compilation
417 # case needed to be done earlier, but this can only be done after
418 # the native tools have been localized.
419 BUILD_CC="$CC"
420 BUILD_CXX="$CXX"
421 BUILD_LD="$LD"
422 fi
424 # for solaris we really need solaris tools, and not gnu equivalent
425 # these seems to normally reside in /usr/ccs/bin so add that to path before
426 # starting to probe
427 #
428 # NOTE: I add this /usr/ccs/bin after TOOLS but before OLD_PATH
429 # so that it can be overriden --with-tools-dir
430 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
431 PATH="${TOOLS_DIR}:/usr/ccs/bin:${OLD_PATH}"
432 fi
434 # Find the right assembler.
435 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
436 AC_PATH_PROG(AS, as)
437 BASIC_FIXUP_EXECUTABLE(AS)
438 else
439 AS="$CC -c"
440 fi
441 AC_SUBST(AS)
443 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
444 AC_PATH_PROG(NM, nm)
445 BASIC_FIXUP_EXECUTABLE(NM)
446 AC_PATH_PROG(GNM, gnm)
447 BASIC_FIXUP_EXECUTABLE(GNM)
448 AC_PATH_PROG(STRIP, strip)
449 BASIC_FIXUP_EXECUTABLE(STRIP)
450 AC_PATH_PROG(MCS, mcs)
451 BASIC_FIXUP_EXECUTABLE(MCS)
452 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
453 AC_CHECK_TOOL(NM, nm)
454 BASIC_FIXUP_EXECUTABLE(NM)
455 GNM="$NM"
456 AC_SUBST(GNM)
457 AC_CHECK_TOOL(STRIP, strip)
458 BASIC_FIXUP_EXECUTABLE(STRIP)
459 fi
461 # objcopy is used for moving debug symbols to separate files when
462 # full debug symbols are enabled.
463 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
464 AC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
465 # Only call fixup if objcopy was found.
466 if test -n "$OBJCOPY"; then
467 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
468 fi
469 fi
471 AC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
472 if test "x$OBJDUMP" != x; then
473 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE bails if argument is missing.
474 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
475 fi
477 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
478 AC_PATH_PROG(LIPO, lipo)
479 BASIC_FIXUP_EXECUTABLE(LIPO)
480 fi
482 TOOLCHAIN_SETUP_JTREG
484 # Restore old path without tools dir
485 PATH="$OLD_PATH"
486 ])
489 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_LIBS],
490 [
492 ###############################################################################
493 #
494 # How to compile shared libraries.
495 #
497 if test "x$GCC" = xyes; then
498 COMPILER_NAME=gcc
499 PICFLAG="-fPIC"
500 LIBRARY_PREFIX=lib
501 SHARED_LIBRARY='lib[$]1.so'
502 STATIC_LIBRARY='lib[$]1.a'
503 SHARED_LIBRARY_FLAGS="-shared"
504 SHARED_LIBRARY_SUFFIX='.so'
505 STATIC_LIBRARY_SUFFIX='.a'
506 OBJ_SUFFIX='.o'
507 EXE_SUFFIX=''
508 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
509 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
510 C_FLAG_REORDER=''
511 CXX_FLAG_REORDER=''
512 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -z -Xlinker origin -Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
513 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
514 LD="$CC"
515 LDEXE="$CC"
516 LDCXX="$CXX"
517 LDEXECXX="$CXX"
518 POST_STRIP_CMD="$STRIP -g"
520 # Linking is different on MacOSX
521 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
522 # Might change in the future to clang.
523 COMPILER_NAME=gcc
524 SHARED_LIBRARY='lib[$]1.dylib'
525 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
526 SHARED_LIBRARY_SUFFIX='.dylib'
527 EXE_SUFFIX=''
528 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
529 SET_SHARED_LIBRARY_MAPFILE=''
530 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
531 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
532 POST_STRIP_CMD="$STRIP -S"
533 fi
534 else
535 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
536 # If it is not gcc, then assume it is the Oracle Solaris Studio Compiler
537 COMPILER_NAME=ossc
538 PICFLAG="-KPIC"
539 LIBRARY_PREFIX=lib
540 SHARED_LIBRARY='lib[$]1.so'
541 STATIC_LIBRARY='lib[$]1.a'
542 SHARED_LIBRARY_FLAGS="-G"
543 SHARED_LIBRARY_SUFFIX='.so'
544 STATIC_LIBRARY_SUFFIX='.a'
545 OBJ_SUFFIX='.o'
546 EXE_SUFFIX=''
547 SET_SHARED_LIBRARY_NAME=''
548 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
549 C_FLAG_REORDER='-xF'
550 CXX_FLAG_REORDER='-xF'
551 SET_SHARED_LIBRARY_ORIGIN='-R\$$$$ORIGIN[$]1'
552 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
553 CFLAGS_JDK="${CFLAGS_JDK} -D__solaris__"
554 CXXFLAGS_JDK="${CXXFLAGS_JDK} -D__solaris__"
555 CFLAGS_JDKLIB_EXTRA='-xstrconst'
556 POST_STRIP_CMD="$STRIP -x"
557 POST_MCS_CMD="$MCS -d -a \"JDK $FULL_VERSION\""
558 fi
559 if test "x$OPENJDK_TARGET_OS" = xwindows; then
560 # If it is not gcc, then assume it is the MS Visual Studio compiler
561 COMPILER_NAME=cl
562 PICFLAG=""
563 LIBRARY_PREFIX=
564 SHARED_LIBRARY='[$]1.dll'
565 STATIC_LIBRARY='[$]1.lib'
566 SHARED_LIBRARY_FLAGS="-LD"
567 SHARED_LIBRARY_SUFFIX='.dll'
568 STATIC_LIBRARY_SUFFIX='.lib'
569 OBJ_SUFFIX='.obj'
570 EXE_SUFFIX='.exe'
571 SET_SHARED_LIBRARY_NAME=''
572 SET_SHARED_LIBRARY_MAPFILE=''
573 SET_SHARED_LIBRARY_ORIGIN=''
574 SET_EXECUTABLE_ORIGIN=''
575 fi
576 fi
578 AC_SUBST(COMPILER_NAME)
579 AC_SUBST(OBJ_SUFFIX)
580 AC_SUBST(SHARED_LIBRARY)
581 AC_SUBST(STATIC_LIBRARY)
582 AC_SUBST(LIBRARY_PREFIX)
583 AC_SUBST(SHARED_LIBRARY_SUFFIX)
584 AC_SUBST(STATIC_LIBRARY_SUFFIX)
585 AC_SUBST(EXE_SUFFIX)
586 AC_SUBST(SHARED_LIBRARY_FLAGS)
587 AC_SUBST(SET_SHARED_LIBRARY_NAME)
588 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
589 AC_SUBST(C_FLAG_REORDER)
590 AC_SUBST(CXX_FLAG_REORDER)
591 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
592 AC_SUBST(SET_EXECUTABLE_ORIGIN)
593 AC_SUBST(POST_STRIP_CMD)
594 AC_SUBST(POST_MCS_CMD)
596 # The (cross) compiler is now configured, we can now test capabilities
597 # of the target platform.
598 ])
600 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
601 [
603 ###############################################################################
604 #
605 # Setup the opt flags for different compilers
606 # and different operating systems.
607 #
609 #
610 # NOTE: check for -mstackrealign needs to be below potential addition of -m32
611 #
612 if test "x$OPENJDK_TARGET_CPU_BITS" = x32 && test "x$OPENJDK_TARGET_OS" = xmacosx; then
613 # On 32-bit MacOSX the OS requires C-entry points to be 16 byte aligned.
614 # While waiting for a better solution, the current workaround is to use -mstackrealign.
615 CFLAGS="$CFLAGS -mstackrealign"
616 AC_MSG_CHECKING([if 32-bit compiler supports -mstackrealign])
617 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])],
618 [
619 AC_MSG_RESULT([yes])
620 ],
621 [
622 AC_MSG_RESULT([no])
623 AC_MSG_ERROR([The selected compiler $CXX does not support -mstackrealign! Try to put another compiler in the path.])
624 ])
625 fi
627 C_FLAG_DEPS="-MMD -MF"
628 CXX_FLAG_DEPS="-MMD -MF"
630 case $COMPILER_TYPE in
631 CC )
632 D_FLAG="-g"
633 case $COMPILER_NAME in
634 gcc )
635 case $OPENJDK_TARGET_OS in
636 macosx )
637 # On MacOSX we optimize for size, something
638 # we should do for all platforms?
639 C_O_FLAG_HI="-Os"
640 C_O_FLAG_NORM="-Os"
641 C_O_FLAG_NONE=""
642 ;;
643 *)
644 C_O_FLAG_HI="-O3"
645 C_O_FLAG_NORM="-O2"
646 C_O_FLAG_NONE="-O0"
647 CFLAGS_DEBUG_SYMBOLS="-g"
648 CXXFLAGS_DEBUG_SYMBOLS="-g"
649 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
650 CFLAGS_DEBUG_SYMBOLS="-g1"
651 CXXFLAGS_DEBUG_SYMBOLS="-g1"
652 fi
653 ;;
654 esac
655 CXX_O_FLAG_HI="$C_O_FLAG_HI"
656 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
657 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
658 ;;
659 ossc )
660 #
661 # Forte has different names for this with their C++ compiler...
662 #
663 C_FLAG_DEPS="-xMMD -xMF"
664 CXX_FLAG_DEPS="-xMMD -xMF"
666 # Extra options used with HIGHEST
667 #
668 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
669 # done with care, there are some assumptions below that need to
670 # be understood about the use of pointers, and IEEE behavior.
671 #
672 # Use non-standard floating point mode (not IEEE 754)
673 CC_HIGHEST="$CC_HIGHEST -fns"
674 # Do some simplification of floating point arithmetic (not IEEE 754)
675 CC_HIGHEST="$CC_HIGHEST -fsimple"
676 # Use single precision floating point with 'float'
677 CC_HIGHEST="$CC_HIGHEST -fsingle"
678 # Assume memory references via basic pointer types do not alias
679 # (Source with excessing pointer casting and data access with mixed
680 # pointer types are not recommended)
681 CC_HIGHEST="$CC_HIGHEST -xalias_level=basic"
682 # Use intrinsic or inline versions for math/std functions
683 # (If you expect perfect errno behavior, do not use this)
684 CC_HIGHEST="$CC_HIGHEST -xbuiltin=%all"
685 # Loop data dependency optimizations (need -xO3 or higher)
686 CC_HIGHEST="$CC_HIGHEST -xdepend"
687 # Pointer parameters to functions do not overlap
688 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
689 # If you pass in multiple pointers to the same data, do not use this)
690 CC_HIGHEST="$CC_HIGHEST -xrestrict"
691 # Inline some library routines
692 # (If you expect perfect errno behavior, do not use this)
693 CC_HIGHEST="$CC_HIGHEST -xlibmil"
694 # Use optimized math routines
695 # (If you expect perfect errno behavior, do not use this)
696 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
697 #CC_HIGHEST="$CC_HIGHEST -xlibmopt"
699 if test "x$OPENJDK_TARGET_CPU" = xsparc; then
700 CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
701 CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
702 fi
704 case $OPENJDK_TARGET_CPU_ARCH in
705 x86)
706 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xregs=no%frameptr"
707 C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
708 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
709 C_O_FLAG_NONE="-xregs=no%frameptr"
710 CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
711 CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
712 CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
713 CXX_O_FLAG_NONE="-xregs=no%frameptr"
714 if test "x$OPENJDK_TARGET_CPU" = xx86; then
715 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
716 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
717 fi
718 ;;
719 sparc)
720 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
721 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
722 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
723 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
724 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
725 C_O_FLAG_NONE=""
726 CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
727 CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
728 CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
729 CXX_O_FLAG_NONE=""
730 ;;
731 esac
733 CFLAGS_DEBUG_SYMBOLS="-g -xs"
734 CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
735 esac
736 ;;
737 CL )
738 D_FLAG=
739 C_O_FLAG_HIGHEST="-O2"
740 C_O_FLAG_HI="-O1"
741 C_O_FLAG_NORM="-O1"
742 C_O_FLAG_NONE="-Od"
743 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
744 CXX_O_FLAG_HI="$C_O_FLAG_HI"
745 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
746 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
747 ;;
748 esac
750 if test -z "$C_O_FLAG_HIGHEST"; then
751 C_O_FLAG_HIGHEST="$C_O_FLAG_HI"
752 fi
754 if test -z "$CXX_O_FLAG_HIGHEST"; then
755 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HI"
756 fi
758 AC_SUBST(C_O_FLAG_HIGHEST)
759 AC_SUBST(C_O_FLAG_HI)
760 AC_SUBST(C_O_FLAG_NORM)
761 AC_SUBST(C_O_FLAG_NONE)
762 AC_SUBST(CXX_O_FLAG_HIGHEST)
763 AC_SUBST(CXX_O_FLAG_HI)
764 AC_SUBST(CXX_O_FLAG_NORM)
765 AC_SUBST(CXX_O_FLAG_NONE)
766 AC_SUBST(C_FLAG_DEPS)
767 AC_SUBST(CXX_FLAG_DEPS)
768 ])
770 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_JDK],
771 [
773 if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
774 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
775 fi
777 if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
778 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
779 fi
781 if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
782 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
783 fi
785 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
786 [extra flags to be used when compiling jdk c-files])])
788 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
789 [extra flags to be used when compiling jdk c++-files])])
791 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
792 [extra flags to be used when linking jdk])])
794 CFLAGS_JDK="${CFLAGS_JDK} $with_extra_cflags"
795 CXXFLAGS_JDK="${CXXFLAGS_JDK} $with_extra_cxxflags"
796 LDFLAGS_JDK="${LDFLAGS_JDK} $with_extra_ldflags"
798 # Hotspot needs these set in their legacy form
799 LEGACY_EXTRA_CFLAGS=$with_extra_cflags
800 LEGACY_EXTRA_CXXFLAGS=$with_extra_cxxflags
801 LEGACY_EXTRA_LDFLAGS=$with_extra_ldflags
803 AC_SUBST(LEGACY_EXTRA_CFLAGS)
804 AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
805 AC_SUBST(LEGACY_EXTRA_LDFLAGS)
807 ###############################################################################
808 #
809 # Now setup the CFLAGS and LDFLAGS for the JDK build.
810 # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
811 #
812 case $COMPILER_NAME in
813 gcc )
814 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -W -Wall -Wno-unused -Wno-parentheses \
815 -pipe \
816 -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
817 case $OPENJDK_TARGET_CPU_ARCH in
818 arm )
819 # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
820 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
821 ;;
822 ppc )
823 # on ppc we don't prevent gcc to omit frame pointer nor strict-aliasing
824 ;;
825 * )
826 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -fno-omit-frame-pointer"
827 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
828 ;;
829 esac
830 ;;
831 ossc )
832 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
833 case $OPENJDK_TARGET_CPU_ARCH in
834 x86 )
835 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_TARGET_CPU_LEGACY_LIB"
836 CFLAGS_JDK="$CFLAGS_JDK -erroff=E_BAD_PRAGMA_PACK_VALUE"
837 ;;
838 esac
840 CFLAGS_JDK="$CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
841 CXXFLAGS_JDK="$CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
843 LDFLAGS_JDK="$LDFLAGS_JDK -z defs -xildoff -ztext"
844 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK -norunpath -xnolib"
845 ;;
846 cl )
847 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -Zi -MD -Zc:wchar_t- -W3 -wd4800 \
848 -D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB -DWIN32_LEAN_AND_MEAN \
849 -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
850 -DWIN32 -DIAL"
851 case $OPENJDK_TARGET_CPU in
852 x86 )
853 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_X86_ -Dx86"
854 ;;
855 x86_64 )
856 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_AMD64_ -Damd64"
857 ;;
858 esac
859 ;;
860 esac
862 ###############################################################################
864 CCXXFLAGS_JDK="$CCXXFLAGS_JDK $ADD_LP64"
866 # The package path is used only on macosx?
867 PACKAGE_PATH=/opt/local
868 AC_SUBST(PACKAGE_PATH)
870 if test "x$OPENJDK_TARGET_CPU_ENDIAN" = xlittle; then
871 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
872 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
873 # (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
874 # Note: -Dmacro is the same as #define macro 1
875 # -Dmacro= is the same as #define macro
876 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
877 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
878 else
879 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
880 fi
881 else
882 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_BIG_ENDIAN"
883 fi
884 if test "x$OPENJDK_TARGET_OS" = xlinux; then
885 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DLINUX"
886 fi
887 if test "x$OPENJDK_TARGET_OS" = xwindows; then
888 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DWINDOWS"
889 fi
890 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
891 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DSOLARIS"
892 fi
893 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
894 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMACOSX -D_ALLBSD_SOURCE"
895 # Setting these parameters makes it an error to link to macosx APIs that are
896 # newer than the given OS version and makes the linked binaries compatible even
897 # if built on a newer version of the OS.
898 # The expected format is X.Y.Z
899 MACOSX_VERSION_MIN=10.7.0
900 AC_SUBST(MACOSX_VERSION_MIN)
901 # The macro takes the version with no dots, ex: 1070
902 # Let the flags variables get resolved in make for easier override on make
903 # command line.
904 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
905 LDFLAGS_JDK="$LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
906 fi
907 if test "x$OPENJDK_TARGET_OS" = xbsd; then
908 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DBSD -D_ALLBSD_SOURCE"
909 fi
910 if test "x$DEBUG_LEVEL" = xrelease; then
911 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DNDEBUG"
912 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
913 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DTRIMMED"
914 fi
915 else
916 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DDEBUG"
917 fi
919 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DARCH='\"$OPENJDK_TARGET_CPU_LEGACY\"' -D$OPENJDK_TARGET_CPU_LEGACY"
920 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DRELEASE='\"$RELEASE\"'"
922 CCXXFLAGS_JDK="$CCXXFLAGS_JDK \
923 -I${JDK_OUTPUTDIR}/include \
924 -I${JDK_OUTPUTDIR}/include/$OPENJDK_TARGET_OS \
925 -I${JDK_TOPDIR}/src/share/javavm/export \
926 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/javavm/export \
927 -I${JDK_TOPDIR}/src/share/native/common \
928 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/native/common"
930 # The shared libraries are compiled using the picflag.
931 CFLAGS_JDKLIB="$CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
932 CXXFLAGS_JDKLIB="$CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA "
934 # Executable flags
935 CFLAGS_JDKEXE="$CCXXFLAGS_JDK $CFLAGS_JDK"
936 CXXFLAGS_JDKEXE="$CCXXFLAGS_JDK $CXXFLAGS_JDK"
938 # Now this is odd. The JDK native libraries have to link against libjvm.so
939 # On 32-bit machines there is normally two distinct libjvm.so:s, client and server.
940 # Which should we link to? Are we lucky enough that the binary api to the libjvm.so library
941 # is identical for client and server? Yes. Which is picked at runtime (client or server)?
942 # Neither, since the chosen libjvm.so has already been loaded by the launcher, all the following
943 # libraries will link to whatever is in memory. Yuck.
944 #
945 # Thus we offer the compiler to find libjvm.so first in server then in client. It works. Ugh.
946 if test "x$COMPILER_NAME" = xcl; then
947 LDFLAGS_JDK="$LDFLAGS_JDK -nologo -opt:ref -incremental:no"
948 if test "x$OPENJDK_TARGET_CPU" = xx86; then
949 LDFLAGS_JDK="$LDFLAGS_JDK -safeseh"
950 fi
951 # TODO: make -debug optional "--disable-full-debug-symbols"
952 LDFLAGS_JDK="$LDFLAGS_JDK -debug"
953 LDFLAGS_JDKLIB="${LDFLAGS_JDK} -dll -libpath:${JDK_OUTPUTDIR}/lib"
954 LDFLAGS_JDKLIB_SUFFIX=""
955 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
956 LDFLAGS_STACK_SIZE=1048576
957 else
958 LDFLAGS_STACK_SIZE=327680
959 fi
960 LDFLAGS_JDKEXE="${LDFLAGS_JDK} /STACK:$LDFLAGS_STACK_SIZE"
961 else
962 if test "x$COMPILER_NAME" = xgcc; then
963 # If this is a --hash-style=gnu system, use --hash-style=both, why?
964 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
965 if test -n "$HAS_GNU_HASH"; then
966 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker --hash-style=both "
967 fi
968 if test "x$OPENJDK_TARGET_OS" = xlinux; then
969 # And since we now know that the linker is gnu, then add -z defs, to forbid
970 # undefined symbols in object files.
971 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -z -Xlinker defs"
972 if test "x$DEBUG_LEVEL" = "xrelease"; then
973 # When building release libraries, tell the linker optimize them.
974 # Should this be supplied to the OSS linker as well?
975 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -O1"
976 fi
977 fi
978 fi
979 LDFLAGS_JDKLIB="${LDFLAGS_JDK} $SHARED_LIBRARY_FLAGS \
980 -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}"
982 # On some platforms (mac) the linker warns about non existing -L dirs.
983 # Add server first if available. Linking aginst client does not always produce the same results.
984 # Only add client dir if client is being built. Add minimal (note not minimal1) if only building minimal1.
985 # Default to server for other variants.
986 if test "x$JVM_VARIANT_SERVER" = xtrue; then
987 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
988 elif test "x$JVM_VARIANT_CLIENT" = xtrue; then
989 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/client"
990 elif test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
991 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/minimal"
992 else
993 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
994 fi
996 LDFLAGS_JDKLIB_SUFFIX="-ljava -ljvm"
997 if test "x$COMPILER_NAME" = xossc; then
998 LDFLAGS_JDKLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX -lc"
999 fi
1001 LDFLAGS_JDKEXE="${LDFLAGS_JDK}"
1002 if test "x$OPENJDK_TARGET_OS" = xlinux; then
1003 LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE -Xlinker --allow-shlib-undefined"
1004 fi
1005 fi
1007 # Adjust flags according to debug level.
1008 case $DEBUG_LEVEL in
1009 fastdebug )
1010 CFLAGS="$CFLAGS $D_FLAG"
1011 JAVAC_FLAGS="$JAVAC_FLAGS -g"
1012 ;;
1013 slowdebug )
1014 CFLAGS="$CFLAGS $D_FLAG"
1015 C_O_FLAG_HI="$C_O_FLAG_NONE"
1016 C_O_FLAG_NORM="$C_O_FLAG_NONE"
1017 CXX_O_FLAG_HI="$CXX_O_FLAG_NONE"
1018 CXX_O_FLAG_NORM="$CXX_O_FLAG_NONE"
1019 JAVAC_FLAGS="$JAVAC_FLAGS -g"
1020 ;;
1021 esac
1024 AC_SUBST(CFLAGS_JDKLIB)
1025 AC_SUBST(CFLAGS_JDKEXE)
1027 AC_SUBST(CXXFLAGS_JDKLIB)
1028 AC_SUBST(CXXFLAGS_JDKEXE)
1030 AC_SUBST(LDFLAGS_JDKLIB)
1031 AC_SUBST(LDFLAGS_JDKEXE)
1032 AC_SUBST(LDFLAGS_JDKLIB_SUFFIX)
1033 AC_SUBST(LDFLAGS_JDKEXE_SUFFIX)
1034 AC_SUBST(LDFLAGS_CXX_JDK)
1035 ])
1038 # TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
1039 # [RUN-IF-FALSE])
1040 # ------------------------------------------------------------
1041 # Check that the c and c++ compilers support an argument
1042 AC_DEFUN([TOOLCHAIN_COMPILER_CHECK_ARGUMENTS],
1043 [
1044 AC_MSG_CHECKING([if compiler supports "$1"])
1045 supports=yes
1047 saved_cflags="$CFLAGS"
1048 CFLAGS="$CFLAGS $1"
1049 AC_LANG_PUSH([C])
1050 AC_COMPILE_IFELSE([
1051 AC_LANG_SOURCE([[int i;]])
1052 ], [], [supports=no])
1053 AC_LANG_POP([C])
1054 CFLAGS="$saved_cflags"
1056 saved_cxxflags="$CXXFLAGS"
1057 CXXFLAGS="$CXXFLAG $1"
1058 AC_LANG_PUSH([C++])
1059 AC_COMPILE_IFELSE([
1060 AC_LANG_SOURCE([[int i;]])
1061 ], [], [supports=no])
1062 AC_LANG_POP([C++])
1063 CXXFLAGS="$saved_cxxflags"
1065 AC_MSG_RESULT([$supports])
1066 if test "x$supports" = "xyes" ; then
1067 m4_ifval([$2], [$2], [:])
1068 else
1069 m4_ifval([$3], [$3], [:])
1070 fi
1071 ])
1073 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_MISC],
1074 [
1075 # Some Zero and Shark settings.
1076 # ZERO_ARCHFLAG tells the compiler which mode to build for
1077 case "${OPENJDK_TARGET_CPU}" in
1078 s390)
1079 ZERO_ARCHFLAG="-m31"
1080 ;;
1081 *)
1082 ZERO_ARCHFLAG="-m${OPENJDK_TARGET_CPU_BITS}"
1083 esac
1084 TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([$ZERO_ARCHFLAG], [], [ZERO_ARCHFLAG=""])
1085 AC_SUBST(ZERO_ARCHFLAG)
1087 # Check that the compiler supports -mX flags
1088 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
1089 TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([-m${OPENJDK_TARGET_CPU_BITS}],
1090 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
1091 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
1092 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
1093 ])
1095 # Setup the JTREG paths
1096 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
1097 [
1098 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
1099 [Regression Test Harness @<:@probed@:>@])],
1100 [],
1101 [with_jtreg=no])
1103 if test "x$with_jtreg" = xno; then
1104 # jtreg disabled
1105 AC_MSG_CHECKING([for jtreg])
1106 AC_MSG_RESULT(no)
1107 else
1108 if test "x$with_jtreg" != xyes; then
1109 # with path specified.
1110 JT_HOME="$with_jtreg"
1111 fi
1113 if test "x$JT_HOME" != x; then
1114 AC_MSG_CHECKING([for jtreg])
1116 # use JT_HOME enviroment var.
1117 BASIC_FIXUP_PATH([JT_HOME])
1119 # jtreg win32 script works for everybody
1120 JTREGEXE="$JT_HOME/win32/bin/jtreg"
1122 if test ! -f "$JTREGEXE"; then
1123 AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
1124 fi
1126 AC_MSG_RESULT($JTREGEXE)
1127 else
1128 # try to find jtreg on path
1129 BASIC_REQUIRE_PROG(JTREGEXE, jtreg)
1130 JT_HOME="`$DIRNAME $JTREGEXE`"
1131 fi
1132 fi
1134 AC_SUBST(JT_HOME)
1135 AC_SUBST(JTREGEXE)
1136 ])
