Mercurial > jdk8-mips64-public / file revision
common/autoconf/toolchain.m4@ab82853d3365
common/autoconf/toolchain.m4
Thu, 21 Feb 2013 14:16:56 +0100
- author
- erikj
- date
- Thu, 21 Feb 2013 14:16:56 +0100
- changeset 631
- ab82853d3365
- parent 621
- ffb4d2e95140
- child 637
- 52741ab7c601
- child 650
- c4901c0e0579
- permissions
- -rw-r--r--
8008451: Make mac builds on 10.8 work on 10.7
Reviewed-by: ohair, ddehaven
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # $1 = compiler to test (CC or CXX)
27 # $2 = human readable name of compiler (C or C++)
28 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
29 [
30 COMPILER=[$]$1
31 COMPILER_NAME=$2
33 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
34 # Make sure we use the Sun Studio compiler and not gcc on Solaris, which won't work
35 COMPILER_VERSION_TEST=`$COMPILER -V 2>&1 | $HEAD -n 1`
36 $ECHO $COMPILER_VERSION_TEST | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
37 if test $? -ne 0; then
38 GCC_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
40 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required Sun Studio compiler.])
41 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_TEST" and with --version: "$GCC_VERSION_TEST"])
42 AC_MSG_ERROR([Sun Studio compiler is required. Try setting --with-tools-dir.])
43 else
44 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/p"`
45 COMPILER_VENDOR="Sun Studio"
46 fi
47 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
48 # First line typically looks something like:
49 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.30319.01 for 80x86
50 COMPILER_VERSION_TEST=`$COMPILER 2>&1 | $HEAD -n 1`
51 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*Version \(@<:@1-9@:>@@<:@0-9.@:>@*\) .*/\1/p"`
52 COMPILER_VENDOR="Microsoft CL.EXE"
53 COMPILER_CPU_TEST=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* for \(.*\)$/\1/p"`
54 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
55 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
56 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
57 fi
58 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
59 if test "x$COMPILER_CPU_TEST" != "xx64"; then
60 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
61 fi
62 fi
63 else
64 COMPILER_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
65 # Check that this is likely to be GCC.
66 $COMPILER --version 2>&1 | $GREP "Free Software Foundation" > /dev/null
67 if test $? -ne 0; then
68 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required GCC compiler.])
69 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_TEST"])
70 AC_MSG_ERROR([GCC compiler is required. Try setting --with-tools-dir.])
71 fi
73 # First line typically looks something like:
74 # gcc (Ubuntu/Linaro 4.5.2-8ubuntu4) 4.5.2
75 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/p"`
76 COMPILER_VENDOR=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^\(.*\) @<:@1-9@:>@@<:@0-9.@:>@*/\1/p"`
77 fi
78 # This sets CC_VERSION or CXX_VERSION. (This comment is a grep marker)
79 $1_VERSION="$COMPILER_VERSION"
80 # This sets CC_VENDOR or CXX_VENDOR. (This comment is a grep marker)
81 $1_VENDOR="$COMPILER_VENDOR"
83 AC_MSG_NOTICE([Using $COMPILER_VENDOR $COMPILER_NAME compiler version $COMPILER_VERSION (located at $COMPILER)])
84 ])
87 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_SYSROOT_AND_OUT_OPTIONS],
88 [
89 ###############################################################################
90 #
91 # Configure the development tool paths and potential sysroot.
92 #
93 AC_LANG(C++)
95 # The option used to specify the target .o,.a or .so file.
96 # When compiling, how to specify the to be created object file.
97 CC_OUT_OPTION='-o$(SPACE)'
98 # When linking, how to specify the to be created executable.
99 EXE_OUT_OPTION='-o$(SPACE)'
100 # When linking, how to specify the to be created dynamically linkable library.
101 LD_OUT_OPTION='-o$(SPACE)'
102 # When archiving, how to specify the to be create static archive for object files.
103 AR_OUT_OPTION='rcs$(SPACE)'
104 AC_SUBST(CC_OUT_OPTION)
105 AC_SUBST(EXE_OUT_OPTION)
106 AC_SUBST(LD_OUT_OPTION)
107 AC_SUBST(AR_OUT_OPTION)
108 ])
110 # $1 = compiler to test (CC or CXX)
111 # $2 = human readable name of compiler (C or C++)
112 # $3 = list of compiler names to search for
113 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
114 [
115 COMPILER_NAME=$2
117 $1=
118 # If TOOLS_DIR is set, check for all compiler names in there first
119 # before checking the rest of the PATH.
120 if test -n "$TOOLS_DIR"; then
121 PATH_save="$PATH"
122 PATH="$TOOLS_DIR"
123 AC_PATH_PROGS(TOOLS_DIR_$1, $3)
124 $1=$TOOLS_DIR_$1
125 PATH="$PATH_save"
126 fi
128 # AC_PATH_PROGS can't be run multiple times with the same variable,
129 # so create a new name for this run.
130 if test "x[$]$1" = x; then
131 AC_PATH_PROGS(POTENTIAL_$1, $3)
132 $1=$POTENTIAL_$1
133 fi
135 if test "x[$]$1" = x; then
136 HELP_MSG_MISSING_DEPENDENCY([devkit])
137 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
138 fi
139 BASIC_FIXUP_EXECUTABLE($1)
140 AC_MSG_CHECKING([resolved symbolic links for $1])
141 TEST_COMPILER="[$]$1"
142 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
143 AC_MSG_RESULT([$TEST_COMPILER])
144 AC_MSG_CHECKING([if $1 is disguised ccache])
146 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
147 if test "x$COMPILER_BASENAME" = "xccache"; then
148 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
149 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
150 # We want to control ccache invocation ourselves, so ignore this cc and try
151 # searching again.
153 # Remove the path to the fake ccache cc from the PATH
154 RETRY_COMPILER_SAVED_PATH="$PATH"
155 COMPILER_DIRNAME=`$DIRNAME [$]$1`
156 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
158 # Try again looking for our compiler
159 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
160 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
161 PATH="$RETRY_COMPILER_SAVED_PATH"
163 AC_MSG_CHECKING([for resolved symbolic links for $1])
164 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
165 AC_MSG_RESULT([$PROPER_COMPILER_$1])
166 $1="$PROPER_COMPILER_$1"
167 else
168 AC_MSG_RESULT([no, keeping $1])
169 $1="$TEST_COMPILER"
170 fi
171 TOOLCHAIN_CHECK_COMPILER_VERSION([$1], [$COMPILER_NAME])
172 ])
175 AC_DEFUN([TOOLCHAIN_SETUP_PATHS],
176 [
177 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
178 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
179 fi
181 AC_SUBST(MSVCR_DLL)
183 # If --build AND --host is set, then the configure script will find any
184 # cross compilation tools in the PATH. Cross compilation tools
185 # follows the cross compilation standard where they are prefixed with ${host}.
186 # For example the binary i686-sun-solaris2.10-gcc
187 # will cross compile for i686-sun-solaris2.10
188 # If neither of build and host is not set, then build=host and the
189 # default compiler found in the path will be used.
190 # Setting only --host, does not seem to be really supported.
191 # Please set both --build and --host if you want to cross compile.
193 if test "x$COMPILE_TYPE" = "xcross"; then
194 # Now we to find a C/C++ compiler that can build executables for the build
195 # platform. We can't use the AC_PROG_CC macro, since it can only be used
196 # once. Also, we need to do this before adding a tools dir to the path,
197 # otherwise we might pick up cross-compilers which don't use standard naming.
198 # Otherwise, we'll set the BUILD_tools to the native tools, but that'll have
199 # to wait until they are properly discovered.
200 AC_PATH_PROGS(BUILD_CC, [cl cc gcc])
201 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
202 AC_PATH_PROGS(BUILD_CXX, [cl CC g++])
203 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
204 AC_PATH_PROG(BUILD_LD, ld)
205 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
206 fi
207 AC_SUBST(BUILD_CC)
208 AC_SUBST(BUILD_CXX)
209 AC_SUBST(BUILD_LD)
211 # If a devkit is found on the builddeps server, then prepend its path to the
212 # PATH variable. If there are cross compilers available in the devkit, these
213 # will be found by AC_PROG_CC et al.
214 DEVKIT=
215 BDEPS_CHECK_MODULE(DEVKIT, devkit, xxx,
216 [# Found devkit
217 PATH="$DEVKIT/bin:$PATH"
218 SYS_ROOT="$DEVKIT/${rewritten_target}/sys-root"
219 if test "x$x_includes" = "xNONE"; then
220 x_includes="$SYS_ROOT/usr/include/X11"
221 fi
222 if test "x$x_libraries" = "xNONE"; then
223 x_libraries="$SYS_ROOT/usr/lib"
224 fi
225 ],
226 [])
228 if test "x$SYS_ROOT" != "x/" ; then
229 CFLAGS="--sysroot=$SYS_ROOT $CFLAGS"
230 CXXFLAGS="--sysroot=$SYS_ROOT $CXXFLAGS"
231 OBJCFLAGS="--sysroot=$SYS_ROOT $OBJCFLAGS"
232 OBJCXXFLAGS="--sysroot=$SYS_ROOT $OBJCFLAGS"
233 CPPFLAGS="--sysroot=$SYS_ROOT $CPPFLAGS"
234 LDFLAGS="--sysroot=$SYS_ROOT $LDFLAGS"
235 fi
237 # Store the CFLAGS etal passed to the configure script.
238 ORG_CFLAGS="$CFLAGS"
239 ORG_CXXFLAGS="$CXXFLAGS"
240 ORG_OBJCFLAGS="$OBJCFLAGS"
242 # autoconf magic only relies on PATH, so update it if tools dir is specified
243 OLD_PATH="$PATH"
244 if test "x$TOOLS_DIR" != x; then
245 PATH=$TOOLS_DIR:$PATH
246 fi
249 ### Locate C compiler (CC)
251 # gcc is almost always present, but on Windows we
252 # prefer cl.exe and on Solaris we prefer CC.
253 # Thus test for them in this order.
254 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
255 # Do not probe for cc on MacOSX.
256 COMPILER_CHECK_LIST="cl gcc"
257 else
258 COMPILER_CHECK_LIST="cl cc gcc"
259 fi
261 TOOLCHAIN_FIND_COMPILER([CC],[C],[$COMPILER_CHECK_LIST])
262 # Now that we have resolved CC ourself, let autoconf have it's go at it
263 AC_PROG_CC([$CC])
265 ### Locate C++ compiler (CXX)
267 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
268 # Do not probe for CC on MacOSX.
269 COMPILER_CHECK_LIST="cl g++"
270 else
271 COMPILER_CHECK_LIST="cl CC g++"
272 fi
273 TOOLCHAIN_FIND_COMPILER([CXX],[C++],[$COMPILER_CHECK_LIST])
274 # Now that we have resolved CXX ourself, let autoconf have it's go at it
275 AC_PROG_CXX([$CXX])
277 ### Locate other tools
279 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
280 AC_PROG_OBJC
281 BASIC_FIXUP_EXECUTABLE(OBJC)
282 else
283 OBJC=
284 fi
286 # Restore the flags to the user specified values.
287 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
288 CFLAGS="$ORG_CFLAGS"
289 CXXFLAGS="$ORG_CXXFLAGS"
290 OBJCFLAGS="$ORG_OBJCFLAGS"
292 LD="$CC"
293 LDEXE="$CC"
294 LDCXX="$CXX"
295 LDEXECXX="$CXX"
296 AC_SUBST(LD)
297 # LDEXE is the linker to use, when creating executables.
298 AC_SUBST(LDEXE)
299 # Linking C++ libraries.
300 AC_SUBST(LDCXX)
301 # Linking C++ executables.
302 AC_SUBST(LDEXECXX)
304 if test "x$OPENJDK_TARGET_OS" != xwindows; then
305 AC_CHECK_TOOL(AR, ar)
306 BASIC_FIXUP_EXECUTABLE(AR)
307 fi
308 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
309 ARFLAGS="-r"
310 else
311 ARFLAGS=""
312 fi
313 AC_SUBST(ARFLAGS)
315 # For hotspot, we need these in Windows mixed path; other platforms keep them the same
316 HOTSPOT_CXX="$CXX"
317 HOTSPOT_LD="$LD"
318 AC_SUBST(HOTSPOT_CXX)
319 AC_SUBST(HOTSPOT_LD)
321 COMPILER_NAME=gcc
322 COMPILER_TYPE=CC
323 AS_IF([test "x$OPENJDK_TARGET_OS" = xwindows], [
324 # For now, assume that we are always compiling using cl.exe.
325 CC_OUT_OPTION=-Fo
326 EXE_OUT_OPTION=-out:
327 LD_OUT_OPTION=-out:
328 AR_OUT_OPTION=-out:
329 # On Windows, reject /usr/bin/link (as determined in CYGWIN_LINK), which is a cygwin
330 # program for something completely different.
331 AC_CHECK_PROG([WINLD], [link],[link],,, [$CYGWIN_LINK])
332 # Since we must ignore the first found link, WINLD will contain
333 # the full path to the link.exe program.
334 BASIC_FIXUP_EXECUTABLE(WINLD)
335 printf "Windows linker was found at $WINLD\n"
336 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
337 "$WINLD" --version > /dev/null
338 if test $? -eq 0 ; then
339 AC_MSG_RESULT([no])
340 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
341 else
342 AC_MSG_RESULT([yes])
343 fi
344 LD="$WINLD"
345 LDEXE="$WINLD"
346 LDCXX="$WINLD"
347 LDEXECXX="$WINLD"
349 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
350 BASIC_FIXUP_EXECUTABLE(MT)
351 # The resource compiler
352 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
353 BASIC_FIXUP_EXECUTABLE(RC)
355 # For hotspot, we need these in Windows mixed path,
356 # so rewrite them all. Need added .exe suffix.
357 HOTSPOT_CXX="$CXX.exe"
358 HOTSPOT_LD="$LD.exe"
359 HOTSPOT_MT="$MT.exe"
360 HOTSPOT_RC="$RC.exe"
361 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
362 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
363 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
364 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
365 AC_SUBST(HOTSPOT_MT)
366 AC_SUBST(HOTSPOT_RC)
368 RC_FLAGS="-nologo -l 0x409 -r"
369 AS_IF([test "x$VARIANT" = xOPT], [
370 RC_FLAGS="$RC_FLAGS -d NDEBUG"
371 ])
372 JDK_UPDATE_VERSION_NOTNULL=$JDK_UPDATE_VERSION
373 AS_IF([test "x$JDK_UPDATE_VERSION" = x], [
374 JDK_UPDATE_VERSION_NOTNULL=0
375 ])
376 RC_FLAGS="$RC_FLAGS -d \"JDK_BUILD_ID=$FULL_VERSION\""
377 RC_FLAGS="$RC_FLAGS -d \"JDK_COMPANY=$COMPANY_NAME\""
378 RC_FLAGS="$RC_FLAGS -d \"JDK_COMPONENT=$PRODUCT_NAME $JDK_RC_PLATFORM_NAME binary\""
379 RC_FLAGS="$RC_FLAGS -d \"JDK_VER=$JDK_MINOR_VERSION.$JDK_MICRO_VERSION.$JDK_UPDATE_VERSION_NOTNULL.$COOKED_BUILD_NUMBER\""
380 RC_FLAGS="$RC_FLAGS -d \"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\""
381 RC_FLAGS="$RC_FLAGS -d \"JDK_NAME=$PRODUCT_NAME $JDK_RC_PLATFORM_NAME $JDK_MINOR_VERSION $JDK_UPDATE_META_TAG\""
382 RC_FLAGS="$RC_FLAGS -d \"JDK_FVER=$JDK_MINOR_VERSION,$JDK_MICRO_VERSION,$JDK_UPDATE_VERSION_NOTNULL,$COOKED_BUILD_NUMBER\""
384 # lib.exe is used to create static libraries.
385 AC_CHECK_PROG([WINAR], [lib],[lib],,,)
386 BASIC_FIXUP_EXECUTABLE(WINAR)
387 AR="$WINAR"
388 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
390 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
391 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
393 COMPILER_TYPE=CL
394 CCXXFLAGS="$CCXXFLAGS -nologo"
395 ])
396 AC_SUBST(RC_FLAGS)
397 AC_SUBST(COMPILER_TYPE)
399 AC_PROG_CPP
400 BASIC_FIXUP_EXECUTABLE(CPP)
402 AC_PROG_CXXCPP
403 BASIC_FIXUP_EXECUTABLE(CXXCPP)
405 if test "x$COMPILE_TYPE" != "xcross"; then
406 # If we are not cross compiling, use the same compilers for
407 # building the build platform executables. The cross-compilation
408 # case needed to be done earlier, but this can only be done after
409 # the native tools have been localized.
410 BUILD_CC="$CC"
411 BUILD_CXX="$CXX"
412 BUILD_LD="$LD"
413 fi
415 # for solaris we really need solaris tools, and not gnu equivalent
416 # these seems to normally reside in /usr/ccs/bin so add that to path before
417 # starting to probe
418 #
419 # NOTE: I add this /usr/ccs/bin after TOOLS but before OLD_PATH
420 # so that it can be overriden --with-tools-dir
421 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
422 PATH="${TOOLS_DIR}:/usr/ccs/bin:${OLD_PATH}"
423 fi
425 # Find the right assembler.
426 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
427 AC_PATH_PROG(AS, as)
428 BASIC_FIXUP_EXECUTABLE(AS)
429 else
430 AS="$CC -c"
431 fi
432 AC_SUBST(AS)
434 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
435 AC_PATH_PROGS(NM, [gnm nm])
436 BASIC_FIXUP_EXECUTABLE(NM)
437 AC_PATH_PROG(STRIP, strip)
438 BASIC_FIXUP_EXECUTABLE(STRIP)
439 AC_PATH_PROG(MCS, mcs)
440 BASIC_FIXUP_EXECUTABLE(MCS)
441 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
442 AC_CHECK_TOOL(NM, nm)
443 BASIC_FIXUP_EXECUTABLE(NM)
444 AC_CHECK_TOOL(STRIP, strip)
445 BASIC_FIXUP_EXECUTABLE(STRIP)
446 fi
448 # objcopy is used for moving debug symbols to separate files when
449 # full debug symbols are enabled.
450 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
451 AC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
452 # Only call fixup if objcopy was found.
453 if test -n "$OBJCOPY"; then
454 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
455 fi
456 fi
458 AC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
459 if test "x$OBJDUMP" != x; then
460 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE bails if argument is missing.
461 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
462 fi
464 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
465 AC_PATH_PROG(LIPO, lipo)
466 BASIC_FIXUP_EXECUTABLE(LIPO)
467 fi
469 # Restore old path without tools dir
470 PATH="$OLD_PATH"
471 ])
474 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_LIBS],
475 [
477 ###############################################################################
478 #
479 # How to compile shared libraries.
480 #
482 if test "x$GCC" = xyes; then
483 COMPILER_NAME=gcc
484 PICFLAG="-fPIC"
485 LIBRARY_PREFIX=lib
486 SHARED_LIBRARY='lib[$]1.so'
487 STATIC_LIBRARY='lib[$]1.a'
488 SHARED_LIBRARY_FLAGS="-shared"
489 SHARED_LIBRARY_SUFFIX='.so'
490 STATIC_LIBRARY_SUFFIX='.a'
491 OBJ_SUFFIX='.o'
492 EXE_SUFFIX=''
493 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
494 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
495 C_FLAG_REORDER=''
496 CXX_FLAG_REORDER=''
497 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -z -Xlinker origin -Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
498 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
499 LD="$CC"
500 LDEXE="$CC"
501 LDCXX="$CXX"
502 LDEXECXX="$CXX"
503 POST_STRIP_CMD="$STRIP -g"
505 # Linking is different on MacOSX
506 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
507 # Might change in the future to clang.
508 COMPILER_NAME=gcc
509 SHARED_LIBRARY='lib[$]1.dylib'
510 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
511 SHARED_LIBRARY_SUFFIX='.dylib'
512 EXE_SUFFIX=''
513 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
514 SET_SHARED_LIBRARY_MAPFILE=''
515 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
516 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
517 POST_STRIP_CMD="$STRIP -S"
518 fi
519 else
520 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
521 # If it is not gcc, then assume it is the Oracle Solaris Studio Compiler
522 COMPILER_NAME=ossc
523 PICFLAG="-KPIC"
524 LIBRARY_PREFIX=lib
525 SHARED_LIBRARY='lib[$]1.so'
526 STATIC_LIBRARY='lib[$]1.a'
527 SHARED_LIBRARY_FLAGS="-G"
528 SHARED_LIBRARY_SUFFIX='.so'
529 STATIC_LIBRARY_SUFFIX='.a'
530 OBJ_SUFFIX='.o'
531 EXE_SUFFIX=''
532 SET_SHARED_LIBRARY_NAME=''
533 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
534 C_FLAG_REORDER='-xF'
535 CXX_FLAG_REORDER='-xF'
536 SET_SHARED_LIBRARY_ORIGIN='-R\$$$$ORIGIN[$]1'
537 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
538 CFLAGS_JDK="${CFLAGS_JDK} -D__solaris__"
539 CXXFLAGS_JDK="${CXXFLAGS_JDK} -D__solaris__"
540 CFLAGS_JDKLIB_EXTRA='-xstrconst'
541 POST_STRIP_CMD="$STRIP -x"
542 POST_MCS_CMD="$MCS -d -a \"JDK $FULL_VERSION\""
543 fi
544 if test "x$OPENJDK_TARGET_OS" = xwindows; then
545 # If it is not gcc, then assume it is the MS Visual Studio compiler
546 COMPILER_NAME=cl
547 PICFLAG=""
548 LIBRARY_PREFIX=
549 SHARED_LIBRARY='[$]1.dll'
550 STATIC_LIBRARY='[$]1.lib'
551 SHARED_LIBRARY_FLAGS="-LD"
552 SHARED_LIBRARY_SUFFIX='.dll'
553 STATIC_LIBRARY_SUFFIX='.lib'
554 OBJ_SUFFIX='.obj'
555 EXE_SUFFIX='.exe'
556 SET_SHARED_LIBRARY_NAME=''
557 SET_SHARED_LIBRARY_MAPFILE=''
558 SET_SHARED_LIBRARY_ORIGIN=''
559 SET_EXECUTABLE_ORIGIN=''
560 fi
561 fi
563 AC_SUBST(OBJ_SUFFIX)
564 AC_SUBST(SHARED_LIBRARY)
565 AC_SUBST(STATIC_LIBRARY)
566 AC_SUBST(LIBRARY_PREFIX)
567 AC_SUBST(SHARED_LIBRARY_SUFFIX)
568 AC_SUBST(STATIC_LIBRARY_SUFFIX)
569 AC_SUBST(EXE_SUFFIX)
570 AC_SUBST(SHARED_LIBRARY_FLAGS)
571 AC_SUBST(SET_SHARED_LIBRARY_NAME)
572 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
573 AC_SUBST(C_FLAG_REORDER)
574 AC_SUBST(CXX_FLAG_REORDER)
575 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
576 AC_SUBST(SET_EXECUTABLE_ORIGIN)
577 AC_SUBST(POST_STRIP_CMD)
578 AC_SUBST(POST_MCS_CMD)
580 # The (cross) compiler is now configured, we can now test capabilities
581 # of the target platform.
582 ])
584 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
585 [
587 ###############################################################################
588 #
589 # Setup the opt flags for different compilers
590 # and different operating systems.
591 #
593 #
594 # NOTE: check for -mstackrealign needs to be below potential addition of -m32
595 #
596 if test "x$OPENJDK_TARGET_CPU_BITS" = x32 && test "x$OPENJDK_TARGET_OS" = xmacosx; then
597 # On 32-bit MacOSX the OS requires C-entry points to be 16 byte aligned.
598 # While waiting for a better solution, the current workaround is to use -mstackrealign.
599 CFLAGS="$CFLAGS -mstackrealign"
600 AC_MSG_CHECKING([if 32-bit compiler supports -mstackrealign])
601 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])],
602 [
603 AC_MSG_RESULT([yes])
604 ],
605 [
606 AC_MSG_RESULT([no])
607 AC_MSG_ERROR([The selected compiler $CXX does not support -mstackrealign! Try to put another compiler in the path.])
608 ])
609 fi
611 C_FLAG_DEPS="-MMD -MF"
612 CXX_FLAG_DEPS="-MMD -MF"
614 case $COMPILER_TYPE in
615 CC )
616 D_FLAG="-g"
617 case $COMPILER_NAME in
618 gcc )
619 case $OPENJDK_TARGET_OS in
620 macosx )
621 # On MacOSX we optimize for size, something
622 # we should do for all platforms?
623 C_O_FLAG_HI="-Os"
624 C_O_FLAG_NORM="-Os"
625 C_O_FLAG_NONE=""
626 ;;
627 *)
628 C_O_FLAG_HI="-O3"
629 C_O_FLAG_NORM="-O2"
630 C_O_FLAG_NONE="-O0"
631 CFLAGS_DEBUG_SYMBOLS="-g"
632 CXXFLAGS_DEBUG_SYMBOLS="-g"
633 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
634 CFLAGS_DEBUG_SYMBOLS="-g1"
635 CXXFLAGS_DEBUG_SYMBOLS="-g1"
636 fi
637 ;;
638 esac
639 CXX_O_FLAG_HI="$C_O_FLAG_HI"
640 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
641 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
642 ;;
643 ossc )
644 #
645 # Forte has different names for this with their C++ compiler...
646 #
647 C_FLAG_DEPS="-xMMD -xMF"
648 CXX_FLAG_DEPS="-xMMD -xMF"
650 # Extra options used with HIGHEST
651 #
652 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
653 # done with care, there are some assumptions below that need to
654 # be understood about the use of pointers, and IEEE behavior.
655 #
656 # Use non-standard floating point mode (not IEEE 754)
657 CC_HIGHEST="$CC_HIGHEST -fns"
658 # Do some simplification of floating point arithmetic (not IEEE 754)
659 CC_HIGHEST="$CC_HIGHEST -fsimple"
660 # Use single precision floating point with 'float'
661 CC_HIGHEST="$CC_HIGHEST -fsingle"
662 # Assume memory references via basic pointer types do not alias
663 # (Source with excessing pointer casting and data access with mixed
664 # pointer types are not recommended)
665 CC_HIGHEST="$CC_HIGHEST -xalias_level=basic"
666 # Use intrinsic or inline versions for math/std functions
667 # (If you expect perfect errno behavior, do not use this)
668 CC_HIGHEST="$CC_HIGHEST -xbuiltin=%all"
669 # Loop data dependency optimizations (need -xO3 or higher)
670 CC_HIGHEST="$CC_HIGHEST -xdepend"
671 # Pointer parameters to functions do not overlap
672 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
673 # If you pass in multiple pointers to the same data, do not use this)
674 CC_HIGHEST="$CC_HIGHEST -xrestrict"
675 # Inline some library routines
676 # (If you expect perfect errno behavior, do not use this)
677 CC_HIGHEST="$CC_HIGHEST -xlibmil"
678 # Use optimized math routines
679 # (If you expect perfect errno behavior, do not use this)
680 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
681 #CC_HIGHEST="$CC_HIGHEST -xlibmopt"
683 if test "x$OPENJDK_TARGET_CPU" = xsparc; then
684 CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
685 CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
686 fi
688 case $OPENJDK_TARGET_CPU_ARCH in
689 x86)
690 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xregs=no%frameptr"
691 C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
692 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
693 C_O_FLAG_NONE="-xregs=no%frameptr"
694 CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
695 CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
696 CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
697 CXX_O_FLAG_NONE="-xregs=no%frameptr"
698 if test "x$OPENJDK_TARGET_CPU" = xx86; then
699 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
700 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
701 fi
702 ;;
703 sparc)
704 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
705 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
706 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
707 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
708 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
709 C_O_FLAG_NONE=""
710 CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
711 CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
712 CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
713 CXX_O_FLAG_NONE=""
714 ;;
715 esac
717 CFLAGS_DEBUG_SYMBOLS="-g -xs"
718 CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
719 esac
720 ;;
721 CL )
722 D_FLAG=
723 C_O_FLAG_HIGHEST="-O2"
724 C_O_FLAG_HI="-O1"
725 C_O_FLAG_NORM="-O1"
726 C_O_FLAG_NONE="-Od"
727 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
728 CXX_O_FLAG_HI="$C_O_FLAG_HI"
729 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
730 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
731 ;;
732 esac
734 if test -z "$C_O_FLAG_HIGHEST"; then
735 C_O_FLAG_HIGHEST="$C_O_FLAG_HI"
736 fi
738 if test -z "$CXX_O_FLAG_HIGHEST"; then
739 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HI"
740 fi
742 AC_SUBST(C_O_FLAG_HIGHEST)
743 AC_SUBST(C_O_FLAG_HI)
744 AC_SUBST(C_O_FLAG_NORM)
745 AC_SUBST(C_O_FLAG_NONE)
746 AC_SUBST(CXX_O_FLAG_HIGHEST)
747 AC_SUBST(CXX_O_FLAG_HI)
748 AC_SUBST(CXX_O_FLAG_NORM)
749 AC_SUBST(CXX_O_FLAG_NONE)
750 AC_SUBST(C_FLAG_DEPS)
751 AC_SUBST(CXX_FLAG_DEPS)
752 ])
754 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_JDK],
755 [
757 if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
758 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
759 fi
761 if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
762 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
763 fi
765 if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
766 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
767 fi
769 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
770 [extra flags to be used when compiling jdk c-files])])
772 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
773 [extra flags to be used when compiling jdk c++-files])])
775 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
776 [extra flags to be used when linking jdk])])
778 CFLAGS_JDK="${CFLAGS_JDK} $with_extra_cflags"
779 CXXFLAGS_JDK="${CXXFLAGS_JDK} $with_extra_cxxflags"
780 LDFLAGS_JDK="${LDFLAGS_JDK} $with_extra_ldflags"
782 # Hotspot needs these set in their legacy form
783 LEGACY_EXTRA_CFLAGS=$with_extra_cflags
784 LEGACY_EXTRA_CXXFLAGS=$with_extra_cxxflags
785 LEGACY_EXTRA_LDFLAGS=$with_extra_ldflags
787 AC_SUBST(LEGACY_EXTRA_CFLAGS)
788 AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
789 AC_SUBST(LEGACY_EXTRA_LDFLAGS)
791 ###############################################################################
792 #
793 # Now setup the CFLAGS and LDFLAGS for the JDK build.
794 # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
795 #
796 case $COMPILER_NAME in
797 gcc )
798 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -W -Wall -Wno-unused -Wno-parentheses \
799 -pipe \
800 -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
801 case $OPENJDK_TARGET_CPU_ARCH in
802 arm )
803 # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
804 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
805 ;;
806 ppc )
807 # on ppc we don't prevent gcc to omit frame pointer nor strict-aliasing
808 ;;
809 * )
810 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -fno-omit-frame-pointer"
811 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
812 ;;
813 esac
814 ;;
815 ossc )
816 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
817 case $OPENJDK_TARGET_CPU_ARCH in
818 x86 )
819 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_TARGET_CPU_LEGACY_LIB"
820 CFLAGS_JDK="$CFLAGS_JDK -erroff=E_BAD_PRAGMA_PACK_VALUE"
821 ;;
822 esac
824 CFLAGS_JDK="$CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
825 CXXFLAGS_JDK="$CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
827 LDFLAGS_JDK="$LDFLAGS_JDK -z defs -xildoff -ztext"
828 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK -norunpath -xnolib"
829 ;;
830 cl )
831 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -Zi -MD -Zc:wchar_t- -W3 -wd4800 \
832 -D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB -DWIN32_LEAN_AND_MEAN \
833 -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
834 -DWIN32 -DIAL"
835 case $OPENJDK_TARGET_CPU in
836 x86 )
837 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_X86_ -Dx86"
838 ;;
839 x86_64 )
840 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_AMD64_ -Damd64"
841 ;;
842 esac
843 ;;
844 esac
846 ###############################################################################
848 CCXXFLAGS_JDK="$CCXXFLAGS_JDK $ADD_LP64"
850 # The package path is used only on macosx?
851 PACKAGE_PATH=/opt/local
852 AC_SUBST(PACKAGE_PATH)
854 if test "x$OPENJDK_TARGET_CPU_ENDIAN" = xlittle; then
855 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
856 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
857 # (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
858 # Note: -Dmacro is the same as #define macro 1
859 # -Dmacro= is the same as #define macro
860 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
861 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
862 else
863 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
864 fi
865 else
866 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_BIG_ENDIAN"
867 fi
868 if test "x$OPENJDK_TARGET_OS" = xlinux; then
869 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DLINUX"
870 fi
871 if test "x$OPENJDK_TARGET_OS" = xwindows; then
872 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DWINDOWS"
873 fi
874 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
875 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DSOLARIS"
876 fi
877 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
878 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMACOSX -D_ALLBSD_SOURCE"
879 # Setting these parameters makes it an error to link to macosx APIs that are
880 # newer than the given OS version and makes the linked binaries compatible even
881 # if built on a newer version of the OS.
882 # The expected format is X.Y.Z
883 MACOSX_VERSION_MIN=10.7.0
884 AC_SUBST(MACOSX_VERSION_MIN)
885 # The macro takes the version with no dots, ex: 1070
886 # Let the flags variables get resolved in make for easier override on make
887 # command line.
888 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
889 LDFLAGS_JDK="$LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
890 fi
891 if test "x$OPENJDK_TARGET_OS" = xbsd; then
892 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DBSD -D_ALLBSD_SOURCE"
893 fi
894 if test "x$DEBUG_LEVEL" = xrelease; then
895 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DNDEBUG"
896 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
897 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DTRIMMED"
898 fi
899 else
900 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DDEBUG"
901 fi
903 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DARCH='\"$OPENJDK_TARGET_CPU_LEGACY\"' -D$OPENJDK_TARGET_CPU_LEGACY"
904 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DRELEASE='\"$RELEASE\"'"
906 CCXXFLAGS_JDK="$CCXXFLAGS_JDK \
907 -I${JDK_OUTPUTDIR}/include \
908 -I${JDK_OUTPUTDIR}/include/$OPENJDK_TARGET_OS \
909 -I${JDK_TOPDIR}/src/share/javavm/export \
910 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/javavm/export \
911 -I${JDK_TOPDIR}/src/share/native/common \
912 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/native/common"
914 # The shared libraries are compiled using the picflag.
915 CFLAGS_JDKLIB="$CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
916 CXXFLAGS_JDKLIB="$CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA "
918 # Executable flags
919 CFLAGS_JDKEXE="$CCXXFLAGS_JDK $CFLAGS_JDK"
920 CXXFLAGS_JDKEXE="$CCXXFLAGS_JDK $CXXFLAGS_JDK"
922 # Now this is odd. The JDK native libraries have to link against libjvm.so
923 # On 32-bit machines there is normally two distinct libjvm.so:s, client and server.
924 # Which should we link to? Are we lucky enough that the binary api to the libjvm.so library
925 # is identical for client and server? Yes. Which is picked at runtime (client or server)?
926 # Neither, since the chosen libjvm.so has already been loaded by the launcher, all the following
927 # libraries will link to whatever is in memory. Yuck.
928 #
929 # Thus we offer the compiler to find libjvm.so first in server then in client. It works. Ugh.
930 if test "x$COMPILER_NAME" = xcl; then
931 LDFLAGS_JDK="$LDFLAGS_JDK -nologo -opt:ref -incremental:no"
932 if test "x$OPENJDK_TARGET_CPU" = xx86; then
933 LDFLAGS_JDK="$LDFLAGS_JDK -safeseh"
934 fi
935 # TODO: make -debug optional "--disable-full-debug-symbols"
936 LDFLAGS_JDK="$LDFLAGS_JDK -debug"
937 LDFLAGS_JDKLIB="${LDFLAGS_JDK} -dll -libpath:${JDK_OUTPUTDIR}/lib"
938 LDFLAGS_JDKLIB_SUFFIX=""
939 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
940 LDFLAGS_STACK_SIZE=1048576
941 else
942 LDFLAGS_STACK_SIZE=327680
943 fi
944 LDFLAGS_JDKEXE="${LDFLAGS_JDK} /STACK:$LDFLAGS_STACK_SIZE"
945 else
946 if test "x$COMPILER_NAME" = xgcc; then
947 # If this is a --hash-style=gnu system, use --hash-style=both, why?
948 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
949 if test -n "$HAS_GNU_HASH"; then
950 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker --hash-style=both "
951 fi
952 if test "x$OPENJDK_TARGET_OS" = xlinux; then
953 # And since we now know that the linker is gnu, then add -z defs, to forbid
954 # undefined symbols in object files.
955 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -z -Xlinker defs"
956 if test "x$DEBUG_LEVEL" = "xrelease"; then
957 # When building release libraries, tell the linker optimize them.
958 # Should this be supplied to the OSS linker as well?
959 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -O1"
960 fi
961 fi
962 fi
963 LDFLAGS_JDKLIB="${LDFLAGS_JDK} $SHARED_LIBRARY_FLAGS \
964 -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}"
966 # On some platforms (mac) the linker warns about non existing -L dirs.
967 # Add server first if available. Linking aginst client does not always produce the same results.
968 # Only add client dir if client is being built. Add minimal (note not minimal1) if only building minimal1.
969 # Default to server for other variants.
970 if test "x$JVM_VARIANT_SERVER" = xtrue; then
971 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
972 elif test "x$JVM_VARIANT_CLIENT" = xtrue; then
973 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/client"
974 elif test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
975 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/minimal"
976 else
977 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
978 fi
980 LDFLAGS_JDKLIB_SUFFIX="-ljava -ljvm"
981 if test "x$COMPILER_NAME" = xossc; then
982 LDFLAGS_JDKLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX -lc"
983 fi
985 LDFLAGS_JDKEXE="${LDFLAGS_JDK}"
986 if test "x$OPENJDK_TARGET_OS" = xlinux; then
987 LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE -Xlinker --allow-shlib-undefined"
988 fi
989 fi
991 # Adjust flags according to debug level.
992 case $DEBUG_LEVEL in
993 fastdebug )
994 CFLAGS="$CFLAGS $D_FLAG"
995 JAVAC_FLAGS="$JAVAC_FLAGS -g"
996 ;;
997 slowdebug )
998 CFLAGS="$CFLAGS $D_FLAG"
999 C_O_FLAG_HI="$C_O_FLAG_NONE"
1000 C_O_FLAG_NORM="$C_O_FLAG_NONE"
1001 CXX_O_FLAG_HI="$CXX_O_FLAG_NONE"
1002 CXX_O_FLAG_NORM="$CXX_O_FLAG_NONE"
1003 JAVAC_FLAGS="$JAVAC_FLAGS -g"
1004 ;;
1005 esac
1008 AC_SUBST(CFLAGS_JDKLIB)
1009 AC_SUBST(CFLAGS_JDKEXE)
1011 AC_SUBST(CXXFLAGS_JDKLIB)
1012 AC_SUBST(CXXFLAGS_JDKEXE)
1014 AC_SUBST(LDFLAGS_JDKLIB)
1015 AC_SUBST(LDFLAGS_JDKEXE)
1016 AC_SUBST(LDFLAGS_JDKLIB_SUFFIX)
1017 AC_SUBST(LDFLAGS_JDKEXE_SUFFIX)
1018 AC_SUBST(LDFLAGS_CXX_JDK)
1019 ])
