Mercurial > jdk8-mips64-public / file revision
common/autoconf/toolchain.m4@50aaf272884f
common/autoconf/toolchain.m4
Thu, 31 Aug 2017 15:40:18 +0800
- author
- aoqi
- date
- Thu, 31 Aug 2017 15:40:18 +0800
- changeset 1133
- 50aaf272884f
- parent 978
- c5a60709f587
- parent 0
- 75a576e87639
- child 1482
- 8fb429038513
- permissions
- -rw-r--r--
merge
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # $1 = compiler to test (CC or CXX)
27 # $2 = human readable name of compiler (C or C++)
28 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
29 [
30 COMPILER=[$]$1
31 COMPILER_NAME=$2
33 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
34 # Make sure we use the Sun Studio compiler and not gcc on Solaris, which won't work
35 COMPILER_VERSION_TEST=`$COMPILER -V 2>&1 | $HEAD -n 1`
36 $ECHO $COMPILER_VERSION_TEST | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
37 if test $? -ne 0; then
38 GCC_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
40 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required Sun Studio compiler.])
41 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_TEST" and with --version: "$GCC_VERSION_TEST"])
42 AC_MSG_ERROR([Sun Studio compiler is required. Try setting --with-tools-dir.])
43 else
44 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/p"`
45 COMPILER_VENDOR="Sun Studio"
46 fi
47 elif test "x$OPENJDK_TARGET_OS" = xaix; then
48 COMPILER_VERSION_TEST=`$COMPILER -qversion 2>&1 | $TAIL -n 1`
49 $ECHO $COMPILER_VERSION_TEST | $GREP "^Version: " > /dev/null
50 if test $? -ne 0; then
51 AC_MSG_ERROR([Failed to detect the compiler version of $COMPILER ....])
52 else
53 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n 's/Version: \([0-9][0-9]\.[0-9][0-9]*\).*/\1/p'`
54 COMPILER_VENDOR='IBM'
55 fi
56 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
57 # First line typically looks something like:
58 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
59 COMPILER_VERSION_TEST=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
60 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*Version \(@<:@1-9@:>@@<:@0-9.@:>@*\) .*/\1/p"`
61 COMPILER_VENDOR="Microsoft CL.EXE"
62 COMPILER_CPU_TEST=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* for \(.*\)$/\1/p"`
63 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
64 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
65 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
66 fi
67 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
68 if test "x$COMPILER_CPU_TEST" != "xx64"; then
69 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
70 fi
71 fi
72 else
73 COMPILER_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
74 # Check that this is likely to be GCC.
75 $COMPILER --version 2>&1 | $GREP "Free Software Foundation" > /dev/null
76 if test $? -ne 0; then
77 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required GCC compiler.])
78 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_TEST"])
79 AC_MSG_ERROR([GCC compiler is required. Try setting --with-tools-dir.])
80 fi
82 # First line typically looks something like:
83 # gcc (Ubuntu/Linaro 4.5.2-8ubuntu4) 4.5.2
84 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/p"`
85 COMPILER_VENDOR=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^\(.*\) @<:@1-9@:>@@<:@0-9.@:>@*/\1/p"`
86 fi
87 # This sets CC_VERSION or CXX_VERSION. (This comment is a grep marker)
88 $1_VERSION="$COMPILER_VERSION"
89 # This sets CC_VENDOR or CXX_VENDOR. (This comment is a grep marker)
90 $1_VENDOR="$COMPILER_VENDOR"
92 AC_MSG_NOTICE([Using $COMPILER_VENDOR $COMPILER_NAME compiler version $COMPILER_VERSION (located at $COMPILER)])
93 ])
96 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_SYSROOT_AND_OUT_OPTIONS],
97 [
98 ###############################################################################
99 #
100 # Configure the development tool paths and potential sysroot.
101 #
102 AC_LANG(C++)
104 # The option used to specify the target .o,.a or .so file.
105 # When compiling, how to specify the to be created object file.
106 CC_OUT_OPTION='-o$(SPACE)'
107 # When linking, how to specify the to be created executable.
108 EXE_OUT_OPTION='-o$(SPACE)'
109 # When linking, how to specify the to be created dynamically linkable library.
110 LD_OUT_OPTION='-o$(SPACE)'
111 # When archiving, how to specify the to be create static archive for object files.
112 AR_OUT_OPTION='rcs$(SPACE)'
113 AC_SUBST(CC_OUT_OPTION)
114 AC_SUBST(EXE_OUT_OPTION)
115 AC_SUBST(LD_OUT_OPTION)
116 AC_SUBST(AR_OUT_OPTION)
117 ])
119 # $1 = compiler to test (CC or CXX)
120 # $2 = human readable name of compiler (C or C++)
121 # $3 = list of compiler names to search for
122 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
123 [
124 COMPILER_NAME=$2
126 $1=
127 # If TOOLS_DIR is set, check for all compiler names in there first
128 # before checking the rest of the PATH.
129 if test -n "$TOOLS_DIR"; then
130 PATH_save="$PATH"
131 PATH="$TOOLS_DIR"
132 AC_PATH_PROGS(TOOLS_DIR_$1, $3)
133 $1=$TOOLS_DIR_$1
134 PATH="$PATH_save"
135 fi
137 # AC_PATH_PROGS can't be run multiple times with the same variable,
138 # so create a new name for this run.
139 if test "x[$]$1" = x; then
140 AC_PATH_PROGS(POTENTIAL_$1, $3)
141 $1=$POTENTIAL_$1
142 fi
144 if test "x[$]$1" = x; then
145 HELP_MSG_MISSING_DEPENDENCY([devkit])
146 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
147 fi
148 BASIC_FIXUP_EXECUTABLE($1)
149 TEST_COMPILER="[$]$1"
150 # Don't remove symbolic links on AIX because 'xlc_r' and 'xlC_r' may all be links
151 # to 'xlc' but it is crucial that we invoke the compiler with the right name!
152 if test "x$OPENJDK_BUILD_OS" != xaix; then
153 AC_MSG_CHECKING([resolved symbolic links for $1])
154 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
155 AC_MSG_RESULT([$TEST_COMPILER])
156 fi
157 AC_MSG_CHECKING([if $1 is disguised ccache])
159 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
160 if test "x$COMPILER_BASENAME" = "xccache"; then
161 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
162 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
163 # We want to control ccache invocation ourselves, so ignore this cc and try
164 # searching again.
166 # Remove the path to the fake ccache cc from the PATH
167 RETRY_COMPILER_SAVED_PATH="$PATH"
168 COMPILER_DIRNAME=`$DIRNAME [$]$1`
169 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
171 # Try again looking for our compiler
172 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
173 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
174 PATH="$RETRY_COMPILER_SAVED_PATH"
176 AC_MSG_CHECKING([for resolved symbolic links for $1])
177 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
178 AC_MSG_RESULT([$PROPER_COMPILER_$1])
179 $1="$PROPER_COMPILER_$1"
180 else
181 AC_MSG_RESULT([no, keeping $1])
182 $1="$TEST_COMPILER"
183 fi
184 TOOLCHAIN_CHECK_COMPILER_VERSION([$1], [$COMPILER_NAME])
185 ])
188 AC_DEFUN([TOOLCHAIN_SETUP_PATHS],
189 [
190 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
191 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
192 TOOLCHAIN_SETUP_MSVCR_DLL
193 BASIC_DEPRECATED_ARG_WITH([dxsdk])
194 BASIC_DEPRECATED_ARG_WITH([dxsdk-lib])
195 BASIC_DEPRECATED_ARG_WITH([dxsdk-include])
196 fi
198 AC_SUBST(MSVCR_DLL)
200 # If --build AND --host is set, then the configure script will find any
201 # cross compilation tools in the PATH. Cross compilation tools
202 # follows the cross compilation standard where they are prefixed with ${host}.
203 # For example the binary i686-sun-solaris2.10-gcc
204 # will cross compile for i686-sun-solaris2.10
205 # If neither of build and host is not set, then build=host and the
206 # default compiler found in the path will be used.
207 # Setting only --host, does not seem to be really supported.
208 # Please set both --build and --host if you want to cross compile.
210 if test "x$COMPILE_TYPE" = "xcross"; then
211 # Now we to find a C/C++ compiler that can build executables for the build
212 # platform. We can't use the AC_PROG_CC macro, since it can only be used
213 # once. Also, we need to do this before adding a tools dir to the path,
214 # otherwise we might pick up cross-compilers which don't use standard naming.
215 # Otherwise, we'll set the BUILD_tools to the native tools, but that'll have
216 # to wait until they are properly discovered.
217 AC_PATH_PROGS(BUILD_CC, [cl cc gcc])
218 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
219 AC_PATH_PROGS(BUILD_CXX, [cl CC g++])
220 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
221 AC_PATH_PROG(BUILD_LD, ld)
222 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
223 fi
224 AC_SUBST(BUILD_CC)
225 AC_SUBST(BUILD_CXX)
226 AC_SUBST(BUILD_LD)
228 # If a devkit is found on the builddeps server, then prepend its path to the
229 # PATH variable. If there are cross compilers available in the devkit, these
230 # will be found by AC_PROG_CC et al.
231 DEVKIT=
232 BDEPS_CHECK_MODULE(DEVKIT, devkit, xxx,
233 [
234 # Found devkit
235 PATH="$DEVKIT/bin:$PATH"
236 SYS_ROOT="$DEVKIT/${rewritten_target}/sys-root"
237 if test "x$x_includes" = "xNONE"; then
238 x_includes="$SYS_ROOT/usr/include/X11"
239 fi
240 if test "x$x_libraries" = "xNONE"; then
241 x_libraries="$SYS_ROOT/usr/lib"
242 fi
243 ],
244 [])
246 # Store the CFLAGS etal passed to the configure script.
247 ORG_CFLAGS="$CFLAGS"
248 ORG_CXXFLAGS="$CXXFLAGS"
249 ORG_OBJCFLAGS="$OBJCFLAGS"
251 # autoconf magic only relies on PATH, so update it if tools dir is specified
252 OLD_PATH="$PATH"
253 if test "x$TOOLS_DIR" != x; then
254 PATH=$TOOLS_DIR:$PATH
255 fi
258 ### Locate C compiler (CC)
260 # On windows, only cl.exe is supported.
261 # On Solaris, cc is preferred to gcc.
262 # Elsewhere, gcc is preferred to cc.
264 if test "x$CC" != x; then
265 COMPILER_CHECK_LIST="$CC"
266 elif test "x$OPENJDK_TARGET_OS" = "xwindows"; then
267 COMPILER_CHECK_LIST="cl"
268 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
269 COMPILER_CHECK_LIST="cc gcc"
270 elif test "x$OPENJDK_TARGET_OS" = "xaix"; then
271 # Do not probe for cc on AIX.
272 COMPILER_CHECK_LIST="xlc_r"
273 else
274 COMPILER_CHECK_LIST="gcc cc"
275 fi
277 TOOLCHAIN_FIND_COMPILER([CC],[C],[$COMPILER_CHECK_LIST])
278 # Now that we have resolved CC ourself, let autoconf have its go at it
279 AC_PROG_CC([$CC])
281 # Option used to tell the compiler whether to create 32- or 64-bit executables
282 # Notice that CC contains the full compiler path at this point.
283 case $CC in
284 *xlc_r) COMPILER_TARGET_BITS_FLAG="-q";;
285 *) COMPILER_TARGET_BITS_FLAG="-m";;
286 esac
287 AC_SUBST(COMPILER_TARGET_BITS_FLAG)
289 ### Locate C++ compiler (CXX)
291 if test "x$CXX" != x; then
292 COMPILER_CHECK_LIST="$CXX"
293 elif test "x$OPENJDK_TARGET_OS" = "xwindows"; then
294 COMPILER_CHECK_LIST="cl"
295 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
296 COMPILER_CHECK_LIST="CC g++"
297 elif test "x$OPENJDK_TARGET_OS" = "xaix"; then
298 # Do not probe for CC on AIX .
299 COMPILER_CHECK_LIST="xlC_r"
300 else
301 COMPILER_CHECK_LIST="g++ CC"
302 fi
304 TOOLCHAIN_FIND_COMPILER([CXX],[C++],[$COMPILER_CHECK_LIST])
305 # Now that we have resolved CXX ourself, let autoconf have its go at it
306 AC_PROG_CXX([$CXX])
308 ### Locate other tools
310 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
311 AC_PROG_OBJC
312 BASIC_FIXUP_EXECUTABLE(OBJC)
313 else
314 OBJC=
315 fi
317 # Restore the flags to the user specified values.
318 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
319 CFLAGS="$ORG_CFLAGS"
320 CXXFLAGS="$ORG_CXXFLAGS"
321 OBJCFLAGS="$ORG_OBJCFLAGS"
323 LD="$CC"
324 LDEXE="$CC"
325 LDCXX="$CXX"
326 LDEXECXX="$CXX"
327 AC_SUBST(LD)
328 # LDEXE is the linker to use, when creating executables.
329 AC_SUBST(LDEXE)
330 # Linking C++ libraries.
331 AC_SUBST(LDCXX)
332 # Linking C++ executables.
333 AC_SUBST(LDEXECXX)
335 if test "x$OPENJDK_TARGET_OS" != xwindows; then
336 AC_CHECK_TOOL(AR, ar)
337 BASIC_FIXUP_EXECUTABLE(AR)
338 fi
339 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
340 ARFLAGS="-r"
341 elif test "x$OPENJDK_TARGET_OS" = xaix; then
342 ARFLAGS="-X64"
343 else
344 ARFLAGS=""
345 fi
346 AC_SUBST(ARFLAGS)
348 # For hotspot, we need these in Windows mixed path; other platforms keep them the same
349 HOTSPOT_CXX="$CXX"
350 HOTSPOT_LD="$LD"
351 AC_SUBST(HOTSPOT_CXX)
352 AC_SUBST(HOTSPOT_LD)
354 COMPILER_NAME=gcc
355 COMPILER_TYPE=CC
356 AS_IF([test "x$OPENJDK_TARGET_OS" = xwindows], [
357 # For now, assume that we are always compiling using cl.exe.
358 CC_OUT_OPTION=-Fo
359 EXE_OUT_OPTION=-out:
360 LD_OUT_OPTION=-out:
361 AR_OUT_OPTION=-out:
362 # On Windows, reject /usr/bin/link (as determined in CYGWIN_LINK), which is a cygwin
363 # program for something completely different.
364 AC_CHECK_PROG([WINLD], [link],[link],,, [$CYGWIN_LINK])
365 # Since we must ignore the first found link, WINLD will contain
366 # the full path to the link.exe program.
367 BASIC_FIXUP_EXECUTABLE(WINLD)
368 printf "Windows linker was found at $WINLD\n"
369 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
370 "$WINLD" --version > /dev/null
371 if test $? -eq 0 ; then
372 AC_MSG_RESULT([no])
373 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
374 else
375 AC_MSG_RESULT([yes])
376 fi
377 LD="$WINLD"
378 LDEXE="$WINLD"
379 LDCXX="$WINLD"
380 LDEXECXX="$WINLD"
382 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
383 BASIC_FIXUP_EXECUTABLE(MT)
384 # The resource compiler
385 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
386 BASIC_FIXUP_EXECUTABLE(RC)
388 # For hotspot, we need these in Windows mixed path,
389 # so rewrite them all. Need added .exe suffix.
390 HOTSPOT_CXX="$CXX.exe"
391 HOTSPOT_LD="$LD.exe"
392 HOTSPOT_MT="$MT.exe"
393 HOTSPOT_RC="$RC.exe"
394 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
395 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
396 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
397 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
398 AC_SUBST(HOTSPOT_MT)
399 AC_SUBST(HOTSPOT_RC)
401 RC_FLAGS="-nologo -l 0x409 -r"
402 AS_IF([test "x$VARIANT" = xOPT], [
403 RC_FLAGS="$RC_FLAGS -d NDEBUG"
404 ])
406 # The version variables used to create RC_FLAGS may be overridden
407 # in a custom configure script, or possibly the command line.
408 # Let those variables be expanded at make time in spec.gmk.
409 # The \$ are escaped to the shell, and the $(...) variables
410 # are evaluated by make.
411 RC_FLAGS="$RC_FLAGS \
412 -d \"JDK_BUILD_ID=\$(FULL_VERSION)\" \
413 -d \"JDK_COMPANY=\$(COMPANY_NAME)\" \
414 -d \"JDK_COMPONENT=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) binary\" \
415 -d \"JDK_VER=\$(JDK_MINOR_VERSION).\$(JDK_MICRO_VERSION).\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0).\$(COOKED_BUILD_NUMBER)\" \
416 -d \"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\" \
417 -d \"JDK_NAME=\$(PRODUCT_NAME) \$(JDK_RC_PLATFORM_NAME) \$(JDK_MINOR_VERSION) \$(JDK_UPDATE_META_TAG)\" \
418 -d \"JDK_FVER=\$(JDK_MINOR_VERSION),\$(JDK_MICRO_VERSION),\$(if \$(JDK_UPDATE_VERSION),\$(JDK_UPDATE_VERSION),0),\$(COOKED_BUILD_NUMBER)\""
420 # lib.exe is used to create static libraries.
421 AC_CHECK_PROG([WINAR], [lib],[lib],,,)
422 BASIC_FIXUP_EXECUTABLE(WINAR)
423 AR="$WINAR"
424 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
426 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
427 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
429 COMPILER_TYPE=CL
430 CCXXFLAGS="$CCXXFLAGS -nologo"
431 ])
432 AC_SUBST(RC_FLAGS)
433 AC_SUBST(COMPILER_TYPE)
435 AC_PROG_CPP
436 BASIC_FIXUP_EXECUTABLE(CPP)
438 AC_PROG_CXXCPP
439 BASIC_FIXUP_EXECUTABLE(CXXCPP)
441 if test "x$COMPILE_TYPE" != "xcross"; then
442 # If we are not cross compiling, use the same compilers for
443 # building the build platform executables. The cross-compilation
444 # case needed to be done earlier, but this can only be done after
445 # the native tools have been localized.
446 BUILD_CC="$CC"
447 BUILD_CXX="$CXX"
448 BUILD_LD="$LD"
449 fi
451 # for solaris we really need solaris tools, and not gnu equivalent
452 # these seems to normally reside in /usr/ccs/bin so add that to path before
453 # starting to probe
454 #
455 # NOTE: I add this /usr/ccs/bin after TOOLS but before OLD_PATH
456 # so that it can be overriden --with-tools-dir
457 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
458 PATH="${TOOLS_DIR}:/usr/ccs/bin:${OLD_PATH}"
459 fi
461 # Find the right assembler.
462 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
463 AC_PATH_PROG(AS, as)
464 BASIC_FIXUP_EXECUTABLE(AS)
465 else
466 AS="$CC -c"
467 fi
468 AC_SUBST(AS)
470 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
471 AC_PATH_PROG(NM, nm)
472 BASIC_FIXUP_EXECUTABLE(NM)
473 AC_PATH_PROG(GNM, gnm)
474 BASIC_FIXUP_EXECUTABLE(GNM)
475 AC_PATH_PROG(STRIP, strip)
476 BASIC_FIXUP_EXECUTABLE(STRIP)
477 AC_PATH_PROG(MCS, mcs)
478 BASIC_FIXUP_EXECUTABLE(MCS)
479 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
480 AC_CHECK_TOOL(NM, nm)
481 BASIC_FIXUP_EXECUTABLE(NM)
482 GNM="$NM"
483 AC_SUBST(GNM)
484 AC_CHECK_TOOL(STRIP, strip)
485 BASIC_FIXUP_EXECUTABLE(STRIP)
486 fi
488 # objcopy is used for moving debug symbols to separate files when
489 # full debug symbols are enabled.
490 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
491 AC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
492 # Only call fixup if objcopy was found.
493 if test -n "$OBJCOPY"; then
494 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
495 fi
496 fi
498 AC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
499 if test "x$OBJDUMP" != x; then
500 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE bails if argument is missing.
501 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
502 fi
504 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
505 AC_PATH_PROG(LIPO, lipo)
506 BASIC_FIXUP_EXECUTABLE(LIPO)
507 fi
509 TOOLCHAIN_SETUP_JTREG
511 # Restore old path without tools dir
512 PATH="$OLD_PATH"
513 ])
516 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_LIBS],
517 [
519 ###############################################################################
520 #
521 # How to compile shared libraries.
522 #
524 if test "x$GCC" = xyes; then
525 COMPILER_NAME=gcc
526 PICFLAG="-fPIC"
527 LIBRARY_PREFIX=lib
528 SHARED_LIBRARY='lib[$]1.so'
529 STATIC_LIBRARY='lib[$]1.a'
530 SHARED_LIBRARY_FLAGS="-shared"
531 SHARED_LIBRARY_SUFFIX='.so'
532 STATIC_LIBRARY_SUFFIX='.a'
533 OBJ_SUFFIX='.o'
534 EXE_SUFFIX=''
535 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
536 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
537 C_FLAG_REORDER=''
538 CXX_FLAG_REORDER=''
539 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -z -Xlinker origin -Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
540 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
541 LD="$CC"
542 LDEXE="$CC"
543 LDCXX="$CXX"
544 LDEXECXX="$CXX"
545 POST_STRIP_CMD="$STRIP -g"
547 # Linking is different on MacOSX
548 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
549 # Might change in the future to clang.
550 COMPILER_NAME=gcc
551 SHARED_LIBRARY='lib[$]1.dylib'
552 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
553 SHARED_LIBRARY_SUFFIX='.dylib'
554 EXE_SUFFIX=''
555 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
556 SET_SHARED_LIBRARY_MAPFILE=''
557 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
558 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
559 POST_STRIP_CMD="$STRIP -S"
560 fi
561 else
562 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
563 # If it is not gcc, then assume it is the Oracle Solaris Studio Compiler
564 COMPILER_NAME=ossc
565 PICFLAG="-KPIC"
566 LIBRARY_PREFIX=lib
567 SHARED_LIBRARY='lib[$]1.so'
568 STATIC_LIBRARY='lib[$]1.a'
569 SHARED_LIBRARY_FLAGS="-G"
570 SHARED_LIBRARY_SUFFIX='.so'
571 STATIC_LIBRARY_SUFFIX='.a'
572 OBJ_SUFFIX='.o'
573 EXE_SUFFIX=''
574 SET_SHARED_LIBRARY_NAME=''
575 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
576 C_FLAG_REORDER='-xF'
577 CXX_FLAG_REORDER='-xF'
578 SET_SHARED_LIBRARY_ORIGIN='-R\$$$$ORIGIN[$]1'
579 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
580 CFLAGS_JDK="${CFLAGS_JDK} -D__solaris__"
581 CXXFLAGS_JDK="${CXXFLAGS_JDK} -D__solaris__"
582 CFLAGS_JDKLIB_EXTRA='-xstrconst'
583 POST_STRIP_CMD="$STRIP -x"
584 POST_MCS_CMD="$MCS -d -a \"JDK $FULL_VERSION\""
585 fi
586 if test "x$OPENJDK_TARGET_OS" = xaix; then
587 COMPILER_NAME=xlc
588 PICFLAG="-qpic=large"
589 LIBRARY_PREFIX=lib
590 SHARED_LIBRARY='lib[$]1.so'
591 STATIC_LIBRARY='lib[$]1.a'
592 SHARED_LIBRARY_FLAGS="-qmkshrobj"
593 SHARED_LIBRARY_SUFFIX='.so'
594 STATIC_LIBRARY_SUFFIX='.a'
595 OBJ_SUFFIX='.o'
596 EXE_SUFFIX=''
597 SET_SHARED_LIBRARY_NAME=''
598 SET_SHARED_LIBRARY_MAPFILE=''
599 C_FLAG_REORDER=''
600 CXX_FLAG_REORDER=''
601 SET_SHARED_LIBRARY_ORIGIN=''
602 SET_EXECUTABLE_ORIGIN=""
603 CFLAGS_JDK=""
604 CXXFLAGS_JDK=""
605 CFLAGS_JDKLIB_EXTRA=''
606 POST_STRIP_CMD="$STRIP -X32_64"
607 POST_MCS_CMD=""
608 fi
609 if test "x$OPENJDK_TARGET_OS" = xwindows; then
610 # If it is not gcc, then assume it is the MS Visual Studio compiler
611 COMPILER_NAME=cl
612 PICFLAG=""
613 LIBRARY_PREFIX=
614 SHARED_LIBRARY='[$]1.dll'
615 STATIC_LIBRARY='[$]1.lib'
616 SHARED_LIBRARY_FLAGS="-LD"
617 SHARED_LIBRARY_SUFFIX='.dll'
618 STATIC_LIBRARY_SUFFIX='.lib'
619 OBJ_SUFFIX='.obj'
620 EXE_SUFFIX='.exe'
621 SET_SHARED_LIBRARY_NAME=''
622 SET_SHARED_LIBRARY_MAPFILE=''
623 SET_SHARED_LIBRARY_ORIGIN=''
624 SET_EXECUTABLE_ORIGIN=''
625 fi
626 fi
628 AC_SUBST(COMPILER_NAME)
629 AC_SUBST(OBJ_SUFFIX)
630 AC_SUBST(SHARED_LIBRARY)
631 AC_SUBST(STATIC_LIBRARY)
632 AC_SUBST(LIBRARY_PREFIX)
633 AC_SUBST(SHARED_LIBRARY_SUFFIX)
634 AC_SUBST(STATIC_LIBRARY_SUFFIX)
635 AC_SUBST(EXE_SUFFIX)
636 AC_SUBST(SHARED_LIBRARY_FLAGS)
637 AC_SUBST(SET_SHARED_LIBRARY_NAME)
638 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
639 AC_SUBST(C_FLAG_REORDER)
640 AC_SUBST(CXX_FLAG_REORDER)
641 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
642 AC_SUBST(SET_EXECUTABLE_ORIGIN)
643 AC_SUBST(POST_STRIP_CMD)
644 AC_SUBST(POST_MCS_CMD)
646 # The (cross) compiler is now configured, we can now test capabilities
647 # of the target platform.
648 ])
650 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
651 [
653 ###############################################################################
654 #
655 # Setup the opt flags for different compilers
656 # and different operating systems.
657 #
659 #
660 # NOTE: check for -mstackrealign needs to be below potential addition of -m32
661 #
662 if test "x$OPENJDK_TARGET_CPU_BITS" = x32 && test "x$OPENJDK_TARGET_OS" = xmacosx; then
663 # On 32-bit MacOSX the OS requires C-entry points to be 16 byte aligned.
664 # While waiting for a better solution, the current workaround is to use -mstackrealign.
665 CFLAGS="$CFLAGS -mstackrealign"
666 AC_MSG_CHECKING([if 32-bit compiler supports -mstackrealign])
667 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])],
668 [
669 AC_MSG_RESULT([yes])
670 ],
671 [
672 AC_MSG_RESULT([no])
673 AC_MSG_ERROR([The selected compiler $CXX does not support -mstackrealign! Try to put another compiler in the path.])
674 ]
675 )
676 fi
678 C_FLAG_DEPS="-MMD -MF"
679 CXX_FLAG_DEPS="-MMD -MF"
681 case $COMPILER_TYPE in
682 CC )
683 case $COMPILER_NAME in
684 gcc )
685 case $OPENJDK_TARGET_OS in
686 macosx )
687 # On MacOSX we optimize for size, something
688 # we should do for all platforms?
689 C_O_FLAG_HI="-Os"
690 C_O_FLAG_NORM="-Os"
691 C_O_FLAG_NONE=""
692 ;;
693 *)
694 C_O_FLAG_HI="-O3"
695 C_O_FLAG_NORM="-O2"
696 C_O_FLAG_NONE="-O0"
697 ;;
698 esac
699 CXX_O_FLAG_HI="$C_O_FLAG_HI"
700 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
701 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
702 CFLAGS_DEBUG_SYMBOLS="-g"
703 CXXFLAGS_DEBUG_SYMBOLS="-g"
704 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
705 CFLAGS_DEBUG_SYMBOLS="-g1"
706 CXXFLAGS_DEBUG_SYMBOLS="-g1"
707 fi
708 ;;
709 ossc )
710 #
711 # Forte has different names for this with their C++ compiler...
712 #
713 C_FLAG_DEPS="-xMMD -xMF"
714 CXX_FLAG_DEPS="-xMMD -xMF"
716 # Extra options used with HIGHEST
717 #
718 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
719 # done with care, there are some assumptions below that need to
720 # be understood about the use of pointers, and IEEE behavior.
721 #
722 # Use non-standard floating point mode (not IEEE 754)
723 CC_HIGHEST="$CC_HIGHEST -fns"
724 # Do some simplification of floating point arithmetic (not IEEE 754)
725 CC_HIGHEST="$CC_HIGHEST -fsimple"
726 # Use single precision floating point with 'float'
727 CC_HIGHEST="$CC_HIGHEST -fsingle"
728 # Assume memory references via basic pointer types do not alias
729 # (Source with excessing pointer casting and data access with mixed
730 # pointer types are not recommended)
731 CC_HIGHEST="$CC_HIGHEST -xalias_level=basic"
732 # Use intrinsic or inline versions for math/std functions
733 # (If you expect perfect errno behavior, do not use this)
734 CC_HIGHEST="$CC_HIGHEST -xbuiltin=%all"
735 # Loop data dependency optimizations (need -xO3 or higher)
736 CC_HIGHEST="$CC_HIGHEST -xdepend"
737 # Pointer parameters to functions do not overlap
738 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
739 # If you pass in multiple pointers to the same data, do not use this)
740 CC_HIGHEST="$CC_HIGHEST -xrestrict"
741 # Inline some library routines
742 # (If you expect perfect errno behavior, do not use this)
743 CC_HIGHEST="$CC_HIGHEST -xlibmil"
744 # Use optimized math routines
745 # (If you expect perfect errno behavior, do not use this)
746 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
747 #CC_HIGHEST="$CC_HIGHEST -xlibmopt"
749 if test "x$OPENJDK_TARGET_CPU" = xsparc; then
750 CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
751 CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
752 fi
754 case $OPENJDK_TARGET_CPU_ARCH in
755 x86)
756 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xregs=no%frameptr"
757 C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
758 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
759 C_O_FLAG_NONE="-xregs=no%frameptr"
760 CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
761 CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
762 CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
763 CXX_O_FLAG_NONE="-xregs=no%frameptr"
764 if test "x$OPENJDK_TARGET_CPU" = xx86; then
765 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
766 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
767 fi
768 ;;
769 sparc)
770 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
771 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
772 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
773 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
774 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
775 C_O_FLAG_NONE=""
776 CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
777 CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
778 CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
779 CXX_O_FLAG_NONE=""
780 ;;
781 esac
783 CFLAGS_DEBUG_SYMBOLS="-g -xs"
784 CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
785 ;;
786 xlc )
787 C_FLAG_DEPS="-qmakedep=gcc -MF"
788 CXX_FLAG_DEPS="-qmakedep=gcc -MF"
789 C_O_FLAG_HIGHEST="-O3"
790 C_O_FLAG_HI="-O3 -qstrict"
791 C_O_FLAG_NORM="-O2"
792 C_O_FLAG_NONE=""
793 CXX_O_FLAG_HIGHEST="-O3"
794 CXX_O_FLAG_HI="-O3 -qstrict"
795 CXX_O_FLAG_NORM="-O2"
796 CXX_O_FLAG_NONE=""
797 CFLAGS_DEBUG_SYMBOLS="-g"
798 CXXFLAGS_DEBUG_SYMBOLS="-g"
799 LDFLAGS_JDK="${LDFLAGS_JDK} -q64 -brtl -bnolibpath -liconv -bexpall"
800 CFLAGS_JDK="${CFLAGS_JDK} -qchars=signed -q64 -qfullpath -qsaveopt"
801 CXXFLAGS_JDK="${CXXFLAGS_JDK} -qchars=signed -q64 -qfullpath -qsaveopt"
802 ;;
803 esac
804 ;;
805 CL )
806 C_O_FLAG_HIGHEST="-O2"
807 C_O_FLAG_HI="-O1"
808 C_O_FLAG_NORM="-O1"
809 C_O_FLAG_NONE="-Od"
810 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
811 CXX_O_FLAG_HI="$C_O_FLAG_HI"
812 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
813 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
814 ;;
815 esac
817 if test -z "$C_O_FLAG_HIGHEST"; then
818 C_O_FLAG_HIGHEST="$C_O_FLAG_HI"
819 fi
821 if test -z "$CXX_O_FLAG_HIGHEST"; then
822 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HI"
823 fi
825 AC_SUBST(C_O_FLAG_HIGHEST)
826 AC_SUBST(C_O_FLAG_HI)
827 AC_SUBST(C_O_FLAG_NORM)
828 AC_SUBST(C_O_FLAG_NONE)
829 AC_SUBST(CXX_O_FLAG_HIGHEST)
830 AC_SUBST(CXX_O_FLAG_HI)
831 AC_SUBST(CXX_O_FLAG_NORM)
832 AC_SUBST(CXX_O_FLAG_NONE)
833 AC_SUBST(C_FLAG_DEPS)
834 AC_SUBST(CXX_FLAG_DEPS)
835 ])
837 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_JDK],
838 [
840 if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
841 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
842 fi
844 if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
845 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
846 fi
848 if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
849 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
850 fi
852 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
853 [extra flags to be used when compiling jdk c-files])])
855 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
856 [extra flags to be used when compiling jdk c++-files])])
858 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
859 [extra flags to be used when linking jdk])])
861 CFLAGS_JDK="${CFLAGS_JDK} $with_extra_cflags"
862 CXXFLAGS_JDK="${CXXFLAGS_JDK} $with_extra_cxxflags"
863 LDFLAGS_JDK="${LDFLAGS_JDK} $with_extra_ldflags"
865 # Hotspot needs these set in their legacy form
866 LEGACY_EXTRA_CFLAGS=$with_extra_cflags
867 LEGACY_EXTRA_CXXFLAGS=$with_extra_cxxflags
868 LEGACY_EXTRA_LDFLAGS=$with_extra_ldflags
870 AC_SUBST(LEGACY_EXTRA_CFLAGS)
871 AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
872 AC_SUBST(LEGACY_EXTRA_LDFLAGS)
874 ###############################################################################
875 #
876 # Now setup the CFLAGS and LDFLAGS for the JDK build.
877 # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
878 #
879 case $COMPILER_NAME in
880 gcc )
881 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -W -Wall -Wno-unused -Wno-parentheses \
882 -pipe \
883 -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
884 case $OPENJDK_TARGET_CPU_ARCH in
885 arm )
886 # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
887 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
888 ;;
889 ppc )
890 # on ppc we don't prevent gcc to omit frame pointer nor strict-aliasing
891 ;;
892 * )
893 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -fno-omit-frame-pointer"
894 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
895 ;;
896 esac
897 ;;
898 ossc )
899 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
900 case $OPENJDK_TARGET_CPU_ARCH in
901 x86 )
902 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_TARGET_CPU_LEGACY_LIB"
903 CFLAGS_JDK="$CFLAGS_JDK -erroff=E_BAD_PRAGMA_PACK_VALUE"
904 ;;
905 esac
907 CFLAGS_JDK="$CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
908 CXXFLAGS_JDK="$CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
910 LDFLAGS_JDK="$LDFLAGS_JDK -z defs -xildoff -ztext"
911 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK -norunpath -xnolib"
912 ;;
913 xlc )
914 CFLAGS_JDK="$CFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
915 CXXFLAGS_JDK="$CXXFLAGS_JDK -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE -DSTDC"
917 LDFLAGS_JDK="$LDFLAGS_JDK"
918 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK"
919 ;;
920 cl )
921 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -Zi -MD -Zc:wchar_t- -W3 -wd4800 \
922 -D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB -DWIN32_LEAN_AND_MEAN \
923 -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
924 -DWIN32 -DIAL"
925 case $OPENJDK_TARGET_CPU in
926 x86 )
927 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_X86_ -Dx86"
928 ;;
929 x86_64 )
930 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_AMD64_ -Damd64"
931 ;;
932 esac
933 ;;
934 esac
936 ###############################################################################
938 # Adjust flags according to debug level.
939 case $DEBUG_LEVEL in
940 fastdebug )
941 CFLAGS_JDK="$CFLAGS_JDK $CFLAGS_DEBUG_SYMBOLS"
942 CXXFLAGS_JDK="$CXXFLAGS_JDK $CXXFLAGS_DEBUG_SYMBOLS"
943 C_O_FLAG_HI="$C_O_FLAG_NORM"
944 C_O_FLAG_NORM="$C_O_FLAG_NORM"
945 CXX_O_FLAG_HI="$CXX_O_FLAG_NORM"
946 CXX_O_FLAG_NORM="$CXX_O_FLAG_NORM"
947 JAVAC_FLAGS="$JAVAC_FLAGS -g"
948 ;;
949 slowdebug )
950 CFLAGS_JDK="$CFLAGS_JDK $CFLAGS_DEBUG_SYMBOLS"
951 CXXFLAGS_JDK="$CXXFLAGS_JDK $CXXFLAGS_DEBUG_SYMBOLS"
952 C_O_FLAG_HI="$C_O_FLAG_NONE"
953 C_O_FLAG_NORM="$C_O_FLAG_NONE"
954 CXX_O_FLAG_HI="$CXX_O_FLAG_NONE"
955 CXX_O_FLAG_NORM="$CXX_O_FLAG_NONE"
956 JAVAC_FLAGS="$JAVAC_FLAGS -g"
957 ;;
958 esac
960 CCXXFLAGS_JDK="$CCXXFLAGS_JDK $ADD_LP64"
962 # The package path is used only on macosx?
963 PACKAGE_PATH=/opt/local
964 AC_SUBST(PACKAGE_PATH)
966 if test "x$OPENJDK_TARGET_CPU_ENDIAN" = xlittle; then
967 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
968 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
969 # (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
970 # Note: -Dmacro is the same as #define macro 1
971 # -Dmacro= is the same as #define macro
972 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
973 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
974 else
975 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
976 fi
977 else
978 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_BIG_ENDIAN"
979 fi
980 if test "x$OPENJDK_TARGET_OS" = xlinux; then
981 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DLINUX"
982 fi
983 if test "x$OPENJDK_TARGET_OS" = xwindows; then
984 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DWINDOWS"
985 fi
986 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
987 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DSOLARIS"
988 fi
989 if test "x$OPENJDK_TARGET_OS" = xaix; then
990 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DAIX -DPPC64"
991 fi
992 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
993 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMACOSX -D_ALLBSD_SOURCE -D_DARWIN_UNLIMITED_SELECT"
994 # Setting these parameters makes it an error to link to macosx APIs that are
995 # newer than the given OS version and makes the linked binaries compatible even
996 # if built on a newer version of the OS.
997 # The expected format is X.Y.Z
998 MACOSX_VERSION_MIN=10.7.0
999 AC_SUBST(MACOSX_VERSION_MIN)
1000 # The macro takes the version with no dots, ex: 1070
1001 # Let the flags variables get resolved in make for easier override on make
1002 # command line.
1003 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
1004 LDFLAGS_JDK="$LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
1005 fi
1006 if test "x$OPENJDK_TARGET_OS" = xbsd; then
1007 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DBSD -D_ALLBSD_SOURCE"
1008 fi
1009 if test "x$DEBUG_LEVEL" = xrelease; then
1010 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DNDEBUG"
1011 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
1012 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DTRIMMED"
1013 fi
1014 else
1015 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DDEBUG"
1016 fi
1018 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DARCH='\"$OPENJDK_TARGET_CPU_LEGACY\"' -D$OPENJDK_TARGET_CPU_LEGACY"
1019 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DRELEASE='\"\$(RELEASE)\"'"
1021 CCXXFLAGS_JDK="$CCXXFLAGS_JDK \
1022 -I${JDK_OUTPUTDIR}/include \
1023 -I${JDK_OUTPUTDIR}/include/$OPENJDK_TARGET_OS \
1024 -I${JDK_TOPDIR}/src/share/javavm/export \
1025 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_EXPORT_DIR/javavm/export \
1026 -I${JDK_TOPDIR}/src/share/native/common \
1027 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/native/common"
1029 # The shared libraries are compiled using the picflag.
1030 CFLAGS_JDKLIB="$CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
1031 CXXFLAGS_JDKLIB="$CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA "
1033 # Executable flags
1034 CFLAGS_JDKEXE="$CCXXFLAGS_JDK $CFLAGS_JDK"
1035 CXXFLAGS_JDKEXE="$CCXXFLAGS_JDK $CXXFLAGS_JDK"
1037 # Now this is odd. The JDK native libraries have to link against libjvm.so
1038 # On 32-bit machines there is normally two distinct libjvm.so:s, client and server.
1039 # Which should we link to? Are we lucky enough that the binary api to the libjvm.so library
1040 # is identical for client and server? Yes. Which is picked at runtime (client or server)?
1041 # Neither, since the chosen libjvm.so has already been loaded by the launcher, all the following
1042 # libraries will link to whatever is in memory. Yuck.
1043 #
1044 # Thus we offer the compiler to find libjvm.so first in server then in client. It works. Ugh.
1045 if test "x$COMPILER_NAME" = xcl; then
1046 LDFLAGS_JDK="$LDFLAGS_JDK -nologo -opt:ref -incremental:no"
1047 if test "x$OPENJDK_TARGET_CPU" = xx86; then
1048 LDFLAGS_JDK="$LDFLAGS_JDK -safeseh"
1049 fi
1050 # TODO: make -debug optional "--disable-full-debug-symbols"
1051 LDFLAGS_JDK="$LDFLAGS_JDK -debug"
1052 LDFLAGS_JDKLIB="${LDFLAGS_JDK} -dll -libpath:${JDK_OUTPUTDIR}/lib"
1053 LDFLAGS_JDKLIB_SUFFIX=""
1054 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
1055 LDFLAGS_STACK_SIZE=1048576
1056 else
1057 LDFLAGS_STACK_SIZE=327680
1058 fi
1059 LDFLAGS_JDKEXE="${LDFLAGS_JDK} /STACK:$LDFLAGS_STACK_SIZE"
1060 else
1061 if test "x$COMPILER_NAME" = xgcc; then
1062 # If this is a --hash-style=gnu system, use --hash-style=both, why?
1063 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
1064 if test -n "$HAS_GNU_HASH"; then
1065 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker --hash-style=both "
1066 fi
1067 if test "x$OPENJDK_TARGET_OS" = xlinux; then
1068 # And since we now know that the linker is gnu, then add -z defs, to forbid
1069 # undefined symbols in object files.
1070 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -z -Xlinker defs"
1071 if test "x$DEBUG_LEVEL" = "xrelease"; then
1072 # When building release libraries, tell the linker optimize them.
1073 # Should this be supplied to the OSS linker as well?
1074 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -O1"
1075 fi
1076 fi
1077 fi
1078 LDFLAGS_JDKLIB="${LDFLAGS_JDK} $SHARED_LIBRARY_FLAGS \
1079 -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}"
1081 # On some platforms (mac) the linker warns about non existing -L dirs.
1082 # Add server first if available. Linking aginst client does not always produce the same results.
1083 # Only add client dir if client is being built. Add minimal (note not minimal1) if only building minimal1.
1084 # Default to server for other variants.
1085 if test "x$JVM_VARIANT_SERVER" = xtrue; then
1086 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
1087 elif test "x$JVM_VARIANT_CLIENT" = xtrue; then
1088 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/client"
1089 elif test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
1090 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/minimal"
1091 else
1092 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
1093 fi
1095 LDFLAGS_JDKLIB_SUFFIX="-ljava -ljvm"
1096 if test "x$COMPILER_NAME" = xossc; then
1097 LDFLAGS_JDKLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX -lc"
1098 fi
1100 LDFLAGS_JDKEXE="${LDFLAGS_JDK}"
1101 if test "x$OPENJDK_TARGET_OS" = xlinux; then
1102 LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE -Xlinker --allow-shlib-undefined"
1103 fi
1104 fi
1106 AC_SUBST(CFLAGS_JDKLIB)
1107 AC_SUBST(CFLAGS_JDKEXE)
1109 AC_SUBST(CXXFLAGS_JDKLIB)
1110 AC_SUBST(CXXFLAGS_JDKEXE)
1112 AC_SUBST(LDFLAGS_JDKLIB)
1113 AC_SUBST(LDFLAGS_JDKEXE)
1114 AC_SUBST(LDFLAGS_JDKLIB_SUFFIX)
1115 AC_SUBST(LDFLAGS_JDKEXE_SUFFIX)
1116 AC_SUBST(LDFLAGS_CXX_JDK)
1117 ])
1120 # TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([ARGUMENT], [RUN-IF-TRUE],
1121 # [RUN-IF-FALSE])
1122 # ------------------------------------------------------------
1123 # Check that the c and c++ compilers support an argument
1124 AC_DEFUN([TOOLCHAIN_COMPILER_CHECK_ARGUMENTS],
1125 [
1126 AC_MSG_CHECKING([if compiler supports "$1"])
1127 supports=yes
1129 saved_cflags="$CFLAGS"
1130 CFLAGS="$CFLAGS $1"
1131 AC_LANG_PUSH([C])
1132 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
1133 [supports=no])
1134 AC_LANG_POP([C])
1135 CFLAGS="$saved_cflags"
1137 saved_cxxflags="$CXXFLAGS"
1138 CXXFLAGS="$CXXFLAG $1"
1139 AC_LANG_PUSH([C++])
1140 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[int i;]])], [],
1141 [supports=no])
1142 AC_LANG_POP([C++])
1143 CXXFLAGS="$saved_cxxflags"
1145 AC_MSG_RESULT([$supports])
1146 if test "x$supports" = "xyes" ; then
1147 m4_ifval([$2], [$2], [:])
1148 else
1149 m4_ifval([$3], [$3], [:])
1150 fi
1151 ])
1153 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_MISC],
1154 [
1155 # Some Zero and Shark settings.
1156 # ZERO_ARCHFLAG tells the compiler which mode to build for
1157 case "${OPENJDK_TARGET_CPU}" in
1158 s390)
1159 ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}31"
1160 ;;
1161 *)
1162 ZERO_ARCHFLAG="${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
1163 esac
1164 TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([$ZERO_ARCHFLAG], [], [ZERO_ARCHFLAG=""])
1165 AC_SUBST(ZERO_ARCHFLAG)
1167 # Check that the compiler supports -mX (or -qX on AIX) flags
1168 # Set COMPILER_SUPPORTS_TARGET_BITS_FLAG to 'true' if it does
1169 TOOLCHAIN_COMPILER_CHECK_ARGUMENTS([${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}],
1170 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=true],
1171 [COMPILER_SUPPORTS_TARGET_BITS_FLAG=false])
1172 AC_SUBST(COMPILER_SUPPORTS_TARGET_BITS_FLAG)
1175 # Check for broken SuSE 'ld' for which 'Only anonymous version tag is allowed in executable.'
1176 USING_BROKEN_SUSE_LD=no
1177 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$GCC" = xyes; then
1178 AC_MSG_CHECKING([for broken SuSE 'ld' which only understands anonymous version tags in executables])
1179 echo "SUNWprivate_1.1 { local: *; };" > version-script.map
1180 echo "int main() { }" > main.c
1181 if $CXX -Xlinker -version-script=version-script.map main.c 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
1182 AC_MSG_RESULT(no)
1183 USING_BROKEN_SUSE_LD=no
1184 else
1185 AC_MSG_RESULT(yes)
1186 USING_BROKEN_SUSE_LD=yes
1187 fi
1188 rm -rf version-script.map main.c
1189 fi
1190 AC_SUBST(USING_BROKEN_SUSE_LD)
1191 ])
1193 # Setup the JTREG paths
1194 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
1195 [
1196 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
1197 [Regression Test Harness @<:@probed@:>@])],
1198 [],
1199 [with_jtreg=no])
1201 if test "x$with_jtreg" = xno; then
1202 # jtreg disabled
1203 AC_MSG_CHECKING([for jtreg])
1204 AC_MSG_RESULT(no)
1205 else
1206 if test "x$with_jtreg" != xyes; then
1207 # with path specified.
1208 JT_HOME="$with_jtreg"
1209 fi
1211 if test "x$JT_HOME" != x; then
1212 AC_MSG_CHECKING([for jtreg])
1214 # use JT_HOME enviroment var.
1215 BASIC_FIXUP_PATH([JT_HOME])
1217 # jtreg win32 script works for everybody
1218 JTREGEXE="$JT_HOME/win32/bin/jtreg"
1220 if test ! -f "$JTREGEXE"; then
1221 AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
1222 fi
1224 AC_MSG_RESULT($JTREGEXE)
1225 else
1226 # try to find jtreg on path
1227 BASIC_REQUIRE_PROG(JTREGEXE, jtreg)
1228 JT_HOME="`$DIRNAME $JTREGEXE`"
1229 fi
1230 fi
1232 AC_SUBST(JT_HOME)
1233 AC_SUBST(JTREGEXE)
1234 ])
