jdk8-mips64-public: common/autoconf/platform.m4@3c48e11c3901

8016096: [macosx] jawt_md.h shipped with jdk is outdated
Summary: Revised build system and added platform specific headers for Mac OS X
Reviewed-by: ihse, erikj
Contributed-by: david.dehaven@oracle.com

1 #

     2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.

    27 # Converts autoconf style CPU name to OpenJDK style, into

    28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.

    29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],

    30 [

    31   # First argument is the cpu name from the trip/quad

    32   case "$1" in

    33     x86_64)

    34       VAR_CPU=x86_64

    35       VAR_CPU_ARCH=x86

    36       VAR_CPU_BITS=64

    37       VAR_CPU_ENDIAN=little

    38       ;;

    39     i?86)

    40       VAR_CPU=x86

    41       VAR_CPU_ARCH=x86

    42       VAR_CPU_BITS=32

    43       VAR_CPU_ENDIAN=little

    44       ;;

    45     arm*)

    46       VAR_CPU=arm

    47       VAR_CPU_ARCH=arm

    48       VAR_CPU_BITS=32

    49       VAR_CPU_ENDIAN=little

    50       ;;

    51     powerpc)

    52       VAR_CPU=ppc

    53       VAR_CPU_ARCH=ppc

    54       VAR_CPU_BITS=32

    55       VAR_CPU_ENDIAN=big

    56       ;;

    57     powerpc64)

    58       VAR_CPU=ppc64

    59       VAR_CPU_ARCH=ppc

    60       VAR_CPU_BITS=64

    61       VAR_CPU_ENDIAN=big

    62       ;;

    63     s390)

    64       VAR_CPU=s390

    65       VAR_CPU_ARCH=s390

    66       VAR_CPU_BITS=32

    67       VAR_CPU_ENDIAN=big

    68       ;;

    69     s390x)

    70       VAR_CPU=s390x

    71       VAR_CPU_ARCH=s390

    72       VAR_CPU_BITS=64

    73       VAR_CPU_ENDIAN=big

    74       ;;

    75     sparc)

    76       VAR_CPU=sparc

    77       VAR_CPU_ARCH=sparc

    78       VAR_CPU_BITS=32

    79       VAR_CPU_ENDIAN=big

    80       ;;

    81     sparcv9)

    82       VAR_CPU=sparcv9

    83       VAR_CPU_ARCH=sparc

    84       VAR_CPU_BITS=64

    85       VAR_CPU_ENDIAN=big

    86       ;;

    87     *)

    88       AC_MSG_ERROR([unsupported cpu $1])

    89       ;;

    90   esac

    91 ])

    93 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.

    94 # Converts autoconf style OS name to OpenJDK style, into

    95 # VAR_OS and VAR_OS_API.

    96 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],

    97 [

    98   case "$1" in

    99     *linux*)

   100       VAR_OS=linux

   101       VAR_OS_API=posix

   102       VAR_OS_ENV=linux

   103       ;;

   104     *solaris*)

   105       VAR_OS=solaris

   106       VAR_OS_API=posix

   107       VAR_OS_ENV=solaris

   108       ;;

   109     *darwin*)

   110       VAR_OS=macosx

   111       VAR_OS_API=posix

   112       VAR_OS_ENV=macosx

   113       ;;

   114     *bsd*)

   115       VAR_OS=bsd

   116       VAR_OS_API=posix

   117       VAR_OS_ENV=bsd

   118       ;;

   119     *cygwin*)

   120       VAR_OS=windows

   121       VAR_OS_API=winapi

   122       VAR_OS_ENV=windows.cygwin

   123       ;;

   124     *mingw*)

   125       VAR_OS=windows

   126       VAR_OS_API=winapi

   127       VAR_OS_ENV=windows.msys

   128       ;;

   129     *)

   130       AC_MSG_ERROR([unsupported operating system $1])

   131       ;;

   132   esac

   133 ])

   135 # Expects $host_os $host_cpu $build_os and $build_cpu

   136 # and $with_target_bits to have been setup!

   137 #

   138 # Translate the standard triplet(quadruplet) definition

   139 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,

   140 # OPENJDK_BUILD_OS, etc.

   141 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],

   142 [

   143   # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME

   144   # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME

   145   # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,

   146   # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.

   147   OPENJDK_TARGET_AUTOCONF_NAME="$host"

   148   OPENJDK_BUILD_AUTOCONF_NAME="$build"

   149   AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)

   150   AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)

   152   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.

   153   PLATFORM_EXTRACT_VARS_FROM_OS($build_os)

   154   PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)

   155   # ..and setup our own variables. (Do this explicitely to facilitate searching)

   156   OPENJDK_BUILD_OS="$VAR_OS"

   157   OPENJDK_BUILD_OS_API="$VAR_OS_API"

   158   OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"

   159   OPENJDK_BUILD_CPU="$VAR_CPU"

   160   OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"

   161   OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"

   162   OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"

   163   AC_SUBST(OPENJDK_BUILD_OS)

   164   AC_SUBST(OPENJDK_BUILD_OS_API)

   165   AC_SUBST(OPENJDK_BUILD_CPU)

   166   AC_SUBST(OPENJDK_BUILD_CPU_ARCH)

   167   AC_SUBST(OPENJDK_BUILD_CPU_BITS)

   168   AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)

   170   AC_MSG_CHECKING([openjdk-build os-cpu])

   171   AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])

   173   # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.

   174   PLATFORM_EXTRACT_VARS_FROM_OS($host_os)

   175   PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)

   176   # ... and setup our own variables. (Do this explicitely to facilitate searching)

   177   OPENJDK_TARGET_OS="$VAR_OS"

   178   OPENJDK_TARGET_OS_API="$VAR_OS_API"

   179   OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"

   180   OPENJDK_TARGET_CPU="$VAR_CPU"

   181   OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"

   182   OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"

   183   OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"

   184   AC_SUBST(OPENJDK_TARGET_OS)

   185   AC_SUBST(OPENJDK_TARGET_OS_API)

   186   AC_SUBST(OPENJDK_TARGET_CPU)

   187   AC_SUBST(OPENJDK_TARGET_CPU_ARCH)

   188   AC_SUBST(OPENJDK_TARGET_CPU_BITS)

   189   AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)

   191   AC_MSG_CHECKING([openjdk-target os-cpu])

   192   AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])

   193 ])

   195 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour

   196 # accordingly. Must be done after setting up build and target system, but before

   197 # doing anything else with these values.

   198 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],

   199 [

   200   AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],

   201        [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])

   203   # We have three types of compiles:

   204   # native  == normal compilation, target system == build system

   205   # cross   == traditional cross compilation, target system != build system; special toolchain needed

   206   # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines

   207   #

   208   if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then

   209     # We're doing a proper cross-compilation

   210     COMPILE_TYPE="cross"

   211   else

   212     COMPILE_TYPE="native"

   213   fi

   215   if test "x$with_target_bits" != x; then

   216     if test "x$COMPILE_TYPE" = "xcross"; then

   217       AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])

   218     fi

   220     if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   221       # A reduced build is requested

   222       COMPILE_TYPE="reduced"

   223       OPENJDK_TARGET_CPU_BITS=32

   224       if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then

   225         OPENJDK_TARGET_CPU=x86

   226       elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then

   227         OPENJDK_TARGET_CPU=sparc

   228       else

   229         AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])

   230       fi

   231     elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then

   232       AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])

   233     elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then

   234       AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])

   235     else

   236       AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])

   237     fi

   238   fi

   239   AC_SUBST(COMPILE_TYPE)

   241   AC_MSG_CHECKING([compilation type])

   242   AC_MSG_RESULT([$COMPILE_TYPE])

   243 ])

   245 # Setup the legacy variables, for controlling the old makefiles.

   246 #

   247 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],

   248 [

   249   # Also store the legacy naming of the cpu.

   250   # Ie i586 and amd64 instead of x86 and x86_64

   251   OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"

   252   if test "x$OPENJDK_TARGET_CPU" = xx86; then

   253     OPENJDK_TARGET_CPU_LEGACY="i586"

   254   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   255     # On all platforms except MacOSX replace x86_64 with amd64.

   256     OPENJDK_TARGET_CPU_LEGACY="amd64"

   257   fi

   258   AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)

   260   # And the second legacy naming of the cpu.

   261   # Ie i386 and amd64 instead of x86 and x86_64.

   262   OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"

   263   if test "x$OPENJDK_TARGET_CPU" = xx86; then

   264     OPENJDK_TARGET_CPU_LEGACY_LIB="i386"

   265   elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   266     OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"

   267   fi

   268   AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)

   270   # This is the name of the cpu (but using i386 and amd64 instead of

   271   # x86 and x86_64, respectively), preceeded by a /, to be used when

   272   # locating libraries. On macosx, it's empty, though.

   273   OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"

   274   if test "x$OPENJDK_TARGET_OS" = xmacosx; then

   275     OPENJDK_TARGET_CPU_LIBDIR=""

   276   fi

   277   AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)

   279   # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to

   280   # /amd64 or /sparcv9. This string is appended to some library paths, like this:

   281   # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so

   282   OPENJDK_TARGET_CPU_ISADIR=""

   283   if test "x$OPENJDK_TARGET_OS" = xsolaris; then

   284     if test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   285       OPENJDK_TARGET_CPU_ISADIR="/amd64"

   286     elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then

   287       OPENJDK_TARGET_CPU_ISADIR="/sparcv9"

   288     fi

   289   fi

   290   AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)

   292   # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property

   293   OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"

   294   if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then

   295     # On linux only, we replace x86 with i386.

   296     OPENJDK_TARGET_CPU_OSARCH="i386"

   297   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   298     # On all platforms except macosx, we replace x86_64 with amd64.

   299     OPENJDK_TARGET_CPU_OSARCH="amd64"

   300   fi

   301   AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)

   303   OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"

   304   if test "x$OPENJDK_TARGET_CPU" = xx86; then

   305     OPENJDK_TARGET_CPU_JLI="i386"

   306   elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then

   307     # On all platforms except macosx, we replace x86_64 with amd64.

   308     OPENJDK_TARGET_CPU_JLI="amd64"

   309   fi

   310   # Now setup the -D flags for building libjli.

   311   OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"

   312   if test "x$OPENJDK_TARGET_OS" = xsolaris; then

   313     if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then

   314       OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"

   315     elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then

   316       OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"

   317     fi

   318   fi

   319   AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)

   321   # Setup OPENJDK_TARGET_OS_API_DIR, used in source paths.

   322   if test "x$OPENJDK_TARGET_OS_API" = xposix; then

   323     OPENJDK_TARGET_OS_API_DIR="solaris"

   324   fi

   325   if test "x$OPENJDK_TARGET_OS_API" = xwinapi; then

   326     OPENJDK_TARGET_OS_API_DIR="windows"

   327   fi

   328   AC_SUBST(OPENJDK_TARGET_OS_API_DIR)

   330   if test "x$OPENJDK_TARGET_OS" = xmacosx; then

   331       OPENJDK_TARGET_OS_EXPORT_DIR=macosx

   332   else

   333       OPENJDK_TARGET_OS_EXPORT_DIR=${OPENJDK_TARGET_OS_API_DIR}

   334   fi

   335   AC_SUBST(OPENJDK_TARGET_OS_EXPORT_DIR)

   337   if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   338     A_LP64="LP64:="

   339     # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in

   340     # unpack200.exe

   341     if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then

   342       ADD_LP64="-D_LP64=1"

   343     fi

   344   fi

   345   AC_SUBST(LP64,$A_LP64)

   347   if test "x$COMPILE_TYPE" = "xcross"; then

   348     # FIXME: ... or should this include reduced builds..?

   349     DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"

   350   else

   351     DEFINE_CROSS_COMPILE_ARCH=""

   352   fi

   353   AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)

   355   # ZERO_ARCHDEF is used to enable architecture-specific code

   356   case "${OPENJDK_TARGET_CPU}" in

   357     ppc*)    ZERO_ARCHDEF=PPC   ;;

   358     s390*)   ZERO_ARCHDEF=S390  ;;

   359     sparc*)  ZERO_ARCHDEF=SPARC ;;

   360     x86_64*) ZERO_ARCHDEF=AMD64 ;;

   361     x86)     ZERO_ARCHDEF=IA32  ;;

   362     *)      ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)

   363   esac

   364   AC_SUBST(ZERO_ARCHDEF)

   365 ])

   367 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],

   368 [

   369   if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then

   370     REQUIRED_OS_NAME=SunOS

   371     REQUIRED_OS_VERSION=5.10

   372   fi

   373   if test "x$OPENJDK_TARGET_OS" = "xlinux"; then

   374     REQUIRED_OS_NAME=Linux

   375     REQUIRED_OS_VERSION=2.6

   376   fi

   377   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   378     REQUIRED_OS_NAME=Windows

   379     if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then

   380       REQUIRED_OS_VERSION=5.2

   381     else

   382       REQUIRED_OS_VERSION=5.1

   383     fi

   384   fi

   385   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   386     REQUIRED_OS_NAME=Darwin

   387     REQUIRED_OS_VERSION=11.2

   388   fi

   390   AC_SUBST(REQUIRED_OS_NAME)

   391   AC_SUBST(REQUIRED_OS_VERSION)

   392 ])

   394 #%%% Build and target systems %%%

   395 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],

   396 [

   397   # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"

   398   # is confusing; it assumes you are cross-compiling a cross-compiler (!)  and "target" is thus the target of the

   399   # product you're building. The target of this build is called "host". Since this is confusing to most people, we

   400   # have not adopted that system, but use "target" as the platform we are building for. In some places though we need

   401   # to use the configure naming style.

   402   AC_CANONICAL_BUILD

   403   AC_CANONICAL_HOST

   404   AC_CANONICAL_TARGET

   406   PLATFORM_EXTRACT_TARGET_AND_BUILD

   407   PLATFORM_SETUP_TARGET_CPU_BITS

   408   PLATFORM_SET_RELEASE_FILE_OS_VALUES

   409   PLATFORM_SETUP_LEGACY_VARS

   410 ])

   412 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],

   413 [

   414   ###############################################################################

   416   # Note that this is the build platform OS version!

   418   OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"

   419   OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"

   420   OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"

   421   OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"

   422   AC_SUBST(OS_VERSION_MAJOR)

   423   AC_SUBST(OS_VERSION_MINOR)

   424   AC_SUBST(OS_VERSION_MICRO)

   425 ])

   427 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.

   428 # Add -mX to various FLAGS variables.

   429 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],

   430 [

   431   # When we add flags to the "official" CFLAGS etc, we need to

   432   # keep track of these additions in ADDED_CFLAGS etc. These

   433   # will later be checked to make sure only controlled additions

   434   # have been made to CFLAGS etc.

   435   ADDED_CFLAGS=" -m${OPENJDK_TARGET_CPU_BITS}"

   436   ADDED_CXXFLAGS=" -m${OPENJDK_TARGET_CPU_BITS}"

   437   ADDED_LDFLAGS=" -m${OPENJDK_TARGET_CPU_BITS}"

   439   CFLAGS="${CFLAGS}${ADDED_CFLAGS}"

   440   CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"

   441   LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"

   443   CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"

   444   CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"

   445   LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"

   446 ])

   448 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],

   449 [

   450   ###############################################################################

   451   #

   452   # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.

   453   # (The JVM can use 32 or 64 bit Java pointers but that decision

   454   # is made at runtime.)

   455   #

   457   if test "x$OPENJDK_TARGET_OS" = xsolaris; then

   458     # Always specify -m flags on Solaris

   459     PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS

   460   elif test "x$COMPILE_TYPE" = xreduced; then

   461     if test "x$OPENJDK_TARGET_OS" != xwindows; then

   462       # Specify -m if running reduced on other Posix platforms

   463       PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS

   464     fi

   465   fi

   467   # Make compilation sanity check

   468   AC_CHECK_HEADERS([stdio.h], , [

   469     AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])

   470     if test "x$COMPILE_TYPE" = xreduced; then

   471       AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed.])

   472     elif test "x$COMPILE_TYPE" = xcross; then

   473       AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])

   474     fi

   475     AC_MSG_ERROR([Cannot continue.])

   476   ])

   478   AC_CHECK_SIZEOF([int *], [1111])

   480   if test "x$SIZEOF_INT_P" != "x$ac_cv_sizeof_int_p"; then

   481     # Workaround autoconf bug, see http://lists.gnu.org/archive/html/autoconf/2010-07/msg00004.html

   482     SIZEOF_INT_P="$ac_cv_sizeof_int_p"

   483   fi

   485   if test "x$SIZEOF_INT_P" = x; then

   486     # The test failed, lets stick to the assumed value.

   487     AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])

   488   else

   489     TESTED_TARGET_CPU_BITS=`expr 8 \* $SIZEOF_INT_P`

   491     if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then

   492       AC_MSG_ERROR([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])

   493     fi

   494   fi

   496   AC_MSG_CHECKING([for target address size])

   497   AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])

   498 ])

   500 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],

   501 [

   502   ###############################################################################

   503   #

   504   # Is the target little of big endian?

   505   #

   506   AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])

   508   if test "x$ENDIAN" = xuniversal_endianness; then

   509     AC_MSG_ERROR([Building with both big and little endianness is not supported])

   510   fi

   511   if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then

   512     AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])

   513   fi

   514 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/platform.m4@3c48e11c3901

common/autoconf/platform.m4