1.1 --- /dev/null Thu Jan 01 00:00:00 1970 +0000
1.2 +++ b/common/autoconf/build-aux/pkg.m4 Tue Apr 10 08:18:28 2012 -0700
1.3 @@ -0,0 +1,155 @@
1.4 +# pkg.m4 - Macros to locate and utilise pkg-config. -*- Autoconf -*-
1.5 +#
1.6 +# Copyright © 2004 Scott James Remnant <scott@netsplit.com>.
1.7 +#
1.8 +# This program is free software; you can redistribute it and/or modify
1.9 +# it under the terms of the GNU General Public License as published by
1.10 +# the Free Software Foundation; either version 2 of the License, or
1.11 +# (at your option) any later version.
1.12 +#
1.13 +# This program is distributed in the hope that it will be useful, but
1.14 +# WITHOUT ANY WARRANTY; without even the implied warranty of
1.15 +# MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU
1.16 +# General Public License for more details.
1.17 +#
1.18 +# You should have received a copy of the GNU General Public License
1.19 +# along with this program; if not, write to the Free Software
1.20 +# Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA.
1.21 +#
1.22 +# As a special exception to the GNU General Public License, if you
1.23 +# distribute this file as part of a program that contains a
1.24 +# configuration script generated by Autoconf, you may include it under
1.25 +# the same distribution terms that you use for the rest of that program.
1.26 +
1.27 +# PKG_PROG_PKG_CONFIG([MIN-VERSION])
1.28 +# ----------------------------------
1.29 +AC_DEFUN([PKG_PROG_PKG_CONFIG],
1.30 +[m4_pattern_forbid([^_?PKG_[A-Z_]+$])
1.31 +m4_pattern_allow([^PKG_CONFIG(_PATH)?$])
1.32 +AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])dnl
1.33 +if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then
1.34 + AC_PATH_TOOL([PKG_CONFIG], [pkg-config])
1.35 +fi
1.36 +if test -n "$PKG_CONFIG"; then
1.37 + _pkg_min_version=m4_default([$1], [0.9.0])
1.38 + AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version])
1.39 + if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then
1.40 + AC_MSG_RESULT([yes])
1.41 + else
1.42 + AC_MSG_RESULT([no])
1.43 + PKG_CONFIG=""
1.44 + fi
1.45 +
1.46 +fi[]dnl
1.47 +])# PKG_PROG_PKG_CONFIG
1.48 +
1.49 +# PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND])
1.50 +#
1.51 +# Check to see whether a particular set of modules exists. Similar
1.52 +# to PKG_CHECK_MODULES(), but does not set variables or print errors.
1.53 +#
1.54 +#
1.55 +# Similar to PKG_CHECK_MODULES, make sure that the first instance of
1.56 +# this or PKG_CHECK_MODULES is called, or make sure to call
1.57 +# PKG_CHECK_EXISTS manually
1.58 +# --------------------------------------------------------------
1.59 +AC_DEFUN([PKG_CHECK_EXISTS],
1.60 +[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
1.61 +if test -n "$PKG_CONFIG" && \
1.62 + AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then
1.63 + m4_ifval([$2], [$2], [:])
1.64 +m4_ifvaln([$3], [else
1.65 + $3])dnl
1.66 +fi])
1.67 +
1.68 +
1.69 +# _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES])
1.70 +# ---------------------------------------------
1.71 +m4_define([_PKG_CONFIG],
1.72 +[if test -n "$$1"; then
1.73 + pkg_cv_[]$1="$$1"
1.74 + elif test -n "$PKG_CONFIG"; then
1.75 + PKG_CHECK_EXISTS([$3],
1.76 + [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`],
1.77 + [pkg_failed=yes])
1.78 + else
1.79 + pkg_failed=untried
1.80 +fi[]dnl
1.81 +])# _PKG_CONFIG
1.82 +
1.83 +# _PKG_SHORT_ERRORS_SUPPORTED
1.84 +# -----------------------------
1.85 +AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED],
1.86 +[AC_REQUIRE([PKG_PROG_PKG_CONFIG])
1.87 +if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then
1.88 + _pkg_short_errors_supported=yes
1.89 +else
1.90 + _pkg_short_errors_supported=no
1.91 +fi[]dnl
1.92 +])# _PKG_SHORT_ERRORS_SUPPORTED
1.93 +
1.94 +
1.95 +# PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND],
1.96 +# [ACTION-IF-NOT-FOUND])
1.97 +#
1.98 +#
1.99 +# Note that if there is a possibility the first call to
1.100 +# PKG_CHECK_MODULES might not happen, you should be sure to include an
1.101 +# explicit call to PKG_PROG_PKG_CONFIG in your configure.ac
1.102 +#
1.103 +#
1.104 +# --------------------------------------------------------------
1.105 +AC_DEFUN([PKG_CHECK_MODULES],
1.106 +[AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl
1.107 +AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl
1.108 +AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl
1.109 +
1.110 +pkg_failed=no
1.111 +AC_MSG_CHECKING([for $1])
1.112 +
1.113 +_PKG_CONFIG([$1][_CFLAGS], [cflags], [$2])
1.114 +_PKG_CONFIG([$1][_LIBS], [libs], [$2])
1.115 +
1.116 +m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS
1.117 +and $1[]_LIBS to avoid the need to call pkg-config.
1.118 +See the pkg-config man page for more details.])
1.119 +
1.120 +if test $pkg_failed = yes; then
1.121 + _PKG_SHORT_ERRORS_SUPPORTED
1.122 + if test $_pkg_short_errors_supported = yes; then
1.123 + $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --print-errors "$2" 2>&1`
1.124 + else
1.125 + $1[]_PKG_ERRORS=`$PKG_CONFIG --print-errors "$2" 2>&1`
1.126 + fi
1.127 + # Put the nasty error message in config.log where it belongs
1.128 + echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD
1.129 +
1.130 + ifelse([$4], , [AC_MSG_ERROR(dnl
1.131 +[Package requirements ($2) were not met:
1.132 +
1.133 +$$1_PKG_ERRORS
1.134 +
1.135 +Consider adjusting the PKG_CONFIG_PATH environment variable if you
1.136 +installed software in a non-standard prefix.
1.137 +
1.138 +_PKG_TEXT
1.139 +])],
1.140 + [AC_MSG_RESULT([no])
1.141 + $4])
1.142 +elif test $pkg_failed = untried; then
1.143 + ifelse([$4], , [AC_MSG_FAILURE(dnl
1.144 +[The pkg-config script could not be found or is too old. Make sure it
1.145 +is in your PATH or set the PKG_CONFIG environment variable to the full
1.146 +path to pkg-config.
1.147 +
1.148 +_PKG_TEXT
1.149 +
1.150 +To get pkg-config, see <http://pkg-config.freedesktop.org/>.])],
1.151 + [$4])
1.152 +else
1.153 + $1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS
1.154 + $1[]_LIBS=$pkg_cv_[]$1[]_LIBS
1.155 + AC_MSG_RESULT([yes])
1.156 + ifelse([$3], , :, [$3])
1.157 +fi[]dnl
1.158 +])# PKG_CHECK_MODULES
