jdk8-mips64-public: common/autoconf/jdk-options.m4@50aaf272884f

1 #

     2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],

    27 [

    28   ###############################################################################

    29   #

    30   # Check which variant of the JDK that we want to build.

    31   # Currently we have:

    32   #    normal:   standard edition

    33   # but the custom make system may add other variants

    34   #

    35   # Effectively the JDK variant gives a name to a specific set of

    36   # modules to compile into the JDK. In the future, these modules

    37   # might even be Jigsaw modules.

    38   #

    39   AC_MSG_CHECKING([which variant of the JDK to build])

    40   AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],

    41       [JDK variant to build (normal) @<:@normal@:>@])])

    43   if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then

    44     JDK_VARIANT="normal"

    45   else

    46     AC_MSG_ERROR([The available JDK variants are: normal])

    47   fi

    49   AC_SUBST(JDK_VARIANT)

    51   AC_MSG_RESULT([$JDK_VARIANT])

    52 ])

    54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_INTERPRETER],

    55 [

    56 ###############################################################################

    57 #

    58 # Check which interpreter of the JVM we want to build.

    59 # Currently we have:

    60 #    template: Template interpreter (the default)

    61 #    cpp     : C++ interpreter

    62 AC_MSG_CHECKING([which interpreter of the JVM to build])

    63 AC_ARG_WITH([jvm-interpreter], [AS_HELP_STRING([--with-jvm-interpreter],

    64 	[JVM interpreter to build (template, cpp) @<:@template@:>@])])

    66 if test "x$with_jvm_interpreter" = x; then

    67      with_jvm_interpreter="template"

    68 fi

    70 JVM_INTERPRETER="$with_jvm_interpreter"

    72 if test "x$JVM_INTERPRETER" != xtemplate && test "x$JVM_INTERPRETER" != xcpp; then

    73    AC_MSG_ERROR([The available JVM interpreters are: template, cpp])

    74 fi

    76 AC_SUBST(JVM_INTERPRETER)

    78 AC_MSG_RESULT([$with_jvm_interpreter])

    79 ])

    81 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],

    82 [

    84   ###############################################################################

    85   #

    86   # Check which variants of the JVM that we want to build.

    87   # Currently we have:

    88   #    server: normal interpreter and a tiered C1/C2 compiler

    89   #    client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)

    90   #    minimal1: reduced form of client with optional VM services and features stripped out

    91   #    kernel: kernel footprint JVM that passes the TCK without major performance problems,

    92   #             ie normal interpreter and C1, only the serial GC, kernel jvmti etc

    93   #    zero: no machine code interpreter, no compiler

    94   #    zeroshark: zero interpreter and shark/llvm compiler backend

    95 #    core: interpreter only, no compiler (only works on some platforms)

    96   AC_MSG_CHECKING([which variants of the JVM to build])

    97   AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],

    98 	[JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark, core) @<:@server@:>@])])

   100   if test "x$with_jvm_variants" = x; then

   101     with_jvm_variants="server"

   102   fi

   104   JVM_VARIANTS=",$with_jvm_variants,"

   105   TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//'  -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//' -e 's/core,//'`

   107   if test "x$TEST_VARIANTS" != "x,"; then

   108      AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark, core])

   109   fi

   110   AC_MSG_RESULT([$with_jvm_variants])

   112   JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`

   113   JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`

   114   JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`

   115   JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`

   116   JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`

   117   JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`

   118   JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`

   120   if test "x$JVM_VARIANT_CLIENT" = xtrue; then

   121     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   122       AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])

   123     fi

   124   fi

   125   if test "x$JVM_VARIANT_KERNEL" = xtrue; then

   126     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   127       AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])

   128     fi

   129   fi

   130   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then

   131     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   132       AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])

   133     fi

   134   fi

   136   # Replace the commas with AND for use in the build directory name.

   137   ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/'`

   138   COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/' -e 's/core,/1/'`

   139   if test "x$COUNT_VARIANTS" != "x,1"; then

   140     BUILDING_MULTIPLE_JVM_VARIANTS=yes

   141   else

   142     BUILDING_MULTIPLE_JVM_VARIANTS=no

   143   fi

   145   AC_SUBST(JVM_VARIANTS)

   146   AC_SUBST(JVM_VARIANT_SERVER)

   147   AC_SUBST(JVM_VARIANT_CLIENT)

   148   AC_SUBST(JVM_VARIANT_MINIMAL1)

   149   AC_SUBST(JVM_VARIANT_KERNEL)

   150   AC_SUBST(JVM_VARIANT_ZERO)

   151   AC_SUBST(JVM_VARIANT_ZEROSHARK)

   152   AC_SUBST(JVM_VARIANT_CORE)

   154   INCLUDE_SA=true

   155   if test "x$JVM_VARIANT_ZERO" = xtrue ; then

   156     INCLUDE_SA=false

   157   fi

   158   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then

   159     INCLUDE_SA=false

   160   fi

   161   if test "x$VAR_CPU" = xppc64 ; then

   162     INCLUDE_SA=false

   163   fi

   164   AC_SUBST(INCLUDE_SA)

   166   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   167     MACOSX_UNIVERSAL="true"

   168   fi

   170   AC_SUBST(MACOSX_UNIVERSAL)

   171 ])

   173 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],

   174 [

   175   ###############################################################################

   176   #

   177   # Set the debug level

   178   #    release: no debug information, all optimizations, no asserts.

   179   #    fastdebug: debug information (-g), all optimizations, all asserts

   180   #    slowdebug: debug information (-g), no optimizations, all asserts

   181   #

   182   DEBUG_LEVEL="release"

   183   AC_MSG_CHECKING([which debug level to use])

   184   AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],

   185       [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],

   186       [

   187         ENABLE_DEBUG="${enableval}"

   188         DEBUG_LEVEL="fastdebug"

   189       ], [ENABLE_DEBUG="no"])

   191   AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],

   192       [set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],

   193       [

   194         DEBUG_LEVEL="${withval}"

   195         if test "x$ENABLE_DEBUG" = xyes; then

   196           AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])

   197         fi

   198       ])

   199   AC_MSG_RESULT([$DEBUG_LEVEL])

   201   if test "x$DEBUG_LEVEL" != xrelease && \

   202       test "x$DEBUG_LEVEL" != xfastdebug && \

   203       test "x$DEBUG_LEVEL" != xslowdebug; then

   204     AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])

   205   fi

   208   ###############################################################################

   209   #

   210   # Setup legacy vars/targets and new vars to deal with different debug levels.

   211   #

   213   case $DEBUG_LEVEL in

   214     release )

   215       VARIANT="OPT"

   216       FASTDEBUG="false"

   217       DEBUG_CLASSFILES="false"

   218       BUILD_VARIANT_RELEASE=""

   219       HOTSPOT_DEBUG_LEVEL="product"

   220       HOTSPOT_EXPORT="product"

   221       ;;

   222     fastdebug )

   223       VARIANT="DBG"

   224       FASTDEBUG="true"

   225       DEBUG_CLASSFILES="true"

   226       BUILD_VARIANT_RELEASE="-fastdebug"

   227       HOTSPOT_DEBUG_LEVEL="fastdebug"

   228       HOTSPOT_EXPORT="fastdebug"

   229       ;;

   230     slowdebug )

   231       VARIANT="DBG"

   232       FASTDEBUG="false"

   233       DEBUG_CLASSFILES="true"

   234       BUILD_VARIANT_RELEASE="-debug"

   235       HOTSPOT_DEBUG_LEVEL="jvmg"

   236       HOTSPOT_EXPORT="debug"

   237       ;;

   238   esac

   240   #####

   241   # Generate the legacy makefile targets for hotspot.

   242   # The hotspot api for selecting the build artifacts, really, needs to be improved.

   243   # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to

   244   # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc

   245   # But until then ...

   246   HOTSPOT_TARGET=""

   248   if test "x$JVM_VARIANT_SERVER" = xtrue; then

   249     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "

   250   fi

   252   if test "x$JVM_VARIANT_CLIENT" = xtrue; then

   253     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "

   254   fi

   256   if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then

   257     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "

   258   fi

   260   if test "x$JVM_VARIANT_KERNEL" = xtrue; then

   261     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "

   262   fi

   264   if test "x$JVM_VARIANT_ZERO" = xtrue; then

   265     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "

   266   fi

   268   if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then

   269     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "

   270   fi

   272   if test "x$JVM_VARIANT_CORE" = xtrue; then

   273     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "

   274   fi

   276   HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"

   278   # On Macosx universal binaries are produced, but they only contain

   279   # 64 bit intel. This invalidates control of which jvms are built

   280   # from configure, but only server is valid anyway. Fix this

   281   # when hotspot makefiles are rewritten.

   282   if test "x$MACOSX_UNIVERSAL" = xtrue; then

   283     HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}

   284   fi

   286   #####

   288   AC_SUBST(DEBUG_LEVEL)

   289   AC_SUBST(VARIANT)

   290   AC_SUBST(FASTDEBUG)

   291   AC_SUBST(DEBUG_CLASSFILES)

   292   AC_SUBST(BUILD_VARIANT_RELEASE)

   293 ])

   296 ###############################################################################

   297 #

   298 # Should we build only OpenJDK even if closed sources are present?

   299 #

   300 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],

   301 [

   302   AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],

   303       [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])

   305   AC_MSG_CHECKING([for presence of closed sources])

   306   if test -d "$SRC_ROOT/jdk/src/closed"; then

   307     CLOSED_SOURCE_PRESENT=yes

   308   else

   309     CLOSED_SOURCE_PRESENT=no

   310   fi

   311   AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])

   313   AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])

   314   SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"

   315   AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])

   317   if test "x$CLOSED_SOURCE_PRESENT" = xno; then

   318     OPENJDK=true

   319     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then

   320       AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])

   321     fi

   322   else

   323     if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then

   324       OPENJDK=true

   325     else

   326       OPENJDK=false

   327     fi

   328   fi

   330   if test "x$OPENJDK" = "xtrue"; then

   331     SET_OPENJDK="OPENJDK=true"

   332   fi

   334   AC_SUBST(SET_OPENJDK)

   335 ])

   337 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],

   338 [

   340   ###############################################################################

   341   #

   342   # Should we build a JDK/JVM with headful support (ie a graphical ui)?

   343   # We always build headless support.

   344   #

   345   AC_MSG_CHECKING([headful support])

   346   AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],

   347       [disable building headful support (graphical UI support) @<:@enabled@:>@])],

   348       [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])

   350   SUPPORT_HEADLESS=yes

   351   BUILD_HEADLESS="BUILD_HEADLESS:=true"

   353   if test "x$SUPPORT_HEADFUL" = xyes; then

   354     # We are building both headful and headless.

   355     headful_msg="include support for both headful and headless"

   356   fi

   358   if test "x$SUPPORT_HEADFUL" = xno; then

   359     # Thus we are building headless only.

   360     BUILD_HEADLESS="BUILD_HEADLESS:=true"

   361     headful_msg="headless only"

   362   fi

   364   AC_MSG_RESULT([$headful_msg])

   366   AC_SUBST(SUPPORT_HEADLESS)

   367   AC_SUBST(SUPPORT_HEADFUL)

   368   AC_SUBST(BUILD_HEADLESS)

   370   # Control wether Hotspot runs Queens test after build.

   371   AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],

   372       [run the Queens test after Hotspot build @<:@disabled@:>@])],,

   373       [enable_hotspot_test_in_build=no])

   374   if test "x$enable_hotspot_test_in_build" = "xyes"; then

   375     TEST_IN_BUILD=true

   376   else

   377     TEST_IN_BUILD=false

   378   fi

   379   AC_SUBST(TEST_IN_BUILD)

   381   ###############################################################################

   382   #

   383   # Choose cacerts source file

   384   #

   385   AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],

   386       [specify alternative cacerts file])])

   387   if test "x$with_cacerts_file" != x; then

   388     CACERTS_FILE=$with_cacerts_file

   389   else

   390     CACERTS_FILE=${SRC_ROOT}/jdk/src/share/lib/security/cacerts

   391   fi

   392   AC_SUBST(CACERTS_FILE)

   394   ###############################################################################

   395   #

   396   # Enable or disable unlimited crypto

   397   #

   398   AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],

   399       [Enable unlimited crypto policy @<:@disabled@:>@])],,

   400       [enable_unlimited_crypto=no])

   401   if test "x$enable_unlimited_crypto" = "xyes"; then

   402     UNLIMITED_CRYPTO=true

   403   else

   404     UNLIMITED_CRYPTO=false

   405   fi

   406   AC_SUBST(UNLIMITED_CRYPTO)

   408   ###############################################################################

   409   #

   410   # Enable or disable the elliptic curve crypto implementation

   411   #

   412   AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],

   413   [

   414     AC_MSG_CHECKING([if elliptic curve crypto implementation is present])

   416     if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then

   417       ENABLE_INTREE_EC=yes

   418       AC_MSG_RESULT([yes])

   419     else

   420       ENABLE_INTREE_EC=no

   421       AC_MSG_RESULT([no])

   422     fi

   424     AC_SUBST(ENABLE_INTREE_EC)

   425   ])

   427   ###############################################################################

   428   #

   429   # Compress jars

   430   #

   431   COMPRESS_JARS=false

   433   AC_SUBST(COMPRESS_JARS)

   434 ])

   436 ###############################################################################

   437 #

   438 # Setup version numbers

   439 #

   440 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],

   441 [

   442   # Source the version numbers

   443   . $AUTOCONF_DIR/version-numbers

   445   # Get the settings from parameters

   446   AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],

   447       [Set milestone value for build @<:@internal@:>@])])

   448   if test "x$with_milestone" = xyes; then

   449     AC_MSG_ERROR([Milestone must have a value])

   450   elif test "x$with_milestone" != x; then

   451     MILESTONE="$with_milestone"

   452   fi

   453   if test "x$MILESTONE" = x; then

   454     MILESTONE=internal

   455   fi

   457   AC_ARG_WITH(update-version, [AS_HELP_STRING([--with-update-version],

   458       [Set update version value for build @<:@b00@:>@])])

   459   if test "x$with_update_version" = xyes; then

   460     AC_MSG_ERROR([Update version must have a value])

   461   elif test "x$with_update_version" != x; then

   462     JDK_UPDATE_VERSION="$with_update_version"

   463     # On macosx 10.7, it's not possible to set --with-update-version=0X due

   464     # to a bug in expr (which reduces it to just X). To work around this, we

   465     # always add a 0 to one digit update versions.

   466     if test "${#JDK_UPDATE_VERSION}" = "1"; then

   467       JDK_UPDATE_VERSION="0${JDK_UPDATE_VERSION}"

   468     fi

   469   fi

   471   AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],

   472       [Add a custom string to the version string if build number isn't set.@<:@username_builddateb00@:>@])])

   473   if test "x$with_user_release_suffix" = xyes; then

   474     AC_MSG_ERROR([Release suffix must have a value])

   475   elif test "x$with_user_release_suffix" != x; then

   476     USER_RELEASE_SUFFIX="$with_user_release_suffix"

   477   fi

   479   AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],

   480       [Set build number value for build @<:@b00@:>@])])

   481   if test "x$with_build_number" = xyes; then

   482     AC_MSG_ERROR([Build number must have a value])

   483   elif test "x$with_build_number" != x; then

   484     JDK_BUILD_NUMBER="$with_build_number"

   485   fi

   486   # Define default USER_RELEASE_SUFFIX if BUILD_NUMBER and USER_RELEASE_SUFFIX are not set

   487   if test "x$JDK_BUILD_NUMBER" = x; then

   488     JDK_BUILD_NUMBER=b00

   489     if test "x$USER_RELEASE_SUFFIX" = x; then

   490       BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`

   491       # Avoid [:alnum:] since it depends on the locale.

   492       CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyzABCDEFGHIJKLMNOPQRSTUVWXYZ0123456789'`

   493       USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`

   494     fi

   495   fi

   497   # Now set the JDK version, milestone, build number etc.

   498   AC_SUBST(USER_RELEASE_SUFFIX)

   499   AC_SUBST(JDK_MAJOR_VERSION)

   500   AC_SUBST(JDK_MINOR_VERSION)

   501   AC_SUBST(JDK_MICRO_VERSION)

   502   AC_SUBST(JDK_UPDATE_VERSION)

   503   AC_SUBST(JDK_BUILD_NUMBER)

   504   AC_SUBST(MILESTONE)

   505   AC_SUBST(LAUNCHER_NAME)

   506   AC_SUBST(PRODUCT_NAME)

   507   AC_SUBST(PRODUCT_SUFFIX)

   508   AC_SUBST(JDK_RC_PLATFORM_NAME)

   509   AC_SUBST(COMPANY_NAME)

   510   AC_SUBST(MACOSX_BUNDLE_NAME_BASE)

   511   AC_SUBST(MACOSX_BUNDLE_ID_BASE)

   513   COPYRIGHT_YEAR=`date +'%Y'`

   514   AC_SUBST(COPYRIGHT_YEAR)

   516   if test "x$JDK_UPDATE_VERSION" != x; then

   517     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"

   518   else

   519     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"

   520   fi

   521   AC_SUBST(JDK_VERSION)

   523   COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`

   524   AC_SUBST(COOKED_BUILD_NUMBER)

   525 ])

   527 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],

   528 [

   529   HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"

   530   AC_SUBST(HOTSPOT_MAKE_ARGS)

   532   # The name of the Service Agent jar.

   533   SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"

   534   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   535     SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"

   536   fi

   537   AC_SUBST(SALIB_NAME)

   538 ])

   540 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],

   541 [

   542   #

   543   # ENABLE_DEBUG_SYMBOLS

   544   # This must be done after the toolchain is setup, since we're looking at objcopy.

   545   #

   546   AC_ARG_ENABLE([debug-symbols],

   547       [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])

   549   AC_MSG_CHECKING([if we should generate debug symbols])

   551   if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then

   552     # explicit enabling of enable-debug-symbols and can't find objcopy

   553     #   this is an error

   554     AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])

   555   fi

   557   if test "x$enable_debug_symbols" = "xyes"; then

   558     ENABLE_DEBUG_SYMBOLS=true

   559   elif test "x$enable_debug_symbols" = "xno"; then

   560     ENABLE_DEBUG_SYMBOLS=false

   561   else

   562     # Default is on if objcopy is found

   563     if test "x$OBJCOPY" != x; then

   564       ENABLE_DEBUG_SYMBOLS=true

   565     # MacOS X and Windows don't use objcopy but default is on for those OSes

   566     elif test "x$OPENJDK_TARGET_OS" = xmacosx || test "x$OPENJDK_TARGET_OS" = xwindows; then

   567       ENABLE_DEBUG_SYMBOLS=true

   568     else

   569       ENABLE_DEBUG_SYMBOLS=false

   570     fi

   571   fi

   573   AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])

   575   #

   576   # ZIP_DEBUGINFO_FILES

   577   #

   578   AC_MSG_CHECKING([if we should zip debug-info files])

   579   AC_ARG_ENABLE([zip-debug-info],

   580       [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])],

   581       [enable_zip_debug_info="${enableval}"], [enable_zip_debug_info="yes"])

   582   AC_MSG_RESULT([${enable_zip_debug_info}])

   584   if test "x${enable_zip_debug_info}" = "xno"; then

   585     ZIP_DEBUGINFO_FILES=false

   586   else

   587     ZIP_DEBUGINFO_FILES=true

   588   fi

   590   AC_SUBST(ENABLE_DEBUG_SYMBOLS)

   591   AC_SUBST(ZIP_DEBUGINFO_FILES)

   592   AC_SUBST(CFLAGS_DEBUG_SYMBOLS)

   593   AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)

   594 ])

   596 # Support for customization of the build process. Some build files

   597 # will include counterparts from this location, if they exist. This allows

   598 # for a degree of customization of the build targets and the rules/recipes

   599 # to create them

   600 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],

   601 [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])

   602 AC_SUBST(CUSTOM_MAKE_DIR)

Mercurial > jdk8-mips64-public / file revision

common/autoconf/jdk-options.m4@50aaf272884f

common/autoconf/jdk-options.m4