Tue, 28 May 2019 18:50:01 +0200
8218020: Fix version number in mesa.md 3rd party legal file
Reviewed-by: clanger
1 #
2 # Copyright (c) 2011, 2015, Oracle and/or its affiliates. All rights reserved.
3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.
4 #
5 # This code is free software; you can redistribute it and/or modify it
6 # under the terms of the GNU General Public License version 2 only, as
7 # published by the Free Software Foundation. Oracle designates this
8 # particular file as subject to the "Classpath" exception as provided
9 # by Oracle in the LICENSE file that accompanied this code.
10 #
11 # This code is distributed in the hope that it will be useful, but WITHOUT
12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or
13 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License
14 # version 2 for more details (a copy is included in the LICENSE file that
15 # accompanied this code).
16 #
17 # You should have received a copy of the GNU General Public License version
18 # 2 along with this work; if not, write to the Free Software Foundation,
19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.
20 #
21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA
22 # or visit www.oracle.com if you need additional information or have any
23 # questions.
24 #
26 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
27 # Converts autoconf style CPU name to OpenJDK style, into
28 # VAR_CPU, VAR_CPU_ARCH, VAR_CPU_BITS and VAR_CPU_ENDIAN.
29 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_CPU],
30 [
31 # First argument is the cpu name from the trip/quad
32 case "$1" in
33 x86_64)
34 VAR_CPU=x86_64
35 VAR_CPU_ARCH=x86
36 VAR_CPU_BITS=64
37 VAR_CPU_ENDIAN=little
38 ;;
39 i?86)
40 VAR_CPU=x86
41 VAR_CPU_ARCH=x86
42 VAR_CPU_BITS=32
43 VAR_CPU_ENDIAN=little
44 ;;
45 arm*)
46 VAR_CPU=arm
47 VAR_CPU_ARCH=arm
48 VAR_CPU_BITS=32
49 VAR_CPU_ENDIAN=little
50 ;;
51 aarch64)
52 VAR_CPU=aarch64
53 VAR_CPU_ARCH=aarch64
54 VAR_CPU_BITS=64
55 VAR_CPU_ENDIAN=little
56 ;;
57 powerpc)
58 VAR_CPU=ppc
59 VAR_CPU_ARCH=ppc
60 VAR_CPU_BITS=32
61 VAR_CPU_ENDIAN=big
62 ;;
63 powerpc64)
64 VAR_CPU=ppc64
65 VAR_CPU_ARCH=ppc
66 VAR_CPU_BITS=64
67 VAR_CPU_ENDIAN=big
68 ;;
69 powerpc64le)
70 VAR_CPU=ppc64le
71 VAR_CPU_ARCH=ppc
72 VAR_CPU_BITS=64
73 VAR_CPU_ENDIAN=little
74 ;;
75 s390)
76 VAR_CPU=s390
77 VAR_CPU_ARCH=s390
78 VAR_CPU_BITS=32
79 VAR_CPU_ENDIAN=big
80 ;;
81 s390x)
82 VAR_CPU=s390x
83 VAR_CPU_ARCH=s390
84 VAR_CPU_BITS=64
85 VAR_CPU_ENDIAN=big
86 ;;
87 sparc)
88 VAR_CPU=sparc
89 VAR_CPU_ARCH=sparc
90 VAR_CPU_BITS=32
91 VAR_CPU_ENDIAN=big
92 ;;
93 sparcv9|sparc64)
94 VAR_CPU=sparcv9
95 VAR_CPU_ARCH=sparc
96 VAR_CPU_BITS=64
97 VAR_CPU_ENDIAN=big
98 ;;
99 *)
100 AC_MSG_ERROR([unsupported cpu $1])
101 ;;
102 esac
103 ])
105 # Support macro for PLATFORM_EXTRACT_TARGET_AND_BUILD.
106 # Converts autoconf style OS name to OpenJDK style, into
107 # VAR_OS and VAR_OS_API.
108 AC_DEFUN([PLATFORM_EXTRACT_VARS_FROM_OS],
109 [
110 case "$1" in
111 *linux*)
112 VAR_OS=linux
113 VAR_OS_API=posix
114 VAR_OS_ENV=linux
115 ;;
116 *solaris*)
117 VAR_OS=solaris
118 VAR_OS_API=posix
119 VAR_OS_ENV=solaris
120 ;;
121 *darwin*)
122 VAR_OS=macosx
123 VAR_OS_API=posix
124 VAR_OS_ENV=macosx
125 ;;
126 *bsd*)
127 VAR_OS=bsd
128 VAR_OS_API=posix
129 VAR_OS_ENV=bsd
130 ;;
131 *cygwin*)
132 VAR_OS=windows
133 VAR_OS_API=winapi
134 VAR_OS_ENV=windows.cygwin
135 ;;
136 *mingw*)
137 VAR_OS=windows
138 VAR_OS_API=winapi
139 VAR_OS_ENV=windows.msys
140 ;;
141 *aix*)
142 VAR_OS=aix
143 VAR_OS_API=posix
144 VAR_OS_ENV=aix
145 ;;
146 *)
147 AC_MSG_ERROR([unsupported operating system $1])
148 ;;
149 esac
150 ])
152 # Expects $host_os $host_cpu $build_os and $build_cpu
153 # and $with_target_bits to have been setup!
154 #
155 # Translate the standard triplet(quadruplet) definition
156 # of the target/build system into OPENJDK_TARGET_OS, OPENJDK_TARGET_CPU,
157 # OPENJDK_BUILD_OS, etc.
158 AC_DEFUN([PLATFORM_EXTRACT_TARGET_AND_BUILD],
159 [
160 # Copy the autoconf trip/quadruplet verbatim to OPENJDK_TARGET_AUTOCONF_NAME
161 # (from the autoconf "host") and OPENJDK_BUILD_AUTOCONF_NAME
162 # Note that we might later on rewrite e.g. OPENJDK_TARGET_CPU due to reduced build,
163 # but this will not change the value of OPENJDK_TARGET_AUTOCONF_NAME.
164 OPENJDK_TARGET_AUTOCONF_NAME="$host"
165 OPENJDK_BUILD_AUTOCONF_NAME="$build"
166 AC_SUBST(OPENJDK_TARGET_AUTOCONF_NAME)
167 AC_SUBST(OPENJDK_BUILD_AUTOCONF_NAME)
169 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
170 PLATFORM_EXTRACT_VARS_FROM_OS($build_os)
171 PLATFORM_EXTRACT_VARS_FROM_CPU($build_cpu)
172 # ..and setup our own variables. (Do this explicitely to facilitate searching)
173 OPENJDK_BUILD_OS="$VAR_OS"
174 OPENJDK_BUILD_OS_API="$VAR_OS_API"
175 OPENJDK_BUILD_OS_ENV="$VAR_OS_ENV"
176 OPENJDK_BUILD_CPU="$VAR_CPU"
177 OPENJDK_BUILD_CPU_ARCH="$VAR_CPU_ARCH"
178 OPENJDK_BUILD_CPU_BITS="$VAR_CPU_BITS"
179 OPENJDK_BUILD_CPU_ENDIAN="$VAR_CPU_ENDIAN"
180 AC_SUBST(OPENJDK_BUILD_OS)
181 AC_SUBST(OPENJDK_BUILD_OS_API)
182 AC_SUBST(OPENJDK_BUILD_OS_ENV)
183 AC_SUBST(OPENJDK_BUILD_CPU)
184 AC_SUBST(OPENJDK_BUILD_CPU_ARCH)
185 AC_SUBST(OPENJDK_BUILD_CPU_BITS)
186 AC_SUBST(OPENJDK_BUILD_CPU_ENDIAN)
188 AC_MSG_CHECKING([openjdk-build os-cpu])
189 AC_MSG_RESULT([$OPENJDK_BUILD_OS-$OPENJDK_BUILD_CPU])
191 # Convert the autoconf OS/CPU value to our own data, into the VAR_OS/CPU variables.
192 PLATFORM_EXTRACT_VARS_FROM_OS($host_os)
193 PLATFORM_EXTRACT_VARS_FROM_CPU($host_cpu)
194 # ... and setup our own variables. (Do this explicitely to facilitate searching)
195 OPENJDK_TARGET_OS="$VAR_OS"
196 OPENJDK_TARGET_OS_API="$VAR_OS_API"
197 OPENJDK_TARGET_OS_ENV="$VAR_OS_ENV"
198 OPENJDK_TARGET_CPU="$VAR_CPU"
199 OPENJDK_TARGET_CPU_ARCH="$VAR_CPU_ARCH"
200 OPENJDK_TARGET_CPU_BITS="$VAR_CPU_BITS"
201 OPENJDK_TARGET_CPU_ENDIAN="$VAR_CPU_ENDIAN"
202 AC_SUBST(OPENJDK_TARGET_OS)
203 AC_SUBST(OPENJDK_TARGET_OS_API)
204 AC_SUBST(OPENJDK_TARGET_OS_ENV)
205 AC_SUBST(OPENJDK_TARGET_CPU)
206 AC_SUBST(OPENJDK_TARGET_CPU_ARCH)
207 AC_SUBST(OPENJDK_TARGET_CPU_BITS)
208 AC_SUBST(OPENJDK_TARGET_CPU_ENDIAN)
210 AC_MSG_CHECKING([openjdk-target os-cpu])
211 AC_MSG_RESULT([$OPENJDK_TARGET_OS-$OPENJDK_TARGET_CPU])
212 ])
214 # Check if a reduced build (32-bit on 64-bit platforms) is requested, and modify behaviour
215 # accordingly. Must be done after setting up build and target system, but before
216 # doing anything else with these values.
217 AC_DEFUN([PLATFORM_SETUP_TARGET_CPU_BITS],
218 [
219 AC_ARG_WITH(target-bits, [AS_HELP_STRING([--with-target-bits],
220 [build 32-bit or 64-bit binaries (for platforms that support it), e.g. --with-target-bits=32 @<:@guessed@:>@])])
222 # We have three types of compiles:
223 # native == normal compilation, target system == build system
224 # cross == traditional cross compilation, target system != build system; special toolchain needed
225 # reduced == using native compilers, but with special flags (e.g. -m32) to produce 32-bit builds on 64-bit machines
226 #
227 if test "x$OPENJDK_BUILD_AUTOCONF_NAME" != "x$OPENJDK_TARGET_AUTOCONF_NAME"; then
228 # We're doing a proper cross-compilation
229 COMPILE_TYPE="cross"
230 else
231 COMPILE_TYPE="native"
232 fi
234 if test "x$with_target_bits" != x; then
235 if test "x$COMPILE_TYPE" = "xcross"; then
236 AC_MSG_ERROR([It is not possible to combine --with-target-bits=X and proper cross-compilation. Choose either.])
237 fi
239 if test "x$with_target_bits" = x32 && test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
240 # A reduced build is requested
241 COMPILE_TYPE="reduced"
242 OPENJDK_TARGET_CPU_BITS=32
243 if test "x$OPENJDK_TARGET_CPU_ARCH" = "xx86"; then
244 OPENJDK_TARGET_CPU=x86
245 elif test "x$OPENJDK_TARGET_CPU_ARCH" = "xsparc"; then
246 OPENJDK_TARGET_CPU=sparc
247 else
248 AC_MSG_ERROR([Reduced build (--with-target-bits=32) is only supported on x86_64 and sparcv9])
249 fi
250 elif test "x$with_target_bits" = x64 && test "x$OPENJDK_TARGET_CPU_BITS" = x32; then
251 AC_MSG_ERROR([It is not possible to use --with-target-bits=64 on a 32 bit system. Use proper cross-compilation instead.])
252 elif test "x$with_target_bits" = "x$OPENJDK_TARGET_CPU_BITS"; then
253 AC_MSG_NOTICE([--with-target-bits are set to build platform address size; argument has no meaning])
254 else
255 AC_MSG_ERROR([--with-target-bits can only be 32 or 64, you specified $with_target_bits!])
256 fi
257 fi
258 AC_SUBST(COMPILE_TYPE)
260 AC_MSG_CHECKING([compilation type])
261 AC_MSG_RESULT([$COMPILE_TYPE])
262 ])
264 # Setup the legacy variables, for controlling the old makefiles.
265 #
266 AC_DEFUN([PLATFORM_SETUP_LEGACY_VARS],
267 [
268 # Also store the legacy naming of the cpu.
269 # Ie i586 and amd64 instead of x86 and x86_64
270 OPENJDK_TARGET_CPU_LEGACY="$OPENJDK_TARGET_CPU"
271 if test "x$OPENJDK_TARGET_CPU" = xx86; then
272 OPENJDK_TARGET_CPU_LEGACY="i586"
273 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
274 # On all platforms except MacOSX replace x86_64 with amd64.
275 OPENJDK_TARGET_CPU_LEGACY="amd64"
276 fi
277 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY)
279 # And the second legacy naming of the cpu.
280 # Ie i386 and amd64 instead of x86 and x86_64.
281 OPENJDK_TARGET_CPU_LEGACY_LIB="$OPENJDK_TARGET_CPU"
282 if test "x$OPENJDK_TARGET_CPU" = xx86; then
283 OPENJDK_TARGET_CPU_LEGACY_LIB="i386"
284 elif test "x$OPENJDK_TARGET_CPU" = xx86_64; then
285 OPENJDK_TARGET_CPU_LEGACY_LIB="amd64"
286 fi
287 AC_SUBST(OPENJDK_TARGET_CPU_LEGACY_LIB)
289 # This is the name of the cpu (but using i386 and amd64 instead of
290 # x86 and x86_64, respectively), preceeded by a /, to be used when
291 # locating libraries. On macosx, it's empty, though.
292 OPENJDK_TARGET_CPU_LIBDIR="/$OPENJDK_TARGET_CPU_LEGACY_LIB"
293 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
294 OPENJDK_TARGET_CPU_LIBDIR=""
295 fi
296 AC_SUBST(OPENJDK_TARGET_CPU_LIBDIR)
298 # OPENJDK_TARGET_CPU_ISADIR is normally empty. On 64-bit Solaris systems, it is set to
299 # /amd64 or /sparcv9. This string is appended to some library paths, like this:
300 # /usr/lib${OPENJDK_TARGET_CPU_ISADIR}/libexample.so
301 OPENJDK_TARGET_CPU_ISADIR=""
302 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
303 if test "x$OPENJDK_TARGET_CPU" = xx86_64; then
304 OPENJDK_TARGET_CPU_ISADIR="/amd64"
305 elif test "x$OPENJDK_TARGET_CPU" = xsparcv9; then
306 OPENJDK_TARGET_CPU_ISADIR="/sparcv9"
307 fi
308 fi
309 AC_SUBST(OPENJDK_TARGET_CPU_ISADIR)
311 # Setup OPENJDK_TARGET_CPU_OSARCH, which is used to set the os.arch Java system property
312 OPENJDK_TARGET_CPU_OSARCH="$OPENJDK_TARGET_CPU"
313 if test "x$OPENJDK_TARGET_OS" = xlinux && test "x$OPENJDK_TARGET_CPU" = xx86; then
314 # On linux only, we replace x86 with i386.
315 OPENJDK_TARGET_CPU_OSARCH="i386"
316 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
317 # On all platforms except macosx, we replace x86_64 with amd64.
318 OPENJDK_TARGET_CPU_OSARCH="amd64"
319 fi
320 AC_SUBST(OPENJDK_TARGET_CPU_OSARCH)
322 OPENJDK_TARGET_CPU_JLI="$OPENJDK_TARGET_CPU"
323 if test "x$OPENJDK_TARGET_CPU" = xx86; then
324 OPENJDK_TARGET_CPU_JLI="i386"
325 elif test "x$OPENJDK_TARGET_OS" != xmacosx && test "x$OPENJDK_TARGET_CPU" = xx86_64; then
326 # On all platforms except macosx, we replace x86_64 with amd64.
327 OPENJDK_TARGET_CPU_JLI="amd64"
328 fi
329 # Now setup the -D flags for building libjli.
330 OPENJDK_TARGET_CPU_JLI_CFLAGS="-DLIBARCHNAME='\"$OPENJDK_TARGET_CPU_JLI\"'"
331 if test "x$OPENJDK_TARGET_OS" = xsolaris; then
332 if test "x$OPENJDK_TARGET_CPU_ARCH" = xsparc; then
333 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"sparc\"' -DLIBARCH64NAME='\"sparcv9\"'"
334 elif test "x$OPENJDK_TARGET_CPU_ARCH" = xx86; then
335 OPENJDK_TARGET_CPU_JLI_CFLAGS="$OPENJDK_TARGET_CPU_JLI_CFLAGS -DLIBARCH32NAME='\"i386\"' -DLIBARCH64NAME='\"amd64\"'"
336 fi
337 fi
338 AC_SUBST(OPENJDK_TARGET_CPU_JLI_CFLAGS)
340 # Setup OPENJDK_TARGET_OS_API_DIR, used in source paths.
341 if test "x$OPENJDK_TARGET_OS_API" = xposix; then
342 OPENJDK_TARGET_OS_API_DIR="solaris"
343 fi
344 if test "x$OPENJDK_TARGET_OS_API" = xwinapi; then
345 OPENJDK_TARGET_OS_API_DIR="windows"
346 fi
347 AC_SUBST(OPENJDK_TARGET_OS_API_DIR)
349 if test "x$OPENJDK_TARGET_OS" = xmacosx; then
350 OPENJDK_TARGET_OS_EXPORT_DIR=macosx
351 else
352 OPENJDK_TARGET_OS_EXPORT_DIR=${OPENJDK_TARGET_OS_API_DIR}
353 fi
354 AC_SUBST(OPENJDK_TARGET_OS_EXPORT_DIR)
356 if test "x$OPENJDK_TARGET_CPU_BITS" = x64; then
357 A_LP64="LP64:="
358 # -D_LP64=1 is only set on linux and mac. Setting on windows causes diff in
359 # unpack200.exe
360 if test "x$OPENJDK_TARGET_OS" = xlinux || test "x$OPENJDK_TARGET_OS" = xmacosx; then
361 ADD_LP64="-D_LP64=1"
362 fi
363 fi
364 AC_SUBST(LP64,$A_LP64)
366 if test "x$COMPILE_TYPE" = "xcross"; then
367 # FIXME: ... or should this include reduced builds..?
368 DEFINE_CROSS_COMPILE_ARCH="CROSS_COMPILE_ARCH:=$OPENJDK_TARGET_CPU_LEGACY"
369 else
370 DEFINE_CROSS_COMPILE_ARCH=""
371 fi
372 AC_SUBST(DEFINE_CROSS_COMPILE_ARCH)
374 # ZERO_ARCHDEF is used to enable architecture-specific code
375 case "${OPENJDK_TARGET_CPU}" in
376 ppc) ZERO_ARCHDEF=PPC32 ;;
377 ppc64) ZERO_ARCHDEF=PPC64 ;;
378 s390*) ZERO_ARCHDEF=S390 ;;
379 sparc*) ZERO_ARCHDEF=SPARC ;;
380 x86_64*) ZERO_ARCHDEF=AMD64 ;;
381 x86) ZERO_ARCHDEF=IA32 ;;
382 *) ZERO_ARCHDEF=$(echo "${OPENJDK_TARGET_CPU_LEGACY_LIB}" | tr a-z A-Z)
383 esac
384 AC_SUBST(ZERO_ARCHDEF)
385 ])
387 AC_DEFUN([PLATFORM_SET_RELEASE_FILE_OS_VALUES],
388 [
389 if test "x$OPENJDK_TARGET_OS" = "xsolaris"; then
390 REQUIRED_OS_NAME=SunOS
391 REQUIRED_OS_VERSION=5.10
392 fi
393 if test "x$OPENJDK_TARGET_OS" = "xlinux"; then
394 REQUIRED_OS_NAME=Linux
395 REQUIRED_OS_VERSION=2.6
396 fi
397 if test "x$OPENJDK_TARGET_OS" = "xwindows"; then
398 REQUIRED_OS_NAME=Windows
399 if test "x$OPENJDK_TARGET_CPU_BITS" = "x64"; then
400 REQUIRED_OS_VERSION=5.2
401 else
402 REQUIRED_OS_VERSION=5.1
403 fi
404 fi
405 if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then
406 REQUIRED_OS_NAME=Darwin
407 REQUIRED_OS_VERSION=11.2
408 fi
410 AC_SUBST(REQUIRED_OS_NAME)
411 AC_SUBST(REQUIRED_OS_VERSION)
412 ])
414 #%%% Build and target systems %%%
415 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_AND_TARGET],
416 [
417 # Figure out the build and target systems. # Note that in autoconf terminology, "build" is obvious, but "target"
418 # is confusing; it assumes you are cross-compiling a cross-compiler (!) and "target" is thus the target of the
419 # product you're building. The target of this build is called "host". Since this is confusing to most people, we
420 # have not adopted that system, but use "target" as the platform we are building for. In some places though we need
421 # to use the configure naming style.
422 AC_CANONICAL_BUILD
423 AC_CANONICAL_HOST
424 AC_CANONICAL_TARGET
426 PLATFORM_EXTRACT_TARGET_AND_BUILD
427 PLATFORM_SETUP_TARGET_CPU_BITS
428 PLATFORM_SET_RELEASE_FILE_OS_VALUES
429 PLATFORM_SETUP_LEGACY_VARS
430 ])
432 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_BUILD_OS_VERSION],
433 [
434 ###############################################################################
436 # Note that this is the build platform OS version!
438 OS_VERSION="`uname -r | ${SED} 's!\.! !g' | ${SED} 's!-! !g'`"
439 OS_VERSION_MAJOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 1 -d ' '`"
440 OS_VERSION_MINOR="`${ECHO} ${OS_VERSION} | ${CUT} -f 2 -d ' '`"
441 OS_VERSION_MICRO="`${ECHO} ${OS_VERSION} | ${CUT} -f 3 -d ' '`"
442 AC_SUBST(OS_VERSION_MAJOR)
443 AC_SUBST(OS_VERSION_MINOR)
444 AC_SUBST(OS_VERSION_MICRO)
445 ])
447 # Support macro for PLATFORM_SETUP_OPENJDK_TARGET_BITS.
448 # Add -mX to various FLAGS variables.
449 AC_DEFUN([PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS],
450 [
451 # When we add flags to the "official" CFLAGS etc, we need to
452 # keep track of these additions in ADDED_CFLAGS etc. These
453 # will later be checked to make sure only controlled additions
454 # have been made to CFLAGS etc.
455 ADDED_CFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
456 ADDED_CXXFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
457 ADDED_LDFLAGS=" ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}"
459 CFLAGS="${CFLAGS}${ADDED_CFLAGS}"
460 CXXFLAGS="${CXXFLAGS}${ADDED_CXXFLAGS}"
461 LDFLAGS="${LDFLAGS}${ADDED_LDFLAGS}"
463 CFLAGS_JDK="${CFLAGS_JDK}${ADDED_CFLAGS}"
464 CXXFLAGS_JDK="${CXXFLAGS_JDK}${ADDED_CXXFLAGS}"
465 LDFLAGS_JDK="${LDFLAGS_JDK}${ADDED_LDFLAGS}"
466 ])
468 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_BITS],
469 [
470 ###############################################################################
471 #
472 # Now we check if libjvm.so will use 32 or 64 bit pointers for the C/C++ code.
473 # (The JVM can use 32 or 64 bit Java pointers but that decision
474 # is made at runtime.)
475 #
477 if test "x$OPENJDK_TARGET_OS" = xsolaris || test "x$OPENJDK_TARGET_OS" = xaix; then
478 # Always specify -m flag on Solaris
479 # And -q on AIX because otherwise the compiler produces 32-bit objects by default
480 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
481 elif test "x$COMPILE_TYPE" = xreduced; then
482 if test "x$OPENJDK_TARGET_OS" != xwindows; then
483 # Specify -m if running reduced on other Posix platforms
484 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
485 fi
486 fi
488 # Make compilation sanity check
489 AC_CHECK_HEADERS([stdio.h], , [
490 AC_MSG_NOTICE([Failed to compile stdio.h. This likely implies missing compile dependencies.])
491 if test "x$COMPILE_TYPE" = xreduced; then
492 AC_MSG_NOTICE([You are doing a reduced build. Check that you have 32-bit libraries installed.])
493 elif test "x$COMPILE_TYPE" = xcross; then
494 AC_MSG_NOTICE([You are doing a cross-compilation. Check that you have all target platform libraries installed.])
495 fi
496 AC_MSG_ERROR([Cannot continue.])
497 ])
499 AC_CHECK_SIZEOF([int *], [1111])
501 # AC_CHECK_SIZEOF defines 'ac_cv_sizeof_int_p' to hold the number of bytes used by an 'int*'
502 if test "x$ac_cv_sizeof_int_p" = x; then
503 # The test failed, lets stick to the assumed value.
504 AC_MSG_WARN([The number of bits in the target could not be determined, using $OPENJDK_TARGET_CPU_BITS.])
505 else
506 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
508 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
509 # This situation may happen on 64-bit platforms where the compiler by default only generates 32-bit objects
510 # Let's try to implicitely set the compilers target architecture and retry the test
511 AC_MSG_NOTICE([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS).])
512 AC_MSG_NOTICE([I'll retry after setting the platforms compiler target bits flag to ${COMPILER_TARGET_BITS_FLAG}${OPENJDK_TARGET_CPU_BITS}])
513 PLATFORM_SET_COMPILER_TARGET_BITS_FLAGS
515 # We have to unset 'ac_cv_sizeof_int_p' first, otherwise AC_CHECK_SIZEOF will use the previously cached value!
516 unset ac_cv_sizeof_int_p
517 # And we have to undef the definition of SIZEOF_INT_P in confdefs.h by the previous invocation of AC_CHECK_SIZEOF
518 cat >>confdefs.h <<_ACEOF
519 #undef SIZEOF_INT_P
520 _ACEOF
522 AC_CHECK_SIZEOF([int *], [1111])
524 TESTED_TARGET_CPU_BITS=`expr 8 \* $ac_cv_sizeof_int_p`
526 if test "x$TESTED_TARGET_CPU_BITS" != "x$OPENJDK_TARGET_CPU_BITS"; then
527 AC_MSG_ERROR([The tested number of bits in the target ($TESTED_TARGET_CPU_BITS) differs from the number of bits expected to be found in the target ($OPENJDK_TARGET_CPU_BITS)])
528 fi
529 fi
530 fi
532 AC_MSG_CHECKING([for target address size])
533 AC_MSG_RESULT([$OPENJDK_TARGET_CPU_BITS bits])
534 ])
536 AC_DEFUN_ONCE([PLATFORM_SETUP_OPENJDK_TARGET_ENDIANNESS],
537 [
538 ###############################################################################
539 #
540 # Is the target little of big endian?
541 #
542 AC_C_BIGENDIAN([ENDIAN="big"],[ENDIAN="little"],[ENDIAN="unknown"],[ENDIAN="universal_endianness"])
544 if test "x$ENDIAN" = xuniversal_endianness; then
545 AC_MSG_ERROR([Building with both big and little endianness is not supported])
546 fi
547 if test "x$ENDIAN" != "x$OPENJDK_TARGET_CPU_ENDIAN"; then
548 AC_MSG_ERROR([The tested endian in the target ($ENDIAN) differs from the endian expected to be found in the target ($OPENJDK_TARGET_CPU_ENDIAN)])
549 fi
550 ])