Mercurial > jdk8-mips64-public / file comparison
comparison: common/autoconf/build-aux/pkg.m4
common/autoconf/build-aux/pkg.m4
- changeset 0
- 75a576e87639
- child 1133
- 50aaf272884f
equal
deleted
inserted
replaced
| -1:000000000000 | 0:75a576e87639 |
|---|---|
| 1 # pkg.m4 - Macros to locate and utilise pkg-config. -*- Autoconf -*- | |
| 2 | |
| 3 # | |
| 4 # Copyright (c) 2012, 2013, Oracle and/or its affiliates. All rights reserved. | |
| 5 # DO NOT ALTER OR REMOVE COPYRIGHT NOTICES OR THIS FILE HEADER. | |
| 6 # | |
| 7 # This code is free software; you can redistribute it and/or modify it | |
| 8 # under the terms of the GNU General Public License version 2 only, as | |
| 9 # published by the Free Software Foundation. Oracle designates this | |
| 10 # particular file as subject to the "Classpath" exception as provided | |
| 11 # by Oracle in the LICENSE file that accompanied this code. | |
| 12 # | |
| 13 # This code is distributed in the hope that it will be useful, but WITHOUT | |
| 14 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or | |
| 15 # FITNESS FOR A PARTICULAR PURPOSE. See the GNU General Public License | |
| 16 # version 2 for more details (a copy is included in the LICENSE file that | |
| 17 # accompanied this code). | |
| 18 # | |
| 19 # You should have received a copy of the GNU General Public License version | |
| 20 # 2 along with this work; if not, write to the Free Software Foundation, | |
| 21 # Inc., 51 Franklin St, Fifth Floor, Boston, MA 02110-1301 USA. | |
| 22 # | |
| 23 # Please contact Oracle, 500 Oracle Parkway, Redwood Shores, CA 94065 USA | |
| 24 # or visit www.oracle.com if you need additional information or have any | |
| 25 # questions. | |
| 26 # | |
| 27 | |
| 28 # | |
| 29 # Copyright © 2004 Scott James Remnant <scott@netsplit.com>. | |
| 30 # | |
| 31 # This program is free software; you can redistribute it and/or modify | |
| 32 # it under the terms of the GNU General Public License as published by | |
| 33 # the Free Software Foundation; either version 2 of the License, or | |
| 34 # (at your option) any later version. | |
| 35 # | |
| 36 # This program is distributed in the hope that it will be useful, but | |
| 37 # WITHOUT ANY WARRANTY; without even the implied warranty of | |
| 38 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the GNU | |
| 39 # General Public License for more details. | |
| 40 # | |
| 41 # You should have received a copy of the GNU General Public License | |
| 42 # along with this program; if not, write to the Free Software | |
| 43 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA. | |
| 44 # | |
| 45 # As a special exception to the GNU General Public License, if you | |
| 46 # distribute this file as part of a program that contains a | |
| 47 # configuration script generated by Autoconf, you may include it under | |
| 48 # the same distribution terms that you use for the rest of that program. | |
| 49 | |
| 50 # PKG_PROG_PKG_CONFIG([MIN-VERSION]) | |
| 51 # ---------------------------------- | |
| 52 AC_DEFUN([PKG_PROG_PKG_CONFIG], | |
| 53 [m4_pattern_forbid([^_?PKG_[A-Z_]+$]) | |
| 54 m4_pattern_allow([^PKG_CONFIG(_PATH)?$]) | |
| 55 AC_ARG_VAR([PKG_CONFIG], [path to pkg-config utility])dnl | |
| 56 if test "x$ac_cv_env_PKG_CONFIG_set" != "xset"; then | |
| 57 AC_PATH_TOOL([PKG_CONFIG], [pkg-config]) | |
| 58 fi | |
| 59 if test -n "$PKG_CONFIG"; then | |
| 60 _pkg_min_version=m4_default([$1], [0.9.0]) | |
| 61 AC_MSG_CHECKING([pkg-config is at least version $_pkg_min_version]) | |
| 62 if $PKG_CONFIG --atleast-pkgconfig-version $_pkg_min_version; then | |
| 63 AC_MSG_RESULT([yes]) | |
| 64 else | |
| 65 AC_MSG_RESULT([no]) | |
| 66 PKG_CONFIG="" | |
| 67 fi | |
| 68 | |
| 69 fi[]dnl | |
| 70 ])# PKG_PROG_PKG_CONFIG | |
| 71 | |
| 72 # PKG_CHECK_EXISTS(MODULES, [ACTION-IF-FOUND], [ACTION-IF-NOT-FOUND]) | |
| 73 # | |
| 74 # Check to see whether a particular set of modules exists. Similar | |
| 75 # to PKG_CHECK_MODULES(), but does not set variables or print errors. | |
| 76 # | |
| 77 # | |
| 78 # Similar to PKG_CHECK_MODULES, make sure that the first instance of | |
| 79 # this or PKG_CHECK_MODULES is called, or make sure to call | |
| 80 # PKG_CHECK_EXISTS manually | |
| 81 # -------------------------------------------------------------- | |
| 82 AC_DEFUN([PKG_CHECK_EXISTS], | |
| 83 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl | |
| 84 if test -n "$PKG_CONFIG" && \ | |
| 85 AC_RUN_LOG([$PKG_CONFIG --exists --print-errors "$1"]); then | |
| 86 m4_ifval([$2], [$2], [:]) | |
| 87 m4_ifvaln([$3], [else | |
| 88 $3])dnl | |
| 89 fi]) | |
| 90 | |
| 91 | |
| 92 # _PKG_CONFIG([VARIABLE], [COMMAND], [MODULES]) | |
| 93 # --------------------------------------------- | |
| 94 m4_define([_PKG_CONFIG], | |
| 95 [if test -n "$$1"; then | |
| 96 pkg_cv_[]$1="$$1" | |
| 97 elif test -n "$PKG_CONFIG"; then | |
| 98 PKG_CHECK_EXISTS([$3], | |
| 99 [pkg_cv_[]$1=`$PKG_CONFIG --[]$2 "$3" 2>/dev/null`], | |
| 100 [pkg_failed=yes]) | |
| 101 else | |
| 102 pkg_failed=untried | |
| 103 fi[]dnl | |
| 104 ])# _PKG_CONFIG | |
| 105 | |
| 106 # _PKG_SHORT_ERRORS_SUPPORTED | |
| 107 # ----------------------------- | |
| 108 AC_DEFUN([_PKG_SHORT_ERRORS_SUPPORTED], | |
| 109 [AC_REQUIRE([PKG_PROG_PKG_CONFIG]) | |
| 110 if $PKG_CONFIG --atleast-pkgconfig-version 0.20; then | |
| 111 _pkg_short_errors_supported=yes | |
| 112 else | |
| 113 _pkg_short_errors_supported=no | |
| 114 fi[]dnl | |
| 115 ])# _PKG_SHORT_ERRORS_SUPPORTED | |
| 116 | |
| 117 | |
| 118 # PKG_CHECK_MODULES(VARIABLE-PREFIX, MODULES, [ACTION-IF-FOUND], | |
| 119 # [ACTION-IF-NOT-FOUND]) | |
| 120 # | |
| 121 # | |
| 122 # Note that if there is a possibility the first call to | |
| 123 # PKG_CHECK_MODULES might not happen, you should be sure to include an | |
| 124 # explicit call to PKG_PROG_PKG_CONFIG in your configure.ac | |
| 125 # | |
| 126 # | |
| 127 # -------------------------------------------------------------- | |
| 128 AC_DEFUN([PKG_CHECK_MODULES], | |
| 129 [AC_REQUIRE([PKG_PROG_PKG_CONFIG])dnl | |
| 130 AC_ARG_VAR([$1][_CFLAGS], [C compiler flags for $1, overriding pkg-config])dnl | |
| 131 AC_ARG_VAR([$1][_LIBS], [linker flags for $1, overriding pkg-config])dnl | |
| 132 | |
| 133 pkg_failed=no | |
| 134 AC_MSG_CHECKING([for $1]) | |
| 135 | |
| 136 _PKG_CONFIG([$1][_CFLAGS], [cflags], [$2]) | |
| 137 _PKG_CONFIG([$1][_LIBS], [libs], [$2]) | |
| 138 | |
| 139 m4_define([_PKG_TEXT], [Alternatively, you may set the environment variables $1[]_CFLAGS | |
| 140 and $1[]_LIBS to avoid the need to call pkg-config. | |
| 141 See the pkg-config man page for more details.]) | |
| 142 | |
| 143 if test $pkg_failed = yes; then | |
| 144 _PKG_SHORT_ERRORS_SUPPORTED | |
| 145 if test $_pkg_short_errors_supported = yes; then | |
| 146 $1[]_PKG_ERRORS=`$PKG_CONFIG --short-errors --print-errors "$2" 2>&1` | |
| 147 else | |
| 148 $1[]_PKG_ERRORS=`$PKG_CONFIG --print-errors "$2" 2>&1` | |
| 149 fi | |
| 150 # Put the nasty error message in config.log where it belongs | |
| 151 echo "$$1[]_PKG_ERRORS" >&AS_MESSAGE_LOG_FD | |
| 152 | |
| 153 ifelse([$4], , [AC_MSG_ERROR(dnl | |
| 154 [Package requirements ($2) were not met: | |
| 155 | |
| 156 $$1_PKG_ERRORS | |
| 157 | |
| 158 Consider adjusting the PKG_CONFIG_PATH environment variable if you | |
| 159 installed software in a non-standard prefix. | |
| 160 | |
| 161 _PKG_TEXT | |
| 162 ])], | |
| 163 [AC_MSG_RESULT([no]) | |
| 164 $4]) | |
| 165 elif test $pkg_failed = untried; then | |
| 166 ifelse([$4], , [AC_MSG_FAILURE(dnl | |
| 167 [The pkg-config script could not be found or is too old. Make sure it | |
| 168 is in your PATH or set the PKG_CONFIG environment variable to the full | |
| 169 path to pkg-config. | |
| 170 | |
| 171 _PKG_TEXT | |
| 172 | |
| 173 To get pkg-config, see <http://pkg-config.freedesktop.org/>.])], | |
| 174 [$4]) | |
| 175 else | |
| 176 $1[]_CFLAGS=$pkg_cv_[]$1[]_CFLAGS | |
| 177 $1[]_LIBS=$pkg_cv_[]$1[]_LIBS | |
| 178 AC_MSG_RESULT([yes]) | |
| 179 ifelse([$3], , :, [$3]) | |
| 180 fi[]dnl | |
| 181 ])# PKG_CHECK_MODULES |
