Fri, 12 Jan 2018 17:51:58 -0800
Merge
1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
27 # If so, then append $1 to $2 \
28 # Also set JVM_ARG_OK to true/false depending on outcome.
29 AC_DEFUN([ADD_JVM_ARG_IF_OK],
30 [
31 $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD
32 $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD
33 OUTPUT=`$3 $1 -version 2>&1`
34 FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`
35 FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`
36 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
37 $2="[$]$2 $1"
38 JVM_ARG_OK=true
39 else
40 $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD
41 $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD
42 JVM_ARG_OK=false
43 fi
44 ])
46 # Appends a string to a path variable, only adding the : when needed.
47 AC_DEFUN([BASIC_APPEND_TO_PATH],
48 [
49 if test "x[$]$1" = x; then
50 $1="$2"
51 else
52 $1="[$]$1:$2"
53 fi
54 ])
56 # This will make sure the given variable points to a full and proper
57 # path. This means:
58 # 1) There will be no spaces in the path. On posix platforms,
59 # spaces in the path will result in an error. On Windows,
60 # the path will be rewritten using short-style to be space-free.
61 # 2) The path will be absolute, and it will be in unix-style (on
62 # cygwin).
63 # $1: The name of the variable to fix
64 AC_DEFUN([BASIC_FIXUP_PATH],
65 [
66 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
67 BASIC_FIXUP_PATH_CYGWIN($1)
68 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
69 BASIC_FIXUP_PATH_MSYS($1)
70 else
71 # We're on a posix platform. Hooray! :)
72 path="[$]$1"
73 has_space=`$ECHO "$path" | $GREP " "`
74 if test "x$has_space" != x; then
75 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
76 AC_MSG_ERROR([Spaces are not allowed in this path.])
77 fi
79 # Use eval to expand a potential ~
80 eval path="$path"
81 if test ! -f "$path" && test ! -d "$path"; then
82 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
83 fi
85 $1="`cd "$path"; $THEPWDCMD -L`"
86 fi
87 ])
89 # This will make sure the given variable points to a executable
90 # with a full and proper path. This means:
91 # 1) There will be no spaces in the path. On posix platforms,
92 # spaces in the path will result in an error. On Windows,
93 # the path will be rewritten using short-style to be space-free.
94 # 2) The path will be absolute, and it will be in unix-style (on
95 # cygwin).
96 # Any arguments given to the executable is preserved.
97 # If the input variable does not have a directory specification, then
98 # it need to be in the PATH.
99 # $1: The name of the variable to fix
100 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
101 [
102 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
103 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
104 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
105 BASIC_FIXUP_EXECUTABLE_MSYS($1)
106 else
107 # We're on a posix platform. Hooray! :)
108 # First separate the path from the arguments. This will split at the first
109 # space.
110 complete="[$]$1"
111 path="${complete%% *}"
112 tmp="$complete EOL"
113 arguments="${tmp#* }"
115 # Cannot rely on the command "which" here since it doesn't always work.
116 is_absolute_path=`$ECHO "$path" | $GREP ^/`
117 if test -z "$is_absolute_path"; then
118 # Path to executable is not absolute. Find it.
119 IFS_save="$IFS"
120 IFS=:
121 for p in $PATH; do
122 if test -f "$p/$path" && test -x "$p/$path"; then
123 new_path="$p/$path"
124 break
125 fi
126 done
127 IFS="$IFS_save"
128 else
129 AC_MSG_NOTICE([Resolving $1 (as $path) failed, using $path directly.])
130 new_path="$path"
131 fi
133 if test "x$new_path" = x; then
134 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
135 has_space=`$ECHO "$complete" | $GREP " "`
136 if test "x$has_space" != x; then
137 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
138 fi
139 AC_MSG_ERROR([Cannot locate the the path of $1])
140 fi
141 fi
143 # Now join together the path and the arguments once again
144 if test "x$arguments" != xEOL; then
145 new_complete="$new_path ${arguments% *}"
146 else
147 new_complete="$new_path"
148 fi
150 if test "x$complete" != "x$new_complete"; then
151 $1="$new_complete"
152 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
153 fi
154 ])
156 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
157 [
158 if test "x$OPENJDK_BUILD_OS" != xwindows; then
159 # Follow a chain of symbolic links. Use readlink
160 # where it exists, else fall back to horribly
161 # complicated shell code.
162 if test "x$READLINK_TESTED" != yes; then
163 # On MacOSX there is a readlink tool with a different
164 # purpose than the GNU readlink tool. Check the found readlink.
165 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
166 if test "x$ISGNU" = x; then
167 # A readlink that we do not know how to use.
168 # Are there other non-GNU readlinks out there?
169 READLINK_TESTED=yes
170 READLINK=
171 fi
172 fi
174 if test "x$READLINK" != x; then
175 $1=`$READLINK -f [$]$1`
176 else
177 # Save the current directory for restoring afterwards
178 STARTDIR=$PWD
179 COUNTER=0
180 sym_link_dir=`$DIRNAME [$]$1`
181 sym_link_file=`$BASENAME [$]$1`
182 cd $sym_link_dir
183 # Use -P flag to resolve symlinks in directories.
184 cd `$THEPWDCMD -P`
185 sym_link_dir=`$THEPWDCMD -P`
186 # Resolve file symlinks
187 while test $COUNTER -lt 20; do
188 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
189 if test "x$ISLINK" == x; then
190 # This is not a symbolic link! We are done!
191 break
192 fi
193 # Again resolve directory symlinks since the target of the just found
194 # link could be in a different directory
195 cd `$DIRNAME $ISLINK`
196 sym_link_dir=`$THEPWDCMD -P`
197 sym_link_file=`$BASENAME $ISLINK`
198 let COUNTER=COUNTER+1
199 done
200 cd $STARTDIR
201 $1=$sym_link_dir/$sym_link_file
202 fi
203 fi
204 ])
206 # Register a --with argument but mark it as deprecated
207 # $1: The name of the with argument to deprecate, not including --with-
208 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],
209 [
210 AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],
211 [Deprecated. Option is kept for backwards compatibility and is ignored])],
212 [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])
213 ])
215 # Register a --enable argument but mark it as deprecated
216 # $1: The name of the with argument to deprecate, not including --enable-
217 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)
218 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],
219 [
220 AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],
221 [Deprecated. Option is kept for backwards compatibility and is ignored])])
222 if test "x$enable_$2" != x; then
223 AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])
224 fi
225 ])
227 AC_DEFUN_ONCE([BASIC_INIT],
228 [
229 # Save the original command line. This is passed to us by the wrapper configure script.
230 AC_SUBST(CONFIGURE_COMMAND_LINE)
231 DATE_WHEN_CONFIGURED=`LANG=C date`
232 AC_SUBST(DATE_WHEN_CONFIGURED)
233 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
234 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
235 ])
237 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
238 # $1: variable to check
239 # $2: executable name to print in warning (optional)
240 AC_DEFUN([BASIC_CHECK_NONEMPTY],
241 [
242 if test "x[$]$1" = x; then
243 if test "x$2" = x; then
244 PROG_NAME=translit($1,A-Z,a-z)
245 else
246 PROG_NAME=$2
247 fi
248 AC_MSG_NOTICE([Could not find $PROG_NAME!])
249 AC_MSG_ERROR([Cannot continue])
250 fi
251 ])
253 # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.
254 # Arguments as AC_PATH_PROG:
255 # $1: variable to set
256 # $2: executable name to look for
257 AC_DEFUN([BASIC_REQUIRE_PROG],
258 [
259 AC_PATH_PROGS($1, $2)
260 BASIC_CHECK_NONEMPTY($1, $2)
261 ])
263 # Setup the most fundamental tools that relies on not much else to set up,
264 # but is used by much of the early bootstrap code.
265 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
266 [
268 # Start with tools that do not need have cross compilation support
269 # and can be expected to be found in the default PATH. These tools are
270 # used by configure. Nor are these tools expected to be found in the
271 # devkit from the builddeps server either, since they are
272 # needed to download the devkit.
274 # First are all the simple required tools.
275 BASIC_REQUIRE_PROG(BASENAME, basename)
276 BASIC_REQUIRE_PROG(BASH, bash)
277 BASIC_REQUIRE_PROG(CAT, cat)
278 BASIC_REQUIRE_PROG(CHMOD, chmod)
279 BASIC_REQUIRE_PROG(CMP, cmp)
280 BASIC_REQUIRE_PROG(COMM, comm)
281 BASIC_REQUIRE_PROG(CP, cp)
282 BASIC_REQUIRE_PROG(CPIO, cpio)
283 BASIC_REQUIRE_PROG(CUT, cut)
284 BASIC_REQUIRE_PROG(DATE, date)
285 BASIC_REQUIRE_PROG(DIFF, [gdiff diff])
286 BASIC_REQUIRE_PROG(DIRNAME, dirname)
287 BASIC_REQUIRE_PROG(ECHO, echo)
288 BASIC_REQUIRE_PROG(EXPR, expr)
289 BASIC_REQUIRE_PROG(FILE, file)
290 BASIC_REQUIRE_PROG(FIND, find)
291 BASIC_REQUIRE_PROG(HEAD, head)
292 BASIC_REQUIRE_PROG(LN, ln)
293 BASIC_REQUIRE_PROG(LS, ls)
294 BASIC_REQUIRE_PROG(MKDIR, mkdir)
295 BASIC_REQUIRE_PROG(MKTEMP, mktemp)
296 BASIC_REQUIRE_PROG(MV, mv)
297 BASIC_REQUIRE_PROG(PRINTF, printf)
298 BASIC_REQUIRE_PROG(RM, rm)
299 BASIC_REQUIRE_PROG(SH, sh)
300 BASIC_REQUIRE_PROG(SORT, sort)
301 BASIC_REQUIRE_PROG(TAIL, tail)
302 BASIC_REQUIRE_PROG(TAR, tar)
303 BASIC_REQUIRE_PROG(TEE, tee)
304 BASIC_REQUIRE_PROG(TOUCH, touch)
305 BASIC_REQUIRE_PROG(TR, tr)
306 BASIC_REQUIRE_PROG(UNAME, uname)
307 BASIC_REQUIRE_PROG(UNIQ, uniq)
308 BASIC_REQUIRE_PROG(WC, wc)
309 BASIC_REQUIRE_PROG(WHICH, which)
310 BASIC_REQUIRE_PROG(XARGS, xargs)
312 # Then required tools that require some special treatment.
313 AC_PROG_AWK
314 BASIC_CHECK_NONEMPTY(AWK)
315 AC_PROG_GREP
316 BASIC_CHECK_NONEMPTY(GREP)
317 AC_PROG_EGREP
318 BASIC_CHECK_NONEMPTY(EGREP)
319 AC_PROG_FGREP
320 BASIC_CHECK_NONEMPTY(FGREP)
321 AC_PROG_SED
322 BASIC_CHECK_NONEMPTY(SED)
324 AC_PATH_PROGS(NAWK, [nawk gawk awk])
325 BASIC_CHECK_NONEMPTY(NAWK)
327 # Always force rm.
328 RM="$RM -f"
330 # pwd behaves differently on various platforms and some don't support the -L flag.
331 # Always use the bash builtin pwd to get uniform behavior.
332 THEPWDCMD=pwd
334 # These are not required on all platforms
335 AC_PATH_PROG(CYGPATH, cygpath)
336 AC_PATH_PROG(READLINK, readlink)
337 AC_PATH_PROG(DF, df)
338 AC_PATH_PROG(SETFILE, SetFile)
339 ])
341 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
342 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
343 [
344 # Locate the directory of this script.
345 SCRIPT="[$]0"
346 AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD -L`
348 # Where is the source? It is located two levels above the configure script.
349 CURDIR="$PWD"
350 cd "$AUTOCONF_DIR/../.."
351 SRC_ROOT="`$THEPWDCMD -L`"
353 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
354 PATH_SEP=";"
355 BASIC_CHECK_PATHS_WINDOWS
356 else
357 PATH_SEP=":"
358 fi
360 AC_SUBST(SRC_ROOT)
361 AC_SUBST(PATH_SEP)
362 cd "$CURDIR"
364 BASIC_FIXUP_PATH(SRC_ROOT)
365 BASIC_FIXUP_PATH(CURDIR)
367 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
368 # Add extra search paths on solaris for utilities like ar and as etc...
369 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
370 fi
372 # You can force the sys-root if the sys-root encoded into the cross compiler tools
373 # is not correct.
374 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
375 [pass this sys-root to the compilers and tools (for cross-compiling)])])
377 if test "x$with_sys_root" != x; then
378 SYS_ROOT=$with_sys_root
379 else
380 SYS_ROOT=/
381 fi
382 AC_SUBST(SYS_ROOT)
384 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
385 [search this directory for compilers and tools (for cross-compiling)])],
386 [TOOLS_DIR=$with_tools_dir]
387 )
389 # Xcode version will be validated later
390 AC_ARG_WITH([xcode-path], [AS_HELP_STRING([--with-xcode-path],
391 [explicit path to Xcode 4 (generally for building on 10.9 and later)])],
392 [XCODE_PATH=$with_xcode_path]
393 )
395 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
396 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
397 [
398 if test "x$with_sys_root" != x; then
399 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
400 fi
401 BASIC_FIXUP_PATH([with_devkit])
402 BASIC_APPEND_TO_PATH([TOOLS_DIR],$with_devkit/bin)
403 if test -d "$with_devkit/$host_alias/libc"; then
404 SYS_ROOT=$with_devkit/$host_alias/libc
405 elif test -d "$with_devkit/$host/sys-root"; then
406 SYS_ROOT=$with_devkit/$host/sys-root
407 fi
408 ])
409 ])
411 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
412 [
414 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
415 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
416 [ CONF_NAME=${with_conf_name} ])
418 # Test from where we are running configure, in or outside of src root.
419 if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \
420 || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \
421 || test "x$CURDIR" = "x$SRC_ROOT/make" ; then
422 # We are running configure from the src root.
423 # Create a default ./build/target-variant-debuglevel output root.
424 if test "x${CONF_NAME}" = x; then
425 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
426 fi
427 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
428 $MKDIR -p "$OUTPUT_ROOT"
429 if test ! -d "$OUTPUT_ROOT"; then
430 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
431 fi
432 else
433 # We are running configure from outside of the src dir.
434 # Then use the current directory as output dir!
435 # If configuration is situated in normal build directory, just use the build
436 # directory name as configuration name, otherwise use the complete path.
437 if test "x${CONF_NAME}" = x; then
438 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
439 fi
440 OUTPUT_ROOT="$CURDIR"
442 # WARNING: This might be a bad thing to do. You need to be sure you want to
443 # have a configuration in this directory. Do some sanity checks!
445 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
446 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
447 # other files
448 files_present=`$LS $OUTPUT_ROOT`
449 # Configure has already touched config.log and confdefs.h in the current dir when this check
450 # is performed.
451 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
452 | $TR -d '\n'`
453 if test "x$filtered_files" != x; then
454 AC_MSG_NOTICE([Current directory is $CURDIR.])
455 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
456 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
457 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
458 AC_MSG_NOTICE([seriously mess up just about everything.])
459 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
460 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
461 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
462 fi
463 fi
464 fi
465 AC_MSG_CHECKING([what configuration name to use])
466 AC_MSG_RESULT([$CONF_NAME])
468 BASIC_FIXUP_PATH(OUTPUT_ROOT)
470 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
471 AC_SUBST(CONF_NAME, $CONF_NAME)
472 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
474 # Most of the probed defines are put into config.h
475 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
476 # The spec.gmk file contains all variables for the make system.
477 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
478 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
479 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
480 # The bootcycle-spec.gmk file contains support for boot cycle builds.
481 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
482 # The compare.sh is used to compare the build output to other builds.
483 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
484 # Spec.sh is currently used by compare-objects.sh
485 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
486 # The generated Makefile knows where the spec.gmk is and where the source is.
487 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
488 # which will look for generated configurations
489 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
491 # Save the arguments given to us
492 echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
493 ])
495 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
496 [
497 # Setup default logging of stdout and stderr to build.log in the output root.
498 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
499 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
500 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
501 AC_SUBST(BUILD_LOG)
502 AC_SUBST(BUILD_LOG_PREVIOUS)
503 AC_SUBST(BUILD_LOG_WRAPPER)
504 ])
507 #%%% Simple tools %%%
509 # Check if we have found a usable version of make
510 # $1: the path to a potential make binary (or empty)
511 # $2: the description on how we found this
512 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
513 [
514 MAKE_CANDIDATE="$1"
515 DESCRIPTION="$2"
516 if test "x$MAKE_CANDIDATE" != x; then
517 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
518 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
519 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
520 if test "x$IS_GNU_MAKE" = x; then
521 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
522 else
523 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP -e '3\.8[[12]]' -e '4\.'`
524 if test "x$IS_MODERN_MAKE" = x; then
525 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
526 else
527 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
528 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
529 MAKE_EXPECTED_ENV='cygwin'
530 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
531 MAKE_EXPECTED_ENV='msys'
532 else
533 AC_MSG_ERROR([Unknown Windows environment])
534 fi
535 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
536 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
537 else
538 # Not relevant for non-Windows
539 IS_MAKE_CORRECT_ENV=true
540 fi
541 if test "x$IS_MAKE_CORRECT_ENV" = x; then
542 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
543 else
544 FOUND_MAKE=$MAKE_CANDIDATE
545 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
546 fi
547 fi
548 fi
549 fi
550 ])
552 # Goes looking for a usable version of GNU make.
553 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
554 [
555 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
556 if test "x$MAKE" != x; then
557 # User has supplied a make, test it.
558 if test ! -f "$MAKE"; then
559 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
560 fi
561 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
562 if test "x$FOUND_MAKE" = x; then
563 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
564 fi
565 else
566 # Try our hardest to locate a correct version of GNU make
567 AC_PATH_PROGS(CHECK_GMAKE, gmake)
568 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
570 if test "x$FOUND_MAKE" = x; then
571 AC_PATH_PROGS(CHECK_MAKE, make)
572 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
573 fi
575 if test "x$FOUND_MAKE" = x; then
576 if test "x$TOOLS_DIR" != x; then
577 # We have a tools-dir, check that as well before giving up.
578 OLD_PATH=$PATH
579 PATH=$TOOLS_DIR:$PATH
580 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
581 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
582 if test "x$FOUND_MAKE" = x; then
583 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
584 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
585 fi
586 PATH=$OLD_PATH
587 fi
588 fi
590 if test "x$FOUND_MAKE" = x; then
591 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
592 fi
593 fi
595 MAKE=$FOUND_MAKE
596 AC_SUBST(MAKE)
597 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
598 ])
600 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
601 [
602 # Test if find supports -delete
603 AC_MSG_CHECKING([if find supports -delete])
604 FIND_DELETE="-delete"
606 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
608 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
610 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
611 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
612 # No, it does not.
613 rm $DELETEDIR/TestIfFindSupportsDelete
614 FIND_DELETE="-exec rm \{\} \+"
615 AC_MSG_RESULT([no])
616 else
617 AC_MSG_RESULT([yes])
618 fi
619 rmdir $DELETEDIR
620 AC_SUBST(FIND_DELETE)
621 ])
623 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
624 [
625 BASIC_CHECK_GNU_MAKE
627 BASIC_CHECK_FIND_DELETE
629 # These tools might not be installed by default,
630 # need hint on how to install them.
631 BASIC_REQUIRE_PROG(UNZIP, unzip)
632 BASIC_REQUIRE_PROG(ZIP, zip)
634 # Non-required basic tools
636 AC_PATH_PROG(LDD, ldd)
637 if test "x$LDD" = "x"; then
638 # List shared lib dependencies is used for
639 # debug output and checking for forbidden dependencies.
640 # We can build without it.
641 LDD="true"
642 fi
643 AC_PATH_PROGS(READELF, [readelf greadelf])
644 AC_PATH_PROG(HG, hg)
645 AC_PATH_PROG(STAT, stat)
646 AC_PATH_PROG(TIME, time)
647 # Check if it's GNU time
648 IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`
649 if test "x$IS_GNU_TIME" != x; then
650 IS_GNU_TIME=yes
651 else
652 IS_GNU_TIME=no
653 fi
654 AC_SUBST(IS_GNU_TIME)
656 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
657 BASIC_REQUIRE_PROG(COMM, comm)
658 fi
660 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
661 BASIC_REQUIRE_PROG(DSYMUTIL, dsymutil)
662 BASIC_REQUIRE_PROG(XATTR, xattr)
663 AC_PATH_PROG(CODESIGN, codesign)
664 if test "x$CODESIGN" != "x"; then
665 # Verify that the openjdk_codesign certificate is present
666 AC_MSG_CHECKING([if openjdk_codesign certificate is present])
667 rm -f codesign-testfile
668 touch codesign-testfile
669 codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=
670 rm -f codesign-testfile
671 if test "x$CODESIGN" = x; then
672 AC_MSG_RESULT([no])
673 else
674 AC_MSG_RESULT([yes])
675 fi
676 fi
677 fi
678 ])
680 # Check if build directory is on local disk. If not possible to determine,
681 # we prefer to claim it's local.
682 # Argument 1: directory to test
683 # Argument 2: what to do if it is on local disk
684 # Argument 3: what to do otherwise (remote disk or failure)
685 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
686 [
687 # df -l lists only local disks; if the given directory is not found then
688 # a non-zero exit code is given
689 if test "x$DF" = x; then
690 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
691 # msys does not have df; use Windows "net use" instead.
692 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
693 if test "x$IS_NETWORK_DISK" = x; then
694 $2
695 else
696 $3
697 fi
698 else
699 # No df here, say it's local
700 $2
701 fi
702 else
703 if $DF -l $1 > /dev/null 2>&1; then
704 $2
705 else
706 $3
707 fi
708 fi
709 ])
711 # Check that source files have basic read permissions set. This might
712 # not be the case in cygwin in certain conditions.
713 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],
714 [
715 if test x"$OPENJDK_BUILD_OS" = xwindows; then
716 file_to_test="$SRC_ROOT/LICENSE"
717 if test `$STAT -c '%a' "$file_to_test"` -lt 400; then
718 AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])
719 fi
720 fi
721 ])
723 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
724 [
725 AC_MSG_CHECKING([if build directory is on local disk])
726 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
727 [OUTPUT_DIR_IS_LOCAL="yes"],
728 [OUTPUT_DIR_IS_LOCAL="no"])
729 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
731 BASIC_CHECK_SRC_PERMS
733 # Check if the user has any old-style ALT_ variables set.
734 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
736 # Before generating output files, test if they exist. If they do, this is a reconfigure.
737 # Since we can't properly handle the dependencies for this, warn the user about the situation
738 if test -e $OUTPUT_ROOT/spec.gmk; then
739 IS_RECONFIGURE=yes
740 else
741 IS_RECONFIGURE=no
742 fi
744 if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then
745 HIDE_PERFORMANCE_HINTS=yes
746 else
747 HIDE_PERFORMANCE_HINTS=no
748 # Hide it the next time around...
749 $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1
750 fi
751 ])