jdk8-mips64-public: common/autoconf/jdk-options.m4@2d9bb72b4e34

8004490: build-infra: mac: hotspot is always built in product, regardless of --with-debug-level setting
Reviewed-by: tbell

1 #

     2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VARIANT],

    27 [

    28 ###############################################################################

    29 #

    30 # Check which variant of the JDK that we want to build.

    31 # Currently we have:

    32 #    normal:   standard edition

    33 # but the custom make system may add other variants

    34 #

    35 # Effectively the JDK variant gives a name to a specific set of

    36 # modules to compile into the JDK. In the future, these modules

    37 # might even be Jigsaw modules.

    38 #

    39 AC_MSG_CHECKING([which variant of the JDK to build])

    40 AC_ARG_WITH([jdk-variant], [AS_HELP_STRING([--with-jdk-variant],

    41 	[JDK variant to build (normal) @<:@normal@:>@])])

    43 if test "x$with_jdk_variant" = xnormal || test "x$with_jdk_variant" = x; then

    44     JDK_VARIANT="normal"

    45 else

    46     AC_MSG_ERROR([The available JDK variants are: normal])

    47 fi

    49 AC_SUBST(JDK_VARIANT)

    51 AC_MSG_RESULT([$JDK_VARIANT])

    52 ])

    54 AC_DEFUN_ONCE([JDKOPT_SETUP_JVM_VARIANTS],

    55 [

    57 ###############################################################################

    58 #

    59 # Check which variants of the JVM that we want to build.

    60 # Currently we have:

    61 #    server: normal interpreter and a tiered C1/C2 compiler

    62 #    client: normal interpreter and C1 (no C2 compiler) (only 32-bit platforms)

    63 #    minimal1: reduced form of client with optional VM services and features stripped out

    64 #    kernel: kernel footprint JVM that passes the TCK without major performance problems,

    65 #             ie normal interpreter and C1, only the serial GC, kernel jvmti etc

    66 #    zero: no machine code interpreter, no compiler

    67 #    zeroshark: zero interpreter and shark/llvm compiler backend

    68 AC_MSG_CHECKING([which variants of the JVM to build])

    69 AC_ARG_WITH([jvm-variants], [AS_HELP_STRING([--with-jvm-variants],

    70 	[JVM variants (separated by commas) to build (server, client, minimal1, kernel, zero, zeroshark) @<:@server@:>@])])

    72 if test "x$with_jvm_variants" = x; then

    73      with_jvm_variants="server"

    74 fi

    76 JVM_VARIANTS=",$with_jvm_variants,"

    77 TEST_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,//' -e 's/client,//'  -e 's/minimal1,//' -e 's/kernel,//' -e 's/zero,//' -e 's/zeroshark,//'`

    79 if test "x$TEST_VARIANTS" != "x,"; then

    80    AC_MSG_ERROR([The available JVM variants are: server, client, minimal1, kernel, zero, zeroshark])

    81 fi

    82 AC_MSG_RESULT([$with_jvm_variants])

    84 JVM_VARIANT_SERVER=`$ECHO "$JVM_VARIANTS" | $SED -e '/,server,/!s/.*/false/g' -e '/,server,/s/.*/true/g'`

    85 JVM_VARIANT_CLIENT=`$ECHO "$JVM_VARIANTS" | $SED -e '/,client,/!s/.*/false/g' -e '/,client,/s/.*/true/g'`

    86 JVM_VARIANT_MINIMAL1=`$ECHO "$JVM_VARIANTS" | $SED -e '/,minimal1,/!s/.*/false/g' -e '/,minimal1,/s/.*/true/g'`

    87 JVM_VARIANT_KERNEL=`$ECHO "$JVM_VARIANTS" | $SED -e '/,kernel,/!s/.*/false/g' -e '/,kernel,/s/.*/true/g'`

    88 JVM_VARIANT_ZERO=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zero,/!s/.*/false/g' -e '/,zero,/s/.*/true/g'`

    89 JVM_VARIANT_ZEROSHARK=`$ECHO "$JVM_VARIANTS" | $SED -e '/,zeroshark,/!s/.*/false/g' -e '/,zeroshark,/s/.*/true/g'`

    91 if test "x$JVM_VARIANT_CLIENT" = xtrue; then

    92     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

    93         AC_MSG_ERROR([You cannot build a client JVM for a 64-bit machine.])

    94     fi

    95 fi

    96 if test "x$JVM_VARIANT_KERNEL" = xtrue; then

    97     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

    98         AC_MSG_ERROR([You cannot build a kernel JVM for a 64-bit machine.])

    99     fi

   100 fi

   101 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then

   102     if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then

   103         AC_MSG_ERROR([You cannot build a minimal JVM for a 64-bit machine.])

   104     fi

   105 fi

   107 # Replace the commas with AND for use in the build directory name.

   108 ANDED_JVM_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/^,//' -e 's/,$//' -e 's/,/AND/'`

   109 COUNT_VARIANTS=`$ECHO "$JVM_VARIANTS" | $SED -e 's/server,/1/' -e 's/client,/1/' -e 's/minimal1,/1/' -e 's/kernel,/1/' -e 's/zero,/1/' -e 's/zeroshark,/1/'`

   110 if test "x$COUNT_VARIANTS" != "x,1"; then

   111     BUILDING_MULTIPLE_JVM_VARIANTS=yes

   112 else

   113     BUILDING_MULTIPLE_JVM_VARIANTS=no

   114 fi

   116 AC_SUBST(JVM_VARIANTS)

   117 AC_SUBST(JVM_VARIANT_SERVER)

   118 AC_SUBST(JVM_VARIANT_CLIENT)

   119 AC_SUBST(JVM_VARIANT_MINIMAL1)

   120 AC_SUBST(JVM_VARIANT_KERNEL)

   121 AC_SUBST(JVM_VARIANT_ZERO)

   122 AC_SUBST(JVM_VARIANT_ZEROSHARK)

   124 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   125    MACOSX_UNIVERSAL="true"

   126 fi

   128 AC_SUBST(MACOSX_UNIVERSAL)

   130 ])

   132 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_LEVEL],

   133 [

   134 ###############################################################################

   135 #

   136 # Set the debug level

   137 #    release: no debug information, all optimizations, no asserts.

   138 #    fastdebug: debug information (-g), all optimizations, all asserts

   139 #    slowdebug: debug information (-g), no optimizations, all asserts

   140 #

   141 DEBUG_LEVEL="release"

   142 AC_MSG_CHECKING([which debug level to use])

   143 AC_ARG_ENABLE([debug], [AS_HELP_STRING([--enable-debug],

   144 	[set the debug level to fastdebug (shorthand for --with-debug-level=fastdebug) @<:@disabled@:>@])],

   145 	[

   146         ENABLE_DEBUG="${enableval}"

   147         DEBUG_LEVEL="fastdebug"

   148     ], [ENABLE_DEBUG="no"])

   150 AC_ARG_WITH([debug-level], [AS_HELP_STRING([--with-debug-level],

   151 	[set the debug level (release, fastdebug, slowdebug) @<:@release@:>@])],

   152 	[

   153         DEBUG_LEVEL="${withval}"

   154         if test "x$ENABLE_DEBUG" = xyes; then

   155 			AC_MSG_ERROR([You cannot use both --enable-debug and --with-debug-level at the same time.])

   156         fi

   157     ])

   158 AC_MSG_RESULT([$DEBUG_LEVEL])

   160 if test "x$DEBUG_LEVEL" != xrelease && \

   161    test "x$DEBUG_LEVEL" != xfastdebug && \

   162    test "x$DEBUG_LEVEL" != xslowdebug; then

   163    AC_MSG_ERROR([Allowed debug levels are: release, fastdebug and slowdebug])

   164 fi

   167 ###############################################################################

   168 #

   169 # Setup legacy vars/targets and new vars to deal with different debug levels.

   170 #

   172 case $DEBUG_LEVEL in

   173       release )

   174           VARIANT="OPT"

   175           FASTDEBUG="false"

   176           DEBUG_CLASSFILES="false"

   177           BUILD_VARIANT_RELEASE=""

   178           HOTSPOT_DEBUG_LEVEL="product"

   179           HOTSPOT_EXPORT="product"

   180            ;;

   181       fastdebug )

   182           VARIANT="DBG"

   183           FASTDEBUG="true"

   184           DEBUG_CLASSFILES="true"

   185           BUILD_VARIANT_RELEASE="-fastdebug"

   186           HOTSPOT_DEBUG_LEVEL="fastdebug"

   187           HOTSPOT_EXPORT="fastdebug"

   188            ;;

   189       slowdebug )

   190           VARIANT="DBG"

   191           FASTDEBUG="false"

   192           DEBUG_CLASSFILES="true"

   193           BUILD_VARIANT_RELEASE="-debug"

   194           HOTSPOT_DEBUG_LEVEL="jvmg"

   195           HOTSPOT_EXPORT="debug"

   196            ;;

   197 esac

   199 #####

   200 # Generate the legacy makefile targets for hotspot.

   201 # The hotspot api for selecting the build artifacts, really, needs to be improved.

   202 # JDK-7195896 will fix this on the hotspot side by using the JVM_VARIANT_* variables to

   203 # determine what needs to be built. All we will need to set here is all_product, all_fastdebug etc

   204 # But until then ...

   205 HOTSPOT_TARGET=""

   207 if test "x$JVM_VARIANT_SERVER" = xtrue; then

   208     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL} "

   209 fi

   211 if test "x$JVM_VARIANT_CLIENT" = xtrue; then

   212     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}1 "

   213 fi

   215 if test "x$JVM_VARIANT_MINIMAL1" = xtrue; then

   216     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}minimal1 "

   217 fi

   219 if test "x$JVM_VARIANT_KERNEL" = xtrue; then

   220     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}kernel "

   221 fi

   223 if test "x$JVM_VARIANT_ZERO" = xtrue; then

   224     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}zero "

   225 fi

   227 if test "x$JVM_VARIANT_ZEROSHARK" = xtrue; then

   228     HOTSPOT_TARGET="$HOTSPOT_TARGET${HOTSPOT_DEBUG_LEVEL}shark "

   229 fi

   231 HOTSPOT_TARGET="$HOTSPOT_TARGET docs export_$HOTSPOT_EXPORT"

   233 # On Macosx universal binaries are produced, but they only contain

   234 # 64 bit intel. This invalidates control of which jvms are built

   235 # from configure, but only server is valid anyway. Fix this

   236 # when hotspot makefiles are rewritten.

   237 if test "x$MACOSX_UNIVERSAL" = xtrue; then

   238     HOTSPOT_TARGET=universal_${HOTSPOT_EXPORT}

   239 fi

   241 #####

   243 AC_SUBST(DEBUG_LEVEL)

   244 AC_SUBST(VARIANT)

   245 AC_SUBST(FASTDEBUG)

   246 AC_SUBST(DEBUG_CLASSFILES)

   247 AC_SUBST(BUILD_VARIANT_RELEASE)

   248 ])

   250 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_OPTIONS],

   251 [

   253 ###############################################################################

   254 #

   255 # Should we build only OpenJDK even if closed sources are present?

   256 #

   257 AC_ARG_ENABLE([openjdk-only], [AS_HELP_STRING([--enable-openjdk-only],

   258     [supress building closed source even if present @<:@disabled@:>@])],,[enable_openjdk_only="no"])

   260 AC_MSG_CHECKING([for presence of closed sources])

   261 if test -d "$SRC_ROOT/jdk/src/closed"; then

   262     CLOSED_SOURCE_PRESENT=yes

   263 else

   264     CLOSED_SOURCE_PRESENT=no

   265 fi

   266 AC_MSG_RESULT([$CLOSED_SOURCE_PRESENT])

   268 AC_MSG_CHECKING([if closed source is supressed (openjdk-only)])

   269 SUPRESS_CLOSED_SOURCE="$enable_openjdk_only"

   270 AC_MSG_RESULT([$SUPRESS_CLOSED_SOURCE])

   272 if test "x$CLOSED_SOURCE_PRESENT" = xno; then

   273   OPENJDK=true

   274   if test "x$SUPRESS_CLOSED_SOURCE" = "xyes"; then

   275     AC_MSG_WARN([No closed source present, --enable-openjdk-only makes no sense])

   276   fi

   277 else

   278   if test "x$SUPRESS_CLOSED_SOURCE" = "xyes"; then

   279     OPENJDK=true

   280   else

   281     OPENJDK=false

   282   fi

   283 fi

   285 if test "x$OPENJDK" = "xtrue"; then

   286     SET_OPENJDK="OPENJDK=true"

   287 fi

   289 AC_SUBST(SET_OPENJDK)

   291 ###############################################################################

   292 #

   293 # Should we build a JDK/JVM with headful support (ie a graphical ui)?

   294 # We always build headless support.

   295 #

   296 AC_MSG_CHECKING([headful support])

   297 AC_ARG_ENABLE([headful], [AS_HELP_STRING([--disable-headful],

   298 	[disable building headful support (graphical UI support) @<:@enabled@:>@])],

   299     [SUPPORT_HEADFUL=${enable_headful}], [SUPPORT_HEADFUL=yes])

   301 SUPPORT_HEADLESS=yes

   302 BUILD_HEADLESS="BUILD_HEADLESS:=true"

   304 if test "x$SUPPORT_HEADFUL" = xyes; then

   305     # We are building both headful and headless.

   306     headful_msg="inlude support for both headful and headless"

   307 fi

   309 if test "x$SUPPORT_HEADFUL" = xno; then

   310     # Thus we are building headless only.

   311     BUILD_HEADLESS="BUILD_HEADLESS:=true"

   312     headful_msg="headless only"

   313 fi

   315 AC_MSG_RESULT([$headful_msg])

   317 AC_SUBST(SUPPORT_HEADLESS)

   318 AC_SUBST(SUPPORT_HEADFUL)

   319 AC_SUBST(BUILD_HEADLESS)

   321 # Control wether Hotspot runs Queens test after build.

   322 AC_ARG_ENABLE([hotspot-test-in-build], [AS_HELP_STRING([--enable-hotspot-test-in-build],

   323 	[run the Queens test after Hotspot build @<:@disabled@:>@])],,

   324     [enable_hotspot_test_in_build=no])

   325 if test "x$enable_hotspot_test_in_build" = "xyes"; then

   326     TEST_IN_BUILD=true

   327 else

   328     TEST_IN_BUILD=false

   329 fi

   330 AC_SUBST(TEST_IN_BUILD)

   332 ###############################################################################

   333 #

   334 # Choose cacerts source file

   335 #

   336 AC_ARG_WITH(cacerts-file, [AS_HELP_STRING([--with-cacerts-file],

   337     [specify alternative cacerts file])])

   338 if test "x$with_cacerts_file" != x; then

   339     CACERTS_FILE=$with_cacerts_file

   340 else

   341     if test "x$OPENJDK" = "xtrue"; then

   342         CACERTS_FILE=${SRC_ROOT}/jdk/src/share/lib/security/cacerts

   343     else

   344         CACERTS_FILE=${SRC_ROOT}/jdk/src/closed/share/lib/security/cacerts.internal

   345     fi

   346 fi

   347 AC_SUBST(CACERTS_FILE)

   349 ###############################################################################

   350 #

   351 # Enable or disable unlimited crypto

   352 #

   353 AC_ARG_ENABLE(unlimited-crypto, [AS_HELP_STRING([--enable-unlimited-crypto],

   354         [Enable unlimited crypto policy @<:@disabled@:>@])],,

   355     [enable_unlimited_crypto=no])

   356 if test "x$enable_unlimited_crypto" = "xyes"; then

   357     UNLIMITED_CRYPTO=true

   358 else

   359     UNLIMITED_CRYPTO=false

   360 fi

   361 AC_SUBST(UNLIMITED_CRYPTO)

   363 ###############################################################################

   364 #

   365 # Compress jars

   366 #

   367 COMPRESS_JARS=false

   369 AC_SUBST(COMPRESS_JARS)

   370 ])

   372 AC_DEFUN_ONCE([JDKOPT_SETUP_JDK_VERSION_NUMBERS],

   373 [

   374 # Source the version numbers

   375 . $AUTOCONF_DIR/version.numbers

   376 if test "x$OPENJDK" = "xfalse"; then

   377     . $AUTOCONF_DIR/closed.version.numbers

   378 fi

   379 # Now set the JDK version, milestone, build number etc.

   380 AC_SUBST(JDK_MAJOR_VERSION)

   381 AC_SUBST(JDK_MINOR_VERSION)

   382 AC_SUBST(JDK_MICRO_VERSION)

   383 AC_SUBST(JDK_UPDATE_VERSION)

   384 AC_SUBST(JDK_BUILD_NUMBER)

   385 AC_SUBST(MILESTONE)

   386 AC_SUBST(LAUNCHER_NAME)

   387 AC_SUBST(PRODUCT_NAME)

   388 AC_SUBST(PRODUCT_SUFFIX)

   389 AC_SUBST(JDK_RC_PLATFORM_NAME)

   390 AC_SUBST(COMPANY_NAME)

   391 AC_SUBST(MACOSX_BUNDLE_NAME_BASE)

   392 AC_SUBST(MACOSX_BUNDLE_ID_BASE)

   394 COPYRIGHT_YEAR=`date +'%Y'`

   395 AC_SUBST(COPYRIGHT_YEAR)

   397 RUNTIME_NAME="$PRODUCT_NAME $PRODUCT_SUFFIX"

   398 AC_SUBST(RUNTIME_NAME)

   400 if test "x$JDK_UPDATE_VERSION" != x; then

   401     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}_${JDK_UPDATE_VERSION}"

   402 else

   403     JDK_VERSION="${JDK_MAJOR_VERSION}.${JDK_MINOR_VERSION}.${JDK_MICRO_VERSION}"

   404 fi

   405 AC_SUBST(JDK_VERSION)

   407 if test "x$MILESTONE" != x; then

   408     RELEASE="${JDK_VERSION}-${MILESTONE}${BUILD_VARIANT_RELEASE}"

   409 else

   410     RELEASE="${JDK_VERSION}${BUILD_VARIANT_RELEASE}"

   411 fi

   412 AC_SUBST(RELEASE)

   414 if test "x$JDK_BUILD_NUMBER" != x; then

   415     FULL_VERSION="${RELEASE}-${JDK_BUILD_NUMBER}"

   416 else

   417     JDK_BUILD_NUMBER=b00

   418     BUILD_DATE=`date '+%Y_%m_%d_%H_%M'`

   419     # Avoid [:alnum:] since it depends on the locale.

   420     CLEAN_USERNAME=`echo "$USER" | $TR -d -c 'abcdefghijklmnopqrstuvqxyz0123456789'`

   421     USER_RELEASE_SUFFIX=`echo "${CLEAN_USERNAME}_${BUILD_DATE}" | $TR 'ABCDEFGHIJKLMNOPQRSTUVWXYZ' 'abcdefghijklmnopqrstuvwxyz'`

   422     FULL_VERSION="${RELEASE}-${USER_RELEASE_SUFFIX}-${JDK_BUILD_NUMBER}"

   423 fi

   424 AC_SUBST(FULL_VERSION)

   425 COOKED_BUILD_NUMBER=`$ECHO $JDK_BUILD_NUMBER | $SED -e 's/^b//' -e 's/^0//'`

   426 AC_SUBST(COOKED_BUILD_NUMBER)

   427 ])

   429 AC_DEFUN_ONCE([JDKOPT_SETUP_BUILD_TWEAKS],

   430 [

   431 HOTSPOT_MAKE_ARGS="$HOTSPOT_TARGET"

   432 AC_SUBST(HOTSPOT_MAKE_ARGS)

   434 # The name of the Service Agent jar.

   435 SALIB_NAME="${LIBRARY_PREFIX}saproc${SHARED_LIBRARY_SUFFIX}"

   436 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   437     SALIB_NAME="${LIBRARY_PREFIX}sawindbg${SHARED_LIBRARY_SUFFIX}"

   438 fi

   439 AC_SUBST(SALIB_NAME)

   441 ])

   443 AC_DEFUN_ONCE([JDKOPT_SETUP_DEBUG_SYMBOLS],

   444 [

   445 #

   446 # ENABLE_DEBUG_SYMBOLS

   447 # This must be done after the toolchain is setup, since we're looking at objcopy.

   448 #

   449 AC_ARG_ENABLE([debug-symbols],

   450               [AS_HELP_STRING([--disable-debug-symbols],[disable generation of debug symbols @<:@enabled@:>@])])

   452 AC_MSG_CHECKING([if we should generate debug symbols])

   454 if test "x$enable_debug_symbols" = "xyes" && test "x$OBJCOPY" = x; then

   455    # explicit enabling of enable-debug-symbols and can't find objcopy

   456    #   this is an error

   457    AC_MSG_ERROR([Unable to find objcopy, cannot enable debug-symbols])

   458 fi

   460 if test "x$enable_debug_symbols" = "xyes"; then

   461   ENABLE_DEBUG_SYMBOLS=true

   462 elif test "x$enable_debug_symbols" = "xno"; then

   463   ENABLE_DEBUG_SYMBOLS=false

   464 else

   465   # default on macosx is false

   466   if test "x$OPENJDK_TARGET_OS" = xmacosx; then

   467     ENABLE_DEBUG_SYMBOLS=false

   468   # Default is on if objcopy is found, otherwise off

   469   elif test "x$OBJCOPY" != x || test "x$OPENJDK_TARGET_OS" = xwindows; then

   470     ENABLE_DEBUG_SYMBOLS=true

   471   else

   472     ENABLE_DEBUG_SYMBOLS=false

   473   fi

   474 fi

   476 AC_MSG_RESULT([$ENABLE_DEBUG_SYMBOLS])

   478 #

   479 # ZIP_DEBUGINFO_FILES

   480 #

   481 AC_ARG_ENABLE([zip-debug-info],

   482               [AS_HELP_STRING([--disable-zip-debug-info],[disable zipping of debug-info files @<:@enabled@:>@])])

   484 AC_MSG_CHECKING([if we should zip debug-info files])

   485 AC_MSG_RESULT([${enable_zip_debug_info}])

   487 if test "x${enable_zip_debug_info}" = "xno"; then

   488    ZIP_DEBUGINFO_FILES=false

   489 else

   490    ZIP_DEBUGINFO_FILES=true

   491 fi

   493 AC_SUBST(ENABLE_DEBUG_SYMBOLS)

   494 AC_SUBST(ZIP_DEBUGINFO_FILES)

   495 AC_SUBST(CFLAGS_DEBUG_SYMBOLS)

   496 AC_SUBST(CXXFLAGS_DEBUG_SYMBOLS)

   497 ])

   499 # Support for customization of the build process. Some build files

   500 # will include counterparts from this location, if they exist. This allows

   501 # for a degree of customization of the build targets and the rules/recipes

   502 # to create them

   503 AC_ARG_WITH([custom-make-dir], [AS_HELP_STRING([--with-custom-make-dir],

   504     [use this directory for custom build/make files])], [CUSTOM_MAKE_DIR=$with_custom_make_dir])

   505 AC_SUBST(CUSTOM_MAKE_DIR)

Mercurial > jdk8-mips64-public / file revision

common/autoconf/jdk-options.m4@2d9bb72b4e34

common/autoconf/jdk-options.m4