Mercurial > jdk8-mips64-public / file revision
common/autoconf/toolchain.m4@22b9a31a92eb
common/autoconf/toolchain.m4
Wed, 13 Mar 2013 23:21:35 -0700
- author
- lana
- date
- Wed, 13 Mar 2013 23:21:35 -0700
- changeset 654
- 22b9a31a92eb
- parent 637
- 52741ab7c601
- parent 650
- c4901c0e0579
- child 672
- 2f43964043c2
- permissions
- -rw-r--r--
Merge
1 #
2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # $1 = compiler to test (CC or CXX)
27 # $2 = human readable name of compiler (C or C++)
28 AC_DEFUN([TOOLCHAIN_CHECK_COMPILER_VERSION],
29 [
30 COMPILER=[$]$1
31 COMPILER_NAME=$2
33 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
34 # Make sure we use the Sun Studio compiler and not gcc on Solaris, which won't work
35 COMPILER_VERSION_TEST=`$COMPILER -V 2>&1 | $HEAD -n 1`
36 $ECHO $COMPILER_VERSION_TEST | $GREP "^.*: Sun $COMPILER_NAME" > /dev/null
37 if test $? -ne 0; then
38 GCC_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
40 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required Sun Studio compiler.])
41 AC_MSG_NOTICE([The result from running with -V was: "$COMPILER_VERSION_TEST" and with --version: "$GCC_VERSION_TEST"])
42 AC_MSG_ERROR([Sun Studio compiler is required. Try setting --with-tools-dir.])
43 else
44 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*@<:@ ,\t@:>@$COMPILER_NAME@<:@ ,\t@:>@\(@<:@1-9@:>@\.@<:@0-9@:>@@<:@0-9@:>@*\).*/\1/p"`
45 COMPILER_VENDOR="Sun Studio"
46 fi
47 elif test "x$OPENJDK_TARGET_OS" = xwindows; then
48 # First line typically looks something like:
49 # Microsoft (R) 32-bit C/C++ Optimizing Compiler Version 16.00.30319.01 for 80x86
50 COMPILER_VERSION_TEST=`$COMPILER 2>&1 | $HEAD -n 1`
51 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.*Version \(@<:@1-9@:>@@<:@0-9.@:>@*\) .*/\1/p"`
52 COMPILER_VENDOR="Microsoft CL.EXE"
53 COMPILER_CPU_TEST=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* for \(.*\)$/\1/p"`
54 if test "x$OPENJDK_TARGET_CPU" = "xx86"; then
55 if test "x$COMPILER_CPU_TEST" != "x80x86"; then
56 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "80x86".])
57 fi
58 elif test "x$OPENJDK_TARGET_CPU" = "xx86_64"; then
59 if test "x$COMPILER_CPU_TEST" != "xx64"; then
60 AC_MSG_ERROR([Target CPU mismatch. We are building for $OPENJDK_TARGET_CPU but CL is for "$COMPILER_CPU_TEST"; expected "x64".])
61 fi
62 fi
63 else
64 COMPILER_VERSION_TEST=`$COMPILER --version 2>&1 | $HEAD -n 1`
65 # Check that this is likely to be GCC.
66 $COMPILER --version 2>&1 | $GREP "Free Software Foundation" > /dev/null
67 if test $? -ne 0; then
68 AC_MSG_NOTICE([The $COMPILER_NAME compiler (located as $COMPILER) does not seem to be the required GCC compiler.])
69 AC_MSG_NOTICE([The result from running with --version was: "$COMPILER_VERSION_TEST"])
70 AC_MSG_ERROR([GCC compiler is required. Try setting --with-tools-dir.])
71 fi
73 # First line typically looks something like:
74 # gcc (Ubuntu/Linaro 4.5.2-8ubuntu4) 4.5.2
75 COMPILER_VERSION=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^.* \(@<:@1-9@:>@@<:@0-9.@:>@*\)/\1/p"`
76 COMPILER_VENDOR=`$ECHO $COMPILER_VERSION_TEST | $SED -n "s/^\(.*\) @<:@1-9@:>@@<:@0-9.@:>@*/\1/p"`
77 fi
78 # This sets CC_VERSION or CXX_VERSION. (This comment is a grep marker)
79 $1_VERSION="$COMPILER_VERSION"
80 # This sets CC_VENDOR or CXX_VENDOR. (This comment is a grep marker)
81 $1_VENDOR="$COMPILER_VENDOR"
83 AC_MSG_NOTICE([Using $COMPILER_VENDOR $COMPILER_NAME compiler version $COMPILER_VERSION (located at $COMPILER)])
84 ])
87 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_SYSROOT_AND_OUT_OPTIONS],
88 [
89 ###############################################################################
90 #
91 # Configure the development tool paths and potential sysroot.
92 #
93 AC_LANG(C++)
95 # The option used to specify the target .o,.a or .so file.
96 # When compiling, how to specify the to be created object file.
97 CC_OUT_OPTION='-o$(SPACE)'
98 # When linking, how to specify the to be created executable.
99 EXE_OUT_OPTION='-o$(SPACE)'
100 # When linking, how to specify the to be created dynamically linkable library.
101 LD_OUT_OPTION='-o$(SPACE)'
102 # When archiving, how to specify the to be create static archive for object files.
103 AR_OUT_OPTION='rcs$(SPACE)'
104 AC_SUBST(CC_OUT_OPTION)
105 AC_SUBST(EXE_OUT_OPTION)
106 AC_SUBST(LD_OUT_OPTION)
107 AC_SUBST(AR_OUT_OPTION)
108 ])
110 # $1 = compiler to test (CC or CXX)
111 # $2 = human readable name of compiler (C or C++)
112 # $3 = list of compiler names to search for
113 AC_DEFUN([TOOLCHAIN_FIND_COMPILER],
114 [
115 COMPILER_NAME=$2
117 $1=
118 # If TOOLS_DIR is set, check for all compiler names in there first
119 # before checking the rest of the PATH.
120 if test -n "$TOOLS_DIR"; then
121 PATH_save="$PATH"
122 PATH="$TOOLS_DIR"
123 AC_PATH_PROGS(TOOLS_DIR_$1, $3)
124 $1=$TOOLS_DIR_$1
125 PATH="$PATH_save"
126 fi
128 # AC_PATH_PROGS can't be run multiple times with the same variable,
129 # so create a new name for this run.
130 if test "x[$]$1" = x; then
131 AC_PATH_PROGS(POTENTIAL_$1, $3)
132 $1=$POTENTIAL_$1
133 fi
135 if test "x[$]$1" = x; then
136 HELP_MSG_MISSING_DEPENDENCY([devkit])
137 AC_MSG_ERROR([Could not find a $COMPILER_NAME compiler. $HELP_MSG])
138 fi
139 BASIC_FIXUP_EXECUTABLE($1)
140 AC_MSG_CHECKING([resolved symbolic links for $1])
141 TEST_COMPILER="[$]$1"
142 BASIC_REMOVE_SYMBOLIC_LINKS(TEST_COMPILER)
143 AC_MSG_RESULT([$TEST_COMPILER])
144 AC_MSG_CHECKING([if $1 is disguised ccache])
146 COMPILER_BASENAME=`$BASENAME "$TEST_COMPILER"`
147 if test "x$COMPILER_BASENAME" = "xccache"; then
148 AC_MSG_RESULT([yes, trying to find proper $COMPILER_NAME compiler])
149 # We /usr/lib/ccache in the path, so cc is a symlink to /usr/bin/ccache.
150 # We want to control ccache invocation ourselves, so ignore this cc and try
151 # searching again.
153 # Remove the path to the fake ccache cc from the PATH
154 RETRY_COMPILER_SAVED_PATH="$PATH"
155 COMPILER_DIRNAME=`$DIRNAME [$]$1`
156 PATH="`$ECHO $PATH | $SED -e "s,$COMPILER_DIRNAME,,g" -e "s,::,:,g" -e "s,^:,,g"`"
158 # Try again looking for our compiler
159 AC_CHECK_TOOLS(PROPER_COMPILER_$1, $3)
160 BASIC_FIXUP_EXECUTABLE(PROPER_COMPILER_$1)
161 PATH="$RETRY_COMPILER_SAVED_PATH"
163 AC_MSG_CHECKING([for resolved symbolic links for $1])
164 BASIC_REMOVE_SYMBOLIC_LINKS(PROPER_COMPILER_$1)
165 AC_MSG_RESULT([$PROPER_COMPILER_$1])
166 $1="$PROPER_COMPILER_$1"
167 else
168 AC_MSG_RESULT([no, keeping $1])
169 $1="$TEST_COMPILER"
170 fi
171 TOOLCHAIN_CHECK_COMPILER_VERSION([$1], [$COMPILER_NAME])
172 ])
175 AC_DEFUN([TOOLCHAIN_SETUP_PATHS],
176 [
177 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
178 TOOLCHAIN_SETUP_VISUAL_STUDIO_ENV
179 TOOLCHAIN_SETUP_DXSDK
180 fi
182 AC_SUBST(MSVCR_DLL)
184 # If --build AND --host is set, then the configure script will find any
185 # cross compilation tools in the PATH. Cross compilation tools
186 # follows the cross compilation standard where they are prefixed with ${host}.
187 # For example the binary i686-sun-solaris2.10-gcc
188 # will cross compile for i686-sun-solaris2.10
189 # If neither of build and host is not set, then build=host and the
190 # default compiler found in the path will be used.
191 # Setting only --host, does not seem to be really supported.
192 # Please set both --build and --host if you want to cross compile.
194 if test "x$COMPILE_TYPE" = "xcross"; then
195 # Now we to find a C/C++ compiler that can build executables for the build
196 # platform. We can't use the AC_PROG_CC macro, since it can only be used
197 # once. Also, we need to do this before adding a tools dir to the path,
198 # otherwise we might pick up cross-compilers which don't use standard naming.
199 # Otherwise, we'll set the BUILD_tools to the native tools, but that'll have
200 # to wait until they are properly discovered.
201 AC_PATH_PROGS(BUILD_CC, [cl cc gcc])
202 BASIC_FIXUP_EXECUTABLE(BUILD_CC)
203 AC_PATH_PROGS(BUILD_CXX, [cl CC g++])
204 BASIC_FIXUP_EXECUTABLE(BUILD_CXX)
205 AC_PATH_PROG(BUILD_LD, ld)
206 BASIC_FIXUP_EXECUTABLE(BUILD_LD)
207 fi
208 AC_SUBST(BUILD_CC)
209 AC_SUBST(BUILD_CXX)
210 AC_SUBST(BUILD_LD)
212 # If a devkit is found on the builddeps server, then prepend its path to the
213 # PATH variable. If there are cross compilers available in the devkit, these
214 # will be found by AC_PROG_CC et al.
215 DEVKIT=
216 BDEPS_CHECK_MODULE(DEVKIT, devkit, xxx,
217 [# Found devkit
218 PATH="$DEVKIT/bin:$PATH"
219 SYS_ROOT="$DEVKIT/${rewritten_target}/sys-root"
220 if test "x$x_includes" = "xNONE"; then
221 x_includes="$SYS_ROOT/usr/include/X11"
222 fi
223 if test "x$x_libraries" = "xNONE"; then
224 x_libraries="$SYS_ROOT/usr/lib"
225 fi
226 ],
227 [])
229 if test "x$SYS_ROOT" != "x/" ; then
230 CFLAGS="--sysroot=$SYS_ROOT $CFLAGS"
231 CXXFLAGS="--sysroot=$SYS_ROOT $CXXFLAGS"
232 OBJCFLAGS="--sysroot=$SYS_ROOT $OBJCFLAGS"
233 OBJCXXFLAGS="--sysroot=$SYS_ROOT $OBJCFLAGS"
234 CPPFLAGS="--sysroot=$SYS_ROOT $CPPFLAGS"
235 LDFLAGS="--sysroot=$SYS_ROOT $LDFLAGS"
236 fi
238 # Store the CFLAGS etal passed to the configure script.
239 ORG_CFLAGS="$CFLAGS"
240 ORG_CXXFLAGS="$CXXFLAGS"
241 ORG_OBJCFLAGS="$OBJCFLAGS"
243 # autoconf magic only relies on PATH, so update it if tools dir is specified
244 OLD_PATH="$PATH"
245 if test "x$TOOLS_DIR" != x; then
246 PATH=$TOOLS_DIR:$PATH
247 fi
250 ### Locate C compiler (CC)
252 # On windows, only cl.exe is supported.
253 # On Solaris, cc is preferred to gcc.
254 # Elsewhere, gcc is preferred to cc.
256 if test "x$CC" != x; then
257 COMPILER_CHECK_LIST="$CC"
258 elif test "x$OPENJDK_TARGET_OS" = "xwindows"; then
259 COMPILER_CHECK_LIST="cl"
260 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
261 COMPILER_CHECK_LIST="cc gcc"
262 else
263 COMPILER_CHECK_LIST="gcc cc"
264 fi
266 TOOLCHAIN_FIND_COMPILER([CC],[C],[$COMPILER_CHECK_LIST])
267 # Now that we have resolved CC ourself, let autoconf have its go at it
268 AC_PROG_CC([$CC])
270 ### Locate C++ compiler (CXX)
272 if test "x$CXX" != x; then
273 COMPILER_CHECK_LIST="$CXX"
274 elif test "x$OPENJDK_TARGET_OS" = "xwindows"; then
275 COMPILER_CHECK_LIST="cl"
276 elif test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
277 COMPILER_CHECK_LIST="CC g++"
278 else
279 COMPILER_CHECK_LIST="g++ CC"
280 fi
282 TOOLCHAIN_FIND_COMPILER([CXX],[C++],[$COMPILER_CHECK_LIST])
283 # Now that we have resolved CXX ourself, let autoconf have its go at it
284 AC_PROG_CXX([$CXX])
286 ### Locate other tools
288 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
289 AC_PROG_OBJC
290 BASIC_FIXUP_EXECUTABLE(OBJC)
291 else
292 OBJC=
293 fi
295 # Restore the flags to the user specified values.
296 # This is necessary since AC_PROG_CC defaults CFLAGS to "-g -O2"
297 CFLAGS="$ORG_CFLAGS"
298 CXXFLAGS="$ORG_CXXFLAGS"
299 OBJCFLAGS="$ORG_OBJCFLAGS"
301 LD="$CC"
302 LDEXE="$CC"
303 LDCXX="$CXX"
304 LDEXECXX="$CXX"
305 AC_SUBST(LD)
306 # LDEXE is the linker to use, when creating executables.
307 AC_SUBST(LDEXE)
308 # Linking C++ libraries.
309 AC_SUBST(LDCXX)
310 # Linking C++ executables.
311 AC_SUBST(LDEXECXX)
313 if test "x$OPENJDK_TARGET_OS" != xwindows; then
314 AC_CHECK_TOOL(AR, ar)
315 BASIC_FIXUP_EXECUTABLE(AR)
316 fi
317 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
318 ARFLAGS="-r"
319 else
320 ARFLAGS=""
321 fi
322 AC_SUBST(ARFLAGS)
324 # For hotspot, we need these in Windows mixed path; other platforms keep them the same
325 HOTSPOT_CXX="$CXX"
326 HOTSPOT_LD="$LD"
327 AC_SUBST(HOTSPOT_CXX)
328 AC_SUBST(HOTSPOT_LD)
330 COMPILER_NAME=gcc
331 COMPILER_TYPE=CC
332 AS_IF([test "x$OPENJDK_TARGET_OS" = xwindows], [
333 # For now, assume that we are always compiling using cl.exe.
334 CC_OUT_OPTION=-Fo
335 EXE_OUT_OPTION=-out:
336 LD_OUT_OPTION=-out:
337 AR_OUT_OPTION=-out:
338 # On Windows, reject /usr/bin/link (as determined in CYGWIN_LINK), which is a cygwin
339 # program for something completely different.
340 AC_CHECK_PROG([WINLD], [link],[link],,, [$CYGWIN_LINK])
341 # Since we must ignore the first found link, WINLD will contain
342 # the full path to the link.exe program.
343 BASIC_FIXUP_EXECUTABLE(WINLD)
344 printf "Windows linker was found at $WINLD\n"
345 AC_MSG_CHECKING([if the found link.exe is actually the Visual Studio linker])
346 "$WINLD" --version > /dev/null
347 if test $? -eq 0 ; then
348 AC_MSG_RESULT([no])
349 AC_MSG_ERROR([This is the Cygwin link tool. Please check your PATH and rerun configure.])
350 else
351 AC_MSG_RESULT([yes])
352 fi
353 LD="$WINLD"
354 LDEXE="$WINLD"
355 LDCXX="$WINLD"
356 LDEXECXX="$WINLD"
358 AC_CHECK_PROG([MT], [mt], [mt],,, [/usr/bin/mt])
359 BASIC_FIXUP_EXECUTABLE(MT)
360 # The resource compiler
361 AC_CHECK_PROG([RC], [rc], [rc],,, [/usr/bin/rc])
362 BASIC_FIXUP_EXECUTABLE(RC)
364 # For hotspot, we need these in Windows mixed path,
365 # so rewrite them all. Need added .exe suffix.
366 HOTSPOT_CXX="$CXX.exe"
367 HOTSPOT_LD="$LD.exe"
368 HOTSPOT_MT="$MT.exe"
369 HOTSPOT_RC="$RC.exe"
370 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_CXX)
371 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_LD)
372 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_MT)
373 BASIC_WINDOWS_REWRITE_AS_WINDOWS_MIXED_PATH(HOTSPOT_RC)
374 AC_SUBST(HOTSPOT_MT)
375 AC_SUBST(HOTSPOT_RC)
377 RC_FLAGS="-nologo -l 0x409 -r"
378 AS_IF([test "x$VARIANT" = xOPT], [
379 RC_FLAGS="$RC_FLAGS -d NDEBUG"
380 ])
381 JDK_UPDATE_VERSION_NOTNULL=$JDK_UPDATE_VERSION
382 AS_IF([test "x$JDK_UPDATE_VERSION" = x], [
383 JDK_UPDATE_VERSION_NOTNULL=0
384 ])
385 RC_FLAGS="$RC_FLAGS -d \"JDK_BUILD_ID=$FULL_VERSION\""
386 RC_FLAGS="$RC_FLAGS -d \"JDK_COMPANY=$COMPANY_NAME\""
387 RC_FLAGS="$RC_FLAGS -d \"JDK_COMPONENT=$PRODUCT_NAME $JDK_RC_PLATFORM_NAME binary\""
388 RC_FLAGS="$RC_FLAGS -d \"JDK_VER=$JDK_MINOR_VERSION.$JDK_MICRO_VERSION.$JDK_UPDATE_VERSION_NOTNULL.$COOKED_BUILD_NUMBER\""
389 RC_FLAGS="$RC_FLAGS -d \"JDK_COPYRIGHT=Copyright \xA9 $COPYRIGHT_YEAR\""
390 RC_FLAGS="$RC_FLAGS -d \"JDK_NAME=$PRODUCT_NAME $JDK_RC_PLATFORM_NAME $JDK_MINOR_VERSION $JDK_UPDATE_META_TAG\""
391 RC_FLAGS="$RC_FLAGS -d \"JDK_FVER=$JDK_MINOR_VERSION,$JDK_MICRO_VERSION,$JDK_UPDATE_VERSION_NOTNULL,$COOKED_BUILD_NUMBER\""
393 # lib.exe is used to create static libraries.
394 AC_CHECK_PROG([WINAR], [lib],[lib],,,)
395 BASIC_FIXUP_EXECUTABLE(WINAR)
396 AR="$WINAR"
397 ARFLAGS="-nologo -NODEFAULTLIB:MSVCRT"
399 AC_CHECK_PROG([DUMPBIN], [dumpbin], [dumpbin],,,)
400 BASIC_FIXUP_EXECUTABLE(DUMPBIN)
402 COMPILER_TYPE=CL
403 CCXXFLAGS="$CCXXFLAGS -nologo"
404 ])
405 AC_SUBST(RC_FLAGS)
406 AC_SUBST(COMPILER_TYPE)
408 AC_PROG_CPP
409 BASIC_FIXUP_EXECUTABLE(CPP)
411 AC_PROG_CXXCPP
412 BASIC_FIXUP_EXECUTABLE(CXXCPP)
414 if test "x$COMPILE_TYPE" != "xcross"; then
415 # If we are not cross compiling, use the same compilers for
416 # building the build platform executables. The cross-compilation
417 # case needed to be done earlier, but this can only be done after
418 # the native tools have been localized.
419 BUILD_CC="$CC"
420 BUILD_CXX="$CXX"
421 BUILD_LD="$LD"
422 fi
424 # for solaris we really need solaris tools, and not gnu equivalent
425 # these seems to normally reside in /usr/ccs/bin so add that to path before
426 # starting to probe
427 #
428 # NOTE: I add this /usr/ccs/bin after TOOLS but before OLD_PATH
429 # so that it can be overriden --with-tools-dir
430 if test "x$OPENJDK_BUILD_OS" = xsolaris; then
431 PATH="${TOOLS_DIR}:/usr/ccs/bin:${OLD_PATH}"
432 fi
434 # Find the right assembler.
435 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
436 AC_PATH_PROG(AS, as)
437 BASIC_FIXUP_EXECUTABLE(AS)
438 else
439 AS="$CC -c"
440 fi
441 AC_SUBST(AS)
443 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
444 AC_PATH_PROGS(NM, [gnm nm])
445 BASIC_FIXUP_EXECUTABLE(NM)
446 AC_PATH_PROG(STRIP, strip)
447 BASIC_FIXUP_EXECUTABLE(STRIP)
448 AC_PATH_PROG(MCS, mcs)
449 BASIC_FIXUP_EXECUTABLE(MCS)
450 elif test "x$OPENJDK_TARGET_OS" != xwindows; then
451 AC_CHECK_TOOL(NM, nm)
452 BASIC_FIXUP_EXECUTABLE(NM)
453 AC_CHECK_TOOL(STRIP, strip)
454 BASIC_FIXUP_EXECUTABLE(STRIP)
455 fi
457 # objcopy is used for moving debug symbols to separate files when
458 # full debug symbols are enabled.
459 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xlinux; then
460 AC_CHECK_TOOLS(OBJCOPY, [gobjcopy objcopy])
461 # Only call fixup if objcopy was found.
462 if test -n "$OBJCOPY"; then
463 BASIC_FIXUP_EXECUTABLE(OBJCOPY)
464 fi
465 fi
467 AC_CHECK_TOOLS(OBJDUMP, [gobjdump objdump])
468 if test "x$OBJDUMP" != x; then
469 # Only used for compare.sh; we can live without it. BASIC_FIXUP_EXECUTABLE bails if argument is missing.
470 BASIC_FIXUP_EXECUTABLE(OBJDUMP)
471 fi
473 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
474 AC_PATH_PROG(LIPO, lipo)
475 BASIC_FIXUP_EXECUTABLE(LIPO)
476 fi
478 # Restore old path without tools dir
479 PATH="$OLD_PATH"
480 ])
483 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_LIBS],
484 [
486 ###############################################################################
487 #
488 # How to compile shared libraries.
489 #
491 if test "x$GCC" = xyes; then
492 COMPILER_NAME=gcc
493 PICFLAG="-fPIC"
494 LIBRARY_PREFIX=lib
495 SHARED_LIBRARY='lib[$]1.so'
496 STATIC_LIBRARY='lib[$]1.a'
497 SHARED_LIBRARY_FLAGS="-shared"
498 SHARED_LIBRARY_SUFFIX='.so'
499 STATIC_LIBRARY_SUFFIX='.a'
500 OBJ_SUFFIX='.o'
501 EXE_SUFFIX=''
502 SET_SHARED_LIBRARY_NAME='-Xlinker -soname=[$]1'
503 SET_SHARED_LIBRARY_MAPFILE='-Xlinker -version-script=[$]1'
504 C_FLAG_REORDER=''
505 CXX_FLAG_REORDER=''
506 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -z -Xlinker origin -Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
507 SET_EXECUTABLE_ORIGIN='-Xlinker -rpath -Xlinker \$$$$ORIGIN[$]1'
508 LD="$CC"
509 LDEXE="$CC"
510 LDCXX="$CXX"
511 LDEXECXX="$CXX"
512 POST_STRIP_CMD="$STRIP -g"
514 # Linking is different on MacOSX
515 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
516 # Might change in the future to clang.
517 COMPILER_NAME=gcc
518 SHARED_LIBRARY='lib[$]1.dylib'
519 SHARED_LIBRARY_FLAGS="-dynamiclib -compatibility_version 1.0.0 -current_version 1.0.0 $PICFLAG"
520 SHARED_LIBRARY_SUFFIX='.dylib'
521 EXE_SUFFIX=''
522 SET_SHARED_LIBRARY_NAME='-Xlinker -install_name -Xlinker @rpath/[$]1'
523 SET_SHARED_LIBRARY_MAPFILE=''
524 SET_SHARED_LIBRARY_ORIGIN='-Xlinker -rpath -Xlinker @loader_path/.'
525 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
526 POST_STRIP_CMD="$STRIP -S"
527 fi
528 else
529 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
530 # If it is not gcc, then assume it is the Oracle Solaris Studio Compiler
531 COMPILER_NAME=ossc
532 PICFLAG="-KPIC"
533 LIBRARY_PREFIX=lib
534 SHARED_LIBRARY='lib[$]1.so'
535 STATIC_LIBRARY='lib[$]1.a'
536 SHARED_LIBRARY_FLAGS="-G"
537 SHARED_LIBRARY_SUFFIX='.so'
538 STATIC_LIBRARY_SUFFIX='.a'
539 OBJ_SUFFIX='.o'
540 EXE_SUFFIX=''
541 SET_SHARED_LIBRARY_NAME=''
542 SET_SHARED_LIBRARY_MAPFILE='-M[$]1'
543 C_FLAG_REORDER='-xF'
544 CXX_FLAG_REORDER='-xF'
545 SET_SHARED_LIBRARY_ORIGIN='-R\$$$$ORIGIN[$]1'
546 SET_EXECUTABLE_ORIGIN="$SET_SHARED_LIBRARY_ORIGIN"
547 CFLAGS_JDK="${CFLAGS_JDK} -D__solaris__"
548 CXXFLAGS_JDK="${CXXFLAGS_JDK} -D__solaris__"
549 CFLAGS_JDKLIB_EXTRA='-xstrconst'
550 POST_STRIP_CMD="$STRIP -x"
551 POST_MCS_CMD="$MCS -d -a \"JDK $FULL_VERSION\""
552 fi
553 if test "x$OPENJDK_TARGET_OS" = xwindows; then
554 # If it is not gcc, then assume it is the MS Visual Studio compiler
555 COMPILER_NAME=cl
556 PICFLAG=""
557 LIBRARY_PREFIX=
558 SHARED_LIBRARY='[$]1.dll'
559 STATIC_LIBRARY='[$]1.lib'
560 SHARED_LIBRARY_FLAGS="-LD"
561 SHARED_LIBRARY_SUFFIX='.dll'
562 STATIC_LIBRARY_SUFFIX='.lib'
563 OBJ_SUFFIX='.obj'
564 EXE_SUFFIX='.exe'
565 SET_SHARED_LIBRARY_NAME=''
566 SET_SHARED_LIBRARY_MAPFILE=''
567 SET_SHARED_LIBRARY_ORIGIN=''
568 SET_EXECUTABLE_ORIGIN=''
569 fi
570 fi
572 AC_SUBST(OBJ_SUFFIX)
573 AC_SUBST(SHARED_LIBRARY)
574 AC_SUBST(STATIC_LIBRARY)
575 AC_SUBST(LIBRARY_PREFIX)
576 AC_SUBST(SHARED_LIBRARY_SUFFIX)
577 AC_SUBST(STATIC_LIBRARY_SUFFIX)
578 AC_SUBST(EXE_SUFFIX)
579 AC_SUBST(SHARED_LIBRARY_FLAGS)
580 AC_SUBST(SET_SHARED_LIBRARY_NAME)
581 AC_SUBST(SET_SHARED_LIBRARY_MAPFILE)
582 AC_SUBST(C_FLAG_REORDER)
583 AC_SUBST(CXX_FLAG_REORDER)
584 AC_SUBST(SET_SHARED_LIBRARY_ORIGIN)
585 AC_SUBST(SET_EXECUTABLE_ORIGIN)
586 AC_SUBST(POST_STRIP_CMD)
587 AC_SUBST(POST_MCS_CMD)
589 # The (cross) compiler is now configured, we can now test capabilities
590 # of the target platform.
591 ])
593 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_OPTIMIZATION],
594 [
596 ###############################################################################
597 #
598 # Setup the opt flags for different compilers
599 # and different operating systems.
600 #
602 #
603 # NOTE: check for -mstackrealign needs to be below potential addition of -m32
604 #
605 if test "x$OPENJDK_TARGET_CPU_BITS" = x32 && test "x$OPENJDK_TARGET_OS" = xmacosx; then
606 # On 32-bit MacOSX the OS requires C-entry points to be 16 byte aligned.
607 # While waiting for a better solution, the current workaround is to use -mstackrealign.
608 CFLAGS="$CFLAGS -mstackrealign"
609 AC_MSG_CHECKING([if 32-bit compiler supports -mstackrealign])
610 AC_LINK_IFELSE([AC_LANG_SOURCE([[int main() { return 0; }]])],
611 [
612 AC_MSG_RESULT([yes])
613 ],
614 [
615 AC_MSG_RESULT([no])
616 AC_MSG_ERROR([The selected compiler $CXX does not support -mstackrealign! Try to put another compiler in the path.])
617 ])
618 fi
620 C_FLAG_DEPS="-MMD -MF"
621 CXX_FLAG_DEPS="-MMD -MF"
623 case $COMPILER_TYPE in
624 CC )
625 D_FLAG="-g"
626 case $COMPILER_NAME in
627 gcc )
628 case $OPENJDK_TARGET_OS in
629 macosx )
630 # On MacOSX we optimize for size, something
631 # we should do for all platforms?
632 C_O_FLAG_HI="-Os"
633 C_O_FLAG_NORM="-Os"
634 C_O_FLAG_NONE=""
635 ;;
636 *)
637 C_O_FLAG_HI="-O3"
638 C_O_FLAG_NORM="-O2"
639 C_O_FLAG_NONE="-O0"
640 CFLAGS_DEBUG_SYMBOLS="-g"
641 CXXFLAGS_DEBUG_SYMBOLS="-g"
642 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64" && test "x$DEBUG_LEVEL" = "xfastdebug"; then
643 CFLAGS_DEBUG_SYMBOLS="-g1"
644 CXXFLAGS_DEBUG_SYMBOLS="-g1"
645 fi
646 ;;
647 esac
648 CXX_O_FLAG_HI="$C_O_FLAG_HI"
649 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
650 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
651 ;;
652 ossc )
653 #
654 # Forte has different names for this with their C++ compiler...
655 #
656 C_FLAG_DEPS="-xMMD -xMF"
657 CXX_FLAG_DEPS="-xMMD -xMF"
659 # Extra options used with HIGHEST
660 #
661 # WARNING: Use of OPTIMIZATION_LEVEL=HIGHEST in your Makefile needs to be
662 # done with care, there are some assumptions below that need to
663 # be understood about the use of pointers, and IEEE behavior.
664 #
665 # Use non-standard floating point mode (not IEEE 754)
666 CC_HIGHEST="$CC_HIGHEST -fns"
667 # Do some simplification of floating point arithmetic (not IEEE 754)
668 CC_HIGHEST="$CC_HIGHEST -fsimple"
669 # Use single precision floating point with 'float'
670 CC_HIGHEST="$CC_HIGHEST -fsingle"
671 # Assume memory references via basic pointer types do not alias
672 # (Source with excessing pointer casting and data access with mixed
673 # pointer types are not recommended)
674 CC_HIGHEST="$CC_HIGHEST -xalias_level=basic"
675 # Use intrinsic or inline versions for math/std functions
676 # (If you expect perfect errno behavior, do not use this)
677 CC_HIGHEST="$CC_HIGHEST -xbuiltin=%all"
678 # Loop data dependency optimizations (need -xO3 or higher)
679 CC_HIGHEST="$CC_HIGHEST -xdepend"
680 # Pointer parameters to functions do not overlap
681 # (Similar to -xalias_level=basic usage, but less obvious sometimes.
682 # If you pass in multiple pointers to the same data, do not use this)
683 CC_HIGHEST="$CC_HIGHEST -xrestrict"
684 # Inline some library routines
685 # (If you expect perfect errno behavior, do not use this)
686 CC_HIGHEST="$CC_HIGHEST -xlibmil"
687 # Use optimized math routines
688 # (If you expect perfect errno behavior, do not use this)
689 # Can cause undefined external on Solaris 8 X86 on __sincos, removing for now
690 #CC_HIGHEST="$CC_HIGHEST -xlibmopt"
692 if test "x$OPENJDK_TARGET_CPU" = xsparc; then
693 CFLAGS_JDK="${CFLAGS_JDK} -xmemalign=4s"
694 CXXFLAGS_JDK="${CXXFLAGS_JDK} -xmemalign=4s"
695 fi
697 case $OPENJDK_TARGET_CPU_ARCH in
698 x86)
699 C_O_FLAG_HIGHEST="-xO4 -Wu,-O4~yz $CC_HIGHEST -xregs=no%frameptr"
700 C_O_FLAG_HI="-xO4 -Wu,-O4~yz -xregs=no%frameptr"
701 C_O_FLAG_NORM="-xO2 -Wu,-O2~yz -xregs=no%frameptr"
702 C_O_FLAG_NONE="-xregs=no%frameptr"
703 CXX_O_FLAG_HIGHEST="-xO4 -Qoption ube -O4~yz $CC_HIGHEST -xregs=no%frameptr"
704 CXX_O_FLAG_HI="-xO4 -Qoption ube -O4~yz -xregs=no%frameptr"
705 CXX_O_FLAG_NORM="-xO2 -Qoption ube -O2~yz -xregs=no%frameptr"
706 CXX_O_FLAG_NONE="-xregs=no%frameptr"
707 if test "x$OPENJDK_TARGET_CPU" = xx86; then
708 C_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST -xchip=pentium"
709 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HIGHEST -xchip=pentium"
710 fi
711 ;;
712 sparc)
713 CFLAGS_JDKLIB_EXTRA="${CFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
714 CXXFLAGS_JDKLIB_EXTRA="${CXXFLAGS_JDKLIB_EXTRA} -xregs=no%appl"
715 C_O_FLAG_HIGHEST="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
716 C_O_FLAG_HI="-xO4 -Wc,-Qrm-s -Wc,-Qiselect-T0"
717 C_O_FLAG_NORM="-xO2 -Wc,-Qrm-s -Wc,-Qiselect-T0"
718 C_O_FLAG_NONE=""
719 CXX_O_FLAG_HIGHEST="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0 $CC_HIGHEST -xprefetch=auto,explicit -xchip=ultra"
720 CXX_O_FLAG_HI="-xO4 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
721 CXX_O_FLAG_NORM="-xO2 -Qoption cg -Qrm-s -Qoption cg -Qiselect-T0"
722 CXX_O_FLAG_NONE=""
723 ;;
724 esac
726 CFLAGS_DEBUG_SYMBOLS="-g -xs"
727 CXXFLAGS_DEBUG_SYMBOLS="-g0 -xs"
728 esac
729 ;;
730 CL )
731 D_FLAG=
732 C_O_FLAG_HIGHEST="-O2"
733 C_O_FLAG_HI="-O1"
734 C_O_FLAG_NORM="-O1"
735 C_O_FLAG_NONE="-Od"
736 CXX_O_FLAG_HIGHEST="$C_O_FLAG_HIGHEST"
737 CXX_O_FLAG_HI="$C_O_FLAG_HI"
738 CXX_O_FLAG_NORM="$C_O_FLAG_NORM"
739 CXX_O_FLAG_NONE="$C_O_FLAG_NONE"
740 ;;
741 esac
743 if test -z "$C_O_FLAG_HIGHEST"; then
744 C_O_FLAG_HIGHEST="$C_O_FLAG_HI"
745 fi
747 if test -z "$CXX_O_FLAG_HIGHEST"; then
748 CXX_O_FLAG_HIGHEST="$CXX_O_FLAG_HI"
749 fi
751 AC_SUBST(C_O_FLAG_HIGHEST)
752 AC_SUBST(C_O_FLAG_HI)
753 AC_SUBST(C_O_FLAG_NORM)
754 AC_SUBST(C_O_FLAG_NONE)
755 AC_SUBST(CXX_O_FLAG_HIGHEST)
756 AC_SUBST(CXX_O_FLAG_HI)
757 AC_SUBST(CXX_O_FLAG_NORM)
758 AC_SUBST(CXX_O_FLAG_NONE)
759 AC_SUBST(C_FLAG_DEPS)
760 AC_SUBST(CXX_FLAG_DEPS)
761 ])
763 AC_DEFUN_ONCE([TOOLCHAIN_SETUP_COMPILER_FLAGS_FOR_JDK],
764 [
766 if test "x$CFLAGS" != "x${ADDED_CFLAGS}"; then
767 AC_MSG_WARN([Ignoring CFLAGS($CFLAGS) found in environment. Use --with-extra-cflags])
768 fi
770 if test "x$CXXFLAGS" != "x${ADDED_CXXFLAGS}"; then
771 AC_MSG_WARN([Ignoring CXXFLAGS($CXXFLAGS) found in environment. Use --with-extra-cxxflags])
772 fi
774 if test "x$LDFLAGS" != "x${ADDED_LDFLAGS}"; then
775 AC_MSG_WARN([Ignoring LDFLAGS($LDFLAGS) found in environment. Use --with-extra-ldflags])
776 fi
778 AC_ARG_WITH(extra-cflags, [AS_HELP_STRING([--with-extra-cflags],
779 [extra flags to be used when compiling jdk c-files])])
781 AC_ARG_WITH(extra-cxxflags, [AS_HELP_STRING([--with-extra-cxxflags],
782 [extra flags to be used when compiling jdk c++-files])])
784 AC_ARG_WITH(extra-ldflags, [AS_HELP_STRING([--with-extra-ldflags],
785 [extra flags to be used when linking jdk])])
787 CFLAGS_JDK="${CFLAGS_JDK} $with_extra_cflags"
788 CXXFLAGS_JDK="${CXXFLAGS_JDK} $with_extra_cxxflags"
789 LDFLAGS_JDK="${LDFLAGS_JDK} $with_extra_ldflags"
791 # Hotspot needs these set in their legacy form
792 LEGACY_EXTRA_CFLAGS=$with_extra_cflags
793 LEGACY_EXTRA_CXXFLAGS=$with_extra_cxxflags
794 LEGACY_EXTRA_LDFLAGS=$with_extra_ldflags
796 AC_SUBST(LEGACY_EXTRA_CFLAGS)
797 AC_SUBST(LEGACY_EXTRA_CXXFLAGS)
798 AC_SUBST(LEGACY_EXTRA_LDFLAGS)
800 ###############################################################################
801 #
802 # Now setup the CFLAGS and LDFLAGS for the JDK build.
803 # Later we will also have CFLAGS and LDFLAGS for the hotspot subrepo build.
804 #
805 case $COMPILER_NAME in
806 gcc )
807 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -W -Wall -Wno-unused -Wno-parentheses \
808 -pipe \
809 -D_GNU_SOURCE -D_REENTRANT -D_LARGEFILE64_SOURCE"
810 case $OPENJDK_TARGET_CPU_ARCH in
811 arm )
812 # on arm we don't prevent gcc to omit frame pointer but do prevent strict aliasing
813 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
814 ;;
815 ppc )
816 # on ppc we don't prevent gcc to omit frame pointer nor strict-aliasing
817 ;;
818 * )
819 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -fno-omit-frame-pointer"
820 CFLAGS_JDK="${CFLAGS_JDK} -fno-strict-aliasing"
821 ;;
822 esac
823 ;;
824 ossc )
825 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -DTRACING -DMACRO_MEMSYS_OPS -DBREAKPTS"
826 case $OPENJDK_TARGET_CPU_ARCH in
827 x86 )
828 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DcpuIntel -Di586 -D$OPENJDK_TARGET_CPU_LEGACY_LIB"
829 CFLAGS_JDK="$CFLAGS_JDK -erroff=E_BAD_PRAGMA_PACK_VALUE"
830 ;;
831 esac
833 CFLAGS_JDK="$CFLAGS_JDK -xc99=%none -xCC -errshort=tags -Xa -v -mt -W0,-noglobal"
834 CXXFLAGS_JDK="$CXXFLAGS_JDK -errtags=yes +w -mt -features=no%except -DCC_NOEX -norunpath -xnolib"
836 LDFLAGS_JDK="$LDFLAGS_JDK -z defs -xildoff -ztext"
837 LDFLAGS_CXX_JDK="$LDFLAGS_CXX_JDK -norunpath -xnolib"
838 ;;
839 cl )
840 CCXXFLAGS_JDK="$CCXXFLAGS $CCXXFLAGS_JDK -Zi -MD -Zc:wchar_t- -W3 -wd4800 \
841 -D_STATIC_CPPLIB -D_DISABLE_DEPRECATE_STATIC_CPPLIB -DWIN32_LEAN_AND_MEAN \
842 -D_CRT_SECURE_NO_DEPRECATE -D_CRT_NONSTDC_NO_DEPRECATE \
843 -DWIN32 -DIAL"
844 case $OPENJDK_TARGET_CPU in
845 x86 )
846 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_X86_ -Dx86"
847 ;;
848 x86_64 )
849 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_AMD64_ -Damd64"
850 ;;
851 esac
852 ;;
853 esac
855 ###############################################################################
857 CCXXFLAGS_JDK="$CCXXFLAGS_JDK $ADD_LP64"
859 # The package path is used only on macosx?
860 PACKAGE_PATH=/opt/local
861 AC_SUBST(PACKAGE_PATH)
863 if test "x$OPENJDK_TARGET_CPU_ENDIAN" = xlittle; then
864 # The macro _LITTLE_ENDIAN needs to be defined the same to avoid the
865 # Sun C compiler warning message: warning: macro redefined: _LITTLE_ENDIAN
866 # (The Solaris X86 system defines this in file /usr/include/sys/isa_defs.h).
867 # Note: -Dmacro is the same as #define macro 1
868 # -Dmacro= is the same as #define macro
869 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
870 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN="
871 else
872 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_LITTLE_ENDIAN"
873 fi
874 else
875 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -D_BIG_ENDIAN"
876 fi
877 if test "x$OPENJDK_TARGET_OS" = xlinux; then
878 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DLINUX"
879 fi
880 if test "x$OPENJDK_TARGET_OS" = xwindows; then
881 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DWINDOWS"
882 fi
883 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
884 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DSOLARIS"
885 fi
886 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
887 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMACOSX -D_ALLBSD_SOURCE"
888 # Setting these parameters makes it an error to link to macosx APIs that are
889 # newer than the given OS version and makes the linked binaries compatible even
890 # if built on a newer version of the OS.
891 # The expected format is X.Y.Z
892 MACOSX_VERSION_MIN=10.7.0
893 AC_SUBST(MACOSX_VERSION_MIN)
894 # The macro takes the version with no dots, ex: 1070
895 # Let the flags variables get resolved in make for easier override on make
896 # command line.
897 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DMAC_OS_X_VERSION_MAX_ALLOWED=\$(subst .,,\$(MACOSX_VERSION_MIN)) -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
898 LDFLAGS_JDK="$LDFLAGS_JDK -mmacosx-version-min=\$(MACOSX_VERSION_MIN)"
899 fi
900 if test "x$OPENJDK_TARGET_OS" = xbsd; then
901 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DBSD -D_ALLBSD_SOURCE"
902 fi
903 if test "x$DEBUG_LEVEL" = xrelease; then
904 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DNDEBUG"
905 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
906 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DTRIMMED"
907 fi
908 else
909 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DDEBUG"
910 fi
912 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DARCH='\"$OPENJDK_TARGET_CPU_LEGACY\"' -D$OPENJDK_TARGET_CPU_LEGACY"
913 CCXXFLAGS_JDK="$CCXXFLAGS_JDK -DRELEASE='\"$RELEASE\"'"
915 CCXXFLAGS_JDK="$CCXXFLAGS_JDK \
916 -I${JDK_OUTPUTDIR}/include \
917 -I${JDK_OUTPUTDIR}/include/$OPENJDK_TARGET_OS \
918 -I${JDK_TOPDIR}/src/share/javavm/export \
919 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/javavm/export \
920 -I${JDK_TOPDIR}/src/share/native/common \
921 -I${JDK_TOPDIR}/src/$OPENJDK_TARGET_OS_API_DIR/native/common"
923 # The shared libraries are compiled using the picflag.
924 CFLAGS_JDKLIB="$CCXXFLAGS_JDK $CFLAGS_JDK $PICFLAG $CFLAGS_JDKLIB_EXTRA"
925 CXXFLAGS_JDKLIB="$CCXXFLAGS_JDK $CXXFLAGS_JDK $PICFLAG $CXXFLAGS_JDKLIB_EXTRA "
927 # Executable flags
928 CFLAGS_JDKEXE="$CCXXFLAGS_JDK $CFLAGS_JDK"
929 CXXFLAGS_JDKEXE="$CCXXFLAGS_JDK $CXXFLAGS_JDK"
931 # Now this is odd. The JDK native libraries have to link against libjvm.so
932 # On 32-bit machines there is normally two distinct libjvm.so:s, client and server.
933 # Which should we link to? Are we lucky enough that the binary api to the libjvm.so library
934 # is identical for client and server? Yes. Which is picked at runtime (client or server)?
935 # Neither, since the chosen libjvm.so has already been loaded by the launcher, all the following
936 # libraries will link to whatever is in memory. Yuck.
937 #
938 # Thus we offer the compiler to find libjvm.so first in server then in client. It works. Ugh.
939 if test "x$COMPILER_NAME" = xcl; then
940 LDFLAGS_JDK="$LDFLAGS_JDK -nologo -opt:ref -incremental:no"
941 if test "x$OPENJDK_TARGET_CPU" = xx86; then
942 LDFLAGS_JDK="$LDFLAGS_JDK -safeseh"
943 fi
944 # TODO: make -debug optional "--disable-full-debug-symbols"
945 LDFLAGS_JDK="$LDFLAGS_JDK -debug"
946 LDFLAGS_JDKLIB="${LDFLAGS_JDK} -dll -libpath:${JDK_OUTPUTDIR}/lib"
947 LDFLAGS_JDKLIB_SUFFIX=""
948 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
949 LDFLAGS_STACK_SIZE=1048576
950 else
951 LDFLAGS_STACK_SIZE=327680
952 fi
953 LDFLAGS_JDKEXE="${LDFLAGS_JDK} /STACK:$LDFLAGS_STACK_SIZE"
954 else
955 if test "x$COMPILER_NAME" = xgcc; then
956 # If this is a --hash-style=gnu system, use --hash-style=both, why?
957 HAS_GNU_HASH=`$CC -dumpspecs 2>/dev/null | $GREP 'hash-style=gnu'`
958 if test -n "$HAS_GNU_HASH"; then
959 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker --hash-style=both "
960 fi
961 if test "x$OPENJDK_TARGET_OS" = xlinux; then
962 # And since we now know that the linker is gnu, then add -z defs, to forbid
963 # undefined symbols in object files.
964 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -z -Xlinker defs"
965 if test "x$DEBUG_LEVEL" = "xrelease"; then
966 # When building release libraries, tell the linker optimize them.
967 # Should this be supplied to the OSS linker as well?
968 LDFLAGS_JDK="${LDFLAGS_JDK} -Xlinker -O1"
969 fi
970 fi
971 fi
972 LDFLAGS_JDKLIB="${LDFLAGS_JDK} $SHARED_LIBRARY_FLAGS \
973 -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}"
975 # On some platforms (mac) the linker warns about non existing -L dirs.
976 # Add server first if available. Linking aginst client does not always produce the same results.
977 # Only add client dir if client is being built. Add minimal (note not minimal1) if only building minimal1.
978 # Default to server for other variants.
979 if test "x$JVM_VARIANT_SERVER" = xtrue; then
980 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
981 elif test "x$JVM_VARIANT_CLIENT" = xtrue; then
982 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/client"
983 elif test "x$JVM_VARIANT_MINIMAL1" = xtrue; then
984 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/minimal"
985 else
986 LDFLAGS_JDKLIB="${LDFLAGS_JDKLIB} -L${JDK_OUTPUTDIR}/lib${OPENJDK_TARGET_CPU_LIBDIR}/server"
987 fi
989 LDFLAGS_JDKLIB_SUFFIX="-ljava -ljvm"
990 if test "x$COMPILER_NAME" = xossc; then
991 LDFLAGS_JDKLIB_SUFFIX="$LDFLAGS_JDKLIB_SUFFIX -lc"
992 fi
994 LDFLAGS_JDKEXE="${LDFLAGS_JDK}"
995 if test "x$OPENJDK_TARGET_OS" = xlinux; then
996 LDFLAGS_JDKEXE="$LDFLAGS_JDKEXE -Xlinker --allow-shlib-undefined"
997 fi
998 fi
1000 # Adjust flags according to debug level.
1001 case $DEBUG_LEVEL in
1002 fastdebug )
1003 CFLAGS="$CFLAGS $D_FLAG"
1004 JAVAC_FLAGS="$JAVAC_FLAGS -g"
1005 ;;
1006 slowdebug )
1007 CFLAGS="$CFLAGS $D_FLAG"
1008 C_O_FLAG_HI="$C_O_FLAG_NONE"
1009 C_O_FLAG_NORM="$C_O_FLAG_NONE"
1010 CXX_O_FLAG_HI="$CXX_O_FLAG_NONE"
1011 CXX_O_FLAG_NORM="$CXX_O_FLAG_NONE"
1012 JAVAC_FLAGS="$JAVAC_FLAGS -g"
1013 ;;
1014 esac
1017 AC_SUBST(CFLAGS_JDKLIB)
1018 AC_SUBST(CFLAGS_JDKEXE)
1020 AC_SUBST(CXXFLAGS_JDKLIB)
1021 AC_SUBST(CXXFLAGS_JDKEXE)
1023 AC_SUBST(LDFLAGS_JDKLIB)
1024 AC_SUBST(LDFLAGS_JDKEXE)
1025 AC_SUBST(LDFLAGS_JDKLIB_SUFFIX)
1026 AC_SUBST(LDFLAGS_JDKEXE_SUFFIX)
1027 AC_SUBST(LDFLAGS_CXX_JDK)
1028 ])
