jdk8-mips64-public: common/autoconf/basics.m4@1a853fac18ff

8026528: [build] configure does not recognize newer make in cygwin
Reviewed-by: tbell, ksrini, ihse

1 #

     2 # Copyright (c) 2011, 2013, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 # Test if $1 is a valid argument to $3 (often is $JAVA passed as $3)

    27 # If so, then append $1 to $2 \

    28 # Also set JVM_ARG_OK to true/false depending on outcome.

    29 AC_DEFUN([ADD_JVM_ARG_IF_OK],

    30 [

    31   $ECHO "Check if jvm arg is ok: $1" >&AS_MESSAGE_LOG_FD

    32   $ECHO "Command: $3 $1 -version" >&AS_MESSAGE_LOG_FD

    33   OUTPUT=`$3 $1 -version 2>&1`

    34   FOUND_WARN=`$ECHO "$OUTPUT" | grep -i warn`

    35   FOUND_VERSION=`$ECHO $OUTPUT | grep " version \""`

    36   if test "x$FOUND_VERSION" != x && test "x$FOUND_WARN" = x; then

    37     $2="[$]$2 $1"

    38     JVM_ARG_OK=true

    39   else

    40     $ECHO "Arg failed:" >&AS_MESSAGE_LOG_FD

    41     $ECHO "$OUTPUT" >&AS_MESSAGE_LOG_FD

    42     JVM_ARG_OK=false

    43   fi

    44 ])

    46 # Appends a string to a path variable, only adding the : when needed.

    47 AC_DEFUN([BASIC_APPEND_TO_PATH],

    48 [

    49   if test "x[$]$1" = x; then

    50     $1="$2"

    51   else

    52     $1="[$]$1:$2"

    53   fi

    54 ])

    56 # This will make sure the given variable points to a full and proper

    57 # path. This means:

    58 # 1) There will be no spaces in the path. On posix platforms,

    59 #    spaces in the path will result in an error. On Windows,

    60 #    the path will be rewritten using short-style to be space-free.

    61 # 2) The path will be absolute, and it will be in unix-style (on

    62 #     cygwin).

    63 # $1: The name of the variable to fix

    64 AC_DEFUN([BASIC_FIXUP_PATH],

    65 [

    66   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

    67     BASIC_FIXUP_PATH_CYGWIN($1)

    68   elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

    69     BASIC_FIXUP_PATH_MSYS($1)

    70   else

    71     # We're on a posix platform. Hooray! :)

    72     path="[$]$1"

    73     has_space=`$ECHO "$path" | $GREP " "`

    74     if test "x$has_space" != x; then

    75       AC_MSG_NOTICE([The path of $1, which resolves as "$path", is invalid.])

    76       AC_MSG_ERROR([Spaces are not allowed in this path.])

    77     fi

    79     # Use eval to expand a potential ~

    80     eval path="$path"

    81     if test ! -f "$path" && test ! -d "$path"; then

    82       AC_MSG_ERROR([The path of $1, which resolves as "$path", is not found.])

    83     fi

    85     $1="`cd "$path"; $THEPWDCMD -L`"

    86   fi

    87 ])

    89 # This will make sure the given variable points to a executable

    90 # with a full and proper path. This means:

    91 # 1) There will be no spaces in the path. On posix platforms,

    92 #    spaces in the path will result in an error. On Windows,

    93 #    the path will be rewritten using short-style to be space-free.

    94 # 2) The path will be absolute, and it will be in unix-style (on

    95 #     cygwin).

    96 # Any arguments given to the executable is preserved.

    97 # If the input variable does not have a directory specification, then

    98 # it need to be in the PATH.

    99 # $1: The name of the variable to fix

   100 AC_DEFUN([BASIC_FIXUP_EXECUTABLE],

   101 [

   102   if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

   103     BASIC_FIXUP_EXECUTABLE_CYGWIN($1)

   104   elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   105     BASIC_FIXUP_EXECUTABLE_MSYS($1)

   106   else

   107     # We're on a posix platform. Hooray! :)

   108     # First separate the path from the arguments. This will split at the first

   109     # space.

   110     complete="[$]$1"

   111     path="${complete%% *}"

   112     tmp="$complete EOL"

   113     arguments="${tmp#* }"

   115     # Cannot rely on the command "which" here since it doesn't always work.

   116     is_absolute_path=`$ECHO "$path" | $GREP ^/`

   117     if test -z "$is_absolute_path"; then

   118       # Path to executable is not absolute. Find it.

   119       IFS_save="$IFS"

   120       IFS=:

   121       for p in $PATH; do

   122         if test -f "$p/$path" && test -x "$p/$path"; then

   123           new_path="$p/$path"

   124           break

   125         fi

   126       done

   127       IFS="$IFS_save"

   128     else

   129       AC_MSG_NOTICE([Resolving $1 (as $path) failed, using $path directly.])

   130       new_path="$path"

   131     fi

   133     if test "x$new_path" = x; then

   134       AC_MSG_NOTICE([The path of $1, which resolves as "$complete", is not found.])

   135       has_space=`$ECHO "$complete" | $GREP " "`

   136       if test "x$has_space" != x; then

   137         AC_MSG_NOTICE([This might be caused by spaces in the path, which is not allowed.])

   138       fi

   139       AC_MSG_ERROR([Cannot locate the the path of $1])

   140     fi

   141   fi

   143   # Now join together the path and the arguments once again

   144   if test "x$arguments" != xEOL; then

   145     new_complete="$new_path ${arguments% *}"

   146   else

   147     new_complete="$new_path"

   148   fi

   150   if test "x$complete" != "x$new_complete"; then

   151     $1="$new_complete"

   152     AC_MSG_NOTICE([Rewriting $1 to "$new_complete"])

   153   fi

   154 ])

   156 AC_DEFUN([BASIC_REMOVE_SYMBOLIC_LINKS],

   157 [

   158   if test "x$OPENJDK_BUILD_OS" != xwindows; then

   159     # Follow a chain of symbolic links. Use readlink

   160     # where it exists, else fall back to horribly

   161     # complicated shell code.

   162     if test "x$READLINK_TESTED" != yes; then

   163       # On MacOSX there is a readlink tool with a different

   164       # purpose than the GNU readlink tool. Check the found readlink.

   165       ISGNU=`$READLINK --version 2>&1 | $GREP GNU`

   166       if test "x$ISGNU" = x; then

   167         # A readlink that we do not know how to use.

   168         # Are there other non-GNU readlinks out there?

   169         READLINK_TESTED=yes

   170         READLINK=

   171       fi

   172     fi

   174     if test "x$READLINK" != x; then

   175       $1=`$READLINK -f [$]$1`

   176     else

   177       # Save the current directory for restoring afterwards

   178       STARTDIR=$PWD

   179       COUNTER=0

   180       sym_link_dir=`$DIRNAME [$]$1`

   181       sym_link_file=`$BASENAME [$]$1`

   182       cd $sym_link_dir

   183       # Use -P flag to resolve symlinks in directories.

   184       cd `$THEPWDCMD -P`

   185       sym_link_dir=`$THEPWDCMD -P`

   186       # Resolve file symlinks

   187       while test $COUNTER -lt 20; do

   188         ISLINK=`$LS -l $sym_link_dir/$sym_link_file | $GREP '\->' | $SED -e 's/.*-> \(.*\)/\1/'`

   189         if test "x$ISLINK" == x; then

   190           # This is not a symbolic link! We are done!

   191           break

   192         fi

   193         # Again resolve directory symlinks since the target of the just found

   194         # link could be in a different directory

   195         cd `$DIRNAME $ISLINK`

   196         sym_link_dir=`$THEPWDCMD -P`

   197         sym_link_file=`$BASENAME $ISLINK`

   198         let COUNTER=COUNTER+1

   199       done

   200       cd $STARTDIR

   201       $1=$sym_link_dir/$sym_link_file

   202     fi

   203   fi

   204 ])

   206 # Register a --with argument but mark it as deprecated

   207 # $1: The name of the with argument to deprecate, not including --with-

   208 AC_DEFUN([BASIC_DEPRECATED_ARG_WITH],

   209 [

   210   AC_ARG_WITH($1, [AS_HELP_STRING([--with-$1],

   211       [Deprecated. Option is kept for backwards compatibility and is ignored])],

   212       [AC_MSG_WARN([Option --with-$1 is deprecated and will be ignored.])])

   213 ])

   215 AC_DEFUN_ONCE([BASIC_INIT],

   216 [

   217   # Save the original command line. This is passed to us by the wrapper configure script.

   218   AC_SUBST(CONFIGURE_COMMAND_LINE)

   219   DATE_WHEN_CONFIGURED=`LANG=C date`

   220   AC_SUBST(DATE_WHEN_CONFIGURED)

   221   AC_MSG_NOTICE([Configuration created at $DATE_WHEN_CONFIGURED.])

   222   AC_MSG_NOTICE([configure script generated at timestamp $DATE_WHEN_GENERATED.])

   223 ])

   225 # Test that variable $1 denoting a program is not empty. If empty, exit with an error.

   226 # $1: variable to check

   227 # $2: executable name to print in warning (optional)

   228 AC_DEFUN([BASIC_CHECK_NONEMPTY],

   229 [

   230   if test "x[$]$1" = x; then

   231     if test "x$2" = x; then

   232       PROG_NAME=translit($1,A-Z,a-z)

   233     else

   234       PROG_NAME=$2

   235     fi

   236     AC_MSG_NOTICE([Could not find $PROG_NAME!])

   237     AC_MSG_ERROR([Cannot continue])

   238   fi

   239 ])

   241 # Does AC_PATH_PROG followed by BASIC_CHECK_NONEMPTY.

   242 # Arguments as AC_PATH_PROG:

   243 # $1: variable to set

   244 # $2: executable name to look for

   245 AC_DEFUN([BASIC_REQUIRE_PROG],

   246 [

   247   AC_PATH_PROGS($1, $2)

   248   BASIC_CHECK_NONEMPTY($1, $2)

   249 ])

   251 # Setup the most fundamental tools that relies on not much else to set up,

   252 # but is used by much of the early bootstrap code.

   253 AC_DEFUN_ONCE([BASIC_SETUP_FUNDAMENTAL_TOOLS],

   254 [

   256   # Start with tools that do not need have cross compilation support

   257   # and can be expected to be found in the default PATH. These tools are

   258   # used by configure. Nor are these tools expected to be found in the

   259   # devkit from the builddeps server either, since they are

   260   # needed to download the devkit.

   262   # First are all the simple required tools.

   263   BASIC_REQUIRE_PROG(BASENAME, basename)

   264   BASIC_REQUIRE_PROG(BASH, bash)

   265   BASIC_REQUIRE_PROG(CAT, cat)

   266   BASIC_REQUIRE_PROG(CHMOD, chmod)

   267   BASIC_REQUIRE_PROG(CMP, cmp)

   268   BASIC_REQUIRE_PROG(COMM, comm)

   269   BASIC_REQUIRE_PROG(CP, cp)

   270   BASIC_REQUIRE_PROG(CPIO, cpio)

   271   BASIC_REQUIRE_PROG(CUT, cut)

   272   BASIC_REQUIRE_PROG(DATE, date)

   273   BASIC_REQUIRE_PROG(DIFF, [gdiff diff])

   274   BASIC_REQUIRE_PROG(DIRNAME, dirname)

   275   BASIC_REQUIRE_PROG(ECHO, echo)

   276   BASIC_REQUIRE_PROG(EXPR, expr)

   277   BASIC_REQUIRE_PROG(FILE, file)

   278   BASIC_REQUIRE_PROG(FIND, find)

   279   BASIC_REQUIRE_PROG(HEAD, head)

   280   BASIC_REQUIRE_PROG(LN, ln)

   281   BASIC_REQUIRE_PROG(LS, ls)

   282   BASIC_REQUIRE_PROG(MKDIR, mkdir)

   283   BASIC_REQUIRE_PROG(MKTEMP, mktemp)

   284   BASIC_REQUIRE_PROG(MV, mv)

   285   BASIC_REQUIRE_PROG(PRINTF, printf)

   286   BASIC_REQUIRE_PROG(RM, rm)

   287   BASIC_REQUIRE_PROG(SH, sh)

   288   BASIC_REQUIRE_PROG(SORT, sort)

   289   BASIC_REQUIRE_PROG(TAIL, tail)

   290   BASIC_REQUIRE_PROG(TAR, tar)

   291   BASIC_REQUIRE_PROG(TEE, tee)

   292   BASIC_REQUIRE_PROG(TOUCH, touch)

   293   BASIC_REQUIRE_PROG(TR, tr)

   294   BASIC_REQUIRE_PROG(UNAME, uname)

   295   BASIC_REQUIRE_PROG(UNIQ, uniq)

   296   BASIC_REQUIRE_PROG(WC, wc)

   297   BASIC_REQUIRE_PROG(WHICH, which)

   298   BASIC_REQUIRE_PROG(XARGS, xargs)

   300   # Then required tools that require some special treatment.

   301   AC_PROG_AWK

   302   BASIC_CHECK_NONEMPTY(AWK)

   303   AC_PROG_GREP

   304   BASIC_CHECK_NONEMPTY(GREP)

   305   AC_PROG_EGREP

   306   BASIC_CHECK_NONEMPTY(EGREP)

   307   AC_PROG_FGREP

   308   BASIC_CHECK_NONEMPTY(FGREP)

   309   AC_PROG_SED

   310   BASIC_CHECK_NONEMPTY(SED)

   312   AC_PATH_PROGS(NAWK, [nawk gawk awk])

   313   BASIC_CHECK_NONEMPTY(NAWK)

   315   # Always force rm.

   316   RM="$RM -f"

   318   # pwd behaves differently on various platforms and some don't support the -L flag.

   319   # Always use the bash builtin pwd to get uniform behavior.

   320   THEPWDCMD=pwd

   322   # These are not required on all platforms

   323   AC_PATH_PROG(CYGPATH, cygpath)

   324   AC_PATH_PROG(READLINK, readlink)

   325   AC_PATH_PROG(DF, df)

   326   AC_PATH_PROG(SETFILE, SetFile)

   327 ])

   329 # Setup basic configuration paths, and platform-specific stuff related to PATHs.

   330 AC_DEFUN_ONCE([BASIC_SETUP_PATHS],

   331 [

   332   # Locate the directory of this script.

   333   SCRIPT="[$]0"

   334   AUTOCONF_DIR=`cd \`$DIRNAME $SCRIPT\`; $THEPWDCMD -L`

   336   # Where is the source? It is located two levels above the configure script.

   337   CURDIR="$PWD"

   338   cd "$AUTOCONF_DIR/../.."

   339   SRC_ROOT="`$THEPWDCMD -L`"

   341   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   342     PATH_SEP=";"

   343     BASIC_CHECK_PATHS_WINDOWS

   344   else

   345     PATH_SEP=":"

   346   fi

   348   AC_SUBST(SRC_ROOT)

   349   AC_SUBST(PATH_SEP)

   350   cd "$CURDIR"

   352   BASIC_FIXUP_PATH(SRC_ROOT)

   353   BASIC_FIXUP_PATH(CURDIR)

   355   if test "x$OPENJDK_BUILD_OS" = "xsolaris"; then

   356     # Add extra search paths on solaris for utilities like ar and as etc...

   357     PATH="$PATH:/usr/ccs/bin:/usr/sfw/bin:/opt/csw/bin"

   358   fi

   360   # You can force the sys-root if the sys-root encoded into the cross compiler tools

   361   # is not correct.

   362   AC_ARG_WITH(sys-root, [AS_HELP_STRING([--with-sys-root],

   363       [pass this sys-root to the compilers and tools (for cross-compiling)])])

   365   if test "x$with_sys_root" != x; then

   366     SYS_ROOT=$with_sys_root

   367   else

   368     SYS_ROOT=/

   369   fi

   370   AC_SUBST(SYS_ROOT)

   372   AC_ARG_WITH([tools-dir], [AS_HELP_STRING([--with-tools-dir],

   373       [search this directory for compilers and tools (for cross-compiling)])],

   374       [TOOLS_DIR=$with_tools_dir]

   375   )

   377   AC_ARG_WITH([devkit], [AS_HELP_STRING([--with-devkit],

   378       [use this directory as base for tools-dir and sys-root (for cross-compiling)])],

   379       [

   380         if test "x$with_sys_root" != x; then

   381           AC_MSG_ERROR([Cannot specify both --with-devkit and --with-sys-root at the same time])

   382         fi

   383         BASIC_FIXUP_PATH([with_devkit])

   384         BASIC_APPEND_TO_PATH([TOOLS_DIR],$with_devkit/bin)

   385         if test -d "$with_devkit/$host_alias/libc"; then

   386           SYS_ROOT=$with_devkit/$host_alias/libc

   387         elif test -d "$with_devkit/$host/sys-root"; then

   388           SYS_ROOT=$with_devkit/$host/sys-root

   389         fi

   390       ])

   391 ])

   393 AC_DEFUN_ONCE([BASIC_SETUP_OUTPUT_DIR],

   394 [

   396   AC_ARG_WITH(conf-name, [AS_HELP_STRING([--with-conf-name],

   397       [use this as the name of the configuration @<:@generated from important configuration options@:>@])],

   398       [ CONF_NAME=${with_conf_name} ])

   400   # Test from where we are running configure, in or outside of src root.

   401   if test "x$CURDIR" = "x$SRC_ROOT" || test "x$CURDIR" = "x$SRC_ROOT/common" \

   402       || test "x$CURDIR" = "x$SRC_ROOT/common/autoconf" \

   403       || test "x$CURDIR" = "x$SRC_ROOT/common/makefiles" ; then

   404     # We are running configure from the src root.

   405     # Create a default ./build/target-variant-debuglevel output root.

   406     if test "x${CONF_NAME}" = x; then

   407       CONF_NAME="${OPENJDK_TARGET_OS}-${OPENJDK_TARGET_CPU}-${JDK_VARIANT}-${ANDED_JVM_VARIANTS}-${DEBUG_LEVEL}"

   408     fi

   409     OUTPUT_ROOT="$SRC_ROOT/build/${CONF_NAME}"

   410     $MKDIR -p "$OUTPUT_ROOT"

   411     if test ! -d "$OUTPUT_ROOT"; then

   412       AC_MSG_ERROR([Could not create build directory $OUTPUT_ROOT])

   413     fi

   414   else

   415     # We are running configure from outside of the src dir.

   416     # Then use the current directory as output dir!

   417     # If configuration is situated in normal build directory, just use the build

   418     # directory name as configuration name, otherwise use the complete path.

   419     if test "x${CONF_NAME}" = x; then

   420       CONF_NAME=`$ECHO $CURDIR | $SED -e "s!^${SRC_ROOT}/build/!!"`

   421     fi

   422     OUTPUT_ROOT="$CURDIR"

   424     # WARNING: This might be a bad thing to do. You need to be sure you want to

   425     # have a configuration in this directory. Do some sanity checks!

   427     if test ! -e "$OUTPUT_ROOT/spec.gmk"; then

   428       # If we have a spec.gmk, we have run here before and we are OK. Otherwise, check for

   429       # other files

   430       files_present=`$LS $OUTPUT_ROOT`

   431       # Configure has already touched config.log and confdefs.h in the current dir when this check

   432       # is performed.

   433       filtered_files=`$ECHO "$files_present" | $SED -e 's/config.log//g' -e 's/confdefs.h//g' -e 's/ //g' \

   434       | $TR -d '\n'`

   435       if test "x$filtered_files" != x; then

   436         AC_MSG_NOTICE([Current directory is $CURDIR.])

   437         AC_MSG_NOTICE([Since this is not the source root, configure will output the configuration here])

   438         AC_MSG_NOTICE([(as opposed to creating a configuration in <src_root>/build/<conf-name>).])

   439         AC_MSG_NOTICE([However, this directory is not empty. This is not allowed, since it could])

   440         AC_MSG_NOTICE([seriously mess up just about everything.])

   441         AC_MSG_NOTICE([Try 'cd $SRC_ROOT' and restart configure])

   442         AC_MSG_NOTICE([(or create a new empty directory and cd to it).])

   443         AC_MSG_ERROR([Will not continue creating configuration in $CURDIR])

   444       fi

   445     fi

   446   fi

   447   AC_MSG_CHECKING([what configuration name to use])

   448   AC_MSG_RESULT([$CONF_NAME])

   450   BASIC_FIXUP_PATH(OUTPUT_ROOT)

   452   AC_SUBST(SPEC, $OUTPUT_ROOT/spec.gmk)

   453   AC_SUBST(CONF_NAME, $CONF_NAME)

   454   AC_SUBST(OUTPUT_ROOT, $OUTPUT_ROOT)

   456   # Most of the probed defines are put into config.h

   457   AC_CONFIG_HEADERS([$OUTPUT_ROOT/config.h:$AUTOCONF_DIR/config.h.in])

   458   # The spec.gmk file contains all variables for the make system.

   459   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.gmk:$AUTOCONF_DIR/spec.gmk.in])

   460   # The hotspot-spec.gmk file contains legacy variables for the hotspot make system.

   461   AC_CONFIG_FILES([$OUTPUT_ROOT/hotspot-spec.gmk:$AUTOCONF_DIR/hotspot-spec.gmk.in])

   462   # The bootcycle-spec.gmk file contains support for boot cycle builds.

   463   AC_CONFIG_FILES([$OUTPUT_ROOT/bootcycle-spec.gmk:$AUTOCONF_DIR/bootcycle-spec.gmk.in])

   464   # The compare.sh is used to compare the build output to other builds.

   465   AC_CONFIG_FILES([$OUTPUT_ROOT/compare.sh:$AUTOCONF_DIR/compare.sh.in])

   466   # Spec.sh is currently used by compare-objects.sh

   467   AC_CONFIG_FILES([$OUTPUT_ROOT/spec.sh:$AUTOCONF_DIR/spec.sh.in])

   468   # The generated Makefile knows where the spec.gmk is and where the source is.

   469   # You can run make from the OUTPUT_ROOT, or from the top-level Makefile

   470   # which will look for generated configurations

   471   AC_CONFIG_FILES([$OUTPUT_ROOT/Makefile:$AUTOCONF_DIR/Makefile.in])

   473   # Save the arguments given to us

   474   echo "$CONFIGURE_COMMAND_LINE" > $OUTPUT_ROOT/configure-arguments

   475 ])

   477 AC_DEFUN_ONCE([BASIC_SETUP_LOGGING],

   478 [

   479   # Setup default logging of stdout and stderr to build.log in the output root.

   480   BUILD_LOG='$(OUTPUT_ROOT)/build.log'

   481   BUILD_LOG_PREVIOUS='$(OUTPUT_ROOT)/build.log.old'

   482   BUILD_LOG_WRAPPER='$(BASH) $(SRC_ROOT)/common/bin/logger.sh $(BUILD_LOG)'

   483   AC_SUBST(BUILD_LOG)

   484   AC_SUBST(BUILD_LOG_PREVIOUS)

   485   AC_SUBST(BUILD_LOG_WRAPPER)

   486 ])

   489 #%%% Simple tools %%%

   491 # Check if we have found a usable version of make

   492 # $1: the path to a potential make binary (or empty)

   493 # $2: the description on how we found this

   494 AC_DEFUN([BASIC_CHECK_MAKE_VERSION],

   495 [

   496   MAKE_CANDIDATE="$1"

   497   DESCRIPTION="$2"

   498   if test "x$MAKE_CANDIDATE" != x; then

   499     AC_MSG_NOTICE([Testing potential make at $MAKE_CANDIDATE, found using $DESCRIPTION])

   500     MAKE_VERSION_STRING=`$MAKE_CANDIDATE --version | $HEAD -n 1`

   501     IS_GNU_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP 'GNU Make'`

   502     if test "x$IS_GNU_MAKE" = x; then

   503       AC_MSG_NOTICE([Found potential make at $MAKE_CANDIDATE, however, this is not GNU Make. Ignoring.])

   504     else

   505       IS_MODERN_MAKE=`$ECHO $MAKE_VERSION_STRING | $GREP '\(3\.8[[12]]\)\|\(4\.\)'`

   506       if test "x$IS_MODERN_MAKE" = x; then

   507         AC_MSG_NOTICE([Found GNU make at $MAKE_CANDIDATE, however this is not version 3.81 or later. (it is: $MAKE_VERSION_STRING). Ignoring.])

   508       else

   509         if test "x$OPENJDK_BUILD_OS" = "xwindows"; then

   510           if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.cygwin"; then

   511             MAKE_EXPECTED_ENV='cygwin'

   512           elif test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   513             MAKE_EXPECTED_ENV='msys'

   514           else

   515             AC_MSG_ERROR([Unknown Windows environment])

   516           fi

   517           MAKE_BUILT_FOR=`$MAKE_CANDIDATE --version | $GREP -i 'built for'`

   518           IS_MAKE_CORRECT_ENV=`$ECHO $MAKE_BUILT_FOR | $GREP $MAKE_EXPECTED_ENV`

   519         else

   520           # Not relevant for non-Windows

   521           IS_MAKE_CORRECT_ENV=true

   522         fi

   523         if test "x$IS_MAKE_CORRECT_ENV" = x; then

   524           AC_MSG_NOTICE([Found GNU make version $MAKE_VERSION_STRING at $MAKE_CANDIDATE, but it is not for $MAKE_EXPECTED_ENV (it says: $MAKE_BUILT_FOR). Ignoring.])

   525         else

   526           FOUND_MAKE=$MAKE_CANDIDATE

   527           BASIC_FIXUP_EXECUTABLE(FOUND_MAKE)

   528         fi

   529       fi

   530     fi

   531   fi

   532 ])

   534 # Goes looking for a usable version of GNU make.

   535 AC_DEFUN([BASIC_CHECK_GNU_MAKE],

   536 [

   537   # We need to find a recent version of GNU make. Especially on Solaris, this can be tricky.

   538   if test "x$MAKE" != x; then

   539     # User has supplied a make, test it.

   540     if test ! -f "$MAKE"; then

   541       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not found.])

   542     fi

   543     BASIC_CHECK_MAKE_VERSION("$MAKE", [user supplied MAKE=$MAKE])

   544     if test "x$FOUND_MAKE" = x; then

   545       AC_MSG_ERROR([The specified make (by MAKE=$MAKE) is not GNU make 3.81 or newer.])

   546     fi

   547   else

   548     # Try our hardest to locate a correct version of GNU make

   549     AC_PATH_PROGS(CHECK_GMAKE, gmake)

   550     BASIC_CHECK_MAKE_VERSION("$CHECK_GMAKE", [gmake in PATH])

   552     if test "x$FOUND_MAKE" = x; then

   553       AC_PATH_PROGS(CHECK_MAKE, make)

   554       BASIC_CHECK_MAKE_VERSION("$CHECK_MAKE", [make in PATH])

   555     fi

   557     if test "x$FOUND_MAKE" = x; then

   558       if test "x$TOOLS_DIR" != x; then

   559         # We have a tools-dir, check that as well before giving up.

   560         OLD_PATH=$PATH

   561         PATH=$TOOLS_DIR:$PATH

   562         AC_PATH_PROGS(CHECK_TOOLSDIR_GMAKE, gmake)

   563         BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_GMAKE", [gmake in tools-dir])

   564         if test "x$FOUND_MAKE" = x; then

   565           AC_PATH_PROGS(CHECK_TOOLSDIR_MAKE, make)

   566           BASIC_CHECK_MAKE_VERSION("$CHECK_TOOLSDIR_MAKE", [make in tools-dir])

   567         fi

   568         PATH=$OLD_PATH

   569       fi

   570     fi

   572     if test "x$FOUND_MAKE" = x; then

   573       AC_MSG_ERROR([Cannot find GNU make 3.81 or newer! Please put it in the path, or add e.g. MAKE=/opt/gmake3.81/make as argument to configure.])

   574     fi

   575   fi

   577   MAKE=$FOUND_MAKE

   578   AC_SUBST(MAKE)

   579   AC_MSG_NOTICE([Using GNU make 3.81 (or later) at $FOUND_MAKE (version: $MAKE_VERSION_STRING)])

   580 ])

   582 AC_DEFUN([BASIC_CHECK_FIND_DELETE],

   583 [

   584   # Test if find supports -delete

   585   AC_MSG_CHECKING([if find supports -delete])

   586   FIND_DELETE="-delete"

   588   DELETEDIR=`$MKTEMP -d tmp.XXXXXXXXXX` || (echo Could not create temporary directory!; exit $?)

   590   echo Hejsan > $DELETEDIR/TestIfFindSupportsDelete

   592   TEST_DELETE=`$FIND "$DELETEDIR" -name TestIfFindSupportsDelete $FIND_DELETE 2>&1`

   593   if test -f $DELETEDIR/TestIfFindSupportsDelete; then

   594     # No, it does not.

   595     rm $DELETEDIR/TestIfFindSupportsDelete

   596     FIND_DELETE="-exec rm \{\} \+"

   597     AC_MSG_RESULT([no])

   598   else

   599     AC_MSG_RESULT([yes])

   600   fi

   601   rmdir $DELETEDIR

   602   AC_SUBST(FIND_DELETE)

   603 ])

   605 AC_DEFUN_ONCE([BASIC_SETUP_COMPLEX_TOOLS],

   606 [

   607   BASIC_CHECK_GNU_MAKE

   609   BASIC_CHECK_FIND_DELETE

   611   # These tools might not be installed by default,

   612   # need hint on how to install them.

   613   BASIC_REQUIRE_PROG(UNZIP, unzip)

   614   BASIC_REQUIRE_PROG(ZIP, zip)

   616   # Non-required basic tools

   618   AC_PATH_PROG(LDD, ldd)

   619   if test "x$LDD" = "x"; then

   620     # List shared lib dependencies is used for

   621     # debug output and checking for forbidden dependencies.

   622     # We can build without it.

   623     LDD="true"

   624   fi

   625   AC_PATH_PROG(OTOOL, otool)

   626   if test "x$OTOOL" = "x"; then

   627     OTOOL="true"

   628   fi

   629   AC_PATH_PROGS(READELF, [readelf greadelf])

   630   AC_PATH_PROG(HG, hg)

   631   AC_PATH_PROG(STAT, stat)

   632   AC_PATH_PROG(TIME, time)

   633   # Check if it's GNU time

   634   IS_GNU_TIME=`$TIME --version 2>&1 | $GREP 'GNU time'`

   635   if test "x$IS_GNU_TIME" != x; then

   636     IS_GNU_TIME=yes

   637   else

   638     IS_GNU_TIME=no

   639   fi

   640   AC_SUBST(IS_GNU_TIME)

   642   if test "x$OPENJDK_TARGET_OS" = "xwindows"; then

   643     BASIC_REQUIRE_PROG(COMM, comm)

   644   fi

   646   if test "x$OPENJDK_TARGET_OS" = "xmacosx"; then

   647     BASIC_REQUIRE_PROG(XATTR, xattr)

   648     AC_PATH_PROG(CODESIGN, codesign)

   649     if test "x$CODESIGN" != "x"; then

   650       # Verify that the openjdk_codesign certificate is present

   651       AC_MSG_CHECKING([if openjdk_codesign certificate is present])

   652       rm -f codesign-testfile

   653       touch codesign-testfile

   654       codesign -s openjdk_codesign codesign-testfile 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD || CODESIGN=

   655       rm -f codesign-testfile

   656       if test "x$CODESIGN" = x; then

   657         AC_MSG_RESULT([no])

   658       else

   659         AC_MSG_RESULT([yes])

   660       fi

   661     fi

   662   fi

   663 ])

   665 # Check if build directory is on local disk. If not possible to determine,

   666 # we prefer to claim it's local.

   667 # Argument 1: directory to test

   668 # Argument 2: what to do if it is on local disk

   669 # Argument 3: what to do otherwise (remote disk or failure)

   670 AC_DEFUN([BASIC_CHECK_DIR_ON_LOCAL_DISK],

   671 [

   672   # df -l lists only local disks; if the given directory is not found then

   673   # a non-zero exit code is given

   674   if test "x$DF" = x; then

   675     if test "x$OPENJDK_BUILD_OS_ENV" = "xwindows.msys"; then

   676       # msys does not have df; use Windows "net use" instead.

   677       IS_NETWORK_DISK=`net use | grep \`pwd -W | cut -d ":" -f 1 | tr a-z A-Z\`:`

   678       if test "x$IS_NETWORK_DISK" = x; then

   679         $2

   680       else

   681         $3

   682       fi

   683     else

   684       # No df here, say it's local

   685       $2

   686     fi

   687   else

   688     if $DF -l $1 > /dev/null 2>&1; then

   689       $2

   690     else

   691       $3

   692     fi

   693   fi

   694 ])

   696 # Check that source files have basic read permissions set. This might

   697 # not be the case in cygwin in certain conditions.

   698 AC_DEFUN_ONCE([BASIC_CHECK_SRC_PERMS],

   699 [

   700   if test x"$OPENJDK_BUILD_OS" = xwindows; then

   701     file_to_test="$SRC_ROOT/LICENSE"

   702     if test `$STAT -c '%a' "$file_to_test"` -lt 400; then

   703       AC_MSG_ERROR([Bad file permissions on src files. This is usually caused by cloning the repositories with a non cygwin hg in a directory not created in cygwin.])

   704     fi

   705   fi

   706 ])

   708 AC_DEFUN_ONCE([BASIC_TEST_USABILITY_ISSUES],

   709 [

   710   AC_MSG_CHECKING([if build directory is on local disk])

   711   BASIC_CHECK_DIR_ON_LOCAL_DISK($OUTPUT_ROOT,

   712       [OUTPUT_DIR_IS_LOCAL="yes"],

   713       [OUTPUT_DIR_IS_LOCAL="no"])

   714   AC_MSG_RESULT($OUTPUT_DIR_IS_LOCAL)

   716   BASIC_CHECK_SRC_PERMS

   718   # Check if the user has any old-style ALT_ variables set.

   719   FOUND_ALT_VARIABLES=`env | grep ^ALT_`

   721   # Before generating output files, test if they exist. If they do, this is a reconfigure.

   722   # Since we can't properly handle the dependencies for this, warn the user about the situation

   723   if test -e $OUTPUT_ROOT/spec.gmk; then

   724     IS_RECONFIGURE=yes

   725   else

   726     IS_RECONFIGURE=no

   727   fi

   729   if test -e $SRC_ROOT/build/.hide-configure-performance-hints; then

   730     HIDE_PERFORMANCE_HINTS=yes

   731   else

   732     HIDE_PERFORMANCE_HINTS=no

   733     # Hide it the next time around...

   734     $TOUCH $SRC_ROOT/build/.hide-configure-performance-hints > /dev/null 2>&1

   735   fi

   736 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/basics.m4@1a853fac18ff

common/autoconf/basics.m4