jdk8-mips64-public: common/autoconf/build-performance.m4@0e87966d7ff1

8031759: Improved tool overriding in configure
Reviewed-by: ihse, tbell, mduigou, erikj

1 #

     2 # Copyright (c) 2011, 2012, Oracle and/or its affiliates. All rights reserved.

     3 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER.

4 #

     5 # This code is free software; you can redistribute it and/or modify it

     6 # under the terms of the GNU General Public License version 2 only, as

     7 # published by the Free Software Foundation.  Oracle designates this

     8 # particular file as subject to the "Classpath" exception as provided

     9 # by Oracle in the LICENSE file that accompanied this code.

    10 #

    11 # This code is distributed in the hope that it will be useful, but WITHOUT

    12 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or

    13 # FITNESS FOR A PARTICULAR PURPOSE.  See the GNU General Public License

    14 # version 2 for more details (a copy is included in the LICENSE file that

    15 # accompanied this code).

    16 #

    17 # You should have received a copy of the GNU General Public License version

    18 # 2 along with this work; if not, write to the Free Software Foundation,

    19 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA.

    20 #

    21 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA

    22 # or visit www.oracle.com if you need additional information or have any

    23 # questions.

    24 #

    26 AC_DEFUN([BPERF_CHECK_CORES],

    27 [

    28   AC_MSG_CHECKING([for number of cores])

    29   NUM_CORES=1

    30   FOUND_CORES=no

    32   if test -f /proc/cpuinfo; then

    33     # Looks like a Linux (or cygwin) system

    34     NUM_CORES=`cat /proc/cpuinfo  | grep -c processor`

    35     FOUND_CORES=yes

    36   elif test -x /usr/sbin/psrinfo; then

    37     # Looks like a Solaris system

    38     NUM_CORES=`LC_MESSAGES=C /usr/sbin/psrinfo -v | grep -c on-line`

    39     FOUND_CORES=yes

    40   elif test -x /usr/sbin/system_profiler; then

    41     # Looks like a MacOSX system

    42     NUM_CORES=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Cores' | awk  '{print [$]5}'`

    43     FOUND_CORES=yes

    44   elif test "x$OPENJDK_BUILD_OS" = xaix ; then

    45     NUM_CORES=`/usr/sbin/prtconf | grep "^Number Of Processors" | awk '{ print [$]4 }'`

    46     FOUND_CORES=yes

    47   elif test -n "$NUMBER_OF_PROCESSORS"; then

    48     # On windows, look in the env

    49     NUM_CORES=$NUMBER_OF_PROCESSORS

    50     FOUND_CORES=yes

    51   fi

    53   if test "x$FOUND_CORES" = xyes; then

    54     AC_MSG_RESULT([$NUM_CORES])

    55   else

    56     AC_MSG_RESULT([could not detect number of cores, defaulting to 1])

    57     AC_MSG_WARN([This will disable all parallelism from build!])

    58   fi

    59 ])

    61 AC_DEFUN([BPERF_CHECK_MEMORY_SIZE],

    62 [

    63   AC_MSG_CHECKING([for memory size])

    64   # Default to 1024 MB

    65   MEMORY_SIZE=1024

    66   FOUND_MEM=no

    68   if test -f /proc/meminfo; then

    69     # Looks like a Linux (or cygwin) system

    70     MEMORY_SIZE=`cat /proc/meminfo | grep MemTotal | awk '{print [$]2}'`

    71     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024`

    72     FOUND_MEM=yes

    73   elif test -x /usr/sbin/prtconf; then

    74     # Looks like a Solaris or AIX system

    75     MEMORY_SIZE=`/usr/sbin/prtconf | grep "^Memory [[Ss]]ize" | awk '{ print [$]3 }'`

    76     FOUND_MEM=yes

    77   elif test -x /usr/sbin/system_profiler; then

    78     # Looks like a MacOSX system

    79     MEMORY_SIZE=`/usr/sbin/system_profiler -detailLevel full SPHardwareDataType | grep 'Memory' | awk  '{print [$]2}'`

    80     MEMORY_SIZE=`expr $MEMORY_SIZE \* 1024`

    81     FOUND_MEM=yes

    82   elif test "x$OPENJDK_BUILD_OS" = xwindows; then

    83     # Windows, but without cygwin

    84     MEMORY_SIZE=`wmic computersystem get totalphysicalmemory -value | grep = | cut -d "=" -f 2-`

    85     MEMORY_SIZE=`expr $MEMORY_SIZE / 1024 / 1024`

    86     FOUND_MEM=yes

    87   fi

    89   if test "x$FOUND_MEM" = xyes; then

    90     AC_MSG_RESULT([$MEMORY_SIZE MB])

    91   else

    92     AC_MSG_RESULT([could not detect memory size, defaulting to 1024 MB])

    93     AC_MSG_WARN([This might seriously impact build performance!])

    94   fi

    95 ])

    97 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_CORES],

    98 [

    99   # How many cores do we have on this build system?

   100   AC_ARG_WITH(num-cores, [AS_HELP_STRING([--with-num-cores],

   101       [number of cores in the build system, e.g. --with-num-cores=8 @<:@probed@:>@])])

   102   if test "x$with_num_cores" = x; then

   103     # The number of cores were not specified, try to probe them.

   104     BPERF_CHECK_CORES

   105   else

   106     NUM_CORES=$with_num_cores

   107   fi

   108   AC_SUBST(NUM_CORES)

   109 ])

   111 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_MEMORY],

   112 [

   113   # How much memory do we have on this build system?

   114   AC_ARG_WITH(memory-size, [AS_HELP_STRING([--with-memory-size],

   115       [memory (in MB) available in the build system, e.g. --with-memory-size=1024 @<:@probed@:>@])])

   116   if test "x$with_memory_size" = x; then

   117     # The memory size was not specified, try to probe it.

   118     BPERF_CHECK_MEMORY_SIZE

   119   else

   120     MEMORY_SIZE=$with_memory_size

   121   fi

   122   AC_SUBST(MEMORY_SIZE)

   123 ])

   125 AC_DEFUN_ONCE([BPERF_SETUP_BUILD_JOBS],

   126 [

   127   # Provide a decent default number of parallel jobs for make depending on

   128   # number of cores, amount of memory and machine architecture.

   129   AC_ARG_WITH(jobs, [AS_HELP_STRING([--with-jobs],

   130       [number of parallel jobs to let make run @<:@calculated based on cores and memory@:>@])])

   131   if test "x$with_jobs" = x; then

   132     # Number of jobs was not specified, calculate.

   133     AC_MSG_CHECKING([for appropriate number of jobs to run in parallel])

   134     # Approximate memory in GB, rounding up a bit.

   135     memory_gb=`expr $MEMORY_SIZE / 1100`

   136     # Pick the lowest of memory in gb and number of cores.

   137     if test "$memory_gb" -lt "$NUM_CORES"; then

   138       JOBS="$memory_gb"

   139     else

   140       JOBS="$NUM_CORES"

   141       # On bigger machines, leave some room for other processes to run

   142       if test "$JOBS" -gt "4"; then

   143         JOBS=`expr $JOBS '*' 90 / 100`

   144       fi

   145     fi

   146     # Cap number of jobs to 16

   147     if test "$JOBS" -gt "16"; then

   148       JOBS=16

   149     fi

   150     if test "$JOBS" -eq "0"; then

   151       JOBS=1

   152     fi

   153     AC_MSG_RESULT([$JOBS])

   154   else

   155     JOBS=$with_jobs

   156   fi

   157   AC_SUBST(JOBS)

   158 ])

   160 AC_DEFUN([BPERF_SETUP_CCACHE],

   161 [

   162   AC_ARG_ENABLE([ccache],

   163       [AS_HELP_STRING([--enable-ccache],

   164       [enable using ccache to speed up recompilations @<:@disabled@:>@])])

   166   CCACHE=

   167   AC_MSG_CHECKING([is ccache enabled])

   168   ENABLE_CCACHE=$enable_ccache

   169   if test "x$enable_ccache" = xyes; then

   170     AC_MSG_RESULT([yes])

   171     OLD_PATH="$PATH"

   172     if test "x$TOOLS_DIR" != x; then

   173       PATH=$TOOLS_DIR:$PATH

   174     fi

   175     BASIC_REQUIRE_PROGS(CCACHE, ccache)

   176     CCACHE_STATUS="enabled"

   177     PATH="$OLD_PATH"

   178   elif test "x$enable_ccache" = xno; then

   179     AC_MSG_RESULT([no, explicitly disabled])

   180   elif test "x$enable_ccache" = x; then

   181     AC_MSG_RESULT([no])

   182   else

   183     AC_MSG_RESULT([unknown])

   184     AC_MSG_ERROR([--enable-ccache does not accept any parameters])

   185   fi

   186   AC_SUBST(CCACHE)

   188   AC_ARG_WITH([ccache-dir],

   189       [AS_HELP_STRING([--with-ccache-dir],

   190       [where to store ccache files @<:@~/.ccache@:>@])])

   192   if test "x$with_ccache_dir" != x; then

   193     # When using a non home ccache directory, assume the use is to share ccache files

   194     # with other users. Thus change the umask.

   195     SET_CCACHE_DIR="CCACHE_DIR=$with_ccache_dir CCACHE_UMASK=002"

   196     if test "x$CCACHE" = x; then

   197       AC_MSG_WARN([--with-ccache-dir has no meaning when ccache is not enabled])

   198     fi

   199   fi

   201   if test "x$CCACHE" != x; then

   202     BPERF_SETUP_CCACHE_USAGE

   203   fi

   204 ])

   206 AC_DEFUN([BPERF_SETUP_CCACHE_USAGE],

   207 [

   208   if test "x$CCACHE" != x; then

   209     # Only use ccache if it is 3.1.4 or later, which supports

   210     # precompiled headers.

   211     AC_MSG_CHECKING([if ccache supports precompiled headers])

   212     HAS_GOOD_CCACHE=`($CCACHE --version | head -n 1 | grep -E 3.1.@<:@456789@:>@) 2> /dev/null`

   213     if test "x$HAS_GOOD_CCACHE" = x; then

   214       AC_MSG_RESULT([no, disabling ccache])

   215       CCACHE=

   216       CCACHE_STATUS="disabled"

   217     else

   218       AC_MSG_RESULT([yes])

   219       AC_MSG_CHECKING([if C-compiler supports ccache precompiled headers])

   220       PUSHED_FLAGS="$CXXFLAGS"

   221       CXXFLAGS="-fpch-preprocess $CXXFLAGS"

   222       AC_COMPILE_IFELSE([AC_LANG_PROGRAM([], [])], [CC_KNOWS_CCACHE_TRICK=yes], [CC_KNOWS_CCACHE_TRICK=no])

   223       CXXFLAGS="$PUSHED_FLAGS"

   224       if test "x$CC_KNOWS_CCACHE_TRICK" = xyes; then

   225         AC_MSG_RESULT([yes])

   226       else

   227         AC_MSG_RESULT([no, disabling ccaching of precompiled headers])

   228         CCACHE=

   229         CCACHE_STATUS="disabled"

   230       fi

   231     fi

   232   fi

   234   if test "x$CCACHE" != x; then

   235     CCACHE_SLOPPINESS=time_macros

   236     CCACHE="CCACHE_COMPRESS=1 $SET_CCACHE_DIR CCACHE_SLOPPINESS=$CCACHE_SLOPPINESS $CCACHE"

   237     CCACHE_FLAGS=-fpch-preprocess

   239     if test "x$SET_CCACHE_DIR" != x; then

   240       mkdir -p $CCACHE_DIR > /dev/null 2>&1

   241       chmod a+rwxs $CCACHE_DIR > /dev/null 2>&1

   242     fi

   243   fi

   244 ])

   246 AC_DEFUN_ONCE([BPERF_SETUP_PRECOMPILED_HEADERS],

   247 [

   249   ###############################################################################

   250   #

   251   # Can the C/C++ compiler use precompiled headers?

   252   #

   253   AC_ARG_ENABLE([precompiled-headers], [AS_HELP_STRING([--disable-precompiled-headers],

   254       [disable using precompiled headers when compiling C++ @<:@enabled@:>@])],

   255       [ENABLE_PRECOMPH=${enable_precompiled_headers}], [ENABLE_PRECOMPH=yes])

   257   USE_PRECOMPILED_HEADER=1

   258   if test "x$ENABLE_PRECOMPH" = xno; then

   259     USE_PRECOMPILED_HEADER=0

   260   fi

   262   if test "x$ENABLE_PRECOMPH" = xyes; then

   263     # Check that the compiler actually supports precomp headers.

   264     if test "x$GCC" = xyes; then

   265       AC_MSG_CHECKING([that precompiled headers work])

   266       echo "int alfa();" > conftest.h

   267       $CXX -x c++-header conftest.h -o conftest.hpp.gch 2>&AS_MESSAGE_LOG_FD >&AS_MESSAGE_LOG_FD

   268       if test ! -f conftest.hpp.gch; then

   269         USE_PRECOMPILED_HEADER=0

   270         AC_MSG_RESULT([no])

   271       else

   272         AC_MSG_RESULT([yes])

   273       fi

   274       rm -f conftest.h conftest.hpp.gch

   275     fi

   276   fi

   278   AC_SUBST(USE_PRECOMPILED_HEADER)

   279 ])

   282 AC_DEFUN_ONCE([BPERF_SETUP_SMART_JAVAC],

   283 [

   284   AC_ARG_WITH(sjavac-server-java, [AS_HELP_STRING([--with-sjavac-server-java],

   285       [use this java binary for running the sjavac background server @<:@Boot JDK java@:>@])])

   287   if test "x$with_sjavac_server_java" != x; then

   288     SJAVAC_SERVER_JAVA="$with_sjavac_server_java"

   289     FOUND_VERSION=`$SJAVAC_SERVER_JAVA -version 2>&1 | grep " version \""`

   290     if test "x$FOUND_VERSION" = x; then

   291       AC_MSG_ERROR([Could not execute server java: $SJAVAC_SERVER_JAVA])

   292     fi

   293   else

   294     SJAVAC_SERVER_JAVA=""

   295     # Hotspot specific options.

   296     ADD_JVM_ARG_IF_OK([-verbosegc],SJAVAC_SERVER_JAVA,[$JAVA])

   297     # JRockit specific options.

   298     ADD_JVM_ARG_IF_OK([-Xverbose:gc],SJAVAC_SERVER_JAVA,[$JAVA])

   299     SJAVAC_SERVER_JAVA="$JAVA $SJAVAC_SERVER_JAVA"

   300   fi

   301   AC_SUBST(SJAVAC_SERVER_JAVA)

   303   if test "$MEMORY_SIZE" -gt "2500"; then

   304     ADD_JVM_ARG_IF_OK([-d64],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   305     if test "$JVM_ARG_OK" = true; then

   306       JVM_64BIT=true

   307       JVM_ARG_OK=false

   308     fi

   309   fi

   311   if test "$JVM_64BIT" = true; then

   312     if test "$MEMORY_SIZE" -gt "17000"; then

   313       ADD_JVM_ARG_IF_OK([-Xms10G -Xmx10G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   314     fi

   315     if test "$MEMORY_SIZE" -gt "10000" && test "$JVM_ARG_OK" = false; then

   316       ADD_JVM_ARG_IF_OK([-Xms6G -Xmx6G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   317     fi

   318     if test "$MEMORY_SIZE" -gt "5000" && test "$JVM_ARG_OK" = false; then

   319       ADD_JVM_ARG_IF_OK([-Xms1G -Xmx3G],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   320     fi

   321     if test "$MEMORY_SIZE" -gt "3800" && test "$JVM_ARG_OK" = false; then

   322       ADD_JVM_ARG_IF_OK([-Xms1G -Xmx2500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   323     fi

   324   fi

   325   if test "$MEMORY_SIZE" -gt "2500" && test "$JVM_ARG_OK" = false; then

   326     ADD_JVM_ARG_IF_OK([-Xms1000M -Xmx1500M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   327   fi

   328   if test "$MEMORY_SIZE" -gt "1000" && test "$JVM_ARG_OK" = false; then

   329     ADD_JVM_ARG_IF_OK([-Xms400M -Xmx1100M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   330   fi

   331   if test "$JVM_ARG_OK" = false; then

   332     ADD_JVM_ARG_IF_OK([-Xms256M -Xmx512M],SJAVAC_SERVER_JAVA,[$SJAVAC_SERVER_JAVA])

   333   fi

   335   AC_MSG_CHECKING([whether to use sjavac])

   336   AC_ARG_ENABLE([sjavac], [AS_HELP_STRING([--enable-sjavac],

   337       [use sjavac to do fast incremental compiles @<:@disabled@:>@])],

   338       [ENABLE_SJAVAC="${enableval}"], [ENABLE_SJAVAC='no'])

   339   AC_MSG_RESULT([$ENABLE_SJAVAC])

   340   AC_SUBST(ENABLE_SJAVAC)

   342   if test "x$ENABLE_SJAVAC" = xyes; then

   343     SJAVAC_SERVER_DIR="$OUTPUT_ROOT/javacservers"

   344   else

   345     SJAVAC_SERVER_DIR=

   346   fi

   347   AC_SUBST(SJAVAC_SERVER_DIR)

   348 ])

Mercurial > jdk8-mips64-public / file revision

common/autoconf/build-performance.m4@0e87966d7ff1

common/autoconf/build-performance.m4