Tue, 18 Sep 2012 11:29:16 -0700
7197849: Update new build-infra makefiles
Reviewed-by: ihse, erikj, ohrstrom, tbell
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # Execute the check given as argument, and verify the result
27 # If the Boot JDK was previously found, do nothing
28 # $1 A command line (typically autoconf macro) to execute
29 AC_DEFUN([BOOTJDK_DO_CHECK],
30 [
31 if test "x$BOOT_JDK_FOUND" = xno; then
32 # Now execute the test
33 $1
35 # If previous step claimed to have found a JDK, check it to see if it seems to be valid.
36 if test "x$BOOT_JDK_FOUND" = xmaybe; then
37 # Do we have a bin/java?
38 if test ! -x "$BOOT_JDK/bin/java"; then
39 AC_MSG_NOTICE([Potential Boot JDK found at $BOOT_JDK did not contain bin/java; ignoring])
40 BOOT_JDK_FOUND=no
41 else
42 # Do we have a bin/javac?
43 if test ! -x "$BOOT_JDK/bin/javac"; then
44 AC_MSG_NOTICE([Potential Boot JDK found at $BOOT_JDK did not contain bin/javac; ignoring])
45 AC_MSG_NOTICE([(This might be an JRE instead of an JDK)])
46 BOOT_JDK_FOUND=no
47 else
48 # Do we have an rt.jar? (On MacOSX it is called classes.jar)
49 if test ! -f "$BOOT_JDK/jre/lib/rt.jar" && test ! -f "$BOOT_JDK/../Classes/classes.jar"; then
50 AC_MSG_NOTICE([Potential Boot JDK found at $BOOT_JDK did not contain an rt.jar; ignoring])
51 BOOT_JDK_FOUND=no
52 else
53 # Oh, this is looking good! We probably have found a proper JDK. Is it the correct version?
54 BOOT_JDK_VERSION=`"$BOOT_JDK/bin/java" -version 2>&1 | head -n 1`
56 # Extra M4 quote needed to protect [] in grep expression.
57 [FOUND_VERSION_78=`echo $BOOT_JDK_VERSION | grep '\"1\.[78]\.'`]
58 if test "x$FOUND_VERSION_78" = x; then
59 AC_MSG_NOTICE([Potential Boot JDK found at $BOOT_JDK is incorrect JDK version ($BOOT_JDK_VERSION); ignoring])
60 AC_MSG_NOTICE([(Your Boot JDK must be version 7 or 8)])
61 BOOT_JDK_FOUND=no
62 else
63 # We're done! :-)
64 BOOT_JDK_FOUND=yes
65 SPACESAFE(BOOT_JDK,[the path to the Boot JDK])
66 AC_MSG_CHECKING([for Boot JDK])
67 AC_MSG_RESULT([$BOOT_JDK ($BOOT_JDK_VERSION)])
68 fi # end check jdk version
69 fi # end check rt.jar
70 fi # end check javac
71 fi # end check java
72 fi # end check boot jdk found
73 fi
74 ])
76 # Test: Is bootjdk explicitely set by command line arguments?
77 AC_DEFUN([BOOTJDK_CHECK_ARGUMENTS],
78 [
79 if test "x$with_boot_jdk" != x; then
80 BOOT_JDK=$with_boot_jdk
81 BOOT_JDK_FOUND=maybe
82 AC_MSG_NOTICE([Found potential Boot JDK using configure arguments])
83 fi
84 ])
86 # Test: Is bootjdk available from builddeps?
87 AC_DEFUN([BOOTJDK_CHECK_BUILDDEPS],
88 [
89 BDEPS_CHECK_MODULE(BOOT_JDK, bootjdk, xxx, [BOOT_JDK_FOUND=maybe], [BOOT_JDK_FOUND=no])
90 ])
92 # Test: Is $JAVA_HOME set?
93 AC_DEFUN([BOOTJDK_CHECK_JAVA_HOME],
94 [
95 if test "x$JAVA_HOME" != x; then
96 if test "x$OPENJDK_TARGET_OS" = xwindows; then
97 # On Windows, JAVA_HOME is likely in DOS-style
98 JAVA_HOME_PROCESSED="`$CYGPATH -u "$JAVA_HOME"`"
99 else
100 JAVA_HOME_PROCESSED="$JAVA_HOME"
101 fi
102 if test ! -d "$JAVA_HOME_PROCESSED"; then
103 AC_MSG_NOTICE([Your JAVA_HOME points to a non-existing directory!])
104 else
105 # Aha, the user has set a JAVA_HOME
106 # let us use that as the Boot JDK.
107 BOOT_JDK="$JAVA_HOME_PROCESSED"
108 BOOT_JDK_FOUND=maybe
109 AC_MSG_NOTICE([Found potential Boot JDK using JAVA_HOME])
110 fi
111 fi
112 ])
114 # Test: Is there a java or javac in the PATH, which is a symlink to the JDK?
115 AC_DEFUN([BOOTJDK_CHECK_JAVA_IN_PATH_IS_SYMLINK],
116 [
117 AC_PATH_PROG(JAVAC_CHECK, javac)
118 AC_PATH_PROG(JAVA_CHECK, java)
119 BINARY="$JAVAC_CHECK"
120 if test "x$JAVAC_CHECK" = x; then
121 BINARY="$JAVA_CHECK"
122 fi
123 if test "x$BINARY" != x; then
124 # So there is a java(c) binary, it might be part of a JDK.
125 # Lets find the JDK/JRE directory by following symbolic links.
126 # Linux/GNU systems often have links from /usr/bin/java to
127 # /etc/alternatives/java to the real JDK binary.
128 SET_FULL_PATH_SPACESAFE(BINARY)
129 REMOVE_SYMBOLIC_LINKS(BINARY)
130 BOOT_JDK=`dirname "$BINARY"`
131 BOOT_JDK=`cd "$BOOT_JDK/.."; pwd`
132 if test -x "$BOOT_JDK/bin/javac" && test -x "$BOOT_JDK/bin/java"; then
133 # Looks like we found ourselves an JDK
134 BOOT_JDK_FOUND=maybe
135 AC_MSG_NOTICE([Found potential Boot JDK using java(c) in PATH])
136 fi
137 fi
138 ])
140 # Test: Is there a /usr/libexec/java_home? (Typically on MacOSX)
141 AC_DEFUN([BOOTJDK_CHECK_LIBEXEC_JAVA_HOME],
142 [
143 if test -x /usr/libexec/java_home; then
144 BOOT_JDK=`/usr/libexec/java_home`
145 BOOT_JDK_FOUND=maybe
146 AC_MSG_NOTICE([Found potential Boot JDK using /usr/libexec/java_home])
147 fi
148 ])
150 # Look for a jdk in the given path. If there are multiple, try to select the newest.
151 # If found, set BOOT_JDK and BOOT_JDK_FOUND.
152 # $1 = Path to directory containing jdk installations.
153 # $2 = String to append to the found JDK directory to get the proper JDK home
154 AC_DEFUN([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY],
155 [
156 BOOT_JDK_PREFIX="$1"
157 BOOT_JDK_SUFFIX="$2"
158 BEST_JDK_FOUND=`$LS "$BOOT_JDK_PREFIX" 2> /dev/null | $GREP jdk | $SORT -r | $HEAD -n 1 `
159 if test "x$BEST_JDK_FOUND" != x; then
160 BOOT_JDK="${BOOT_JDK_PREFIX}/${BEST_JDK_FOUND}${BOOT_JDK_SUFFIX}"
161 if test -d "$BOOT_JDK"; then
162 BOOT_JDK_FOUND=maybe
163 AC_MSG_NOTICE([Found potential Boot JDK using well-known locations (in $BOOT_JDK_PREFIX)])
164 fi
165 fi
166 ])
168 # Call BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY, but use the given
169 # environmental variable as base for where to look.
170 # $1 Name of an environmal variable, assumed to point to the Program Files directory.
171 AC_DEFUN([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY],
172 [
173 if test "x[$]$1" != x; then
174 BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY([`$CYGPATH -u "[$]$1"`/Java])
175 fi
176 ])
178 # Test: Is there a JDK installed in default, well-known locations?
179 AC_DEFUN([BOOTJDK_CHECK_WELL_KNOWN_LOCATIONS],
180 [
181 if test "x$OPENJDK_TARGET_OS" = xwindows; then
182 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY([ProgramW6432])])
183 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY([PROGRAMW6432])])
184 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY([PROGRAMFILES])])
185 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_WINDOWS_VIRTUAL_DIRECTORY([ProgramFiles])])
186 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY([/cygdrive/c/Program Files/Java])])
187 elif test "x$OPENJDK_TARGET_OS" = xmacosx; then
188 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY([/Library/Java/JavaVirtualMachines],[/Contents/Home])])
189 BOOTJDK_DO_CHECK([BOOTJDK_FIND_BEST_JDK_IN_DIRECTORY([/System/Library/Java/JavaVirtualMachines],[/Contents/Home])])
190 fi
191 ])
193 # Check that a command-line tool in the Boot JDK is correct
194 # $1 = name of variable to assign
195 # $2 = name of binary
196 AC_DEFUN([BOOTJDK_CHECK_TOOL_IN_BOOTJDK],
197 [
198 AC_MSG_CHECKING([for $2 in Boot JDK])
199 $1=$BOOT_JDK/bin/$2
200 if test ! -x [$]$1; then
201 AC_MSG_RESULT(not found)
202 AC_MSG_NOTICE([Your Boot JDK seems broken. This might be fixed by explicitely setting --with-boot-jdk])
203 AC_MSG_ERROR([Could not find $2 in the Boot JDK])
204 fi
205 AC_MSG_RESULT(ok)
206 ])
208 ###############################################################################
209 #
210 # We need a Boot JDK to bootstrap the build.
211 #
213 AC_DEFUN_ONCE([BOOTJDK_SETUP_BOOT_JDK],
214 [
215 BOOT_JDK_FOUND=no
216 AC_ARG_WITH(boot-jdk, [AS_HELP_STRING([--with-boot-jdk],
217 [path to Boot JDK (used to bootstrap build) @<:@probed@:>@])])
219 # We look for the Boot JDK through various means, going from more certain to
220 # more of a guess-work. After each test, BOOT_JDK_FOUND is set to "yes" if
221 # we detected something (if so, the path to the jdk is in BOOT_JDK). But we
222 # must check if this is indeed valid; otherwise we'll continue looking.
224 # Test: Is bootjdk explicitely set by command line arguments?
225 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_ARGUMENTS])
226 if test "x$with_boot_jdk" != x && test "x$BOOT_JDK_FOUND" = xno; then
227 # Having specified an argument which is incorrect will produce an instant failure;
228 # we should not go on looking
229 AC_MSG_ERROR([The path given by --with-boot-jdk does not contain a valid Boot JDK])
230 fi
232 # Test: Is bootjdk available from builddeps?
233 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_BUILDDEPS])
235 # Test: Is $JAVA_HOME set?
236 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_JAVA_HOME])
238 # Test: Is there a /usr/libexec/java_home? (Typically on MacOSX)
239 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_LIBEXEC_JAVA_HOME])
241 # Test: Is there a java or javac in the PATH, which is a symlink to the JDK?
242 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_JAVA_IN_PATH_IS_SYMLINK])
244 # Test: Is there a JDK installed in default, well-known locations?
245 BOOTJDK_DO_CHECK([BOOTJDK_CHECK_WELL_KNOWN_LOCATIONS])
247 # If we haven't found anything yet, we've truly lost. Give up.
248 if test "x$BOOT_JDK_FOUND" = xno; then
249 HELP_MSG_MISSING_DEPENDENCY([openjdk])
250 AC_MSG_NOTICE([Could not find a valid Boot JDK. $HELP_MSG])
251 AC_MSG_NOTICE([This might be fixed by explicitely setting --with-boot-jdk])
252 AC_MSG_ERROR([Cannot continue])
253 fi
255 # Setup proper paths for what we found
256 BOOT_RTJAR="$BOOT_JDK/jre/lib/rt.jar"
257 if test ! -f "$BOOT_RTJAR"; then
258 # On MacOSX it is called classes.jar
259 BOOT_RTJAR="$BOOT_JDK/../Classes/classes.jar"
260 if test -f "$BOOT_RTJAR"; then
261 # Remove the ..
262 BOOT_RTJAR="`cd ${BOOT_RTJAR%/*} && pwd`/${BOOT_RTJAR##*/}"
263 fi
264 fi
265 BOOT_TOOLSJAR="$BOOT_JDK/lib/tools.jar"
266 BOOT_JDK="$BOOT_JDK"
267 AC_SUBST(BOOT_RTJAR)
268 AC_SUBST(BOOT_TOOLSJAR)
269 AC_SUBST(BOOT_JDK)
271 # Setup tools from the Boot JDK.
272 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAVA,java)
273 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAVAC,javac)
274 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAVAH,javah)
275 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAVAP,javap)
276 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(JAR,jar)
277 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(RMIC,rmic)
278 BOOTJDK_CHECK_TOOL_IN_BOOTJDK(NATIVE2ASCII,native2ascii)
280 # Finally, set some other options...
282 # When compiling code to be executed by the Boot JDK, force jdk7 compatibility.
283 BOOT_JDK_SOURCETARGET="-source 7 -target 7"
284 AC_SUBST(BOOT_JDK_SOURCETARGET)
285 AC_SUBST(JAVAC_FLAGS)
286 ])
288 AC_DEFUN_ONCE([BOOTJDK_SETUP_BOOT_JDK_ARGUMENTS],
289 [
290 ##############################################################################
291 #
292 # Specify options for anything that is run with the Boot JDK.
293 #
294 AC_ARG_WITH(boot-jdk-jvmargs, [AS_HELP_STRING([--with-boot-jdk-jvmargs],
295 [specify JVM arguments to be passed to all invocations of the Boot JDK, overriding the default values,
296 e.g --with-boot-jdk-jvmargs="-Xmx8G -enableassertions"])])
298 if test "x$with_boot_jdk_jvmargs" = x; then
299 # Not all JVM:s accept the same arguments on the command line.
300 # OpenJDK specific increase in thread stack for JDK build,
301 # well more specifically, when running javac.
302 if test "x$BUILD_NUM_BITS" = x32; then
303 STACK_SIZE=768
304 else
305 # Running Javac on a JVM on a 64-bit machine, the stack takes more space
306 # since 64-bit pointers are pushed on the stach. Apparently, we need
307 # to increase the stack space when javacing the JDK....
308 STACK_SIZE=1536
309 fi
311 # Minimum amount of heap memory.
312 ADD_JVM_ARG_IF_OK([-Xms64M],boot_jdk_jvmargs,[$JAVA])
313 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
314 # Why does macosx need more heap? Its the huge JDK batch.
315 ADD_JVM_ARG_IF_OK([-Xmx1600M],boot_jdk_jvmargs,[$JAVA])
316 else
317 ADD_JVM_ARG_IF_OK([-Xmx1100M],boot_jdk_jvmargs,[$JAVA])
318 fi
319 # When is adding -client something that speeds up the JVM?
320 # ADD_JVM_ARG_IF_OK([-client],boot_jdk_jvmargs,[$JAVA])
321 ADD_JVM_ARG_IF_OK([-XX:PermSize=32m],boot_jdk_jvmargs,[$JAVA])
322 ADD_JVM_ARG_IF_OK([-XX:MaxPermSize=160m],boot_jdk_jvmargs,[$JAVA])
323 ADD_JVM_ARG_IF_OK([-XX:ThreadStackSize=$STACK_SIZE],boot_jdk_jvmargs,[$JAVA])
324 # Disable special log output when a debug build is used as Boot JDK...
325 ADD_JVM_ARG_IF_OK([-XX:-PrintVMOptions -XX:-UnlockDiagnosticVMOptions -XX:-LogVMOutput],boot_jdk_jvmargs,[$JAVA])
326 fi
328 AC_SUBST(BOOT_JDK_JVMARGS, $boot_jdk_jvmargs)
329 ])