jdk8-mips64-public: common/autoconf/platform.m4@584dc2e95e04

1 #

     2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.

    27 # Converts autoconf style CPU name to OpenJDK style, into

    28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.

    29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],

    30 [

    31   # First argument is the cpu name from the trip/quad

    32   case "$1" in

    33     x86_64)

    34       VAR_CPU=x86_64

    35       VAR_CPU_ARCH=x86

    36       VAR_CPU_BITS=64

    37       VAR_CPU_ENDIAN=little

    38       ;;

    39     i?86)

    40       VAR_CPU=x86

    41       VAR_CPU_ARCH=x86

    42       VAR_CPU_BITS=32

    43       VAR_CPU_ENDIAN=little

    44       ;;

    45     arm*)

    46       VAR_CPU=arm

    47       VAR_CPU_ARCH=arm

    48       VAR_CPU_BITS=32

    49       VAR_CPU_ENDIAN=little

    50       ;;

    51     powerpc)

    52       VAR_CPU=ppc

    53       VAR_CPU_ARCH=ppc

    54       VAR_CPU_BITS=32

    55       VAR_CPU_ENDIAN=big

    56        ;;

    57     powerpc64)

    58       VAR_CPU=ppc64

    59       VAR_CPU_ARCH=ppc

    60       VAR_CPU_BITS=64

    61       VAR_CPU_ENDIAN=big

    62        ;;

    63     sparc)

    64       VAR_CPU=sparc

    65       VAR_CPU_ARCH=sparc

    66       VAR_CPU_BITS=32

    67       VAR_CPU_ENDIAN=big

    68        ;;

    69     sparcv9)

    70       VAR_CPU=sparcv9

    71       VAR_CPU_ARCH=sparc

    72       VAR_CPU_BITS=64

    73       VAR_CPU_ENDIAN=big

    74        ;;

    75     *)

    76       AC_MSG_ERROR([unsupported cpu $1])

    77       ;;

    78   esac

    79 ])

    81 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.

    82 # Converts autoconf style OS name to OpenJDK style, into

    83 # VAR_OS and VAR_OS_API.

    84 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],

    85 [

    86   case "$1" in

    87     *linux*)

    88       VAR_OS=linux

    89       VAR_OS_API=posix

    90       VAR_OS_ENV=linux

    91       ;;

    92     *solaris*)

    93       VAR_OS=solaris

    94       VAR_OS_API=posix

    95       VAR_OS_ENV=solaris

    96       ;;

    97     *darwin*)

    98       VAR_OS=macosx

    99       VAR_OS_API=posix

   100       VAR_OS_ENV=macosx

   101       ;;

   102     *bsd*)

   103       VAR_OS=bsd

   104       VAR_OS_API=posix

   105       VAR_OS_ENV=bsd

   106       ;;

   107     *cygwin*)

   108       VAR_OS=windows

   109       VAR_OS_API=winapi

   110       VAR_OS_ENV=windows.cygwin

   111       ;;

   112     *mingw*)

   113       VAR_OS=windows

   114       VAR_OS_API=winapi

   115       VAR_OS_ENV=windows.msys

   116       ;;

   117     *aix*)

   118       VAR_OS=aix

   119       VAR_OS_API=posix

   120       VAR_OS_ENV=aix

   121       ;;

   122     *)

   123       AC_MSG_ERROR([unsupported operating system $1])

   124       ;;

   125   esac

   126 ])

   128 # Expects $host_os $host_cpu $build_os and $build_cpu

   129 # and $with_target_bits to have been setup!

   130 #

   131 # Translate the standard triplet(quadruplet) definition

   132 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,

   133 # OPENJDK_BUILD_OS, etc.

   134 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],

   135 [

   136     # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME

   137     # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME

   138     # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,

   139     # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.

   140     OPENJDK_TARGET_AUTOCONF_NAME="$host"

   141     OPENJDK_BUILD_AUTOCONF_NAME="$build"

   142     AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)

   143     AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)

   145     # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.

   146     PLATFORM_EXTRACT_VARS_FROM_OS($build_os)

   147     PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)

   148     # ..and setup our own variables. (Do this explicitely to facilitate searching)

   149     OPENJDK_BUILD_OS="$VAR_OS"

   150     OPENJDK_BUILD_OS_API="$VAR_OS_API"

   151     OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"

   152     OPENJDK_BUILD_CPU="$VAR_CPU"

   153     OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"

   154     OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"

   155     OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"

   156     AC_SUBST(OPENJDK_BUILD_OS)

   157     AC_SUBST(OPENJDK_BUILD_OS_API)

   158     AC_SUBST(OPENJDK_BUILD_CPU)

   159     AC_SUBST(OPENJDK_BUILD_CPU_ARCH)

   160     AC_SUBST(OPENJDK_BUILD_CPU_BITS)

   161     AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)

   163     AC_MSG_CHECKING([openjdk-build os-cpu])

   164     AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])

   166     # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.

   167     PLATFORM_EXTRACT_VARS_FROM_OS($host_os)

   168     PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)

   169     # ... and setup our own variables. (Do this explicitely to facilitate searching)

   170     OPENJDK_TARGET_OS="$VAR_OS"

   171     OPENJDK_TARGET_OS_API="$VAR_OS_API"

   172     OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"

   173     OPENJDK_TARGET_CPU="$VAR_CPU"

   174     OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"

   175     OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"

   176     OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"

   177     AC_SUBST(OPENJDK_TARGET_OS)

   178     AC_SUBST(OPENJDK_TARGET_OS_API)

   179     AC_SUBST(OPENJDK_TARGET_CPU)

   180     AC_SUBST(OPENJDK_TARGET_CPU_ARCH)

   181     AC_SUBST(OPENJDK_TARGET_CPU_BITS)

   182     AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)

   184     AC_MSG_CHECKING([openjdk-target os-cpu])

   185     AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])

   186 ])

   188 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour

   189 # accordingly. Must be done after setting up build and target system, but before

   190 # doing anything else with these values.

   191 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],

   192 [

   193   AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],

   194      [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])

   196   # We have three types of compiles:

   197   # native  == normal compilation, target system == build system

   198   # cross   == traditional cross compilation, target system != build system; special toolchain needed

   199   # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines

   200   #

   201   if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then

   202     # We're doing a proper cross-compilation

   203     COMPILE_TYPE="cross"

   204   else

   205     COMPILE_TYPE="native"

   206   fi

   208   if test "x$with_target_bits" != x; then

   209     if test "x$COMPILE_TYPE" = "xcross"; then

   210       AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])

   211     fi

   213     if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   214       # A reduced build is requested

   215       COMPILE_TYPE="reduced"

   216       OPENJDK_TARGET_CPU_BITS=32

   217       if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then

   218         OPENJDK_TARGET_CPU=x86

   219       elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then

   220         OPENJDK_TARGET_CPU=sparc

   221       else

   222         AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])

   223       fi

   224     elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then

   225       AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])

   226     elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then

   227       AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])

   228     else

   229       AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])

   230     fi

   231   fi

   232   AC_SUBST(COMPILE_TYPE)

   234 AC_MSG_CHECKING([compilation type])

   235 AC_MSG_RESULT([$COMPILE_TYPE])

   236 ])

   238     # Setup the legacy variables, for controlling the old makefiles.

   239     #

   240 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],

   241 [

   242     # Also store the legacy naming of the cpu.

   243     # Ie i586 and amd64 instead of x86 and x86_64

   244     OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"

   245     if test "x$OPENJDK_TARGET_CPU" = xx86; then

   246       OPENJDK_TARGET_CPU_LEGACY="i586"

   247     elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   248       # On all platforms except MacOSX replace x86_64 with amd64.

   249       OPENJDK_TARGET_CPU_LEGACY="amd64"

   250     fi

   251     AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)

   253     # And the second legacy naming of the cpu.

   254     # Ie i386 and amd64 instead of x86 and x86_64.

   255     OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"

   256     if test "x$OPENJDK_TARGET_CPU" = xx86; then

   257       OPENJDK_TARGET_CPU_LEGACY_LIB="i386"

   258     elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   259       OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"

   260     fi

   261     AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)

   263     # This is the name of the cpu (but using i386 and amd64 instead of

   264     # x86 and x86_64, respectively), preceeded by a /, to be used when

   265     # locating libraries. On macosx, it's empty, though.

   266     OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"

   267     if test "x$OPENJDK_TARGET_OS" = xmacosx; then

   268         OPENJDK_TARGET_CPU_LIBDIR=""

   269     fi

   270     AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)

   272     # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to

   273     # /amd64 or /sparcv9. This string is appended to some library paths, like this:

   274     # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so

   275     OPENJDK_TARGET_CPU_ISADIR=""

   276     if test "x$OPENJDK_TARGET_OS" = xsolaris; then

   277       if test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   278           OPENJDK_TARGET_CPU_ISADIR="/amd64"

   279       elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then

   280           OPENJDK_TARGET_CPU_ISADIR="/sparcv9"

   281       fi

   282     fi

   283     AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)

   285     # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property

   286     OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"

   287     if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then

   288       # On linux only, we replace x86 with i386.

   289       OPENJDK_TARGET_CPU_OSARCH="i386"

   290     elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   291       # On all platforms except macosx, we replace x86_64 with amd64.

   292       OPENJDK_TARGET_CPU_OSARCH="amd64"

   293     fi

   294     AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)

   296     OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"

   297     if test "x$OPENJDK_TARGET_CPU" = xx86; then

   298       OPENJDK_TARGET_CPU_JLI="i386"

   299     elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   300       # On all platforms except macosx, we replace x86_64 with amd64.

   301       OPENJDK_TARGET_CPU_JLI="amd64"

   302     fi

   303     # Now setup the -D flags for building libjli.

   304     OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"

   305     if test "x$OPENJDK_TARGET_OS" = xsolaris; then

   306       if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then

   307         OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"

   308       elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then

   309         OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"

   310       fi

   311     fi

   312     AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)

   314     # Setup OPENJDK_TARGET_OS_API_DIR, used in source paths.

   315     if test "x$OPENJDK_TARGET_OS_API" = xposix; then

   316         OPENJDK_TARGET_OS_API_DIR="solaris"

   317     fi

   318     if test "x$OPENJDK_TARGET_OS_API" = xwinapi; then

   319         OPENJDK_TARGET_OS_API_DIR="windows"

   320     fi

   321     AC_SUBST(OPENJDK_TARGET_OS_API_DIR)

   323     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   324         A_LP64="LP64:="

   325         # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in

   326         # unpack200.exe

   327         if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then

   328             ADD_LP64="-D_LP64=1"

   329         fi

   330     fi

   331     AC_SUBST(LP64,$A_LP64)

   333     if test "x$COMPILE_TYPE" = "xcross"; then

   334       # FIXME: ... or should this include reduced builds..?

   335       DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"

   336     else

   337       DEFINE_CROSS_COMPILE_ARCH=""

   338     fi

   339     AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)

   341     # ZERO_ARCHDEF is used to enable architecture-specific code

   342     case "${OPENJDK_TARGET_CPU}" in

   343       ppc*)    ZERO_ARCHDEF=PPC   ;;

   344       s390*)   ZERO_ARCHDEF=S390  ;;

   345       sparc*)  ZERO_ARCHDEF=SPARC ;;

   346       x86_64*) ZERO_ARCHDEF=AMD64 ;;

   347       x86)     ZERO_ARCHDEF=IA32  ;;

   348       *)      ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)

   349     esac

   350     AC_SUBST(ZERO_ARCHDEF)

   352 ])

   354 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],

   355 [

   356     if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then

   357        REQUIRED_OS_NAME=SunOS

   358        REQUIRED_OS_VERSION=5.10

   359     fi

   360     if test "x$OPENJDK_TARGET_OS" = "xlinux"; then

   361        REQUIRED_OS_NAME=Linux

   362        REQUIRED_OS_VERSION=2.6

   363     fi

   364     if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   365         REQUIRED_OS_NAME=Windows

   366         if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then

   367             REQUIRED_OS_VERSION=5.2

   368         else

   369             REQUIRED_OS_VERSION=5.1

   370         fi

   371     fi

   372     if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   373         REQUIRED_OS_NAME=Darwin

   374         REQUIRED_OS_VERSION=11.2

   375     fi

   377     AC_SUBST(REQUIRED_OS_NAME)

   378     AC_SUBST(REQUIRED_OS_VERSION)

   379 ])

   381 #%%% Build and target systems %%%

   382 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],

   383 [

   384 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"

   385 # is confusing; it assumes you are cross-compiling a cross-compiler (!)  and "target" is thus the target of the

   386 # product you're building. The target of this build is called "host". Since this is confusing to most people, we

   387 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need

   388 # to use the configure naming style.

   389 AC_CANONICAL_BUILD

   390 AC_CANONICAL_HOST

   391 AC_CANONICAL_TARGET

   393 PLATFORM_EXTRACT_TARGET_AND_BUILD

   394 PLATFORM_SETUP_TARGET_CPU_BITS

   395 PLATFORM_SET_RELEASE_FILE_OS_VALUES

   396 PLATFORM_SETUP_LEGACY_VARS

   397 ])

   399 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],

   400 [

   401 ###############################################################################

   403 # Note that this is the build platform OS version!

   405 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"

   406 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"

   407 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"

   408 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"

   409 AC_SUBST(OS_VERSION_MAJOR)

   410 AC_SUBST(OS_VERSION_MINOR)

   411 AC_SUBST(OS_VERSION_MICRO)

   412 ])

   414 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.

   415 # Add -mX to various FLAGS variables.

   416 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],

   417 [

   418   # keep track of c/cxx flags that we added outselves...

   419   #   to prevent emitting warning...

   420   ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"

   421   ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"

   422   ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"

   424   CFLAGS="${CFLAGS}${ADDED_CFLAGS}"

   425   CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"

   426   LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"

   428   CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"

   429   CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"

   430   LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"

   431 ])

   433 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],

   434 [

   435 ###############################################################################

   436 #

   437 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.

   438 # (The JVM can use 32 or 64 bit Java pointers but that decision

   439 # is made at runtime.)

   440 #

   442 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then

   443   # Always specify -m flag on Solaris

   444   # And -q on AIX because otherwise the compiler produces 32-bit objects by default

   445   PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS

   446 elif test "x$COMPILE_TYPE" = xreduced; then

   447   if test "x$OPENJDK_TARGET_OS" != xwindows; then

   448     # Specify -m if running reduced on other Posix platforms

   449     PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS

   450   fi

   451 fi

   453 # Make compilation sanity check

   454 AC_CHECK_HEADERS([stdio.h], , [

   455   AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])

   456   if test "x$COMPILE_TYPE" = xreduced; then

   457     AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed.])

   458   elif test "x$COMPILE_TYPE" = xcross; then

   459     AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])

   460   fi

   461   AC_MSG_ERROR([Cannot continue.])

   462 ])

   464 AC_CHECK_SIZEOF([int *], [1111])

   466 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'

   467 if test "x$ac_cv_sizeof_int_p" = x; then

   468     # The test failed, lets stick to the assumed value.

   469     AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])

   470 else

   471     TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`

   473     if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then

   474         # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects

   475         # Let's try to implicitely set the compilers target architecture and retry the test

   476         AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])

   477         AC_MSG_NOTICE([I'll retry after setting the platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])

   478         PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS

   480         # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!

   481         unset ac_cv_sizeof_int_p

   482 	# And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF

   483 	cat >>confdefs.h <<_ACEOF

   484 #undef SIZEOF_INT_P

   485 _ACEOF

   487         AC_CHECK_SIZEOF([int *], [1111])

   489         TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`

   491         if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then

   492             AC_MSG_ERROR([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])

   493         fi

   494     fi

   495 fi

   497 AC_MSG_CHECKING([for target address size])

   498 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])

   499 ])

   501 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],

   502 [

   503 ###############################################################################

   504 #

   505 # Is the target little of big endian?

   506 #

   507 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])

   509 if test "x$ENDIAN" = xuniversal_endianness; then

   510     AC_MSG_ERROR([Building with both big and little endianness is not supported])

   511 fi

   512 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then

   513     AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])

   514 fi

   515 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/platform.m4@584dc2e95e04

common/autoconf/platform.m4