jdk8-mips64-public: common/autoconf/basics.m4@5510b933fa58

8035825: Warn instead of fail when calling the configure wrapper directly
Reviewed-by: ihse, dholmes, tbell

1 #

     2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)

    27 # If so, then append $1 to $2 \

    28 # Also set JVM_ARG_OK to true/false depending on outcome.

    29 AC_DEFUN([ADD_JVM_ARG_IF_OK],

    30 [

    31   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD

    32   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD

    33   OUTPUT=`$3 $1 -version 2>&1`

    34   FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`

    35   FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`

    36   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then

    37     $2="[$]$2 $1"

    38     JVM_ARG_OK=true

    39   else

    40     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD

    41     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD

    42     JVM_ARG_OK=false

    43   fi

    44 ])

    46 # Appends a string to a path variable, only adding the : when needed.

    47 AC_DEFUN([BASIC_APPEND_TO_PATH],

    48 [

    49   if test "x[$]$1" = x; then

    50     $1="$2"

    51   else

    52     $1="[$]$1:$2"

    53   fi

    54 ])

    56 # This will make sure the given variable points to a full and proper

    57 # path. This means:

    58 # 1) There will be no spaces in the path. On posix platforms,

    59 #    spaces in the path will result in an error. On Windows,

    60 #    the path will be rewritten using short-style to be space-free.

    61 # 2) The path will be absolute, and it will be in unix-style (on

    62 #     cygwin).

    63 # $1: The name of the variable to fix

    64 AC_DEFUN([BASIC_FIXUP_PATH],

    65 [

    66   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

    67     BASIC_FIXUP_PATH_CYGWIN($1)

    68   elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

    69     BASIC_FIXUP_PATH_MSYS($1)

    70   else

    71     # We're on a posix platform. Hooray! :)

    72     path="[$]$1"

    73     has_space=`$ECHO "$path" | $GREP " "`

    74     if test "x$has_space" != x; then

    75       AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])

    76       AC_MSG_ERROR([Spaces are not allowed in this path.])

    77     fi

    79     # Use eval to expand a potential ~

    80     eval path="$path"

    81     if test ! -f "$path" && test ! -d "$path"; then

    82       AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])

    83     fi

    85     $1="`cd "$path"; $THEPWDCMD -L`"

    86   fi

    87 ])

    89 # This will make sure the given variable points to a executable

    90 # with a full and proper path. This means:

    91 # 1) There will be no spaces in the path. On posix platforms,

    92 #    spaces in the path will result in an error. On Windows,

    93 #    the path will be rewritten using short-style to be space-free.

    94 # 2) The path will be absolute, and it will be in unix-style (on

    95 #     cygwin).

    96 # Any arguments given to the executable is preserved.

    97 # If the input variable does not have a directory specification, then

    98 # it need to be in the PATH.

    99 # $1: The name of the variable to fix

   100 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],

   101 [

   102   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

   103     BASIC_FIXUP_EXECUTABLE_CYGWIN($1)

   104   elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   105     BASIC_FIXUP_EXECUTABLE_MSYS($1)

   106   else

   107     # We're on a posix platform. Hooray! :)

   108     # First separate the path from the arguments. This will split at the first

   109     # space.

   110     complete="[$]$1"

   111     path="${complete%% *}"

   112     tmp="$complete EOL"

   113     arguments="${tmp#* }"

   115     # Cannot rely on the command "which" here since it doesn't always work.

   116     is_absolute_path=`$ECHO "$path" | $GREP ^/`

   117     if test -z "$is_absolute_path"; then

   118       # Path to executable is not absolute. Find it.

   119       IFS_save="$IFS"

   120       IFS=:

   121       for p in $PATH; do

   122         if test -f "$p/$path" && test -x "$p/$path"; then

   123           new_path="$p/$path"

   124           break

   125         fi

   126       done

   127       IFS="$IFS_save"

   128     else

   129       # This is an absolute path, we can use it without further modifications.

   130       new_path="$path"

   131     fi

   133     if test "x$new_path" = x; then

   134       AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])

   135       has_space=`$ECHO "$complete" | $GREP " "`

   136       if test "x$has_space" != x; then

   137         AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])

   138       fi

   139       AC_MSG_ERROR([Cannot locate the the path of $1])

   140     fi

   141   fi

   143   # Now join together the path and the arguments once again

   144   if test "x$arguments" != xEOL; then

   145     new_complete="$new_path ${arguments% *}"

   146   else

   147     new_complete="$new_path"

   148   fi

   150   if test "x$complete" != "x$new_complete"; then

   151     $1="$new_complete"

   152     AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])

   153   fi

   154 ])

   156 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],

   157 [

   158   if test "x$OPENJDK_BUILD_OS" != xwindows; then

   159     # Follow a chain of symbolic links. Use readlink

   160     # where it exists, else fall back to horribly

   161     # complicated shell code.

   162     if test "x$READLINK_TESTED" != yes; then

   163       # On MacOSX there is a readlink tool with a different

   164       # purpose than the GNU readlink tool. Check the found readlink.

   165       ISGNU=`$READLINK --version 2>&1 | $GREP GNU`

   166       if test "x$ISGNU" = x; then

   167         # A readlink that we do not know how to use.

   168         # Are there other non-GNU readlinks out there?

   169         READLINK_TESTED=yes

   170         READLINK=

   171       fi

   172     fi

   174     if test "x$READLINK" != x; then

   175       $1=`$READLINK -f [$]$1`

   176     else

   177       # Save the current directory for restoring afterwards

   178       STARTDIR=$PWD

   179       COUNTER=0

   180       sym_link_dir=`$DIRNAME [$]$1`

   181       sym_link_file=`$BASENAME [$]$1`

   182       cd $sym_link_dir

   183       # Use -P flag to resolve symlinks in directories.

   184       cd `$THEPWDCMD -P`

   185       sym_link_dir=`$THEPWDCMD -P`

   186       # Resolve file symlinks

   187       while test $COUNTER -lt 20; do

   188         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`

   189         if test "x$ISLINK" == x; then

   190           # This is not a symbolic link! We are done!

   191           break

   192         fi

   193         # Again resolve directory symlinks since the target of the just found

   194         # link could be in a different directory

   195         cd `$DIRNAME $ISLINK`

   196         sym_link_dir=`$THEPWDCMD -P`

   197         sym_link_file=`$BASENAME $ISLINK`

   198         let COUNTER=COUNTER+1

   199       done

   200       cd $STARTDIR

   201       $1=$sym_link_dir/$sym_link_file

   202     fi

   203   fi

   204 ])

   206 # Register a --with argument but mark it as deprecated

   207 # $1: The name of the with argument to deprecate, not including --with-

   208 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],

   209 [

   210   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],

   211       [Deprecated. Option is kept for backwards compatibility and is ignored])],

   212       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])

   213 ])

   215 # Register a --enable argument but mark it as deprecated

   216 # $1: The name of the with argument to deprecate, not including --enable-

   217 # $2: The name of the argument to deprecate, in shell variable style (i.e. with _ instead of -)

   218 AC_DEFUN([BASIC_DEPRECATED_ARG_ENABLE],

   219 [

   220   AC_ARG_ENABLE($1, [AS_HELP_STRING([--enable-$1],

   221       [Deprecated. Option is kept for backwards compatibility and is ignored])])

   222   if test "x$enable_$2" != x; then

   223     AC_MSG_WARN([Option --enable-$1 is deprecated and will be ignored.])

   224   fi

   225 ])

   227 AC_DEFUN_ONCE([BASIC_INIT],

   228 [

   229   # Save the original command line. This is passed to us by the wrapper configure script.

   230   AC_SUBST(CONFIGURE_COMMAND_LINE)

   231   DATE_WHEN_CONFIGURED=`LANG=C date`

   232   AC_SUBST(DATE_WHEN_CONFIGURED)

   233   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])

   234   AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])

   235 ])

   237 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.

   238 # $1: variable to check

   239 AC_DEFUN([BASIC_CHECK_NONEMPTY],

   240 [

   241   if test "x[$]$1" = x; then

   242     AC_MSG_ERROR([Could not find required tool for $1])

   243   fi

   244 ])

   246 # Check that there are no unprocessed overridden variables left.

   247 # If so, they are an incorrect argument and we will exit with an error.

   248 AC_DEFUN([BASIC_CHECK_LEFTOVER_OVERRIDDEN],

   249 [

   250   if test "x$CONFIGURE_OVERRIDDEN_VARIABLES" != x; then

   251     # Replace the separating ! with spaces before presenting for end user.

   252     unknown_variables=${CONFIGURE_OVERRIDDEN_VARIABLES//!/ }

   253     AC_MSG_WARN([The following variables might be unknown to configure: $unknown_variables])

   254   fi

   255 ])

   257 # Setup a tool for the given variable. If correctly specified by the user,

   258 # use that value, otherwise search for the tool using the supplied code snippet.

   259 # $1: variable to set

   260 # $2: code snippet to call to look for the tool

   261 AC_DEFUN([BASIC_SETUP_TOOL],

   262 [

   263   # Publish this variable in the help.

   264   AC_ARG_VAR($1, [Override default value for $1])

   266   if test "x[$]$1" = x; then

   267     # The variable is not set by user, try to locate tool using the code snippet

   268     $2

   269   else

   270     # The variable is set, but is it from the command line or the environment?

   272     # Try to remove the string !$1! from our list.

   273     try_remove_var=${CONFIGURE_OVERRIDDEN_VARIABLES//!$1!/}

   274     if test "x$try_remove_var" = "x$CONFIGURE_OVERRIDDEN_VARIABLES"; then

   275       # If it failed, the variable was not from the command line. Ignore it,

   276       # but warn the user (except for BASH, which is always set by the calling BASH).

   277       if test "x$1" != xBASH; then

   278         AC_MSG_WARN([Ignoring value of $1 from the environment. Use command line variables instead.])

   279       fi

   280       # Try to locate tool using the code snippet

   281       $2

   282     else

   283       # If it succeeded, then it was overridden by the user. We will use it

   284       # for the tool.

   286       # First remove it from the list of overridden variables, so we can test

   287       # for unknown variables in the end.

   288       CONFIGURE_OVERRIDDEN_VARIABLES="$try_remove_var"

   290       # Check if the provided tool contains a complete path.

   291       tool_specified="[$]$1"

   292       tool_basename="${tool_specified##*/}"

   293       if test "x$tool_basename" = "x$tool_specified"; then

   294         # A command without a complete path is provided, search $PATH.

   295         AC_MSG_NOTICE([Will search for user supplied tool $1=$tool_basename])

   296         AC_PATH_PROG($1, $tool_basename)

   297         if test "x[$]$1" = x; then

   298           AC_MSG_ERROR([User supplied tool $tool_basename could not be found])

   299         fi

   300       else

   301         # Otherwise we believe it is a complete path. Use it as it is.

   302         AC_MSG_NOTICE([Will use user supplied tool $1=$tool_specified])

   303         AC_MSG_CHECKING([for $1])

   304         if test ! -x "$tool_specified"; then

   305           AC_MSG_RESULT([not found])

   306           AC_MSG_ERROR([User supplied tool $1=$tool_specified does not exist or is not executable])

   307         fi

   308         AC_MSG_RESULT([$tool_specified])

   309       fi

   310     fi

   311   fi

   312 ])

   314 # Call BASIC_SETUP_TOOL with AC_PATH_PROGS to locate the tool

   315 # $1: variable to set

   316 # $2: executable name (or list of names) to look for

   317 AC_DEFUN([BASIC_PATH_PROGS],

   318 [

   319   BASIC_SETUP_TOOL($1, [AC_PATH_PROGS($1, $2)])

   320 ])

   322 # Call BASIC_SETUP_TOOL with AC_CHECK_TOOLS to locate the tool

   323 # $1: variable to set

   324 # $2: executable name (or list of names) to look for

   325 AC_DEFUN([BASIC_CHECK_TOOLS],

   326 [

   327   BASIC_SETUP_TOOL($1, [AC_CHECK_TOOLS($1, $2)])

   328 ])

   330 # Like BASIC_PATH_PROGS but fails if no tool was found.

   331 # $1: variable to set

   332 # $2: executable name (or list of names) to look for

   333 AC_DEFUN([BASIC_REQUIRE_PROGS],

   334 [

   335   BASIC_PATH_PROGS($1, $2)

   336   BASIC_CHECK_NONEMPTY($1)

   337 ])

   339 # Like BASIC_SETUP_TOOL but fails if no tool was found.

   340 # $1: variable to set

   341 # $2: autoconf macro to call to look for the special tool

   342 AC_DEFUN([BASIC_REQUIRE_SPECIAL],

   343 [

   344   BASIC_SETUP_TOOL($1, [$2])

   345   BASIC_CHECK_NONEMPTY($1)

   346 ])

   348 # Setup the most fundamental tools that relies on not much else to set up,

   349 # but is used by much of the early bootstrap code.

   350 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],

   351 [

   352   # Start with tools that do not need have cross compilation support

   353   # and can be expected to be found in the default PATH. These tools are

   354   # used by configure. Nor are these tools expected to be found in the

   355   # devkit from the builddeps server either, since they are

   356   # needed to download the devkit.

   358   # First are all the simple required tools.

   359   BASIC_REQUIRE_PROGS(BASENAME, basename)

   360   BASIC_REQUIRE_PROGS(BASH, bash)

   361   BASIC_REQUIRE_PROGS(CAT, cat)

   362   BASIC_REQUIRE_PROGS(CHMOD, chmod)

   363   BASIC_REQUIRE_PROGS(CMP, cmp)

   364   BASIC_REQUIRE_PROGS(COMM, comm)

   365   BASIC_REQUIRE_PROGS(CP, cp)

   366   BASIC_REQUIRE_PROGS(CPIO, cpio)

   367   BASIC_REQUIRE_PROGS(CUT, cut)

   368   BASIC_REQUIRE_PROGS(DATE, date)

   369   BASIC_REQUIRE_PROGS(DIFF, [gdiff diff])

   370   BASIC_REQUIRE_PROGS(DIRNAME, dirname)

   371   BASIC_REQUIRE_PROGS(ECHO, echo)

   372   BASIC_REQUIRE_PROGS(EXPR, expr)

   373   BASIC_REQUIRE_PROGS(FILE, file)

   374   BASIC_REQUIRE_PROGS(FIND, find)

   375   BASIC_REQUIRE_PROGS(HEAD, head)

   376   BASIC_REQUIRE_PROGS(LN, ln)

   377   BASIC_REQUIRE_PROGS(LS, ls)

   378   BASIC_REQUIRE_PROGS(MKDIR, mkdir)

   379   BASIC_REQUIRE_PROGS(MKTEMP, mktemp)

   380   BASIC_REQUIRE_PROGS(MV, mv)

   381   BASIC_REQUIRE_PROGS(NAWK, [nawk gawk awk])

   382   BASIC_REQUIRE_PROGS(PRINTF, printf)

   383   BASIC_REQUIRE_PROGS(RM, rm)

   384   BASIC_REQUIRE_PROGS(SH, sh)

   385   BASIC_REQUIRE_PROGS(SORT, sort)

   386   BASIC_REQUIRE_PROGS(TAIL, tail)

   387   BASIC_REQUIRE_PROGS(TAR, tar)

   388   BASIC_REQUIRE_PROGS(TEE, tee)

   389   BASIC_REQUIRE_PROGS(TOUCH, touch)

   390   BASIC_REQUIRE_PROGS(TR, tr)

   391   BASIC_REQUIRE_PROGS(UNAME, uname)

   392   BASIC_REQUIRE_PROGS(UNIQ, uniq)

   393   BASIC_REQUIRE_PROGS(WC, wc)

   394   BASIC_REQUIRE_PROGS(WHICH, which)

   395   BASIC_REQUIRE_PROGS(XARGS, xargs)

   397   # Then required tools that require some special treatment.

   398   BASIC_REQUIRE_SPECIAL(AWK, [AC_PROG_AWK])

   399   BASIC_REQUIRE_SPECIAL(GREP, [AC_PROG_GREP])

   400   BASIC_REQUIRE_SPECIAL(EGREP, [AC_PROG_EGREP])

   401   BASIC_REQUIRE_SPECIAL(FGREP, [AC_PROG_FGREP])

   402   BASIC_REQUIRE_SPECIAL(SED, [AC_PROG_SED])

   404   # Always force rm.

   405   RM="$RM -f"

   407   # pwd behaves differently on various platforms and some don't support the -L flag.

   408   # Always use the bash builtin pwd to get uniform behavior.

   409   THEPWDCMD=pwd

   411   # These are not required on all platforms

   412   BASIC_PATH_PROGS(CYGPATH, cygpath)

   413   BASIC_PATH_PROGS(READLINK, [greadlink readlink])

   414   BASIC_PATH_PROGS(DF, df)

   415   BASIC_PATH_PROGS(SETFILE, SetFile)

   416 ])

   418 # Setup basic configuration paths, and platform-specific stuff related to PATHs.

   419 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],

   420 [

   421   # We get the top-level directory from the supporting wrappers.

   422   AC_MSG_CHECKING([for top-level directory])

   423   AC_MSG_RESULT([$TOPDIR])

   424   BASIC_FIXUP_PATH(TOPDIR)

   425   AC_SUBST(TOPDIR)

   427   # SRC_ROOT is a traditional alias for TOPDIR.

   428   SRC_ROOT=$TOPDIR

   430   # Locate the directory of this script.

   431   AUTOCONF_DIR=$TOPDIR/common/autoconf

   433   # Save the current directory this script was started from

   434   CURDIR="$PWD"

   435   BASIC_FIXUP_PATH(CURDIR)

   437   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   438     PATH_SEP=";"

   439     BASIC_CHECK_PATHS_WINDOWS

   440   else

   441     PATH_SEP=":"

   442   fi

   443   AC_SUBST(PATH_SEP)

   445   if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then

   446     # Add extra search paths on solaris for utilities like ar and as etc...

   447     PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"

   448   fi

   450   # You can force the sys-root if the sys-root encoded into the cross compiler tools

   451   # is not correct.

   452   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],

   453       [pass this sys-root to the compilers and tools (for cross-compiling)])])

   455   if test "x$with_sys_root" != x; then

   456     SYS_ROOT=$with_sys_root

   457   else

   458     SYS_ROOT=/

   459   fi

   460   AC_SUBST(SYS_ROOT)

   462   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],

   463       [search this directory for compilers and tools (for cross-compiling)])],

   464       [TOOLS_DIR=$with_tools_dir]

   465   )

   467   # Xcode version will be validated later

   468   AC_ARG_WITH([xcode-path], [AS_HELP_STRING([--with-xcode-path],

   469       [explicit path to Xcode 4 (generally for building on 10.9 and later)])],

   470       [XCODE_PATH=$with_xcode_path]

   471   )

   473   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],

   474       [use this directory as base for tools-dir and sys-root (for cross-compiling)])],

   475       [

   476         if test "x$with_sys_root" != x; then

   477           AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])

   478         fi

   479         BASIC_FIXUP_PATH([with_devkit])

   480         BASIC_APPEND_TO_PATH([TOOLS_DIR],$with_devkit/bin)

   481         if test -d "$with_devkit/$host_alias/libc"; then

   482           SYS_ROOT=$with_devkit/$host_alias/libc

   483         elif test -d "$with_devkit/$host/sys-root"; then

   484           SYS_ROOT=$with_devkit/$host/sys-root

   485         fi

   486       ])

   487 ])

   489 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],

   490 [

   492   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],

   493       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],

   494       [ CONF_NAME=${with_conf_name} ])

   496   # Test from where we are running configure, in or outside of src root.

   497   AC_MSG_CHECKING([where to store configuration])

   498   if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \

   499       || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \

   500       || test "x$CURDIR" = "x$SRC_ROOT/make" ; then

   501     # We are running configure from the src root.

   502     # Create a default ./build/target-variant-debuglevel output root.

   503     if test "x${CONF_NAME}" = x; then

   504       AC_MSG_RESULT([in default location])

   505       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"

   506     else

   507       AC_MSG_RESULT([in build directory with custom name])

   508     fi

   509     OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"

   510     $MKDIR -p "$OUTPUT_ROOT"

   511     if test ! -d "$OUTPUT_ROOT"; then

   512       AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])

   513     fi

   514   else

   515     # We are running configure from outside of the src dir.

   516     # Then use the current directory as output dir!

   517     # If configuration is situated in normal build directory, just use the build

   518     # directory name as configuration name, otherwise use the complete path.

   519     if test "x${CONF_NAME}" = x; then

   520       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`

   521     fi

   522     OUTPUT_ROOT="$CURDIR"

   523     AC_MSG_RESULT([in current directory])

   525     # WARNING: This might be a bad thing to do. You need to be sure you want to

   526     # have a configuration in this directory. Do some sanity checks!

   528     if test ! -e "$OUTPUT_ROOT/spec.gmk"; then

   529       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for

   530       # other files

   531       files_present=`$LS $OUTPUT_ROOT`

   532       # Configure has already touched config.log and confdefs.h in the current dir when this check

   533       # is performed.

   534       filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \

   535       | $TR -d '\n'`

   536       if test "x$filtered_files" != x; then

   537         AC_MSG_NOTICE([Current directory is $CURDIR.])

   538         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])

   539         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])

   540         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])

   541         AC_MSG_NOTICE([seriously mess up just about everything.])

   542         AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])

   543         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])

   544         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])

   545       fi

   546     fi

   547   fi

   548   AC_MSG_CHECKING([what configuration name to use])

   549   AC_MSG_RESULT([$CONF_NAME])

   551   BASIC_FIXUP_PATH(OUTPUT_ROOT)

   553   AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)

   554   AC_SUBST(CONF_NAME, $CONF_NAME)

   555   AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)

   557   # Most of the probed defines are put into config.h

   558   AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])

   559   # The spec.gmk file contains all variables for the make system.

   560   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])

   561   # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.

   562   AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])

   563   # The bootcycle-spec.gmk file contains support for boot cycle builds.

   564   AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])

   565   # The compare.sh is used to compare the build output to other builds.

   566   AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])

   567   # Spec.sh is currently used by compare-objects.sh

   568   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])

   569   # The generated Makefile knows where the spec.gmk is and where the source is.

   570   # You can run make from the OUTPUT_ROOT, or from the top-level Makefile

   571   # which will look for generated configurations

   572   AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])

   573 ])

   575 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],

   576 [

   577   # Setup default logging of stdout and stderr to build.log in the output root.

   578   BUILD_LOG='$(OUTPUT_ROOT)/build.log'

   579   BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'

   580   BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'

   581   AC_SUBST(BUILD_LOG)

   582   AC_SUBST(BUILD_LOG_PREVIOUS)

   583   AC_SUBST(BUILD_LOG_WRAPPER)

   584 ])

   587 #%%% Simple tools %%%

   589 # Check if we have found a usable version of make

   590 # $1: the path to a potential make binary (or empty)

   591 # $2: the description on how we found this

   592 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],

   593 [

   594   MAKE_CANDIDATE="$1"

   595   DESCRIPTION="$2"

   596   if test "x$MAKE_CANDIDATE" != x; then

   597     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])

   598     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`

   599     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`

   600     if test "x$IS_GNU_MAKE" = x; then

   601       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])

   602     else

   603       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP -e '3\.8[[12]]' -e '4\.'`

   604       if test "x$IS_MODERN_MAKE" = x; then

   605         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])

   606       else

   607         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then

   608           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

   609             MAKE_EXPECTED_ENV='cygwin'

   610           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   611             MAKE_EXPECTED_ENV='msys'

   612           else

   613             AC_MSG_ERROR([Unknown Windows environment])

   614           fi

   615           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`

   616           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`

   617         else

   618           # Not relevant for non-Windows

   619           IS_MAKE_CORRECT_ENV=true

   620         fi

   621         if test "x$IS_MAKE_CORRECT_ENV" = x; then

   622           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])

   623         else

   624           FOUND_MAKE=$MAKE_CANDIDATE

   625           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)

   626         fi

   627       fi

   628     fi

   629   fi

   630 ])

   632 # Goes looking for a usable version of GNU make.

   633 AC_DEFUN([BASIC_CHECK_GNU_MAKE],

   634 [

   635   # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.

   636   if test "x$MAKE" != x; then

   637     # User has supplied a make, test it.

   638     if test ! -f "$MAKE"; then

   639       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])

   640     fi

   641     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])

   642     if test "x$FOUND_MAKE" = x; then

   643       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])

   644     fi

   645   else

   646     # Try our hardest to locate a correct version of GNU make

   647     AC_PATH_PROGS(CHECK_GMAKE, gmake)

   648     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])

   650     if test "x$FOUND_MAKE" = x; then

   651       AC_PATH_PROGS(CHECK_MAKE, make)

   652       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])

   653     fi

   655     if test "x$FOUND_MAKE" = x; then

   656       if test "x$TOOLS_DIR" != x; then

   657         # We have a tools-dir, check that as well before giving up.

   658         OLD_PATH=$PATH

   659         PATH=$TOOLS_DIR:$PATH

   660         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)

   661         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])

   662         if test "x$FOUND_MAKE" = x; then

   663           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)

   664           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])

   665         fi

   666         PATH=$OLD_PATH

   667       fi

   668     fi

   670     if test "x$FOUND_MAKE" = x; then

   671       AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])

   672     fi

   673   fi

   675   MAKE=$FOUND_MAKE

   676   AC_SUBST(MAKE)

   677   AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])

   678 ])

   680 AC_DEFUN([BASIC_CHECK_FIND_DELETE],

   681 [

   682   # Test if find supports -delete

   683   AC_MSG_CHECKING([if find supports -delete])

   684   FIND_DELETE="-delete"

   686   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)

   688   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete

   690   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`

   691   if test -f $DELETEDIR/TestIfFindSupportsDelete; then

   692     # No, it does not.

   693     rm $DELETEDIR/TestIfFindSupportsDelete

   694     FIND_DELETE="-exec rm \{\} \+"

   695     AC_MSG_RESULT([no])

   696   else

   697     AC_MSG_RESULT([yes])

   698   fi

   699   rmdir $DELETEDIR

   700   AC_SUBST(FIND_DELETE)

   701 ])

   703 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],

   704 [

   705   BASIC_CHECK_GNU_MAKE

   707   BASIC_CHECK_FIND_DELETE

   709   # These tools might not be installed by default,

   710   # need hint on how to install them.

   711   BASIC_REQUIRE_PROGS(UNZIP, unzip)

   712   BASIC_REQUIRE_PROGS(ZIP, zip)

   714   # Non-required basic tools

   716   BASIC_PATH_PROGS(LDD, ldd)

   717   if test "x$LDD" = "x"; then

   718     # List shared lib dependencies is used for

   719     # debug output and checking for forbidden dependencies.

   720     # We can build without it.

   721     LDD="true"

   722   fi

   723   BASIC_PATH_PROGS(READELF, [readelf greadelf])

   724   BASIC_PATH_PROGS(HG, hg)

   725   BASIC_PATH_PROGS(STAT, stat)

   726   BASIC_PATH_PROGS(TIME, time)

   727   # Check if it's GNU time

   728   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`

   729   if test "x$IS_GNU_TIME" != x; then

   730     IS_GNU_TIME=yes

   731   else

   732     IS_GNU_TIME=no

   733   fi

   734   AC_SUBST(IS_GNU_TIME)

   736   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   737     BASIC_REQUIRE_PROGS(COMM, comm)

   738   fi

   740   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   741     BASIC_REQUIRE_PROGS(DSYMUTIL, dsymutil)

   742     BASIC_REQUIRE_PROGS(XATTR, xattr)

   743     BASIC_PATH_PROGS(CODESIGN, codesign)

   744     if test "x$CODESIGN" != "x"; then

   745       # Verify that the openjdk_codesign certificate is present

   746       AC_MSG_CHECKING([if openjdk_codesign certificate is present])

   747       rm -f codesign-testfile

   748       touch codesign-testfile

   749       codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=

   750       rm -f codesign-testfile

   751       if test "x$CODESIGN" = x; then

   752         AC_MSG_RESULT([no])

   753       else

   754         AC_MSG_RESULT([yes])

   755       fi

   756     fi

   757   fi

   758 ])

   760 # Check if build directory is on local disk. If not possible to determine,

   761 # we prefer to claim it's local.

   762 # Argument 1: directory to test

   763 # Argument 2: what to do if it is on local disk

   764 # Argument 3: what to do otherwise (remote disk or failure)

   765 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],

   766 [

   767   # df -l lists only local disks; if the given directory is not found then

   768   # a non-zero exit code is given

   769   if test "x$DF" = x; then

   770     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   771       # msys does not have df; use Windows "net use" instead.

   772       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`

   773       if test "x$IS_NETWORK_DISK" = x; then

   774         $2

   775       else

   776         $3

   777       fi

   778     else

   779       # No df here, say it's local

   780       $2

   781     fi

   782   else

   783     if $DF -l $1 > /dev/null 2>&1; then

   784       $2

   785     else

   786       $3

   787     fi

   788   fi

   789 ])

   791 # Check that source files have basic read permissions set. This might

   792 # not be the case in cygwin in certain conditions.

   793 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],

   794 [

   795   if test x"$OPENJDK_BUILD_OS" = xwindows; then

   796     file_to_test="$SRC_ROOT/LICENSE"

   797     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then

   798       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])

   799     fi

   800   fi

   801 ])

   803 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],

   804 [

   805   # Did user specify any unknown variables?

   806   BASIC_CHECK_LEFTOVER_OVERRIDDEN

   808   AC_MSG_CHECKING([if build directory is on local disk])

   809   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,

   810       [OUTPUT_DIR_IS_LOCAL="yes"],

   811       [OUTPUT_DIR_IS_LOCAL="no"])

   812   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)

   814   BASIC_CHECK_SRC_PERMS

   816   # Check if the user has any old-style ALT_ variables set.

   817   FOUND_ALT_VARIABLES=`env | grep ^ALT_`

   819   # Before generating output files, test if they exist. If they do, this is a reconfigure.

   820   # Since we can't properly handle the dependencies for this, warn the user about the situation

   821   if test -e $OUTPUT_ROOT/spec.gmk; then

   822     IS_RECONFIGURE=yes

   823   else

   824     IS_RECONFIGURE=no

   825   fi

   826 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/basics.m4@5510b933fa58

common/autoconf/basics.m4