Mon, 31 Dec 2012 14:52:11 -0500
8005583: Install build(gnumake all) failed preventing RE from doing JDK8 combo builds
Reviewed-by: paulk, billyh
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 AC_DEFUN([ADD_JVM_ARG_IF_OK],
27 [
28 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)
29 # If so, then append $1 to $2
30 FOUND_WARN=`$3 $1 -version 2>&1 | grep -i warn`
31 FOUND_VERSION=`$3 $1 -version 2>&1 | grep " version \""`
32 if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then
33 $2="[$]$2 $1"
34 fi
35 ])
37 # This will make sure the given variable points to a full and proper
38 # path. This means:
39 # 1) There will be no spaces in the path. On posix platforms,
40 # spaces in the path will result in an error. On Windows,
41 # the path will be rewritten using short-style to be space-free.
42 # 2) The path will be absolute, and it will be in unix-style (on
43 # cygwin).
44 # $1: The name of the variable to fix
45 AC_DEFUN([BASIC_FIXUP_PATH],
46 [
47 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
48 BASIC_FIXUP_PATH_CYGWIN($1)
49 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
50 BASIC_FIXUP_PATH_MSYS($1)
51 else
52 # We're on a posix platform. Hooray! :)
53 path="[$]$1"
55 if test ! -f "$path" && test ! -d "$path"; then
56 AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])
57 fi
59 has_space=`$ECHO "$path" | $GREP " "`
60 if test "x$has_space" != x; then
61 AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])
62 AC_MSG_ERROR([Spaces are not allowed in this path.])
63 fi
64 fi
65 ])
67 # This will make sure the given variable points to a executable
68 # with a full and proper path. This means:
69 # 1) There will be no spaces in the path. On posix platforms,
70 # spaces in the path will result in an error. On Windows,
71 # the path will be rewritten using short-style to be space-free.
72 # 2) The path will be absolute, and it will be in unix-style (on
73 # cygwin).
74 # Any arguments given to the executable is preserved.
75 # If the input variable does not have a directory specification, then
76 # it need to be in the PATH.
77 # $1: The name of the variable to fix
78 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],
79 [
80 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
81 BASIC_FIXUP_EXECUTABLE_CYGWIN($1)
82 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
83 BASIC_FIXUP_EXECUTABLE_MSYS($1)
84 else
85 # We're on a posix platform. Hooray! :)
86 # First separate the path from the arguments. This will split at the first
87 # space.
88 complete="[$]$1"
89 path="${complete%% *}"
90 tmp="$complete EOL"
91 arguments="${tmp#* }"
93 new_path=`$WHICH $path 2> /dev/null`
94 if test "x$new_path" = x; then
95 is_absolute_path=`$ECHO "$path" | $GREP ^/`
96 if test "x$is_absolute_path" != x; then
97 AC_MSG_NOTICE([Resolving $1 (as $path) with 'which' failed, using $path directly.])
98 new_path="$path"
99 else
100 AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])
101 has_space=`$ECHO "$complete" | $GREP " "`
102 if test "x$has_space" != x; then
103 AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])
104 fi
105 AC_MSG_ERROR([Cannot locate the the path of $1])
106 fi
107 fi
108 fi
110 # Now join together the path and the arguments once again
111 if test "x$arguments" != xEOL; then
112 new_complete="$new_path ${arguments% *}"
113 else
114 new_complete="$new_path"
115 fi
117 if test "x$complete" != "x$new_complete"; then
118 $1="$new_complete"
119 AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])
120 fi
121 ])
123 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],
124 [
125 if test "x$OPENJDK_BUILD_OS" != xwindows; then
126 # Follow a chain of symbolic links. Use readlink
127 # where it exists, else fall back to horribly
128 # complicated shell code.
129 if test "x$READLINK_TESTED" != yes; then
130 # On MacOSX there is a readlink tool with a different
131 # purpose than the GNU readlink tool. Check the found readlink.
132 ISGNU=`$READLINK --version 2>&1 | $GREP GNU`
133 if test "x$ISGNU" = x; then
134 # A readlink that we do not know how to use.
135 # Are there other non-GNU readlinks out there?
136 READLINK_TESTED=yes
137 READLINK=
138 fi
139 fi
141 if test "x$READLINK" != x; then
142 $1=`$READLINK -f [$]$1`
143 else
144 # Save the current directory for restoring afterwards
145 STARTDIR=$PWD
146 COUNTER=0
147 sym_link_dir=`$DIRNAME [$]$1`
148 sym_link_file=`$BASENAME [$]$1`
149 # Use the system pwd and not the shell builtin to resolve directory symlinks
150 cd $sym_link_dir
151 cd `$THEPWDCMD`
152 sym_link_dir=`$THEPWDCMD`
153 # Resolve file symlinks
154 while test $COUNTER -lt 20; do
155 ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`
156 if test "x$ISLINK" == x; then
157 # This is not a symbolic link! We are done!
158 break
159 fi
160 # Again resolve directory symlinks since the target of the just found
161 # link could be in a different directory
162 cd `$DIRNAME $ISLINK`
163 sym_link_dir=`$THEPWDCMD`
164 sym_link_file=`$BASENAME $ISLINK`
165 let COUNTER=COUNTER+1
166 done
167 cd $STARTDIR
168 $1=$sym_link_dir/$sym_link_file
169 fi
170 fi
171 ])
173 AC_DEFUN_ONCE([BASIC_INIT],
174 [
175 # Save the original command line. This is passed to us by the wrapper configure script.
176 AC_SUBST(CONFIGURE_COMMAND_LINE)
177 DATE_WHEN_CONFIGURED=`LANG=C date`
178 AC_SUBST(DATE_WHEN_CONFIGURED)
179 AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])
180 AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])
181 ])
183 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.
184 # $1: variable to check
185 # $2: executable name to print in warning (optional)
186 AC_DEFUN([BASIC_CHECK_NONEMPTY],
187 [
188 if test "x[$]$1" = x; then
189 if test "x$2" = x; then
190 PROG_NAME=translit($1,A-Z,a-z)
191 else
192 PROG_NAME=$2
193 fi
194 AC_MSG_NOTICE([Could not find $PROG_NAME!])
195 AC_MSG_ERROR([Cannot continue])
196 fi
197 ])
199 # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.
200 # Arguments as AC_PATH_PROG:
201 # $1: variable to set
202 # $2: executable name to look for
203 AC_DEFUN([BASIC_REQUIRE_PROG],
204 [
205 AC_PATH_PROGS($1, $2)
206 BASIC_CHECK_NONEMPTY($1, $2)
207 ])
209 # Setup the most fundamental tools that relies on not much else to set up,
210 # but is used by much of the early bootstrap code.
211 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],
212 [
214 # Start with tools that do not need have cross compilation support
215 # and can be expected to be found in the default PATH. These tools are
216 # used by configure. Nor are these tools expected to be found in the
217 # devkit from the builddeps server either, since they are
218 # needed to download the devkit.
220 # First are all the simple required tools.
221 BASIC_REQUIRE_PROG(BASENAME, basename)
222 BASIC_REQUIRE_PROG(BASH, bash)
223 BASIC_REQUIRE_PROG(CAT, cat)
224 BASIC_REQUIRE_PROG(CHMOD, chmod)
225 BASIC_REQUIRE_PROG(CMP, cmp)
226 BASIC_REQUIRE_PROG(CP, cp)
227 BASIC_REQUIRE_PROG(CUT, cut)
228 BASIC_REQUIRE_PROG(DATE, date)
229 BASIC_REQUIRE_PROG(DIFF, [gdiff diff])
230 BASIC_REQUIRE_PROG(DIRNAME, dirname)
231 BASIC_REQUIRE_PROG(ECHO, echo)
232 BASIC_REQUIRE_PROG(EXPR, expr)
233 BASIC_REQUIRE_PROG(FILE, file)
234 BASIC_REQUIRE_PROG(FIND, find)
235 BASIC_REQUIRE_PROG(HEAD, head)
236 BASIC_REQUIRE_PROG(LN, ln)
237 BASIC_REQUIRE_PROG(LS, ls)
238 BASIC_REQUIRE_PROG(MKDIR, mkdir)
239 BASIC_REQUIRE_PROG(MKTEMP, mktemp)
240 BASIC_REQUIRE_PROG(MV, mv)
241 BASIC_REQUIRE_PROG(PRINTF, printf)
242 BASIC_REQUIRE_PROG(THEPWDCMD, pwd)
243 BASIC_REQUIRE_PROG(RM, rm)
244 BASIC_REQUIRE_PROG(SH, sh)
245 BASIC_REQUIRE_PROG(SORT, sort)
246 BASIC_REQUIRE_PROG(TAIL, tail)
247 BASIC_REQUIRE_PROG(TAR, tar)
248 BASIC_REQUIRE_PROG(TEE, tee)
249 BASIC_REQUIRE_PROG(TOUCH, touch)
250 BASIC_REQUIRE_PROG(TR, tr)
251 BASIC_REQUIRE_PROG(UNAME, uname)
252 BASIC_REQUIRE_PROG(UNIQ, uniq)
253 BASIC_REQUIRE_PROG(WC, wc)
254 BASIC_REQUIRE_PROG(WHICH, which)
255 BASIC_REQUIRE_PROG(XARGS, xargs)
257 # Then required tools that require some special treatment.
258 AC_PROG_AWK
259 BASIC_CHECK_NONEMPTY(AWK)
260 AC_PROG_GREP
261 BASIC_CHECK_NONEMPTY(GREP)
262 AC_PROG_EGREP
263 BASIC_CHECK_NONEMPTY(EGREP)
264 AC_PROG_FGREP
265 BASIC_CHECK_NONEMPTY(FGREP)
266 AC_PROG_SED
267 BASIC_CHECK_NONEMPTY(SED)
269 AC_PATH_PROGS(NAWK, [nawk gawk awk])
270 BASIC_CHECK_NONEMPTY(NAWK)
272 # Always force rm.
273 RM="$RM -f"
275 # These are not required on all platforms
276 AC_PATH_PROG(CYGPATH, cygpath)
277 AC_PATH_PROG(READLINK, readlink)
278 AC_PATH_PROG(DF, df)
279 AC_PATH_PROG(SETFILE, SetFile)
280 ])
282 # Setup basic configuration paths, and platform-specific stuff related to PATHs.
283 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],
284 [
285 # Locate the directory of this script.
286 SCRIPT="[$]0"
287 BASIC_REMOVE_SYMBOLIC_LINKS(SCRIPT)
288 AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD`
290 # Where is the source? It is located two levels above the configure script.
291 CURDIR="$PWD"
292 cd "$AUTOCONF_DIR/../.."
293 SRC_ROOT="`$THEPWDCMD`"
295 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
296 PATH_SEP=";"
297 BASIC_CHECK_PATHS_WINDOWS
298 else
299 PATH_SEP=":"
300 fi
302 AC_SUBST(SRC_ROOT)
303 AC_SUBST(PATH_SEP)
304 cd "$CURDIR"
306 BASIC_FIXUP_PATH(SRC_ROOT)
307 BASIC_FIXUP_PATH(CURDIR)
309 if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then
310 # Add extra search paths on solaris for utilities like ar and as etc...
311 PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"
312 fi
314 # You can force the sys-root if the sys-root encoded into the cross compiler tools
315 # is not correct.
316 AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],
317 [pass this sys-root to the compilers and tools (for cross-compiling)])])
319 if test "x$with_sys_root" != x; then
320 SYS_ROOT=$with_sys_root
321 else
322 SYS_ROOT=/
323 fi
324 AC_SUBST(SYS_ROOT)
326 AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],
327 [search this directory for compilers and tools (for cross-compiling)])], [TOOLS_DIR=$with_tools_dir])
329 AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],
330 [use this directory as base for tools-dir and sys-root (for cross-compiling)])],
331 [
332 if test "x$with_sys_root" != x; then
333 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])
334 fi
335 if test "x$with_tools_dir" != x; then
336 AC_MSG_ERROR([Cannot specify both --with-devkit and --with-tools-dir at the same time])
337 fi
338 TOOLS_DIR=$with_devkit/bin
339 SYS_ROOT=$with_devkit/$host_alias/libc
340 ])
342 ])
344 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],
345 [
347 AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],
348 [use this as the name of the configuration @<:@generated from important configuration options@:>@])],
349 [ CONF_NAME=${with_conf_name} ])
351 # Test from where we are running configure, in or outside of src root.
352 # To enable comparison of directories, CURDIR needs to be symlink free
353 # just like SRC_ROOT already is
354 NOSYM_CURDIR="$CURDIR"
355 BASIC_REMOVE_SYMBOLIC_LINKS(NOSYM_CURDIR)
356 if test "x$NOSYM_CURDIR" = "x$SRC_ROOT" || test "x$NOSYM_CURDIR" = "x$SRC_ROOT/common" \
357 || test "x$NOSYM_CURDIR" = "x$SRC_ROOT/common/autoconf" \
358 || test "x$NOSYM_CURDIR" = "x$SRC_ROOT/common/makefiles" ; then
359 # We are running configure from the src root.
360 # Create a default ./build/target-variant-debuglevel output root.
361 if test "x${CONF_NAME}" = x; then
362 CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"
363 fi
364 OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"
365 $MKDIR -p "$OUTPUT_ROOT"
366 if test ! -d "$OUTPUT_ROOT"; then
367 AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])
368 fi
369 else
370 # We are running configure from outside of the src dir.
371 # Then use the current directory as output dir!
372 # If configuration is situated in normal build directory, just use the build
373 # directory name as configuration name, otherwise use the complete path.
374 if test "x${CONF_NAME}" = x; then
375 CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`
376 fi
377 OUTPUT_ROOT="$CURDIR"
379 # WARNING: This might be a bad thing to do. You need to be sure you want to
380 # have a configuration in this directory. Do some sanity checks!
382 if test ! -e "$OUTPUT_ROOT/spec.gmk"; then
383 # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for
384 # other files
385 files_present=`$LS $OUTPUT_ROOT`
386 # Configure has already touched config.log and confdefs.h in the current dir when this check
387 # is performed.
388 filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \
389 | $TR -d '\n'`
390 if test "x$filtered_files" != x; then
391 AC_MSG_NOTICE([Current directory is $CURDIR.])
392 AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])
393 AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])
394 AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])
395 AC_MSG_NOTICE([seriously mess up just about everything.])
396 AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])
397 AC_MSG_NOTICE([(or create a new empty directory and cd to it).])
398 AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])
399 fi
400 fi
401 fi
402 AC_MSG_CHECKING([what configuration name to use])
403 AC_MSG_RESULT([$CONF_NAME])
405 BASIC_FIXUP_PATH(OUTPUT_ROOT)
407 AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)
408 AC_SUBST(CONF_NAME, $CONF_NAME)
409 AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)
411 # Most of the probed defines are put into config.h
412 AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])
413 # The spec.gmk file contains all variables for the make system.
414 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])
415 # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.
416 AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])
417 # The bootcycle-spec.gmk file contains support for boot cycle builds.
418 AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])
419 # The compare.sh is used to compare the build output to other builds.
420 AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])
421 # Spec.sh is currently used by compare-objects.sh
422 AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])
423 # The generated Makefile knows where the spec.gmk is and where the source is.
424 # You can run make from the OUTPUT_ROOT, or from the top-level Makefile
425 # which will look for generated configurations
426 AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])
428 # Save the arguments given to us
429 echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments
430 ])
432 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],
433 [
434 # Setup default logging of stdout and stderr to build.log in the output root.
435 BUILD_LOG='$(OUTPUT_ROOT)/build.log'
436 BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'
437 BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'
438 AC_SUBST(BUILD_LOG)
439 AC_SUBST(BUILD_LOG_PREVIOUS)
440 AC_SUBST(BUILD_LOG_WRAPPER)
441 ])
444 #%%% Simple tools %%%
446 # Check if we have found a usable version of make
447 # $1: the path to a potential make binary (or empty)
448 # $2: the description on how we found this
449 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],
450 [
451 MAKE_CANDIDATE="$1"
452 DESCRIPTION="$2"
453 if test "x$MAKE_CANDIDATE" != x; then
454 AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])
455 MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`
456 IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`
457 if test "x$IS_GNU_MAKE" = x; then
458 AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])
459 else
460 IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP '3.8[[12346789]]'`
461 if test "x$IS_MODERN_MAKE" = x; then
462 AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])
463 else
464 if test "x$OPENJDK_BUILD_OS" = "xwindows"; then
465 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then
466 MAKE_EXPECTED_ENV='cygwin'
467 elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
468 MAKE_EXPECTED_ENV='msys'
469 else
470 AC_MSG_ERROR([Unknown Windows environment])
471 fi
472 MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`
473 IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`
474 else
475 # Not relevant for non-Windows
476 IS_MAKE_CORRECT_ENV=true
477 fi
478 if test "x$IS_MAKE_CORRECT_ENV" = x; then
479 AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])
480 else
481 FOUND_MAKE=$MAKE_CANDIDATE
482 BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)
483 fi
484 fi
485 fi
486 fi
487 ])
489 # Goes looking for a usable version of GNU make.
490 AC_DEFUN([BASIC_CHECK_GNU_MAKE],
491 [
492 # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.
493 if test "x$MAKE" != x; then
494 # User has supplied a make, test it.
495 if test ! -f "$MAKE"; then
496 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])
497 fi
498 BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])
499 if test "x$FOUND_MAKE" = x; then
500 AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])
501 fi
502 else
503 # Try our hardest to locate a correct version of GNU make
504 AC_PATH_PROGS(CHECK_GMAKE, gmake)
505 BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])
507 if test "x$FOUND_MAKE" = x; then
508 AC_PATH_PROGS(CHECK_MAKE, make)
509 BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])
510 fi
512 if test "x$FOUND_MAKE" = x; then
513 if test "x$TOOLS_DIR" != x; then
514 # We have a tools-dir, check that as well before giving up.
515 OLD_PATH=$PATH
516 PATH=$TOOLS_DIR:$PATH
517 AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)
518 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])
519 if test "x$FOUND_MAKE" = x; then
520 AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)
521 BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])
522 fi
523 PATH=$OLD_PATH
524 fi
525 fi
527 if test "x$FOUND_MAKE" = x; then
528 AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])
529 fi
530 fi
532 MAKE=$FOUND_MAKE
533 AC_SUBST(MAKE)
534 AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])
535 ])
537 AC_DEFUN([BASIC_CHECK_FIND_DELETE],
538 [
539 # Test if find supports -delete
540 AC_MSG_CHECKING([if find supports -delete])
541 FIND_DELETE="-delete"
543 DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)
545 echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete
547 TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`
548 if test -f $DELETEDIR/TestIfFindSupportsDelete; then
549 # No, it does not.
550 rm $DELETEDIR/TestIfFindSupportsDelete
551 FIND_DELETE="-exec rm \{\} \+"
552 AC_MSG_RESULT([no])
553 else
554 AC_MSG_RESULT([yes])
555 fi
556 rmdir $DELETEDIR
557 AC_SUBST(FIND_DELETE)
558 ])
560 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],
561 [
562 BASIC_CHECK_GNU_MAKE
564 BASIC_CHECK_FIND_DELETE
566 # These tools might not be installed by default,
567 # need hint on how to install them.
568 BASIC_REQUIRE_PROG(UNZIP, unzip)
569 BASIC_REQUIRE_PROG(ZIP, zip)
571 # Non-required basic tools
573 AC_PATH_PROG(LDD, ldd)
574 if test "x$LDD" = "x"; then
575 # List shared lib dependencies is used for
576 # debug output and checking for forbidden dependencies.
577 # We can build without it.
578 LDD="true"
579 fi
580 AC_PATH_PROG(OTOOL, otool)
581 if test "x$OTOOL" = "x"; then
582 OTOOL="true"
583 fi
584 AC_PATH_PROGS(READELF, [readelf greadelf])
585 AC_PATH_PROG(HG, hg)
586 AC_PATH_PROG(STAT, stat)
587 AC_PATH_PROG(TIME, time)
589 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
590 BASIC_REQUIRE_PROG(COMM, comm)
591 fi
592 ])
594 # Check if build directory is on local disk. If not possible to determine,
595 # we prefer to claim it's local.
596 # Argument 1: directory to test
597 # Argument 2: what to do if it is on local disk
598 # Argument 3: what to do otherwise (remote disk or failure)
599 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],
600 [
601 # df -l lists only local disks; if the given directory is not found then
602 # a non-zero exit code is given
603 if test "x$DF" = x; then
604 if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then
605 # msys does not have df; use Windows "net use" instead.
606 IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`
607 if test "x$IS_NETWORK_DISK" = x; then
608 $2
609 else
610 $3
611 fi
612 else
613 # No df here, say it's local
614 $2
615 fi
616 else
617 if $DF -l $1 > /dev/null 2>&1; then
618 $2
619 else
620 $3
621 fi
622 fi
623 ])
625 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],
626 [
628 AC_MSG_CHECKING([if build directory is on local disk])
629 BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,
630 [OUTPUT_DIR_IS_LOCAL="yes"],
631 [OUTPUT_DIR_IS_LOCAL="no"])
632 AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)
634 # Check if the user has any old-style ALT_ variables set.
635 FOUND_ALT_VARIABLES=`env | grep ^ALT_`
637 # Before generating output files, test if they exist. If they do, this is a reconfigure.
638 # Since we can't properly handle the dependencies for this, warn the user about the situation
639 if test -e $OUTPUT_ROOT/spec.gmk; then
640 IS_RECONFIGURE=yes
641 else
642 IS_RECONFIGURE=no
643 fi
645 if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then
646 HIDE_PERFORMANCE_HINTS=yes
647 else
648 HIDE_PERFORMANCE_HINTS=no
649 # Hide it the next time around...
650 $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1
651 fi
653 ])