jdk8-mips64-public: common/autoconf/build-performance.m4@582c696033f5

8001941: build-infra: --disable-precompiled-headers does not seem to work
Summary: With this fix the flag will do what it advertises
Reviewed-by: ohair, tbell
Contributed-by: erik.joelsson@oracle.com

1 #

     2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 AC_DEFUN([BPERF_CHECK_CORES],

    27 [

    28     AC_MSG_CHECKING([for number of cores])

    29     NUM_CORES=1

    30     FOUND_CORES=no

    32     if test -f /proc/cpuinfo; then

    33         # Looks like a Linux (or cygwin) system

    34         NUM_CORES=`cat /proc/cpuinfo  | grep -c processor`

    35         FOUND_CORES=yes

    36     elif test -x /usr/sbin/psrinfo; then

    37         # Looks like a Solaris system

    38         NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`

    39         FOUND_CORES=yes

    40     elif test -x /usr/sbin/system_profiler; then

    41         # Looks like a MacOSX system

    42         NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk  '{print [$]5}'`

    43         FOUND_CORES=yes

    44     elif test -n "$NUMBER_OF_PROCESSORS"; then

    45         # On windows, look in the env

    46         NUM_CORES=$NUMBER_OF_PROCESSORS

    47         FOUND_CORES=yes

    48     fi

    50     # For c/c++ code we run twice as many concurrent build

    51     # jobs than we have cores, otherwise we will stall on io.

    52     CONCURRENT_BUILD_JOBS=`expr $NUM_CORES \* 2`

    54     if test "x$FOUND_CORES" = xyes; then

    55         AC_MSG_RESULT([$NUM_CORES])

    56     else

    57         AC_MSG_RESULT([could not detect number of cores, defaulting to 1])

    58         AC_MSG_WARN([This will disable all parallelism from build!])

    59     fi

    61 ])

    63 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],

    64 [

    65     AC_MSG_CHECKING([for memory size])

    66     # Default to 1024 MB

    67     MEMORY_SIZE=1024

    68     FOUND_MEM=no

    70     if test -f /proc/meminfo; then

    71         # Looks like a Linux (or cygwin) system

    72         MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`

    73         MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`

    74         FOUND_MEM=yes

    75     elif test -x /usr/sbin/prtconf; then

    76         # Looks like a Solaris system

    77         MEMORY_SIZE=`/usr/sbin/prtconf | grep "Memory size" | awk '{ print [$]3 }'`

    78         FOUND_MEM=yes

    79     elif test -x /usr/sbin/system_profiler; then

    80         # Looks like a MacOSX system

    81         MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk  '{print [$]2}'`

    82         MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`

    83         FOUND_MEM=yes

    84     elif test "x$OPENJDK_BUILD_OS" = xwindows; then

    85         # Windows, but without cygwin

    86         MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`

    87         MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`

    88         FOUND_MEM=yes

    89     fi

    91     if test "x$FOUND_MEM" = xyes; then

    92         AC_MSG_RESULT([$MEMORY_SIZE MB])

    93     else

    94         AC_MSG_RESULT([could not detect memory size, defaulting to 1024 MB])

    95         AC_MSG_WARN([This might seriously impact build performance!])

    96     fi

    97 ])

    99 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],

   100 [

   101 # How many cores do we have on this build system?

   102 AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],

   103     [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])

   104 if test "x$with_num_cores" = x; then

   105     # The number of cores were not specified, try to probe them.

   106     BPERF_CHECK_CORES

   107 else

   108     NUM_CORES=$with_num_cores

   109     CONCURRENT_BUILD_JOBS=`expr $NUM_CORES \* 2`

   110 fi

   111 AC_SUBST(NUM_CORES)

   112 AC_SUBST(CONCURRENT_BUILD_JOBS)

   113 ])

   115 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],

   116 [

   117 # How much memory do we have on this build system?

   118 AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],

   119     [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])

   120 if test "x$with_memory_size" = x; then

   121     # The memory size was not specified, try to probe it.

   122     BPERF_CHECK_MEMORY_SIZE

   123 else

   124     MEMORY_SIZE=$with_memory_size

   125 fi

   126 AC_SUBST(MEMORY_SIZE)

   127 ])

   129 AC_DEFUN([BPERF_SETUP_CCACHE],

   130 [

   131     AC_ARG_ENABLE([ccache],

   132 	      [AS_HELP_STRING([--disable-ccache],

   133 	      		      [disable using ccache to speed up recompilations @<:@enabled@:>@])],

   134               [ENABLE_CCACHE=${enable_ccache}], [ENABLE_CCACHE=yes])

   135     if test "x$ENABLE_CCACHE" = xyes; then

   136         AC_PATH_PROG(CCACHE, ccache)

   137     else

   138         AC_MSG_CHECKING([for ccache])

   139         AC_MSG_RESULT([explicitly disabled])

   140         CCACHE=

   141     fi

   142     AC_SUBST(CCACHE)

   144     AC_ARG_WITH([ccache-dir],

   145 	      [AS_HELP_STRING([--with-ccache-dir],

   146 	      		      [where to store ccache files @<:@~/.ccache@:>@])])

   148     if test "x$with_ccache_dir" != x; then

   149         # When using a non home ccache directory, assume the use is to share ccache files

   150         # with other users. Thus change the umask.

   151         SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"

   152     fi

   153     CCACHE_FOUND=""

   154     if test "x$CCACHE" != x; then

   155         BPERF_SETUP_CCACHE_USAGE

   156     fi

   157 ])

   159 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],

   160 [

   161     if test "x$CCACHE" != x; then

   162         CCACHE_FOUND="true"

   163         # Only use ccache if it is 3.1.4 or later, which supports

   164         # precompiled headers.

   165         AC_MSG_CHECKING([if ccache supports precompiled headers])

   166         HAS_GOOD_CCACHE=`($CCACHE --version | head -n 1 | grep -E 3.1.@<:@456789@:>@) 2> /dev/null`

   167         if test "x$HAS_GOOD_CCACHE" = x; then

   168             AC_MSG_RESULT([no, disabling ccache])

   169             CCACHE=

   170         else

   171             AC_MSG_RESULT([yes])

   172             AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])

   173             PUSHED_FLAGS="$CXXFLAGS"

   174             CXXFLAGS="-fpch-preprocess $CXXFLAGS"

   175             AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])

   176             CXXFLAGS="$PUSHED_FLAGS"

   177             if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then

   178                 AC_MSG_RESULT([yes])

   179             else

   180                 AC_MSG_RESULT([no, disabling ccaching of precompiled headers])

   181                 CCACHE=

   182             fi

   183         fi

   184     fi

   186     if test "x$CCACHE" != x; then

   187         CCACHE_SLOPPINESS=time_macros

   188         CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS $CCACHE"

   189         CCACHE_FLAGS=-fpch-preprocess

   191         if test "x$SET_CCACHE_DIR" != x; then

   192             mkdir -p $CCACHE_DIR > /dev/null 2>&1

   193 	    chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1

   194         fi

   195     fi

   196 ])

   198 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],

   199 [

   201 ###############################################################################

   202 #

   203 # Can the C/C++ compiler use precompiled headers?

   204 #

   205 AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],

   206 	[disable using precompiled headers when compiling C++ @<:@enabled@:>@])],

   207     [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])

   209 USE_PRECOMPILED_HEADER=1

   210 if test "x$ENABLE_PRECOMPH" = xno; then

   211     USE_PRECOMPILED_HEADER=0

   212 fi

   214 if test "x$ENABLE_PRECOMPH" = xyes; then

   215     # Check that the compiler actually supports precomp headers.

   216     if test "x$GCC" = xyes; then

   217          AC_MSG_CHECKING([that precompiled headers work])

   218          echo "int alfa();" > conftest.h

   219          $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD

   220          if test ! -f conftest.hpp.gch; then

   221              USE_PRECOMPILED_HEADER=0

   222              AC_MSG_RESULT([no])

   223          else

   224              AC_MSG_RESULT([yes])

   225          fi

   226          rm -f conftest.h conftest.hpp.gch

   227     fi

   228 fi

   230 AC_SUBST(USE_PRECOMPILED_HEADER)

   231 ])

   234 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],

   235 [

   236 AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],

   237 	[use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])

   239 if test "x$with_sjavac_server_java" != x; then

   240     SJAVAC_SERVER_JAVA="$with_sjavac_server_java"

   241     FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`

   242     if test "x$FOUND_VERSION" = x; then

   243         AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])

   244     fi

   245 else

   246     SJAVAC_SERVER_JAVA=""

   247     # Hotspot specific options.

   248     ADD_JVM_ARG_IF_OK([-verbosegc],SJAVAC_SERVER_JAVA,[$JAVA])

   249     # JRockit specific options.

   250     ADD_JVM_ARG_IF_OK([-Xverbose:gc],SJAVAC_SERVER_JAVA,[$JAVA])

   251     SJAVAC_SERVER_JAVA="$JAVA $SJAVAC_SERVER_JAVA"

   252 fi

   253 AC_SUBST(SJAVAC_SERVER_JAVA)

   255 AC_ARG_WITH(sjavac-server-cores, [AS_HELP_STRING([--with-sjavac-server-cores],

   256 	[use at most this number of concurrent threads on the sjavac server @<:@probed@:>@])])

   257 if test "x$with_sjavac_server_cores" != x; then

   258     SJAVAC_SERVER_CORES="$with_sjavac_server_cores"

   259 else

   260     if test "$NUM_CORES" -gt 16; then

   261         # We set this arbitrary limit because we want to limit the heap

   262         # size of the javac server.

   263         # In the future we will make the javac compilers in the server

   264         # share more and more state, thus enabling us to use more and

   265         # more concurrent threads in the server.

   266         SJAVAC_SERVER_CORES="16"

   267     else

   268         SJAVAC_SERVER_CORES="$NUM_CORES"

   269     fi

   271     if test "$MEMORY_SIZE" -gt "17000"; then

   272         MAX_HEAP_MEM=10000

   273         ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   274         ADD_JVM_ARG_IF_OK([-Xms10G -Xmx10G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   275     elif test "$MEMORY_SIZE" -gt "10000"; then

   276         MAX_HEAP_MEM=6000

   277         ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   278         ADD_JVM_ARG_IF_OK([-Xms6G -Xmx6G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   279     elif test "$MEMORY_SIZE" -gt "5000"; then

   280         MAX_HEAP_MEM=3000

   281         ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   282         ADD_JVM_ARG_IF_OK([-Xms1G -Xmx3G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   283     elif test "$MEMORY_SIZE" -gt "3800"; then

   284         MAX_HEAP_MEM=2500

   285         ADD_JVM_ARG_IF_OK([-Xms1G -Xmx2500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   286     elif test "$MEMORY_SIZE" -gt "1900"; then

   287         MAX_HEAP_MEM=1200

   288         ADD_JVM_ARG_IF_OK([-Xms700M -Xmx1400M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   289     elif test "$MEMORY_SIZE" -gt "1000"; then

   290         MAX_HEAP_MEM=900

   291         ADD_JVM_ARG_IF_OK([-Xms400M -Xmx1100M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   292     else

   293         MAX_HEAP_MEM=512

   294         ADD_JVM_ARG_IF_OK([-Xms256M -Xmx512M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   295     fi

   297     ADD_JVM_ARG_IF_OK([-XX:PermSize=32m],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   298     ADD_JVM_ARG_IF_OK([-XX:MaxPermSize=160m],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   299     ADD_JVM_ARG_IF_OK([-XX:ThreadStackSize=$STACK_SIZE],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   301     MAX_COMPILERS_IN_HEAP=`expr $MAX_HEAP_MEM / 501`

   302     if test "$SJAVAC_SERVER_CORES" -gt "$MAX_COMPILERS_IN_HEAP"; then

   303         AC_MSG_CHECKING([if number of server cores must be reduced])

   304         SJAVAC_SERVER_CORES="$MAX_COMPILERS_IN_HEAP"

   305         AC_MSG_RESULT([yes, to $SJAVAC_SERVER_CORES with max heap size $MAX_HEAP_MEM MB])

   306     fi

   307 fi

   308 AC_SUBST(SJAVAC_SERVER_CORES)

   310 AC_MSG_CHECKING([whether to use sjavac])

   311 AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],

   312 	[use sjavac to do fast incremental compiles @<:@disabled@:>@])],

   313 	[ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC='no'])

   314 AC_MSG_RESULT([$ENABLE_SJAVAC])

   315 AC_SUBST(ENABLE_SJAVAC)

   317 if test "x$ENABLE_SJAVAC" = xyes; then

   318     SJAVAC_SERVER_DIR="$OUTPUT_ROOT/javacservers"

   319 else

   320     SJAVAC_SERVER_DIR=

   321 fi

   322 AC_SUBST(SJAVAC_SERVER_DIR)

   324 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/build-performance.m4@582c696033f5

common/autoconf/build-performance.m4