Fri, 12 Jan 2018 17:51:58 -0800
Merge
1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64)
34 VAR_CPU=x86_64
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=64
37 VAR_CPU_ENDIAN=little
38 ;;
39 i?86)
40 VAR_CPU=x86
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=32
43 VAR_CPU_ENDIAN=little
44 ;;
45 arm*)
46 VAR_CPU=arm
47 VAR_CPU_ARCH=arm
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 aarch64)
52 VAR_CPU=aarch64
53 VAR_CPU_ARCH=aarch64
54 VAR_CPU_BITS=64
55 VAR_CPU_ENDIAN=little
56 ;;
57 powerpc)
58 VAR_CPU=ppc
59 VAR_CPU_ARCH=ppc
60 VAR_CPU_BITS=32
61 VAR_CPU_ENDIAN=big
62 ;;
63 powerpc64)
64 VAR_CPU=ppc64
65 VAR_CPU_ARCH=ppc
66 VAR_CPU_BITS=64
67 VAR_CPU_ENDIAN=big
68 ;;
69 powerpc64le)
70 VAR_CPU=ppc64
71 VAR_CPU_ARCH=ppc
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=little
74 ;;
75 s390)
76 VAR_CPU=s390
77 VAR_CPU_ARCH=s390
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 s390x)
82 VAR_CPU=s390x
83 VAR_CPU_ARCH=s390
84 VAR_CPU_BITS=64
85 VAR_CPU_ENDIAN=big
86 ;;
87 sparc)
88 VAR_CPU=sparc
89 VAR_CPU_ARCH=sparc
90 VAR_CPU_BITS=32
91 VAR_CPU_ENDIAN=big
92 ;;
93 sparcv9|sparc64)
94 VAR_CPU=sparcv9
95 VAR_CPU_ARCH=sparc
96 VAR_CPU_BITS=64
97 VAR_CPU_ENDIAN=big
98 ;;
99 *)
100 AC_MSG_ERROR([unsupported cpu $1])
101 ;;
102 esac
103 ])
105 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
106 # Converts autoconf style OS name to OpenJDK style, into
107 # VAR_OS and VAR_OS_API.
108 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
109 [
110 case "$1" in
111 *linux*)
112 VAR_OS=linux
113 VAR_OS_API=posix
114 VAR_OS_ENV=linux
115 ;;
116 *solaris*)
117 VAR_OS=solaris
118 VAR_OS_API=posix
119 VAR_OS_ENV=solaris
120 ;;
121 *darwin*)
122 VAR_OS=macosx
123 VAR_OS_API=posix
124 VAR_OS_ENV=macosx
125 ;;
126 *bsd*)
127 VAR_OS=bsd
128 VAR_OS_API=posix
129 VAR_OS_ENV=bsd
130 ;;
131 *cygwin*)
132 VAR_OS=windows
133 VAR_OS_API=winapi
134 VAR_OS_ENV=windows.cygwin
135 ;;
136 *mingw*)
137 VAR_OS=windows
138 VAR_OS_API=winapi
139 VAR_OS_ENV=windows.msys
140 ;;
141 *aix*)
142 VAR_OS=aix
143 VAR_OS_API=posix
144 VAR_OS_ENV=aix
145 ;;
146 *)
147 AC_MSG_ERROR([unsupported operating system $1])
148 ;;
149 esac
150 ])
152 # Expects $host_os $host_cpu $build_os and $build_cpu
153 # and $with_target_bits to have been setup!
154 #
155 # Translate the standard triplet(quadruplet) definition
156 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
157 # OPENJDK_BUILD_OS, etc.
158 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
159 [
160 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
161 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
162 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
163 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
164 OPENJDK_TARGET_AUTOCONF_NAME="$host"
165 OPENJDK_BUILD_AUTOCONF_NAME="$build"
166 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
167 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
169 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
170 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
171 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
172 # ..and setup our own variables. (Do this explicitely to facilitate searching)
173 OPENJDK_BUILD_OS="$VAR_OS"
174 OPENJDK_BUILD_OS_API="$VAR_OS_API"
175 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
176 OPENJDK_BUILD_CPU="$VAR_CPU"
177 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
178 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
179 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
180 AC_SUBST(OPENJDK_BUILD_OS)
181 AC_SUBST(OPENJDK_BUILD_OS_API)
182 AC_SUBST(OPENJDK_BUILD_CPU)
183 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
184 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
185 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
187 AC_MSG_CHECKING([openjdk-build os-cpu])
188 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
190 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
191 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
192 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
193 # ... and setup our own variables. (Do this explicitely to facilitate searching)
194 OPENJDK_TARGET_OS="$VAR_OS"
195 OPENJDK_TARGET_OS_API="$VAR_OS_API"
196 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
197 OPENJDK_TARGET_CPU="$VAR_CPU"
198 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
199 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
200 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
201 AC_SUBST(OPENJDK_TARGET_OS)
202 AC_SUBST(OPENJDK_TARGET_OS_API)
203 AC_SUBST(OPENJDK_TARGET_CPU)
204 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
205 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
206 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
208 AC_MSG_CHECKING([openjdk-target os-cpu])
209 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
210 ])
212 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
213 # accordingly. Must be done after setting up build and target system, but before
214 # doing anything else with these values.
215 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
216 [
217 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
218 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
220 # We have three types of compiles:
221 # native == normal compilation, target system == build system
222 # cross == traditional cross compilation, target system != build system; special toolchain needed
223 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
224 #
225 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
226 # We're doing a proper cross-compilation
227 COMPILE_TYPE="cross"
228 else
229 COMPILE_TYPE="native"
230 fi
232 if test "x$with_target_bits" != x; then
233 if test "x$COMPILE_TYPE" = "xcross"; then
234 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
235 fi
237 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
238 # A reduced build is requested
239 COMPILE_TYPE="reduced"
240 OPENJDK_TARGET_CPU_BITS=32
241 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
242 OPENJDK_TARGET_CPU=x86
243 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
244 OPENJDK_TARGET_CPU=sparc
245 else
246 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
247 fi
248 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
249 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
250 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
251 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
252 else
253 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
254 fi
255 fi
256 AC_SUBST(COMPILE_TYPE)
258 AC_MSG_CHECKING([compilation type])
259 AC_MSG_RESULT([$COMPILE_TYPE])
260 ])
262 # Setup the legacy variables, for controlling the old makefiles.
263 #
264 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
265 [
266 # Also store the legacy naming of the cpu.
267 # Ie i586 and amd64 instead of x86 and x86_64
268 OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"
269 if test "x$OPENJDK_TARGET_CPU" = xx86; then
270 OPENJDK_TARGET_CPU_LEGACY="i586"
271 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
272 # On all platforms except MacOSX replace x86_64 with amd64.
273 OPENJDK_TARGET_CPU_LEGACY="amd64"
274 fi
275 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)
277 # And the second legacy naming of the cpu.
278 # Ie i386 and amd64 instead of x86 and x86_64.
279 OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"
280 if test "x$OPENJDK_TARGET_CPU" = xx86; then
281 OPENJDK_TARGET_CPU_LEGACY_LIB="i386"
282 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
283 OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"
284 fi
285 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)
287 # This is the name of the cpu (but using i386 and amd64 instead of
288 # x86 and x86_64, respectively), preceeded by a /, to be used when
289 # locating libraries. On macosx, it's empty, though.
290 OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"
291 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
292 OPENJDK_TARGET_CPU_LIBDIR=""
293 fi
294 AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)
296 # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
297 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
298 # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so
299 OPENJDK_TARGET_CPU_ISADIR=""
300 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
301 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
302 OPENJDK_TARGET_CPU_ISADIR="/amd64"
303 elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then
304 OPENJDK_TARGET_CPU_ISADIR="/sparcv9"
305 fi
306 fi
307 AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)
309 # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property
310 OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"
311 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then
312 # On linux only, we replace x86 with i386.
313 OPENJDK_TARGET_CPU_OSARCH="i386"
314 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
315 # On all platforms except macosx, we replace x86_64 with amd64.
316 OPENJDK_TARGET_CPU_OSARCH="amd64"
317 fi
318 AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)
320 OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"
321 if test "x$OPENJDK_TARGET_CPU" = xx86; then
322 OPENJDK_TARGET_CPU_JLI="i386"
323 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
324 # On all platforms except macosx, we replace x86_64 with amd64.
325 OPENJDK_TARGET_CPU_JLI="amd64"
326 fi
327 # Now setup the -D flags for building libjli.
328 OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"
329 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
330 if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then
331 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"
332 elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
333 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"
334 fi
335 fi
336 AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)
338 # Setup OPENJDK_TARGET_OS_API_DIR, used in source paths.
339 if test "x$OPENJDK_TARGET_OS_API" = xposix; then
340 OPENJDK_TARGET_OS_API_DIR="solaris"
341 fi
342 if test "x$OPENJDK_TARGET_OS_API" = xwinapi; then
343 OPENJDK_TARGET_OS_API_DIR="windows"
344 fi
345 AC_SUBST(OPENJDK_TARGET_OS_API_DIR)
347 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
348 OPENJDK_TARGET_OS_EXPORT_DIR=macosx
349 else
350 OPENJDK_TARGET_OS_EXPORT_DIR=${OPENJDK_TARGET_OS_API_DIR}
351 fi
352 AC_SUBST(OPENJDK_TARGET_OS_EXPORT_DIR)
354 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
355 A_LP64="LP64:="
356 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
357 # unpack200.exe
358 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then
359 ADD_LP64="-D_LP64=1"
360 fi
361 fi
362 AC_SUBST(LP64,$A_LP64)
364 if test "x$COMPILE_TYPE" = "xcross"; then
365 # FIXME: ... or should this include reduced builds..?
366 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"
367 else
368 DEFINE_CROSS_COMPILE_ARCH=""
369 fi
370 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
372 # ZERO_ARCHDEF is used to enable architecture-specific code
373 case "${OPENJDK_TARGET_CPU}" in
374 ppc) ZERO_ARCHDEF=PPC32 ;;
375 ppc64) ZERO_ARCHDEF=PPC64 ;;
376 s390*) ZERO_ARCHDEF=S390 ;;
377 sparc*) ZERO_ARCHDEF=SPARC ;;
378 x86_64*) ZERO_ARCHDEF=AMD64 ;;
379 x86) ZERO_ARCHDEF=IA32 ;;
380 *) ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)
381 esac
382 AC_SUBST(ZERO_ARCHDEF)
383 ])
385 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
386 [
387 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
388 REQUIRED_OS_NAME=SunOS
389 REQUIRED_OS_VERSION=5.10
390 fi
391 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
392 REQUIRED_OS_NAME=Linux
393 REQUIRED_OS_VERSION=2.6
394 fi
395 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
396 REQUIRED_OS_NAME=Windows
397 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
398 REQUIRED_OS_VERSION=5.2
399 else
400 REQUIRED_OS_VERSION=5.1
401 fi
402 fi
403 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
404 REQUIRED_OS_NAME=Darwin
405 REQUIRED_OS_VERSION=11.2
406 fi
408 AC_SUBST(REQUIRED_OS_NAME)
409 AC_SUBST(REQUIRED_OS_VERSION)
410 ])
412 #%%% Build and target systems %%%
413 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
414 [
415 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
416 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
417 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
418 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
419 # to use the configure naming style.
420 AC_CANONICAL_BUILD
421 AC_CANONICAL_HOST
422 AC_CANONICAL_TARGET
424 PLATFORM_EXTRACT_TARGET_AND_BUILD
425 PLATFORM_SETUP_TARGET_CPU_BITS
426 PLATFORM_SET_RELEASE_FILE_OS_VALUES
427 PLATFORM_SETUP_LEGACY_VARS
428 ])
430 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
431 [
432 ###############################################################################
434 # Note that this is the build platform OS version!
436 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
437 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
438 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
439 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
440 AC_SUBST(OS_VERSION_MAJOR)
441 AC_SUBST(OS_VERSION_MINOR)
442 AC_SUBST(OS_VERSION_MICRO)
443 ])
445 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
446 # Add -mX to various FLAGS variables.
447 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
448 [
449 # When we add flags to the "official" CFLAGS etc, we need to
450 # keep track of these additions in ADDED_CFLAGS etc. These
451 # will later be checked to make sure only controlled additions
452 # have been made to CFLAGS etc.
453 ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
454 ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
455 ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
457 CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
458 CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
459 LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
461 CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
462 CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
463 LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
464 ])
466 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
467 [
468 ###############################################################################
469 #
470 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
471 # (The JVM can use 32 or 64 bit Java pointers but that decision
472 # is made at runtime.)
473 #
475 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
476 # Always specify -m flag on Solaris
477 # And -q on AIX because otherwise the compiler produces 32-bit objects by default
478 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
479 elif test "x$COMPILE_TYPE" = xreduced; then
480 if test "x$OPENJDK_TARGET_OS" != xwindows; then
481 # Specify -m if running reduced on other Posix platforms
482 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
483 fi
484 fi
486 # Make compilation sanity check
487 AC_CHECK_HEADERS([stdio.h], , [
488 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
489 if test "x$COMPILE_TYPE" = xreduced; then
490 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed.])
491 elif test "x$COMPILE_TYPE" = xcross; then
492 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
493 fi
494 AC_MSG_ERROR([Cannot continue.])
495 ])
497 AC_CHECK_SIZEOF([int *], [1111])
499 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
500 if test "x$ac_cv_sizeof_int_p" = x; then
501 # The test failed, lets stick to the assumed value.
502 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
503 else
504 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
506 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
507 # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
508 # Let's try to implicitely set the compilers target architecture and retry the test
509 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
510 AC_MSG_NOTICE([I'll retry after setting the platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
511 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
513 # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
514 unset ac_cv_sizeof_int_p
515 # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
516 cat >>confdefs.h <<_ACEOF
517 #undef SIZEOF_INT_P
518 _ACEOF
520 AC_CHECK_SIZEOF([int *], [1111])
522 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
524 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
525 AC_MSG_ERROR([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
526 fi
527 fi
528 fi
530 AC_MSG_CHECKING([for target address size])
531 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
532 ])
534 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
535 [
536 ###############################################################################
537 #
538 # Is the target little of big endian?
539 #
540 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
542 if test "x$ENDIAN" = xuniversal_endianness; then
543 AC_MSG_ERROR([Building with both big and little endianness is not supported])
544 fi
545 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
546 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
547 fi
548 ])