Tue, 04 Jun 2013 10:23:37 +0200
8015784: Add configure parameter --with-update-version
Reviewed-by: tbell, katleman, erikj
Contributed-by: tristan.yan@oracle.com
1 #
2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],
27 [
28 ###############################################################################
29 #
30 # Check which variant of the JDK that we want to build.
31 # Currently we have:
32 # normal: standard edition
33 # but the custom make system may add other variants
34 #
35 # Effectively the JDK variant gives a name to a specific set of
36 # modules to compile into the JDK. In the future, these modules
37 # might even be Jigsaw modules.
38 #
39 AC_MSG_CHECKING([which variant of the JDK to build])
40 AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],
41 [JDK variant to build (normal) @<:@normal@:>@])])
43 if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then
44 JDK_VARIANT="normal"
45 else
46 AC_MSG_ERROR([The available JDK variants are: normal])
47 fi
49 AC_SUBST(JDK_VARIANT)
51 AC_MSG_RESULT([$JDK_VARIANT])
52 ])
54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],
55 [
57 ###############################################################################
58 #
59 # Check which variants of the JVM that we want to build.
60 # Currently we have:
61 # server: normal interpreter and a tiered C1/C2 compiler
62 # client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)
63 # minimal1: reduced form of client with optional VM services and features stripped out
64 # kernel: kernel footprint JVM that passes the TCK without major performance problems,
65 # ie normal interpreter and C1, only the serial GC, kernel jvmti etc
66 # zero: no machine code interpreter, no compiler
67 # zeroshark: zero interpreter and shark/llvm compiler backend
68 AC_MSG_CHECKING([which variants of the JVM to build])
69 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],
70 [JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark) @<:@server@:>@])])
72 if test "x$with_jvm_variants" = x; then
73 with_jvm_variants="server"
74 fi
76 JVM_VARIANTS=",$with_jvm_variants,"
77 TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//' -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//'`
79 if test "x$TEST_VARIANTS" != "x,"; then
80 AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark])
81 fi
82 AC_MSG_RESULT([$with_jvm_variants])
84 JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`
85 JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`
86 JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`
87 JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`
88 JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`
89 JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`
91 if test "x$JVM_VARIANT_CLIENT" = xtrue; then
92 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
93 AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])
94 fi
95 fi
96 if test "x$JVM_VARIANT_KERNEL" = xtrue; then
97 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
98 AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])
99 fi
100 fi
101 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
102 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
103 AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])
104 fi
105 fi
107 # Replace the commas with AND for use in the build directory name.
108 ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/'`
109 COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/'`
110 if test "x$COUNT_VARIANTS" != "x,1"; then
111 BUILDING_MULTIPLE_JVM_VARIANTS=yes
112 else
113 BUILDING_MULTIPLE_JVM_VARIANTS=no
114 fi
116 AC_SUBST(JVM_VARIANTS)
117 AC_SUBST(JVM_VARIANT_SERVER)
118 AC_SUBST(JVM_VARIANT_CLIENT)
119 AC_SUBST(JVM_VARIANT_MINIMAL1)
120 AC_SUBST(JVM_VARIANT_KERNEL)
121 AC_SUBST(JVM_VARIANT_ZERO)
122 AC_SUBST(JVM_VARIANT_ZEROSHARK)
124 INCLUDE_SA=true
125 if test "x$JVM_VARIANT_ZERO" = xtrue ; then
126 INCLUDE_SA=false
127 fi
128 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue ; then
129 INCLUDE_SA=false
130 fi
131 AC_SUBST(INCLUDE_SA)
133 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
134 MACOSX_UNIVERSAL="true"
135 fi
137 AC_SUBST(MACOSX_UNIVERSAL)
139 ])
141 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],
142 [
143 ###############################################################################
144 #
145 # Set the debug level
146 # release: no debug information, all optimizations, no asserts.
147 # fastdebug: debug information (-g), all optimizations, all asserts
148 # slowdebug: debug information (-g), no optimizations, all asserts
149 #
150 DEBUG_LEVEL="release"
151 AC_MSG_CHECKING([which debug level to use])
152 AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],
153 [set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],
154 [
155 ENABLE_DEBUG="${enableval}"
156 DEBUG_LEVEL="fastdebug"
157 ], [ENABLE_DEBUG="no"])
159 AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],
160 [set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],
161 [
162 DEBUG_LEVEL="${withval}"
163 if test "x$ENABLE_DEBUG" = xyes; then
164 AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])
165 fi
166 ])
167 AC_MSG_RESULT([$DEBUG_LEVEL])
169 if test "x$DEBUG_LEVEL" != xrelease && \
170 test "x$DEBUG_LEVEL" != xfastdebug && \
171 test "x$DEBUG_LEVEL" != xslowdebug; then
172 AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])
173 fi
176 ###############################################################################
177 #
178 # Setup legacy vars/targets and new vars to deal with different debug levels.
179 #
181 case $DEBUG_LEVEL in
182 release )
183 VARIANT="OPT"
184 FASTDEBUG="false"
185 DEBUG_CLASSFILES="false"
186 BUILD_VARIANT_RELEASE=""
187 HOTSPOT_DEBUG_LEVEL="product"
188 HOTSPOT_EXPORT="product"
189 ;;
190 fastdebug )
191 VARIANT="DBG"
192 FASTDEBUG="true"
193 DEBUG_CLASSFILES="true"
194 BUILD_VARIANT_RELEASE="-fastdebug"
195 HOTSPOT_DEBUG_LEVEL="fastdebug"
196 HOTSPOT_EXPORT="fastdebug"
197 ;;
198 slowdebug )
199 VARIANT="DBG"
200 FASTDEBUG="false"
201 DEBUG_CLASSFILES="true"
202 BUILD_VARIANT_RELEASE="-debug"
203 HOTSPOT_DEBUG_LEVEL="jvmg"
204 HOTSPOT_EXPORT="debug"
205 ;;
206 esac
208 #####
209 # Generate the legacy makefile targets for hotspot.
210 # The hotspot api for selecting the build artifacts, really, needs to be improved.
211 # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to
212 # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc
213 # But until then ...
214 HOTSPOT_TARGET=""
216 if test "x$JVM_VARIANT_SERVER" = xtrue; then
217 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "
218 fi
220 if test "x$JVM_VARIANT_CLIENT" = xtrue; then
221 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "
222 fi
224 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
225 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "
226 fi
228 if test "x$JVM_VARIANT_KERNEL" = xtrue; then
229 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "
230 fi
232 if test "x$JVM_VARIANT_ZERO" = xtrue; then
233 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "
234 fi
236 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then
237 HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "
238 fi
240 HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"
242 # On Macosx universal binaries are produced, but they only contain
243 # 64 bit intel. This invalidates control of which jvms are built
244 # from configure, but only server is valid anyway. Fix this
245 # when hotspot makefiles are rewritten.
246 if test "x$MACOSX_UNIVERSAL" = xtrue; then
247 HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}
248 fi
250 #####
252 AC_SUBST(DEBUG_LEVEL)
253 AC_SUBST(VARIANT)
254 AC_SUBST(FASTDEBUG)
255 AC_SUBST(DEBUG_CLASSFILES)
256 AC_SUBST(BUILD_VARIANT_RELEASE)
257 ])
260 ###############################################################################
261 #
262 # Should we build only OpenJDK even if closed sources are present?
263 #
264 AC_DEFUN_ONCE([JDKOPT_SETUP_OPEN_OR_CUSTOM],
265 [
266 AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],
267 [suppress building custom source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])
269 AC_MSG_CHECKING([for presence of closed sources])
270 if test -d "$SRC_ROOT/jdk/src/closed"; then
271 CLOSED_SOURCE_PRESENT=yes
272 else
273 CLOSED_SOURCE_PRESENT=no
274 fi
275 AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])
277 AC_MSG_CHECKING([if closed source is suppressed (openjdk-only)])
278 SUPPRESS_CLOSED_SOURCE="$enable_openjdk_only"
279 AC_MSG_RESULT([$SUPPRESS_CLOSED_SOURCE])
281 if test "x$CLOSED_SOURCE_PRESENT" = xno; then
282 OPENJDK=true
283 if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
284 AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])
285 fi
286 else
287 if test "x$SUPPRESS_CLOSED_SOURCE" = "xyes"; then
288 OPENJDK=true
289 else
290 OPENJDK=false
291 fi
292 fi
294 if test "x$OPENJDK" = "xtrue"; then
295 SET_OPENJDK="OPENJDK=true"
296 fi
298 AC_SUBST(SET_OPENJDK)
299 ])
301 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],
302 [
304 ###############################################################################
305 #
306 # Should we build a JDK/JVM with headful support (ie a graphical ui)?
307 # We always build headless support.
308 #
309 AC_MSG_CHECKING([headful support])
310 AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],
311 [disable building headful support (graphical UI support) @<:@enabled@:>@])],
312 [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])
314 SUPPORT_HEADLESS=yes
315 BUILD_HEADLESS="BUILD_HEADLESS:=true"
317 if test "x$SUPPORT_HEADFUL" = xyes; then
318 # We are building both headful and headless.
319 headful_msg="inlude support for both headful and headless"
320 fi
322 if test "x$SUPPORT_HEADFUL" = xno; then
323 # Thus we are building headless only.
324 BUILD_HEADLESS="BUILD_HEADLESS:=true"
325 headful_msg="headless only"
326 fi
328 AC_MSG_RESULT([$headful_msg])
330 AC_SUBST(SUPPORT_HEADLESS)
331 AC_SUBST(SUPPORT_HEADFUL)
332 AC_SUBST(BUILD_HEADLESS)
334 # Control wether Hotspot runs Queens test after build.
335 AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],
336 [run the Queens test after Hotspot build @<:@disabled@:>@])],,
337 [enable_hotspot_test_in_build=no])
338 if test "x$enable_hotspot_test_in_build" = "xyes"; then
339 TEST_IN_BUILD=true
340 else
341 TEST_IN_BUILD=false
342 fi
343 AC_SUBST(TEST_IN_BUILD)
345 ###############################################################################
346 #
347 # Choose cacerts source file
348 #
349 AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],
350 [specify alternative cacerts file])])
351 if test "x$with_cacerts_file" != x; then
352 CACERTS_FILE=$with_cacerts_file
353 else
354 if test "x$OPENJDK" = "xtrue"; then
355 CACERTS_FILE=${SRC_ROOT}/jdk/src/share/lib/security/cacerts
356 else
357 CACERTS_FILE=${SRC_ROOT}/jdk/src/closed/share/lib/security/cacerts.internal
358 fi
359 fi
360 AC_SUBST(CACERTS_FILE)
362 ###############################################################################
363 #
364 # Enable or disable unlimited crypto
365 #
366 AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],
367 [Enable unlimited crypto policy @<:@disabled@:>@])],,
368 [enable_unlimited_crypto=no])
369 if test "x$enable_unlimited_crypto" = "xyes"; then
370 UNLIMITED_CRYPTO=true
371 else
372 UNLIMITED_CRYPTO=false
373 fi
374 AC_SUBST(UNLIMITED_CRYPTO)
376 ###############################################################################
377 #
378 # Enable or disable the elliptic curve crypto implementation
379 #
380 AC_DEFUN_ONCE([JDKOPT_DETECT_INTREE_EC],
381 [
382 AC_MSG_CHECKING([if elliptic curve crypto implementation is present])
384 if test -d "${SRC_ROOT}/jdk/src/share/native/sun/security/ec/impl"; then
385 ENABLE_INTREE_EC=yes
386 AC_MSG_RESULT([yes])
387 else
388 ENABLE_INTREE_EC=no
389 AC_MSG_RESULT([no])
390 fi
392 AC_SUBST(ENABLE_INTREE_EC)
393 ])
395 ###############################################################################
396 #
397 # Compress jars
398 #
399 COMPRESS_JARS=false
401 AC_SUBST(COMPRESS_JARS)
402 ])
404 ###############################################################################
405 #
406 # Setup version numbers
407 #
408 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],
409 [
410 # Source the version numbers
411 . $AUTOCONF_DIR/version-numbers
413 # Get the settings from parameters
414 AC_ARG_WITH(milestone, [AS_HELP_STRING([--with-milestone],
415 [Set milestone value for build @<:@internal@:>@])])
416 if test "x$with_milestone" = xyes; then
417 AC_MSG_ERROR([Milestone must have a value])
418 elif test "x$with_milestone" != x; then
419 MILESTONE="$with_milestone"
420 fi
421 if test "x$MILESTONE" = x; then
422 MILESTONE=internal
423 fi
425 AC_ARG_WITH(update-version, [AS_HELP_STRING([--with-update-version],
426 [Set update version value for build @<:@b00@:>@])])
427 if test "x$with_update_version" = xyes; then
428 AC_MSG_ERROR([Update version must have a value])
429 elif test "x$with_update_version" != x; then
430 JDK_UPDATE_VERSION="$with_update_version"
431 fi
433 AC_ARG_WITH(build-number, [AS_HELP_STRING([--with-build-number],
434 [Set build number value for build @<:@b00@:>@])])
435 if test "x$with_build_number" = xyes; then
436 AC_MSG_ERROR([Build number must have a value])
437 elif test "x$with_build_number" != x; then
438 JDK_BUILD_NUMBER="$with_build_number"
439 fi
440 if test "x$JDK_BUILD_NUMBER" = x; then
441 JDK_BUILD_NUMBER=b00
442 fi
444 AC_ARG_WITH(user-release-suffix, [AS_HELP_STRING([--with-user-release-suffix],
445 [Add a custom string to the version string if build number isn't set.@<:@username_builddateb00@:>@])])
446 if test "x$with_user_release_suffix" = xyes; then
447 AC_MSG_ERROR([Release suffix must have a value])
448 elif test "x$with_user_release_suffix" != x; then
449 USER_RELEASE_SUFFIX="$with_user_release_suffix"
450 else
451 BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`
452 # Avoid [:alnum:] since it depends on the locale.
453 CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyz0123456789'`
454 USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`
455 fi
456 AC_SUBST(USER_RELEASE_SUFFIX)
458 # Now set the JDK version, milestone, build number etc.
459 AC_SUBST(JDK_MAJOR_VERSION)
460 AC_SUBST(JDK_MINOR_VERSION)
461 AC_SUBST(JDK_MICRO_VERSION)
462 AC_SUBST(JDK_UPDATE_VERSION)
463 AC_SUBST(JDK_BUILD_NUMBER)
464 AC_SUBST(MILESTONE)
465 AC_SUBST(LAUNCHER_NAME)
466 AC_SUBST(PRODUCT_NAME)
467 AC_SUBST(PRODUCT_SUFFIX)
468 AC_SUBST(JDK_RC_PLATFORM_NAME)
469 AC_SUBST(COMPANY_NAME)
470 AC_SUBST(MACOSX_BUNDLE_NAME_BASE)
471 AC_SUBST(MACOSX_BUNDLE_ID_BASE)
473 COPYRIGHT_YEAR=`date +'%Y'`
474 AC_SUBST(COPYRIGHT_YEAR)
476 if test "x$JDK_UPDATE_VERSION" != x; then
477 JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"
478 else
479 JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"
480 fi
481 AC_SUBST(JDK_VERSION)
483 COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`
484 AC_SUBST(COOKED_BUILD_NUMBER)
485 ])
487 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],
488 [
489 HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"
490 AC_SUBST(HOTSPOT_MAKE_ARGS)
492 # The name of the Service Agent jar.
493 SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"
494 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
495 SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"
496 fi
497 AC_SUBST(SALIB_NAME)
499 ])
501 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],
502 [
503 #
504 # ENABLE_DEBUG_SYMBOLS
505 # This must be done after the toolchain is setup, since we're looking at objcopy.
506 #
507 AC_ARG_ENABLE([debug-symbols],
508 [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])
510 AC_MSG_CHECKING([if we should generate debug symbols])
512 if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then
513 # explicit enabling of enable-debug-symbols and can't find objcopy
514 # this is an error
515 AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])
516 fi
518 if test "x$enable_debug_symbols" = "xyes"; then
519 ENABLE_DEBUG_SYMBOLS=true
520 elif test "x$enable_debug_symbols" = "xno"; then
521 ENABLE_DEBUG_SYMBOLS=false
522 else
523 # default on macosx is false
524 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
525 ENABLE_DEBUG_SYMBOLS=false
526 # Default is on if objcopy is found, otherwise off
527 elif test "x$OBJCOPY" != x || test "x$OPENJDK_TARGET_OS" = xwindows; then
528 ENABLE_DEBUG_SYMBOLS=true
529 else
530 ENABLE_DEBUG_SYMBOLS=false
531 fi
532 fi
534 AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])
536 #
537 # ZIP_DEBUGINFO_FILES
538 #
539 AC_MSG_CHECKING([if we should zip debug-info files])
540 AC_ARG_ENABLE([zip-debug-info],
541 [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])],
542 [enable_zip_debug_info="${enableval}"], [enable_zip_debug_info="yes"])
543 AC_MSG_RESULT([${enable_zip_debug_info}])
545 if test "x${enable_zip_debug_info}" = "xno"; then
546 ZIP_DEBUGINFO_FILES=false
547 else
548 ZIP_DEBUGINFO_FILES=true
549 fi
551 AC_SUBST(ENABLE_DEBUG_SYMBOLS)
552 AC_SUBST(ZIP_DEBUGINFO_FILES)
553 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)
554 AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)
555 ])
557 # Support for customization of the build process. Some build files
558 # will include counterparts from this location, if they exist. This allows
559 # for a degree of customization of the build targets and the rules/recipes
560 # to create them
561 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],
562 [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])
563 AC_SUBST(CUSTOM_MAKE_DIR)