Wed, 18 Apr 2018 02:21:14 -0700
8057538: Build the freetype library during configure on Windows
Reviewed-by: simonis, erikj, ihse
1 #
2 # Copyright (c) 2011, 2018, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 ########################################################################
27 # This file is responsible for detecting, verifying and setting up the
28 # toolchain, i.e. the compiler, linker and related utilities. It will setup
29 # proper paths to the binaries, but it will not setup any flags.
30 #
31 # The binaries used is determined by the toolchain type, which is the family of
32 # compilers and related tools that are used.
33 ########################################################################
36 # All valid toolchains, regardless of platform (used by help.m4)
37 VALID_TOOLCHAINS_all="gcc clang solstudio xlc microsoft"
39 # These toolchains are valid on different platforms
40 VALID_TOOLCHAINS_linux="gcc clang"
41 VALID_TOOLCHAINS_solaris="solstudio"
42 VALID_TOOLCHAINS_macosx="gcc clang"
43 VALID_TOOLCHAINS_aix="xlc"
44 VALID_TOOLCHAINS_windows="microsoft"
46 # Toolchain descriptions
47 TOOLCHAIN_DESCRIPTION_clang="clang/LLVM"
48 TOOLCHAIN_DESCRIPTION_gcc="GNU Compiler Collection"
49 TOOLCHAIN_DESCRIPTION_microsoft="Microsoft Visual Studio"
50 TOOLCHAIN_DESCRIPTION_solstudio="Oracle Solaris Studio"
51 TOOLCHAIN_DESCRIPTION_xlc="IBM XL C/C++"
53 # Prepare the system so that TOOLCHAIN_CHECK_COMPILER_VERSION can be called.
54 # Must have CC_VERSION_NUMBER and CXX_VERSION_NUMBER.
55 # $1 - optional variable prefix for compiler and version variables (BUILD_)
56 # $2 - optional variable prefix for comparable variable (OPENJDK_BUILD_)
57 AC_DEFUN([TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS],
58 [
59 if test "x$CC_VERSION" != "x$CXX_VERSION"; then
60 AC_MSG_WARN([C and C++ compiler has different version numbers, $CC_VERSION vs $CXX_VERSION.])
61 AC_MSG_WARN([This typically indicates a broken setup, and is not supported])
62 fi
64 # We only check CC_VERSION since we assume CXX_VERSION is equal.
65 if [ [[ "$CC_VERSION" =~ (.*\.){3} ]] ]; then
66 AC_MSG_WARN([C compiler version number has more than three parts (X.Y.Z): $CC_VERSION. Comparisons might be wrong.])
67 fi
69 if [ [[ "$CC_VERSION" =~ [0-9]{6} ]] ]; then
70 AC_MSG_WARN([C compiler version number has a part larger than 99999: $CC_VERSION. Comparisons might be wrong.])
71 fi
73 $2COMPARABLE_ACTUAL_VERSION=`$AWK -F. '{ printf("%05d%05d%05d\n", [$]1, [$]2, [$]3) }' <<< "$CC_VERSION"`
74 ])
76 # Check if the configured compiler (C and C++) is of a specific version or
77 # newer. TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS must have been called before.
78 #
79 # Arguments:
80 # $1: The version string to check against the found version
81 # $2: block to run if the compiler is at least this version (>=)
82 # $3: block to run if the compiler is older than this version (<)
83 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
84 [
85 REFERENCE_VERSION=$1
87 if [ [[ "$REFERENCE_VERSION" =~ (.*\.){3} ]] ]; then
88 AC_MSG_ERROR([Internal error: Cannot compare to $REFERENCE_VERSION, only three parts (X.Y.Z) is supported])
89 fi
91 if [ [[ "$REFERENCE_VERSION" =~ [0-9]{6} ]] ]; then
92 AC_MSG_ERROR([Internal error: Cannot compare to $REFERENCE_VERSION, only parts < 99999 is supported])
93 fi
95 # Version comparison method inspired by http://stackoverflow.com/a/24067243
96 COMPARABLE_REFERENCE_VERSION=`$AWK -F. '{ printf("%05d%05d%05d\n", [$]1, [$]2, [$]3) }' <<< "$REFERENCE_VERSION"`
98 if test $COMPARABLE_ACTUAL_VERSION -ge $COMPARABLE_REFERENCE_VERSION ; then
99 m4_ifval([$2], [$2], [:])
100 else
101 m4_ifval([$3], [$3], [:])
102 fi
103 ])
106 # Setup a number of variables describing how native output files are
107 # named on this platform/toolchain.
108 AC_DEFUN([TOOLCHAIN_SETUP_FILENAME_PATTERNS],
109 [
110 # Define filename patterns
111 if test "x$OPENJDK_TARGET_OS" = xwindows; then
112 LIBRARY_PREFIX=
113 SHARED_LIBRARY_SUFFIX='.dll'
114 STATIC_LIBRARY_SUFFIX='.lib'
115 SHARED_LIBRARY='[$]1.dll'
116 STATIC_LIBRARY='[$]1.lib'
117 OBJ_SUFFIX='.obj'
118 EXE_SUFFIX='.exe'
119 else
120 LIBRARY_PREFIX=lib
121 SHARED_LIBRARY_SUFFIX='.so'
122 STATIC_LIBRARY_SUFFIX='.a'
123 SHARED_LIBRARY='lib[$]1.so'
124 STATIC_LIBRARY='lib[$]1.a'
125 OBJ_SUFFIX='.o'
126 EXE_SUFFIX=''
127 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
128 SHARED_LIBRARY='lib[$]1.dylib'
129 SHARED_LIBRARY_SUFFIX='.dylib'
130 fi
131 fi
133 AC_SUBST(LIBRARY_PREFIX)
134 AC_SUBST(SHARED_LIBRARY_SUFFIX)
135 AC_SUBST(STATIC_LIBRARY_SUFFIX)
136 AC_SUBST(SHARED_LIBRARY)
137 AC_SUBST(STATIC_LIBRARY)
138 AC_SUBST(OBJ_SUFFIX)
139 AC_SUBST(EXE_SUFFIX)
140 ])
142 # Determine which toolchain type to use, and make sure it is valid for this
143 # platform. Setup various information about the selected toolchain.
144 AC_DEFUN_ONCE([TOOLCHAIN_DETERMINE_TOOLCHAIN_TYPE],
145 [
146 AC_ARG_WITH(toolchain-type, [AS_HELP_STRING([--with-toolchain-type],
147 [the toolchain type (or family) to use, use '--help' to show possible values @<:@platform dependent@:>@])])
149 # Use indirect variable referencing
150 toolchain_var_name=VALID_TOOLCHAINS_$OPENJDK_BUILD_OS
151 VALID_TOOLCHAINS=${!toolchain_var_name}
152 # First toolchain type in the list is the default
153 DEFAULT_TOOLCHAIN=${VALID_TOOLCHAINS%% *}
155 if test "x$with_toolchain_type" = xlist; then
156 # List all toolchains
157 AC_MSG_NOTICE([The following toolchains are valid on this platform:])
158 for toolchain in $VALID_TOOLCHAINS; do
159 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$toolchain
160 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
161 $PRINTF " %-10s %s\n" $toolchain "$TOOLCHAIN_DESCRIPTION"
162 done
164 exit 0
165 elif test "x$with_toolchain_type" != x; then
166 # User override; check that it is valid
167 if test "x${VALID_TOOLCHAINS/$with_toolchain_type/}" = "x${VALID_TOOLCHAINS}"; then
168 AC_MSG_NOTICE([Toolchain type $with_toolchain_type is not valid on this platform.])
169 AC_MSG_NOTICE([Valid toolchains: $VALID_TOOLCHAINS.])
170 AC_MSG_ERROR([Cannot continue.])
171 fi
172 TOOLCHAIN_TYPE=$with_toolchain_type
173 else
174 # No flag given, use default
175 TOOLCHAIN_TYPE=$DEFAULT_TOOLCHAIN
176 fi
177 AC_SUBST(TOOLCHAIN_TYPE)
179 TOOLCHAIN_CC_BINARY_clang="clang"
180 TOOLCHAIN_CC_BINARY_gcc="gcc"
181 TOOLCHAIN_CC_BINARY_microsoft="cl"
182 TOOLCHAIN_CC_BINARY_solstudio="cc"
183 TOOLCHAIN_CC_BINARY_xlc="xlc_r"
185 TOOLCHAIN_CXX_BINARY_clang="clang++"
186 TOOLCHAIN_CXX_BINARY_gcc="g++"
187 TOOLCHAIN_CXX_BINARY_microsoft="cl"
188 TOOLCHAIN_CXX_BINARY_solstudio="CC"
189 TOOLCHAIN_CXX_BINARY_xlc="xlC_r"
191 # Use indirect variable referencing
192 toolchain_var_name=TOOLCHAIN_DESCRIPTION_$TOOLCHAIN_TYPE
193 TOOLCHAIN_DESCRIPTION=${!toolchain_var_name}
194 toolchain_var_name=TOOLCHAIN_CC_BINARY_$TOOLCHAIN_TYPE
195 TOOLCHAIN_CC_BINARY=${!toolchain_var_name}
196 toolchain_var_name=TOOLCHAIN_CXX_BINARY_$TOOLCHAIN_TYPE
197 TOOLCHAIN_CXX_BINARY=${!toolchain_var_name}
199 TOOLCHAIN_SETUP_FILENAME_PATTERNS
201 if test "x$TOOLCHAIN_TYPE" = "x$DEFAULT_TOOLCHAIN"; then
202 AC_MSG_NOTICE([Using default toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION)])
203 else
204 AC_MSG_NOTICE([Using user selected toolchain $TOOLCHAIN_TYPE ($TOOLCHAIN_DESCRIPTION). Default toolchain is $DEFAULT_TOOLCHAIN.])
205 fi
206 ])
208 # Before we start detecting the toolchain executables, we might need some
209 # special setup, e.g. additional paths etc.
210 AC_DEFUN_ONCE([TOOLCHAIN_PRE_DETECTION],
211 [
212 # FIXME: Is this needed?
213 AC_LANG(C++)
215 # Store the CFLAGS etal passed to the configure script.
216 ORG_CFLAGS="$CFLAGS"
217 ORG_CXXFLAGS="$CXXFLAGS"
218 ORG_OBJCFLAGS="$OBJCFLAGS"
220 # On Windows, we need to detect the visual studio installation first.
221 # This will change the PATH, but we need to keep that new PATH even
222 # after toolchain detection is done, since the compiler (on x86) uses
223 # it for DLL resolution in runtime.
224 if test "x$OPENJDK_BUILD_OS" = "xwindows" && test "x$TOOLCHAIN_TYPE" = "xmicrosoft"; then
225 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
226 # Reset path to VS_PATH. It will include everything that was on PATH at the time we
227 # ran TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV.
228 PATH="$VS_PATH"
229 # The microsoft toolchain also requires INCLUDE and LIB to be set.
230 export INCLUDE="$VS_INCLUDE"
231 export LIB="$VS_LIB"
232 fi
234 # autoconf magic only relies on PATH, so update it if tools dir is specified
235 OLD_PATH="$PATH"
237 # Before we locate the compilers, we need to sanitize the Xcode build environment
238 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
239 # determine path to Xcode developer directory
240 # can be empty in which case all the tools will rely on a sane Xcode 4 installation
241 SET_DEVELOPER_DIR=
243 if test -n "$XCODE_PATH"; then
244 DEVELOPER_DIR="$XCODE_PATH"/Contents/Developer
245 fi
247 # DEVELOPER_DIR could also be provided directly
248 AC_MSG_CHECKING([Determining if we need to set DEVELOPER_DIR])
249 if test -n "$DEVELOPER_DIR"; then
250 if test ! -d "$DEVELOPER_DIR"; then
251 AC_MSG_ERROR([Xcode Developer path does not exist: $DEVELOPER_DIR, please provide a path to the Xcode 4 application bundle using --with-xcode-path])
252 fi
253 if test ! -f "$DEVELOPER_DIR"/usr/bin/xcodebuild; then
254 AC_MSG_ERROR([Xcode Developer path is not valid: $DEVELOPER_DIR, it must point to Contents/Developer inside an Xcode application bundle])
255 fi
256 # make it visible to all the tools immediately
257 export DEVELOPER_DIR
258 SET_DEVELOPER_DIR="export DEVELOPER_DIR := $DEVELOPER_DIR"
259 AC_MSG_RESULT([yes ($DEVELOPER_DIR)])
260 else
261 AC_MSG_RESULT([no])
262 fi
263 AC_SUBST(SET_DEVELOPER_DIR)
265 AC_PATH_PROG(XCODEBUILD, xcodebuild)
266 if test -z "$XCODEBUILD"; then
267 AC_MSG_ERROR([The xcodebuild tool was not found, the Xcode command line tools are required to build on Mac OS X])
268 fi
270 # Fail-fast: verify we're building on Xcode 4, we cannot build with Xcode 5 or later
271 XCODE_VERSION=`$XCODEBUILD -version | grep '^Xcode ' | sed 's/Xcode //'`
272 XC_VERSION_PARTS=( ${XCODE_VERSION//./ } )
273 if test ! "${XC_VERSION_PARTS[[0]]}" = "4"; then
274 AC_MSG_ERROR([Xcode 4 is required to build JDK 8, the version found was $XCODE_VERSION. Use --with-xcode-path to specify the location of Xcode 4 or make Xcode 4 active by using xcode-select.])
275 fi
277 # Some versions of Xcode 5 command line tools install gcc and g++ as symlinks to
278 # clang and clang++, which will break the build. So handle that here if we need to.
279 if test -L "/usr/bin/gcc" -o -L "/usr/bin/g++"; then
280 # use xcrun to find the real gcc and add it's directory to PATH
281 # then autoconf magic will find it
282 AC_MSG_NOTICE([Found gcc symlinks to clang in /usr/bin, adding path to real gcc to PATH])
283 XCODE_BIN_PATH=$(dirname `xcrun -find gcc`)
284 PATH="$XCODE_BIN_PATH":$PATH
285 fi
287 # Determine appropriate SDKPATH, don't use SDKROOT as it interferes with the stub tools
288 AC_MSG_CHECKING([Determining Xcode SDK path])
289 # allow SDKNAME to be set to override the default SDK selection
290 SDKPATH=`"$XCODEBUILD" -sdk ${SDKNAME:-macosx} -version | grep '^Path: ' | sed 's/Path: //'`
291 if test -n "$SDKPATH"; then
292 AC_MSG_RESULT([$SDKPATH])
293 else
294 AC_MSG_RESULT([(none, will use system headers and frameworks)])
295 fi
296 AC_SUBST(SDKPATH)
298 # Perform a basic sanity test
299 if test ! -f "$SDKPATH/System/Library/Frameworks/Foundation.framework/Headers/Foundation.h"; then
300 AC_MSG_ERROR([Unable to find required framework headers, provide a valid path to Xcode 4 using --with-xcode-path])
301 fi
303 # if SDKPATH is non-empty then we need to add -isysroot and -iframework for gcc and g++
304 if test -n "$SDKPATH"; then
305 # We need -isysroot <path> and -iframework<path>/System/Library/Frameworks
306 CFLAGS_JDK="${CFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
307 CXXFLAGS_JDK="${CXXFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
308 LDFLAGS_JDK="${LDFLAGS_JDK} -isysroot \"$SDKPATH\" -iframework\"$SDKPATH/System/Library/Frameworks\""
309 fi
311 # These always need to be set, or we can't find the frameworks embedded in JavaVM.framework
312 # setting this here means it doesn't have to be peppered throughout the forest
313 CFLAGS_JDK="$CFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
314 CXXFLAGS_JDK="$CXXFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
315 LDFLAGS_JDK="$LDFLAGS_JDK -F\"$SDKPATH/System/Library/Frameworks/JavaVM.framework/Frameworks\""
316 fi
318 # For solaris we really need solaris tools, and not the GNU equivalent.
319 # The build tools on Solaris reside in /usr/ccs (C Compilation System),
320 # so add that to path before starting to probe.
321 # FIXME: This was originally only done for AS,NM,GNM,STRIP,MCS,OBJCOPY,OBJDUMP.
322 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
323 PATH="/usr/ccs/bin:$PATH"
324 fi
326 # Finally add TOOLCHAIN_PATH at the beginning, to allow --with-tools-dir to
327 # override all other locations.
328 if test "x$TOOLCHAIN_PATH" != x; then
329 PATH=$TOOLCHAIN_PATH:$PATH
330 fi
331 ])
333 # Restore path, etc
334 AC_DEFUN_ONCE([TOOLCHAIN_POST_DETECTION],
335 [
336 # Restore old path.
337 PATH="$OLD_PATH"
339 # Restore the flags to the user specified values.
340 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
341 CFLAGS="$ORG_CFLAGS"
342 CXXFLAGS="$ORG_CXXFLAGS"
343 OBJCFLAGS="$ORG_OBJCFLAGS"
344 ])
346 # Check if a compiler is of the toolchain type we expect, and save the version
347 # information from it. If the compiler does not match the expected type,
348 # this function will abort using AC_MSG_ERROR. If it matches, the version will
349 # be stored in CC_VERSION_NUMBER/CXX_VERSION_NUMBER (as a dotted number), and
350 # the full version string in CC_VERSION_STRING/CXX_VERSION_STRING.
351 #
352 # $1 = compiler to test (CC or CXX)
353 # $2 = human readable name of compiler (C or C++)
354 AC_DEFUN([TOOLCHAIN_EXTRACT_COMPILER_VERSION],
355 [
356 COMPILER=[$]$1
357 COMPILER_NAME=$2
359 if test "x$TOOLCHAIN_TYPE" = xsolstudio; then
360 # cc -V output typically looks like
361 # cc: Sun C 5.12 Linux_i386 2011/11/16
362 COMPILER_VERSION_OUTPUT=`$COMPILER -V 2>&1`
363 # Check that this is likely to be the Solaris Studio cc.
364 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
365 if test $? -ne 0; then
366 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
367 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
368 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_OUTPUT"])
369 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
370 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
371 fi
372 # Remove usage instructions (if present), and
373 # collapse compiler output into a single line
374 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
375 $SED -e 's/ *@<:@Uu@:>@sage:.*//'`
376 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
377 $SED -e "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/"`
378 elif test "x$TOOLCHAIN_TYPE" = xxlc; then
379 # xlc -qversion output typically looks like
380 # IBM XL C/C++ for AIX, V11.1 (5724-X13)
381 # Version: 11.01.0000.0015
382 COMPILER_VERSION_OUTPUT=`$COMPILER -qversion 2>&1`
383 # Check that this is likely to be the IBM XL C compiler.
384 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "IBM XL C" > /dev/null
385 if test $? -ne 0; then
386 ALT_VERSION_OUTPUT=`$COMPILER --version 2>&1`
387 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
388 AC_MSG_NOTICE([The result from running with -qversion was: "$COMPILER_VERSION_OUTPUT"])
389 AC_MSG_NOTICE([The result from running with --version was: "$ALT_VERSION_OUTPUT"])
390 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
391 fi
392 # Collapse compiler output into a single line
393 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
394 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
395 $SED -e 's/^.*, V\(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
396 elif test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
397 # There is no specific version flag, but all output starts with a version string.
398 # First line typically looks something like:
399 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.40219.01 for 80x86
400 COMPILER_VERSION_OUTPUT=`$COMPILER 2>&1 | $HEAD -n 1 | $TR -d '\r'`
401 # Check that this is likely to be Microsoft CL.EXE.
402 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Microsoft.*Compiler" > /dev/null
403 if test $? -ne 0; then
404 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
405 AC_MSG_NOTICE([The result from running it was: "$COMPILER_VERSION_OUTPUT"])
406 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
407 fi
408 # Collapse compiler output into a single line
409 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
410 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
411 $SED -e 's/^.*ersion.\(@<:@1-9@:>@@<:@0-9.@:>@*\) .*$/\1/'`
412 elif test "x$TOOLCHAIN_TYPE" = xgcc; then
413 # gcc --version output typically looks like
414 # gcc (Ubuntu/Linaro 4.8.1-10ubuntu9) 4.8.1
415 # Copyright (C) 2013 Free Software Foundation, Inc.
416 # This is free software; see the source for copying conditions. There is NO
417 # warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.
418 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
419 # Check that this is likely to be GCC.
420 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "Free Software Foundation" > /dev/null
421 if test $? -ne 0; then
422 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
423 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION"])
424 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
425 fi
426 # Remove Copyright and legalese from version string, and
427 # collapse into a single line
428 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT | \
429 $SED -e 's/ *Copyright .*//'`
430 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
431 $SED -e 's/^.* \(@<:@1-9@:>@\.@<:@0-9.@:>@*\) .*$/\1/'`
432 elif test "x$TOOLCHAIN_TYPE" = xclang; then
433 # clang --version output typically looks like
434 # Apple LLVM version 5.0 (clang-500.2.79) (based on LLVM 3.3svn)
435 # clang version 3.3 (tags/RELEASE_33/final)
436 # or
437 # Debian clang version 3.2-7ubuntu1 (tags/RELEASE_32/final) (based on LLVM 3.2)
438 # Target: x86_64-pc-linux-gnu
439 # Thread model: posix
440 COMPILER_VERSION_OUTPUT=`$COMPILER --version 2>&1`
441 # Check that this is likely to be clang
442 $ECHO "$COMPILER_VERSION_OUTPUT" | $GREP "clang" > /dev/null
443 if test $? -ne 0; then
444 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required $TOOLCHAIN_TYPE compiler.])
445 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_OUTPUT"])
446 AC_MSG_ERROR([A $TOOLCHAIN_TYPE compiler is required. Try setting --with-tools-dir.])
447 fi
448 # Collapse compiler output into a single line
449 COMPILER_VERSION_STRING=`$ECHO $COMPILER_VERSION_OUTPUT`
450 COMPILER_VERSION_NUMBER=`$ECHO $COMPILER_VERSION_OUTPUT | \
451 $SED -e 's/^.*clang version \(@<:@1-9@:>@@<:@0-9.@:>@*\).*$/\1/'`
453 else
454 AC_MSG_ERROR([Unknown toolchain type $TOOLCHAIN_TYPE.])
455 fi
456 # This sets CC_VERSION_NUMBER or CXX_VERSION_NUMBER. (This comment is a grep marker)
457 $1_VERSION_NUMBER="$COMPILER_VERSION_NUMBER"
458 # This sets CC_VERSION_STRING or CXX_VERSION_STRING. (This comment is a grep marker)
459 $1_VERSION_STRING="$COMPILER_VERSION_STRING"
461 AC_MSG_NOTICE([Using $TOOLCHAIN_TYPE $COMPILER_NAME compiler version $COMPILER_VERSION_NUMBER @<:@$COMPILER_VERSION_STRING@:>@])
462 ])
465 # Try to locate the given C or C++ compiler in the path, or otherwise.
466 #
467 # $1 = compiler to test (CC or CXX)
468 # $2 = human readable name of compiler (C or C++)
469 # $3 = list of compiler names to search for
470 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
471 [
472 COMPILER_NAME=$2
473 SEARCH_LIST="$3"
475 if test "x[$]$1" != x; then
476 # User has supplied compiler name already, always let that override.
477 AC_MSG_NOTICE([Will use user supplied compiler $1=[$]$1])
478 if test "x`basename [$]$1`" = "x[$]$1"; then
479 # A command without a complete path is provided, search $PATH.
481 AC_PATH_PROGS(POTENTIAL_$1, [$]$1)
482 if test "x$POTENTIAL_$1" != x; then
483 $1=$POTENTIAL_$1
484 else
485 AC_MSG_ERROR([User supplied compiler $1=[$]$1 could not be found])
486 fi
487 else
488 # Otherwise it might already be a complete path
489 if test ! -x "[$]$1"; then
490 AC_MSG_ERROR([User supplied compiler $1=[$]$1 does not exist])
491 fi
492 fi
493 else
494 # No user supplied value. Locate compiler ourselves.
496 # If we are cross compiling, assume cross compilation tools follows the
497 # cross compilation standard where they are prefixed with the autoconf
498 # standard name for the target. For example the binary
499 # i686-sun-solaris2.10-gcc will cross compile for i686-sun-solaris2.10.
500 # If we are not cross compiling, then the default compiler name will be
501 # used.
503 $1=
504 # If TOOLCHAIN_PATH is set, check for all compiler names in there first
505 # before checking the rest of the PATH.
506 # FIXME: Now that we prefix the TOOLS_DIR to the PATH in the PRE_DETECTION
507 # step, this should not be necessary.
508 if test -n "$TOOLCHAIN_PATH"; then
509 PATH_save="$PATH"
510 PATH="$TOOLCHAIN_PATH"
511 AC_PATH_PROGS(TOOLCHAIN_PATH_$1, $SEARCH_LIST)
512 $1=$TOOLCHAIN_PATH_$1
513 PATH="$PATH_save"
514 fi
516 # AC_PATH_PROGS can't be run multiple times with the same variable,
517 # so create a new name for this run.
518 if test "x[$]$1" = x; then
519 AC_PATH_PROGS(POTENTIAL_$1, $3)
520 $1=$POTENTIAL_$1
521 fi
523 if test "x[$]$1" = x; then
524 HELP_MSG_MISSING_DEPENDENCY([devkit])
525 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
526 fi
527 fi
529 # Now we have a compiler binary in $1. Make sure it's okay.
530 BASIC_FIXUP_EXECUTABLE($1)
531 TEST_COMPILER="[$]$1"
532 # Don't remove symbolic links on AIX because 'xlc_r' and 'xlC_r' may all be links
533 # to 'xlc' but it is crucial that we invoke the compiler with the right name!
534 if test "x$OPENJDK_BUILD_OS" != xaix; then
535 # FIXME: This test should not be needed anymore; we don't do that for any platform.
536 AC_MSG_CHECKING([resolved symbolic links for $1])
537 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
538 AC_MSG_RESULT([$TEST_COMPILER])
539 fi
540 AC_MSG_CHECKING([if $1 is disguised ccache])
542 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
543 if test "x$COMPILER_BASENAME" = "xccache"; then
544 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
545 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
546 # We want to control ccache invocation ourselves, so ignore this cc and try
547 # searching again.
549 # Remove the path to the fake ccache cc from the PATH
550 RETRY_COMPILER_SAVED_PATH="$PATH"
551 COMPILER_DIRNAME=`$DIRNAME [$]$1`
552 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
554 # Try again looking for our compiler
555 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
556 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
557 PATH="$RETRY_COMPILER_SAVED_PATH"
559 AC_MSG_CHECKING([for resolved symbolic links for $1])
560 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
561 AC_MSG_RESULT([$PROPER_COMPILER_$1])
562 $1="$PROPER_COMPILER_$1"
563 else
564 AC_MSG_RESULT([no, keeping $1])
565 $1="$TEST_COMPILER"
566 fi
568 TOOLCHAIN_EXTRACT_COMPILER_VERSION([$1], [$COMPILER_NAME])
569 ])
571 # Detect the core components of the toolchain, i.e. the compilers (CC and CXX),
572 # preprocessor (CPP and CXXCPP), the linker (LD), the assembler (AS) and the
573 # archiver (AR). Verify that the compilers are correct according to the
574 # toolchain type.
575 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_CORE],
576 [
577 #
578 # Setup the compilers (CC and CXX)
579 #
580 TOOLCHAIN_FIND_COMPILER([CC], [C], $TOOLCHAIN_CC_BINARY)
581 # Now that we have resolved CC ourself, let autoconf have its go at it
582 AC_PROG_CC([$CC])
584 TOOLCHAIN_FIND_COMPILER([CXX], [C++], $TOOLCHAIN_CXX_BINARY)
585 # Now that we have resolved CXX ourself, let autoconf have its go at it
586 AC_PROG_CXX([$CXX])
588 # This is the compiler version number on the form X.Y[.Z]
589 AC_SUBST(CC_VERSION_NUMBER)
590 AC_SUBST(CXX_VERSION_NUMBER)
592 TOOLCHAIN_PREPARE_FOR_VERSION_COMPARISONS
594 #
595 # Setup the preprocessor (CPP and CXXCPP)
596 #
597 AC_PROG_CPP
598 BASIC_FIXUP_EXECUTABLE(CPP)
599 AC_PROG_CXXCPP
600 BASIC_FIXUP_EXECUTABLE(CXXCPP)
602 #
603 # Setup the linker (LD)
604 #
605 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
606 # In the Microsoft toolchain we have a separate LD command "link".
607 # Make sure we reject /usr/bin/link (as determined in CYGWIN_LINK), which is
608 # a cygwin program for something completely different.
609 AC_CHECK_PROG([LD], [link],[link],,, [$CYGWIN_LINK])
610 BASIC_FIXUP_EXECUTABLE(LD)
611 # Verify that we indeed succeeded with this trick.
612 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
613 "$LD" --version > /dev/null
614 if test $? -eq 0 ; then
615 AC_MSG_RESULT([no])
616 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
617 else
618 AC_MSG_RESULT([yes])
619 fi
620 LDCXX="$LD"
621 else
622 # All other toolchains use the compiler to link.
623 LD="$CC"
624 LDCXX="$CXX"
625 fi
626 AC_SUBST(LD)
627 # FIXME: it should be CXXLD, according to standard (cf CXXCPP)
628 AC_SUBST(LDCXX)
630 #
631 # Setup the assembler (AS)
632 #
633 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
634 # FIXME: should this really be solaris, or solstudio?
635 BASIC_PATH_PROGS(AS, as)
636 BASIC_FIXUP_EXECUTABLE(AS)
637 else
638 # FIXME: is this correct for microsoft?
639 AS="$CC -c"
640 fi
641 AC_SUBST(AS)
643 #
644 # Setup the archiver (AR)
645 #
646 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
647 # The corresponding ar tool is lib.exe (used to create static libraries)
648 AC_CHECK_PROG([AR], [lib],[lib],,,)
649 else
650 BASIC_CHECK_TOOLS(AR, ar)
651 fi
652 BASIC_FIXUP_EXECUTABLE(AR)
653 ])
655 # Setup additional tools that is considered a part of the toolchain, but not the
656 # core part. Many of these are highly platform-specific and do not exist,
657 # and/or are not needed on all platforms.
658 AC_DEFUN_ONCE([TOOLCHAIN_DETECT_TOOLCHAIN_EXTRA],
659 [
660 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
661 AC_PROG_OBJC
662 BASIC_FIXUP_EXECUTABLE(OBJC)
663 BASIC_PATH_PROGS(LIPO, lipo)
664 BASIC_FIXUP_EXECUTABLE(LIPO)
665 else
666 OBJC=
667 fi
669 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
670 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
671 BASIC_FIXUP_EXECUTABLE(MT)
672 # Setup the resource compiler (RC)
673 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
674 BASIC_FIXUP_EXECUTABLE(RC)
675 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
676 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
677 # We need to check for 'msbuild.exe' because at the place where we expect to
678 # find 'msbuild.exe' there's also a directory called 'msbuild' and configure
679 # won't find the 'msbuild.exe' executable in that case (and the
680 # 'ac_executable_extensions' is unusable due to performance reasons).
681 # Notice that we intentionally don't fix up the path to MSBUILD because we
682 # will call it in a DOS shell during freetype detection on Windows (see
683 # 'LIB_SETUP_FREETYPE' in "libraries.m4"
684 AC_CHECK_PROG([MSBUILD], [msbuild.exe], [msbuild.exe],,,)
685 fi
687 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
688 BASIC_PATH_PROGS(STRIP, strip)
689 BASIC_FIXUP_EXECUTABLE(STRIP)
690 BASIC_PATH_PROGS(NM, nm)
691 BASIC_FIXUP_EXECUTABLE(NM)
692 BASIC_PATH_PROGS(GNM, gnm)
693 BASIC_FIXUP_EXECUTABLE(GNM)
695 BASIC_PATH_PROGS(MCS, mcs)
696 BASIC_FIXUP_EXECUTABLE(MCS)
697 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
698 # FIXME: we should unify this with the solaris case above.
699 BASIC_CHECK_TOOLS(STRIP, strip)
700 BASIC_FIXUP_EXECUTABLE(STRIP)
701 AC_PATH_PROG(OTOOL, otool)
702 if test "x$OTOOL" = "x"; then
703 OTOOL="true"
704 fi
705 BASIC_CHECK_TOOLS(NM, nm)
706 BASIC_FIXUP_EXECUTABLE(NM)
707 GNM="$NM"
708 AC_SUBST(GNM)
709 fi
711 # objcopy is used for moving debug symbols to separate files when
712 # full debug symbols are enabled.
713 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
714 BASIC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
715 # Only call fixup if objcopy was found.
716 if test -n "$OBJCOPY"; then
717 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
718 fi
719 fi
721 BASIC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
722 if test "x$OBJDUMP" != x; then
723 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE
724 # bails if argument is missing.
725 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
726 fi
727 ])
729 # Setup the build tools (i.e, the compiler and linker used to build programs
730 # that should be run on the build platform, not the target platform, as a build
731 # helper). Since the non-cross-compile case uses the normal, target compilers
732 # for this, we can only do this after these have been setup.
733 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_BUILD_COMPILERS],
734 [
735 if test "x$COMPILE_TYPE" = "xcross"; then
736 # Now we need to find a C/C++ compiler that can build executables for the
737 # build platform. We can't use the AC_PROG_CC macro, since it can only be
738 # used once. Also, we need to do this without adding a tools dir to the
739 # path, otherwise we might pick up cross-compilers which don't use standard
740 # naming.
742 # FIXME: we should list the discovered compilers as an exclude pattern!
743 # If we do that, we can do this detection before POST_DETECTION, and still
744 # find the build compilers in the tools dir, if needed.
745 BASIC_PATH_PROGS(BUILD_CC, [cl cc gcc])
746 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
747 BASIC_PATH_PROGS(BUILD_CXX, [cl CC g++])
748 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
749 BASIC_PATH_PROGS(BUILD_LD, ld)
750 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
751 else
752 # If we are not cross compiling, use the normal target compilers for
753 # building the build platform executables.
754 BUILD_CC="$CC"
755 BUILD_CXX="$CXX"
756 BUILD_LD="$LD"
757 fi
758 ])
760 # Setup legacy variables that are still needed as alternative ways to refer to
761 # parts of the toolchain.
762 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_LEGACY],
763 [
764 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
765 # For hotspot, we need these in Windows mixed path,
766 # so rewrite them all. Need added .exe suffix.
767 HOTSPOT_CXX="$CXX.exe"
768 HOTSPOT_LD="$LD.exe"
769 HOTSPOT_MT="$MT.exe"
770 HOTSPOT_RC="$RC.exe"
771 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
772 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
773 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
774 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
775 AC_SUBST(HOTSPOT_MT)
776 AC_SUBST(HOTSPOT_RC)
777 else
778 HOTSPOT_CXX="$CXX"
779 HOTSPOT_LD="$LD"
780 fi
781 AC_SUBST(HOTSPOT_CXX)
782 AC_SUBST(HOTSPOT_LD)
784 if test "x$TOOLCHAIN_TYPE" = xclang; then
785 USE_CLANG=true
786 fi
787 AC_SUBST(USE_CLANG)
789 # LDEXE is the linker to use, when creating executables. Not really used.
790 # FIXME: These should just be removed!
791 LDEXE="$LD"
792 LDEXECXX="$LDCXX"
793 AC_SUBST(LDEXE)
794 AC_SUBST(LDEXECXX)
795 ])
797 # Do some additional checks on the detected tools.
798 AC_DEFUN_ONCE([TOOLCHAIN_MISC_CHECKS],
799 [
800 # The package path is used only on macosx?
801 # FIXME: clean this up, and/or move it elsewhere.
802 PACKAGE_PATH=/opt/local
803 AC_SUBST(PACKAGE_PATH)
805 # Check for extra potential brokenness.
806 if test "x$TOOLCHAIN_TYPE" = xmicrosoft; then
807 # On Windows, double-check that we got the right compiler.
808 CC_VERSION_OUTPUT=`$CC 2>&1 | $HEAD -n 1 | $TR -d '\r'`
809 COMPILER_CPU_TEST=`$ECHO $CC_VERSION_OUTPUT | $SED -n "s/^.* \(.*\)$/\1/p"`
810 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
811 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
812 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
813 fi
814 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
815 if test "x$COMPILER_CPU_TEST" != "xx64"; then
816 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
817 fi
818 fi
819 fi
821 if test "x$TOOLCHAIN_TYPE" = xgcc; then
822 # If this is a --hash-style=gnu system, use --hash-style=both, why?
823 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
824 # This is later checked when setting flags.
825 fi
827 # Check for broken SuSE 'ld' for which 'Only anonymous version tag is allowed
828 # in executable.'
829 USING_BROKEN_SUSE_LD=no
830 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$TOOLCHAIN_TYPE" = xgcc; then
831 AC_MSG_CHECKING([for broken SuSE 'ld' which only understands anonymous version tags in executables])
832 echo "SUNWprivate_1.1 { local: *; };" > version-script.map
833 echo "int main() { }" > main.c
834 if $CXX -Xlinker -version-script=version-script.map main.c 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD; then
835 AC_MSG_RESULT(no)
836 USING_BROKEN_SUSE_LD=no
837 else
838 AC_MSG_RESULT(yes)
839 USING_BROKEN_SUSE_LD=yes
840 fi
841 rm -rf version-script.map main.c
842 fi
843 AC_SUBST(USING_BROKEN_SUSE_LD)
844 ])
846 # Setup the JTReg Regression Test Harness.
847 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_JTREG],
848 [
849 AC_ARG_WITH(jtreg, [AS_HELP_STRING([--with-jtreg],
850 [Regression Test Harness @<:@probed@:>@])],
851 [],
852 [with_jtreg=no])
854 if test "x$with_jtreg" = xno; then
855 # jtreg disabled
856 AC_MSG_CHECKING([for jtreg])
857 AC_MSG_RESULT(no)
858 else
859 if test "x$with_jtreg" != xyes; then
860 # with path specified.
861 JT_HOME="$with_jtreg"
862 fi
864 if test "x$JT_HOME" != x; then
865 AC_MSG_CHECKING([for jtreg])
867 # use JT_HOME enviroment var.
868 BASIC_FIXUP_PATH([JT_HOME])
870 # jtreg win32 script works for everybody
871 JTREGEXE="$JT_HOME/bin/jtreg"
873 if test ! -f "$JTREGEXE"; then
874 AC_MSG_ERROR([JTReg executable does not exist: $JTREGEXE])
875 fi
877 AC_MSG_RESULT($JTREGEXE)
878 else
879 # try to find jtreg on path
880 BASIC_REQUIRE_PROGS(JTREGEXE, jtreg)
881 JT_HOME="`$DIRNAME $JTREGEXE`"
882 fi
883 fi
885 AC_SUBST(JT_HOME)
886 AC_SUBST(JTREGEXE)
887 ])