Thu, 01 Aug 2013 17:24:26 -0700
Merge
1 #
2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
27 [
28 ###############################################################################
29 #
30 # Check which variant of the JDK that we want to build.
31 # Currently we have:
32 # normal: standard edition
33 # but the custom make system may add other variants
34 #
35 # Effectively the JDK variant gives a name to a specific set of
36 # modules to compile into the JDK. In the future, these modules
37 # might even be Jigsaw modules.
38 #
39 AC_MSG_CHECKING([which variant of the JDK to build])
40 AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
41 [JDK variant to build (normal) @<:@normal@:>@])])
43 if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
44 JDK_VARIANT="normal"
45 else
46 AC_MSG_ERROR([The available JDK variants are: normal])
47 fi
49 AC_SUBST(JDK_VARIANT)
51 AC_MSG_RESULT([$JDK_VARIANT])
52 ])
54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_INTERPRETER],
55 [
56 ###############################################################################
57 #
58 # Check which interpreter of the JVM we want to build.
59 # Currently we have:
60 # template: Template interpreter (the default)
61 # cpp : C++ interpreter
62 AC_MSG_CHECKING([which interpreter of the JVM to build])
63 AC_ARG_WITH([jvm-interpreter], [AS_HELP_STRING([--with-jvm-interpreter],
64 [JVM interpreter to build (template, cpp) @<:@template@:>@])])
66 if test "x$with_jvm_interpreter" = x; then
67 with_jvm_interpreter="template"
68 fi
70 JVM_INTERPRETER="$with_jvm_interpreter"
72 if test "x$JVM_INTERPRETER" != xtemplate && test "x$JVM_INTERPRETER" != xcpp; then
73 AC_MSG_ERROR([The available JVM interpreters are: template, cpp])
74 fi
76 AC_SUBST(JVM_INTERPRETER)
78 AC_MSG_RESULT([$with_jvm_interpreter])
79 ])
81 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
82 [
84 ###############################################################################
85 #
86 # Check which variants of the JVM that we want to build.
87 # Currently we have:
88 # server: normal interpreter and a tiered C1/C2 compiler
89 # client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
90 # minimal1: reduced form of client with optional VM services and features stripped out
91 # kernel: kernel footprint JVM that passes the TCK without major performance problems,
92 # ie normal interpreter and C1, only the serial GC, kernel jvmti etc
93 # zero: no machine code interpreter, no compiler
94 # zeroshark: zero interpreter and shark/llvm compiler backend
95 # core: interpreter only, no compiler (only works on some platforms)
96 AC_MSG_CHECKING([which variants of the JVM to build])
97 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
98 [JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark, core) @<:@server@:>@])])
100 if test "x$with_jvm_variants" = x; then
101 with_jvm_variants="server"
102 fi
104 JVM_VARIANTS=",$with_jvm_variants,"
105 TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//' -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//' -e 's/core,//'`
107 if test "x$TEST_VARIANTS" != "x,"; then
108 AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark, core])
109 fi
110 AC_MSG_RESULT([$with_jvm_variants])
112 JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
113 JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
114 JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
115 JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
116 JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
117 JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
118 JVM_VARIANT_CORE=`$ECHO "$JVM_VARIANTS" | $SED -e '/,core,/!s/.*/false/g' -e '/,core,/s/.*/true/g'`
120 if test "x$JVM_VARIANT_CLIENT" = xtrue; then
121 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
122 AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
123 fi
124 fi
125 if test "x$JVM_VARIANT_KERNEL" = xtrue; then
126 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
127 AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
128 fi
129 fi
130 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
131 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
132 AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
133 fi
134 fi
136 # Replace the commas with AND for use in the build directory name.
137 ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/'`
138 COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/' -e 's/core,/1/'`
139 if test "x$COUNT_VARIANTS" != "x,1"; then
140 BUILDING_MULTIPLE_JVM_VARIANTS=yes
141 else
142 BUILDING_MULTIPLE_JVM_VARIANTS=no
143 fi
145 AC_SUBST(JVM_VARIANTS)
146 AC_SUBST(JVM_VARIANT_SERVER)
147 AC_SUBST(JVM_VARIANT_CLIENT)
148 AC_SUBST(JVM_VARIANT_MINIMAL1)
149 AC_SUBST(JVM_VARIANT_KERNEL)
150 AC_SUBST(JVM_VARIANT_ZERO)
151 AC_SUBST(JVM_VARIANT_ZEROSHARK)
152 AC_SUBST(JVM_VARIANT_CORE)
154 INCLUDE_SA=true
155 if test "x$JVM_VARIANT_ZERO" = xtrue ; then
156 INCLUDE_SA=false
157 fi
158 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then
159 INCLUDE_SA=false
160 fi
161 if test "x$VAR_CPU" = xppc64 ; then
162 INCLUDE_SA=false
163 fi
164 AC_SUBST(INCLUDE_SA)
166 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
167 MACOSX_UNIVERSAL="true"
168 fi
170 AC_SUBST(MACOSX_UNIVERSAL)
172 ])
174 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
175 [
176 ###############################################################################
177 #
178 # Set the debug level
179 # release: no debug information, all optimizations, no asserts.
180 # fastdebug: debug information (-g), all optimizations, all asserts
181 # slowdebug: debug information (-g), no optimizations, all asserts
182 #
183 DEBUG_LEVEL="release"
184 AC_MSG_CHECKING([which debug level to use])
185 AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
186 [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
187 [
188 ENABLE_DEBUG="${enableval}"
189 DEBUG_LEVEL="fastdebug"
190 ], [ENABLE_DEBUG="no"])
192 AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
193 [set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],
194 [
195 DEBUG_LEVEL="${withval}"
196 if test "x$ENABLE_DEBUG" = xyes; then
197 AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
198 fi
199 ])
200 AC_MSG_RESULT([$DEBUG_LEVEL])
202 if test "x$DEBUG_LEVEL" != xrelease && \
203 test "x$DEBUG_LEVEL" != xfastdebug && \
204 test "x$DEBUG_LEVEL" != xslowdebug; then
205 AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
206 fi
209 ###############################################################################
210 #
211 # Setup legacy vars/targets and new vars to deal with different debug levels.
212 #
214 case $DEBUG_LEVEL in
215 release )
216 VARIANT="OPT"
217 FASTDEBUG="false"
218 DEBUG_CLASSFILES="false"
219 BUILD_VARIANT_RELEASE=""
220 HOTSPOT_DEBUG_LEVEL="product"
221 HOTSPOT_EXPORT="product"
222 ;;
223 fastdebug )
224 VARIANT="DBG"
225 FASTDEBUG="true"
226 DEBUG_CLASSFILES="true"
227 BUILD_VARIANT_RELEASE="-fastdebug"
228 HOTSPOT_DEBUG_LEVEL="fastdebug"
229 HOTSPOT_EXPORT="fastdebug"
230 ;;
231 slowdebug )
232 VARIANT="DBG"
233 FASTDEBUG="false"
234 DEBUG_CLASSFILES="true"
235 BUILD_VARIANT_RELEASE="-debug"
236 HOTSPOT_DEBUG_LEVEL="jvmg"
237 HOTSPOT_EXPORT="debug"
238 ;;
239 esac
241 #####
242 # Generate the legacy makefile targets for hotspot.
243 # The hotspot api for selecting the build artifacts, really, needs to be improved.
244 # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
245 # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
246 # But until then ...
247 HOTSPOT_TARGET=""
249 if test "x$JVM_VARIANT_SERVER" = xtrue; then
250 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
251 fi
253 if test "x$JVM_VARIANT_CLIENT" = xtrue; then
254 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
255 fi
257 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
258 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
259 fi
261 if test "x$JVM_VARIANT_KERNEL" = xtrue; then
262 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
263 fi
265 if test "x$JVM_VARIANT_ZERO" = xtrue; then
266 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
267 fi
269 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
270 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
271 fi
273 if test "x$JVM_VARIANT_CORE" = xtrue; then
274 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}core "
275 fi
277 HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
279 # On Macosx universal binaries are produced, but they only contain
280 # 64 bit intel. This invalidates control of which jvms are built
281 # from configure, but only server is valid anyway. Fix this
282 # when hotspot makefiles are rewritten.
283 if test "x$MACOSX_UNIVERSAL" = xtrue; then
284 HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
285 fi
287 #####
289 AC_SUBST(DEBUG_LEVEL)
290 AC_SUBST(VARIANT)
291 AC_SUBST(FASTDEBUG)
292 AC_SUBST(DEBUG_CLASSFILES)
293 AC_SUBST(BUILD_VARIANT_RELEASE)
294 ])
297 ###############################################################################
298 #
299 # Should we build only OpenJDK even if closed sources are present?
300 #
301 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
302 [
303 AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
304 [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
306 AC_MSG_CHECKING([for presence of closed sources])
307 if test -d "$SRC_ROOT/jdk/src/closed"; then
308 CLOSED_SOURCE_PRESENT=yes
309 else
310 CLOSED_SOURCE_PRESENT=no
311 fi
312 AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
314 AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
315 SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
316 AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
318 if test "x$CLOSED_SOURCE_PRESENT" = xno; then
319 OPENJDK=true
320 if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
321 AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
322 fi
323 else
324 if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
325 OPENJDK=true
326 else
327 OPENJDK=false
328 fi
329 fi
331 if test "x$OPENJDK" = "xtrue"; then
332 SET_OPENJDK="OPENJDK=true"
333 fi
335 AC_SUBST(SET_OPENJDK)
336 ])
338 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
339 [
341 ###############################################################################
342 #
343 # Should we build a JDK/JVM with headful support (ie a graphical ui)?
344 # We always build headless support.
345 #
346 AC_MSG_CHECKING([headful support])
347 AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
348 [disable building headful support (graphical UI support) @<:@enabled@:>@])],
349 [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
351 SUPPORT_HEADLESS=yes
352 BUILD_HEADLESS="BUILD_HEADLESS:=true"
354 if test "x$SUPPORT_HEADFUL" = xyes; then
355 # We are building both headful and headless.
356 headful_msg="inlude support for both headful and headless"
357 fi
359 if test "x$SUPPORT_HEADFUL" = xno; then
360 # Thus we are building headless only.
361 BUILD_HEADLESS="BUILD_HEADLESS:=true"
362 headful_msg="headless only"
363 fi
365 AC_MSG_RESULT([$headful_msg])
367 AC_SUBST(SUPPORT_HEADLESS)
368 AC_SUBST(SUPPORT_HEADFUL)
369 AC_SUBST(BUILD_HEADLESS)
371 # Control wether Hotspot runs Queens test after build.
372 AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
373 [run the Queens test after Hotspot build @<:@disabled@:>@])],,
374 [enable_hotspot_test_in_build=no])
375 if test "x$enable_hotspot_test_in_build" = "xyes"; then
376 TEST_IN_BUILD=true
377 else
378 TEST_IN_BUILD=false
379 fi
380 AC_SUBST(TEST_IN_BUILD)
382 ###############################################################################
383 #
384 # Choose cacerts source file
385 #
386 AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
387 [specify alternative cacerts file])])
388 if test "x$with_cacerts_file" != x; then
389 CACERTS_FILE=$with_cacerts_file
390 else
391 CACERTS_FILE=${SRC_ROOT}/jdk/src/share/lib/security/cacerts
392 fi
393 AC_SUBST(CACERTS_FILE)
395 ###############################################################################
396 #
397 # Enable or disable unlimited crypto
398 #
399 AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
400 [Enable unlimited crypto policy @<:@disabled@:>@])],,
401 [enable_unlimited_crypto=no])
402 if test "x$enable_unlimited_crypto" = "xyes"; then
403 UNLIMITED_CRYPTO=true
404 else
405 UNLIMITED_CRYPTO=false
406 fi
407 AC_SUBST(UNLIMITED_CRYPTO)
409 ###############################################################################
410 #
411 # Enable or disable the elliptic curve crypto implementation
412 #
413 AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
414 [
415 AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
417 if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then
418 ENABLE_INTREE_EC=yes
419 AC_MSG_RESULT([yes])
420 else
421 ENABLE_INTREE_EC=no
422 AC_MSG_RESULT([no])
423 fi
425 AC_SUBST(ENABLE_INTREE_EC)
426 ])
428 ###############################################################################
429 #
430 # Compress jars
431 #
432 COMPRESS_JARS=false
434 AC_SUBST(COMPRESS_JARS)
435 ])
437 ###############################################################################
438 #
439 # Setup version numbers
440 #
441 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],
442 [
443 # Source the version numbers
444 . $AUTOCONF_DIR/version-numbers
446 # Get the settings from parameters
447 AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],
448 [Set milestone value for build @<:@internal@:>@])])
449 if test "x$with_milestone" = xyes; then
450 AC_MSG_ERROR([Milestone must have a value])
451 elif test "x$with_milestone" != x; then
452 MILESTONE="$with_milestone"
453 fi
454 if test "x$MILESTONE" = x; then
455 MILESTONE=internal
456 fi
458 AC_ARG_WITH(update-version, [AS_HELP_STRING([--with-update-version],
459 [Set update version value for build @<:@b00@:>@])])
460 if test "x$with_update_version" = xyes; then
461 AC_MSG_ERROR([Update version must have a value])
462 elif test "x$with_update_version" != x; then
463 JDK_UPDATE_VERSION="$with_update_version"
464 fi
466 AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],
467 [Set build number value for build @<:@b00@:>@])])
468 if test "x$with_build_number" = xyes; then
469 AC_MSG_ERROR([Build number must have a value])
470 elif test "x$with_build_number" != x; then
471 JDK_BUILD_NUMBER="$with_build_number"
472 fi
473 if test "x$JDK_BUILD_NUMBER" = x; then
474 JDK_BUILD_NUMBER=b00
475 fi
477 AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],
478 [Add a custom string to the version string if build number isn't set.@<:@username_builddateb00@:>@])])
479 if test "x$with_user_release_suffix" = xyes; then
480 AC_MSG_ERROR([Release suffix must have a value])
481 elif test "x$with_user_release_suffix" != x; then
482 USER_RELEASE_SUFFIX="$with_user_release_suffix"
483 else
484 BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`
485 # Avoid [:alnum:] since it depends on the locale.
486 CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyz0123456789'`
487 USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`
488 fi
489 AC_SUBST(USER_RELEASE_SUFFIX)
491 # Now set the JDK version, milestone, build number etc.
492 AC_SUBST(JDK_MAJOR_VERSION)
493 AC_SUBST(JDK_MINOR_VERSION)
494 AC_SUBST(JDK_MICRO_VERSION)
495 AC_SUBST(JDK_UPDATE_VERSION)
496 AC_SUBST(JDK_BUILD_NUMBER)
497 AC_SUBST(MILESTONE)
498 AC_SUBST(LAUNCHER_NAME)
499 AC_SUBST(PRODUCT_NAME)
500 AC_SUBST(PRODUCT_SUFFIX)
501 AC_SUBST(JDK_RC_PLATFORM_NAME)
502 AC_SUBST(COMPANY_NAME)
503 AC_SUBST(MACOSX_BUNDLE_NAME_BASE)
504 AC_SUBST(MACOSX_BUNDLE_ID_BASE)
506 COPYRIGHT_YEAR=`date +'%Y'`
507 AC_SUBST(COPYRIGHT_YEAR)
509 if test "x$JDK_UPDATE_VERSION" != x; then
510 JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"
511 else
512 JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"
513 fi
514 AC_SUBST(JDK_VERSION)
516 COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`
517 AC_SUBST(COOKED_BUILD_NUMBER)
518 ])
520 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
521 [
522 HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
523 AC_SUBST(HOTSPOT_MAKE_ARGS)
525 # The name of the Service Agent jar.
526 SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
527 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
528 SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
529 fi
530 AC_SUBST(SALIB_NAME)
532 ])
534 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
535 [
536 #
537 # ENABLE_DEBUG_SYMBOLS
538 # This must be done after the toolchain is setup, since we're looking at objcopy.
539 #
540 AC_ARG_ENABLE([debug-symbols],
541 [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])
543 AC_MSG_CHECKING([if we should generate debug symbols])
545 if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then
546 # explicit enabling of enable-debug-symbols and can't find objcopy
547 # this is an error
548 AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])
549 fi
551 if test "x$enable_debug_symbols" = "xyes"; then
552 ENABLE_DEBUG_SYMBOLS=true
553 elif test "x$enable_debug_symbols" = "xno"; then
554 ENABLE_DEBUG_SYMBOLS=false
555 else
556 # default on macosx is false
557 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
558 ENABLE_DEBUG_SYMBOLS=false
559 # Default is on if objcopy is found, otherwise off
560 elif test "x$OBJCOPY" != x || test "x$OPENJDK_TARGET_OS" = xwindows; then
561 ENABLE_DEBUG_SYMBOLS=true
562 else
563 ENABLE_DEBUG_SYMBOLS=false
564 fi
565 fi
567 AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])
569 #
570 # ZIP_DEBUGINFO_FILES
571 #
572 AC_MSG_CHECKING([if we should zip debug-info files])
573 AC_ARG_ENABLE([zip-debug-info],
574 [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])],
575 [enable_zip_debug_info="${enableval}"], [enable_zip_debug_info="yes"])
576 AC_MSG_RESULT([${enable_zip_debug_info}])
578 if test "x${enable_zip_debug_info}" = "xno"; then
579 ZIP_DEBUGINFO_FILES=false
580 else
581 ZIP_DEBUGINFO_FILES=true
582 fi
584 AC_SUBST(ENABLE_DEBUG_SYMBOLS)
585 AC_SUBST(ZIP_DEBUGINFO_FILES)
586 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
587 AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)
588 ])
590 # Support for customization of the build process. Some build files
591 # will include counterparts from this location, if they exist. This allows
592 # for a degree of customization of the build targets and the rules/recipes
593 # to create them
594 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],
595 [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])
596 AC_SUBST(CUSTOM_MAKE_DIR)